src/data/sources/humble/Humble.vala

   1 using Gtk;
   2 using Gee;
   3 using GameHub.Utils;
   4
   5 namespace GameHub.Data.Sources.Humble
   6 {
   7         public class Humble: GameSource
   8         {
   9                 public const string AUTH_COOKIE = "_simpleauth_sess";
  10
  11                 public override string name { get { return "Humble Bundle"; } }
  12                 public override string icon { get { return "humble"; } }
  13
  14                 public string? user_token = null;
  15
  16                 private Settings.Auth.Humble settings;
  17
  18                 public Humble()
  19                 {
  20                         settings = Settings.Auth.Humble.get_instance();
  21                         var access_token = settings.access_token;
  22                         if(access_token.length > 0)
  23                         {
  24                                 user_token = access_token;
  25                         }
  26                 }
  27
  28                 public override bool is_installed(bool refresh)
  29                 {
  30                         return true;
  31                 }
  32
  33                 public override async bool install()
  34                 {
  35                         return true;
  36                 }
  37
  38                 public override async bool authenticate()
  39                 {
  40                         settings.authenticated = true;
  41
  42                         return yield get_token();
  43                 }
  44
  45                 public override bool is_authenticated()
  46                 {
  47                         return user_token != null;
  48                 }
  49
  50                 public override bool can_authenticate_automatically()
  51                 {
  52                         return user_token != null && settings.authenticated;
  53                 }
  54
  55                 private async bool get_token()
  56                 {
  57                         if(user_token != null)
  58                         {
  59                                 return true;
  60                         }
  61
  62                         var wnd = new GameHub.UI.Windows.WebAuthWindow(this.name, @"https://www.humblebundle.com/login?goto=home", null, AUTH_COOKIE);
  63
  64                         wnd.finished.connect(token =>
  65                         {
  66                                 user_token = token;
  67                                 settings.access_token = user_token ?? "";
  68                                 Idle.add(get_token.callback);
  69                         });
  70
  71                         wnd.canceled.connect(() => Idle.add(get_token.callback));
  72
  73                         wnd.show_all();
  74                         wnd.present();
  75
  76                         yield;
  77
  78                         return user_token != null;
  79                 }
  80
  81                 private ArrayList<Game> games = new ArrayList<Game>(Game.is_equal);
  82                 public override async ArrayList<Game> load_games(FutureResult<Game>? game_loaded = null)
  83                 {
  84                         if(user_token == null || games.size > 0)
  85                         {
  86                                 return games;
  87                         }
  88
  89                         games.clear();
  90
  91                         var cached = GamesDB.get_instance().get_games(this);
  92                         if(cached.size > 0)
  93                         {
  94                                 games = cached;
  95                                 if(game_loaded != null)
  96                                 {
  97                                         foreach(var g in cached)
  98                                         {
  99                                                 game_loaded(g);
 100                                         }
 101                                 }
 102                         }
 103                         games_count = games.size;
 104
 105                         var headers = new HashMap<string, string>();
 106                         headers["Cookie"] = @"$(AUTH_COOKIE)=\"$(user_token)\";";
 107
 108                         var orders = (yield Parser.parse_remote_json_file_async("https://www.humblebundle.com/api/v1/user/order?ajax=true", "GET", null, headers)).get_array();
 109
 110                         foreach(var order in orders.get_elements())
 111                         {
 112                                 var key = order.get_object().get_string_member("gamekey");
 113
 114                                 var root = (yield Parser.parse_remote_json_file_async(@"https://www.humblebundle.com/api/v1/order/$(key)?ajax=true", "GET", null, headers)).get_object();
 115                                 var products = root.get_array_member("subproducts");
 116
 117                                 foreach(var product in products.get_elements())
 118                                 {
 119                                         var game = new HumbleGame(this, key, product.get_object());
 120                                         if(!games.contains(game) && yield game.is_for_linux())
 121                                         {
 122                                                 games.add(game);
 123                                                 if(game_loaded != null) game_loaded(game);
 124                                                 GamesDB.get_instance().add_game(game);
 125                                         }
 126                                         games_count = games.size;
 127                                 }
 128                         }
 129
 130                         return games;
 131                 }
 132         }
 133 }