src/data/sources/gog/GOG.vala

   1 using Gtk;
   2 using Gee;
   3 using GameHub.Utils;
   4
   5 namespace GameHub.Data.Sources.GOG
   6 {
   7         public class GOG: GameSource
   8         {
   9                 private const string CLIENT_ID = "46899977096215655";
  10                 private const string CLIENT_SECRET = "9d85c43b1482497dbbce61f6e4aa173a433796eeae2ca8c5f6129f2dc4de46d9";
  11                 private const string REDIRECT = "https%3A%2F%2Fembed.gog.com%2Fon_login_success%3Forigin%3Dclient";
  12
  13                 public override string name { get { return "GOG"; } }
  14                 public override string icon { get { return "gog"; } }
  15
  16                 public string? user_id { get; protected set; }
  17                 public string? user_name { get; protected set; }
  18
  19                 private string? user_auth_code = null;
  20                 public string? user_token = null;
  21                 private string? user_refresh_token = null;
  22                 private bool token_needs_refresh = false;
  23
  24                 private Settings.Auth.GOG settings;
  25
  26                 public GOG()
  27                 {
  28                         settings = Settings.Auth.GOG.get_instance();
  29                         var access_token = settings.access_token;
  30                         var refresh_token = settings.refresh_token;
  31                         if(access_token.length > 0 && refresh_token.length > 0)
  32                         {
  33                                 user_token = access_token;
  34                                 user_refresh_token = refresh_token;
  35                                 token_needs_refresh = true;
  36                         }
  37                 }
  38
  39                 public override bool is_installed(bool refresh)
  40                 {
  41                         return true;
  42                 }
  43
  44                 public override async bool install()
  45                 {
  46                         return true;
  47                 }
  48
  49                 public override async bool authenticate()
  50                 {
  51                         settings.authenticated = true;
  52
  53                         if(token_needs_refresh && user_refresh_token != null)
  54                         {
  55                                 return (yield refresh_token());
  56                         }
  57
  58                         return (yield get_auth_code()) && (yield get_token());
  59                 }
  60
  61                 public override bool is_authenticated()
  62                 {
  63                         return !token_needs_refresh && user_token != null;
  64                 }
  65
  66                 public override bool can_authenticate_automatically()
  67                 {
  68                         return user_refresh_token != null && settings.authenticated;
  69                 }
  70
  71                 private async bool get_auth_code()
  72                 {
  73                         if(user_auth_code != null)
  74                         {
  75                                 return true;
  76                         }
  77
  78                         var wnd = new GameHub.UI.Windows.WebAuthWindow(this.name, @"https://auth.gog.com/auth?client_id=$(CLIENT_ID)&redirect_uri=$(REDIRECT)&response_type=code&layout=client2", "https://embed.gog.com/on_login_success?origin=client&code=");
  79
  80                         wnd.finished.connect(code =>
  81                         {
  82                                 user_auth_code = code;
  83                                 Idle.add(get_auth_code.callback);
  84                         });
  85
  86                         wnd.canceled.connect(() => Idle.add(get_auth_code.callback));
  87
  88                         wnd.set_size_request(550, 680);
  89                         wnd.show_all();
  90                         wnd.present();
  91
  92                         yield;
  93
  94                         return user_auth_code != null;
  95                 }
  96
  97                 private async bool get_token()
  98                 {
  99                         if(user_token != null)
 100                         {
 101                                 return true;
 102                         }
 103
 104                         var url = @"https://auth.gog.com/token?client_id=$(CLIENT_ID)&client_secret=$(CLIENT_SECRET)&grant_type=authorization_code&redirect_uri=$(REDIRECT)&code=$(user_auth_code)";
 105                         var root = (yield Parser.parse_remote_json_file_async(url)).get_object();
 106                         user_token = root.get_string_member("access_token");
 107                         user_refresh_token = root.get_string_member("refresh_token");
 108                         user_id = root.get_string_member("user_id");
 109
 110                         settings.access_token = user_token ?? "";
 111                         settings.refresh_token = user_refresh_token ?? "";
 112
 113                         return user_token != null;
 114                 }
 115
 116                 private async bool refresh_token()
 117                 {
 118                         if(user_refresh_token == null)
 119                         {
 120                                 return false;
 121                         }
 122
 123                         var url = @"https://auth.gog.com/token?client_id=$(CLIENT_ID)&client_secret=$(CLIENT_SECRET)&grant_type=refresh_token&refresh_token=$(user_refresh_token)";
 124                         var root = (yield Parser.parse_remote_json_file_async(url)).get_object();
 125                         user_token = root.get_string_member("access_token");
 126                         user_refresh_token = root.get_string_member("refresh_token");
 127                         user_id = root.get_string_member("user_id");
 128
 129                         settings.access_token = user_token ?? "";
 130                         settings.refresh_token = user_refresh_token ?? "";
 131
 132                         token_needs_refresh = false;
 133
 134                         return user_token != null;
 135                 }
 136
 137                 private ArrayList<Game> games = new ArrayList<Game>(Game.is_equal);
 138                 public override async ArrayList<Game> load_games(FutureResult<Game>? game_loaded = null)
 139                 {
 140                         if(user_id == null || user_token == null || games.size > 0)
 141                         {
 142                                 return games;
 143                         }
 144
 145                         games.clear();
 146
 147                         var cached = GamesDB.get_instance().get_games(this);
 148                         if(cached.size > 0)
 149                         {
 150                                 games = cached;
 151                                 if(game_loaded != null)
 152                                 {
 153                                         foreach(var g in cached)
 154                                         {
 155                                                 game_loaded(g);
 156                                         }
 157                                 }
 158                         }
 159                         games_count = games.size;
 160
 161                         var url = @"https://embed.gog.com/account/getFilteredProducts?mediaType=1";
 162                         var root = (yield Parser.parse_remote_json_file_async(url, "GET", user_token)).get_object();
 163
 164                         var products = root.get_array_member("products");
 165
 166                         foreach(var g in products.get_elements())
 167                         {
 168                                 var game = new GOGGame(this, g.get_object());
 169                                 if(!games.contains(game) && yield game.is_for_linux())
 170                                 {
 171                                         games.add(game);
 172                                         if(game_loaded != null) game_loaded(game);
 173                                         GamesDB.get_instance().add_game(game);
 174                                 }
 175                                 games_count = games.size;
 176                         }
 177
 178                         return games;
 179                 }
 180         }
 181 }