gpxsee.pro

   1 unix:!macx {
   2     TARGET = gpxsee
   3 } else {
   4     TARGET = GPXSee
   5 }
   6 VERSION = 7.3
   7
   8 QT += core \
   9     gui \
  10     network \
  11     sql \
  12     concurrent
  13 greaterThan(QT_MAJOR_VERSION, 4) {
  14     QT += widgets
  15     QT += printsupport
  16 }
  17 lessThan(QT_MAJOR_VERSION, 5) {QT += opengl}
  18 equals(QT_MAJOR_VERSION, 5) : lessThan(QT_MINOR_VERSION, 4) {QT += opengl}
  19
  20 INCLUDEPATH += ./src
  21 HEADERS += src/common/config.h \
  22     src/common/staticassert.h \
  23     src/common/coordinates.h \
  24     src/common/range.h \
  25     src/common/rectc.h \
  26     src/common/wgs84.h \
  27     src/common/util.h \
  28     src/common/rtree.h \
  29     src/common/kv.h \
  30     src/common/greatcircle.h \
  31     src/common/programpaths.h \
  32     src/GUI/app.h \
  33     src/GUI/icons.h \
  34     src/GUI/gui.h \
  35     src/GUI/axisitem.h \
  36     src/GUI/keys.h \
  37     src/GUI/slideritem.h \
  38     src/GUI/markeritem.h \
  39     src/GUI/infoitem.h \
  40     src/GUI/elevationgraph.h \
  41     src/GUI/speedgraph.h \
  42     src/GUI/sliderinfoitem.h \
  43     src/GUI/filebrowser.h \
  44     src/GUI/units.h \
  45     src/GUI/scaleitem.h \
  46     src/GUI/graphview.h \
  47     src/GUI/waypointitem.h \
  48     src/GUI/palette.h \
  49     src/GUI/heartrategraph.h \
  50     src/GUI/trackinfo.h \
  51     src/GUI/exportdialog.h \
  52     src/GUI/fileselectwidget.h \
  53     src/GUI/margins.h \
  54     src/GUI/temperaturegraph.h \
  55     src/GUI/graphtab.h \
  56     src/GUI/trackitem.h \
  57     src/GUI/tooltip.h \
  58     src/GUI/routeitem.h \
  59     src/GUI/graphitem.h \
  60     src/GUI/pathitem.h \
  61     src/GUI/griditem.h \
  62     src/GUI/format.h \
  63     src/GUI/cadencegraph.h \
  64     src/GUI/powergraph.h \
  65     src/GUI/gearratiograph.h \
  66     src/GUI/optionsdialog.h \
  67     src/GUI/colorbox.h \
  68     src/GUI/stylecombobox.h \
  69     src/GUI/opengl.h \
  70     src/GUI/timetype.h \
  71     src/GUI/percentslider.h \
  72     src/GUI/elevationgraphitem.h \
  73     src/GUI/speedgraphitem.h \
  74     src/GUI/heartrategraphitem.h \
  75     src/GUI/temperaturegraphitem.h \
  76     src/GUI/cadencegraphitem.h \
  77     src/GUI/powergraphitem.h \
  78     src/GUI/gearratiographitem.h \
  79     src/GUI/oddspinbox.h \
  80     src/GUI/settings.h \
  81     src/GUI/cpuarch.h \
  82     src/GUI/searchpointer.h \
  83     src/GUI/mapview.h \
  84     src/GUI/font.h \
  85     src/GUI/areaitem.h \
  86     src/map/projection.h \
  87     src/map/ellipsoid.h \
  88     src/map/datum.h \
  89     src/map/webmercator.h \
  90     src/map/transversemercator.h \
  91     src/map/latlon.h \
  92     src/map/utm.h \
  93     src/map/lambertconic.h \
  94     src/map/lambertazimuthal.h \
  95     src/map/albersequal.h \
  96     src/map/map.h \
  97     src/map/maplist.h \
  98     src/map/onlinemap.h \
  99     src/map/downloader.h \
 100     src/map/tile.h \
 101     src/map/emptymap.h \
 102     src/map/ozimap.h \
 103     src/map/tar.h \
 104     src/map/ozf.h \
 105     src/map/atlas.h \
 106     src/map/matrix.h \
 107     src/map/geotiff.h \
 108     src/map/pcs.h \
 109     src/map/transform.h \
 110     src/map/mapfile.h \
 111     src/map/tifffile.h \
 112     src/map/gcs.h \
 113     src/map/angularunits.h \
 114     src/map/primemeridian.h \
 115     src/map/linearunits.h \
 116     src/map/ct.h \
 117     src/map/mapsource.h \
 118     src/map/tileloader.h \
 119     src/map/wmtsmap.h \
 120     src/map/wmts.h \
 121     src/map/wmsmap.h \
 122     src/map/wms.h \
 123     src/map/crs.h \
 124     src/map/coordinatesystem.h \
 125     src/map/pointd.h \
 126     src/map/rectd.h \
 127     src/map/geocentric.h \
 128     src/map/mercator.h \
 129     src/map/jnxmap.h \
 130     src/map/krovak.h \
 131     src/map/geotiffmap.h \
 132     src/map/image.h \
 133     src/map/mbtilesmap.h \
 134     src/map/osm.h \
 135     src/map/polarstereographic.h \
 136     src/data/graph.h \
 137     src/data/poi.h \
 138     src/data/waypoint.h \
 139     src/data/track.h \
 140     src/data/route.h \
 141     src/data/trackpoint.h \
 142     src/data/data.h \
 143     src/data/parser.h \
 144     src/data/trackdata.h \
 145     src/data/routedata.h \
 146     src/data/path.h \
 147     src/data/gpxparser.h \
 148     src/data/tcxparser.h \
 149     src/data/csvparser.h \
 150     src/data/kmlparser.h \
 151     src/data/fitparser.h \
 152     src/data/igcparser.h \
 153     src/data/nmeaparser.h \
 154     src/data/oziparsers.h \
 155     src/data/locparser.h \
 156     src/data/slfparser.h \
 157     src/data/dem.h \
 158     src/data/polygon.h \
 159     src/data/area.h \
 160     src/map/obliquestereographic.h
 161 SOURCES += src/main.cpp \
 162     src/common/coordinates.cpp \
 163     src/common/rectc.cpp \
 164     src/common/range.cpp \
 165     src/common/util.cpp \
 166     src/common/greatcircle.cpp \
 167     src/common/programpaths.cpp \
 168     src/GUI/app.cpp \
 169     src/GUI/gui.cpp \
 170     src/GUI/axisitem.cpp \
 171     src/GUI/slideritem.cpp \
 172     src/GUI/markeritem.cpp \
 173     src/GUI/infoitem.cpp \
 174     src/GUI/elevationgraph.cpp \
 175     src/GUI/speedgraph.cpp \
 176     src/GUI/sliderinfoitem.cpp \
 177     src/GUI/filebrowser.cpp \
 178     src/GUI/scaleitem.cpp \
 179     src/GUI/graphview.cpp \
 180     src/GUI/waypointitem.cpp \
 181     src/GUI/palette.cpp \
 182     src/GUI/heartrategraph.cpp \
 183     src/GUI/trackinfo.cpp \
 184     src/GUI/exportdialog.cpp \
 185     src/GUI/fileselectwidget.cpp \
 186     src/GUI/temperaturegraph.cpp \
 187     src/GUI/trackitem.cpp \
 188     src/GUI/tooltip.cpp \
 189     src/GUI/routeitem.cpp \
 190     src/GUI/graphitem.cpp \
 191     src/GUI/pathitem.cpp \
 192     src/GUI/griditem.cpp \
 193     src/GUI/format.cpp \
 194     src/GUI/cadencegraph.cpp \
 195     src/GUI/powergraph.cpp \
 196     src/GUI/gearratiograph.cpp \
 197     src/GUI/optionsdialog.cpp \
 198     src/GUI/colorbox.cpp \
 199     src/GUI/stylecombobox.cpp \
 200     src/GUI/oddspinbox.cpp \
 201     src/GUI/percentslider.cpp \
 202     src/GUI/elevationgraphitem.cpp \
 203     src/GUI/speedgraphitem.cpp \
 204     src/GUI/heartrategraphitem.cpp \
 205     src/GUI/temperaturegraphitem.cpp \
 206     src/GUI/cadencegraphitem.cpp \
 207     src/GUI/powergraphitem.cpp \
 208     src/GUI/gearratiographitem.cpp \
 209     src/GUI/mapview.cpp \
 210     src/GUI/areaitem.cpp \
 211     src/map/maplist.cpp \
 212     src/map/onlinemap.cpp \
 213     src/map/downloader.cpp \
 214     src/map/emptymap.cpp \
 215     src/map/ozimap.cpp \
 216     src/map/tar.cpp \
 217     src/map/atlas.cpp \
 218     src/map/ozf.cpp \
 219     src/map/matrix.cpp \
 220     src/map/ellipsoid.cpp \
 221     src/map/datum.cpp \
 222     src/map/webmercator.cpp \
 223     src/map/transversemercator.cpp \
 224     src/map/utm.cpp \
 225     src/map/lambertconic.cpp \
 226     src/map/albersequal.cpp \
 227     src/map/lambertazimuthal.cpp \
 228     src/map/geotiff.cpp \
 229     src/map/pcs.cpp \
 230     src/map/transform.cpp \
 231     src/map/mapfile.cpp \
 232     src/map/tifffile.cpp \
 233     src/map/projection.cpp \
 234     src/map/gcs.cpp \
 235     src/map/angularunits.cpp \
 236     src/map/primemeridian.cpp \
 237     src/map/linearunits.cpp \
 238     src/map/mapsource.cpp \
 239     src/map/tileloader.cpp \
 240     src/map/wmtsmap.cpp \
 241     src/map/wmts.cpp \
 242     src/map/wmsmap.cpp \
 243     src/map/wms.cpp \
 244     src/map/crs.cpp \
 245     src/map/coordinatesystem.cpp \
 246     src/map/geocentric.cpp \
 247     src/map/mercator.cpp \
 248     src/map/jnxmap.cpp \
 249     src/map/krovak.cpp \
 250     src/map/map.cpp \
 251     src/map/geotiffmap.cpp \
 252     src/map/image.cpp \
 253     src/map/mbtilesmap.cpp \
 254     src/map/osm.cpp \
 255     src/map/polarstereographic.cpp \
 256     src/map/rectd.cpp \
 257     src/data/data.cpp \
 258     src/data/poi.cpp \
 259     src/data/track.cpp \
 260     src/data/route.cpp \
 261     src/data/path.cpp \
 262     src/data/gpxparser.cpp \
 263     src/data/tcxparser.cpp \
 264     src/data/csvparser.cpp \
 265     src/data/kmlparser.cpp \
 266     src/data/fitparser.cpp \
 267     src/data/igcparser.cpp \
 268     src/data/nmeaparser.cpp \
 269     src/data/oziparsers.cpp \
 270     src/data/locparser.cpp \
 271     src/data/slfparser.cpp \
 272     src/data/dem.cpp \
 273     src/data/polygon.cpp \
 274     src/map/obliquestereographic.cpp
 275
 276 greaterThan(QT_MAJOR_VERSION, 4) {
 277     HEADERS += src/data/geojsonparser.h
 278     SOURCES += src/data/geojsonparser.cpp
 279 }
 280
 281 DEFINES += APP_VERSION=\\\"$$VERSION\\\"
 282 DEFINES *= QT_USE_QSTRINGBUILDER
 283
 284 RESOURCES += gpxsee.qrc
 285 TRANSLATIONS = lang/gpxsee_en.ts \
 286     lang/gpxsee_cs.ts \
 287     lang/gpxsee_sv.ts \
 288     lang/gpxsee_de.ts \
 289     lang/gpxsee_ru.ts \
 290     lang/gpxsee_fi.ts \
 291     lang/gpxsee_fr.ts \
 292     lang/gpxsee_pl.ts \
 293     lang/gpxsee_nb.ts \
 294     lang/gpxsee_da.ts \
 295     lang/gpxsee_tr.ts \
 296     lang/gpxsee_es.ts
 297
 298 macx {
 299     ICON = icons/gpxsee.icns
 300     QMAKE_INFO_PLIST = pkg/Info.plist
 301     locale.path = Contents/Resources/translations
 302     locale.files = lang/gpxsee_en.qm \
 303         lang/gpxsee_cs.qm \
 304         lang/gpxsee_de.qm \
 305         lang/gpxsee_fi.qm \
 306         lang/gpxsee_fr.qm \
 307         lang/gpxsee_ru.qm \
 308         lang/gpxsee_sv.qm \
 309         lang/gpxsee_pl.qm \
 310         lang/gpxsee_nb.qm \
 311         lang/gpxsee_da.qm \
 312         lang/gpxsee_tr.qm \
 313         lang/gpxsee_es.qm
 314     csv.path = Contents/Resources
 315     csv.files = pkg/csv
 316     maps.path = Contents/Resources
 317     maps.files = pkg/maps
 318     icons.path = Contents/Resources/icons
 319     icons.files = icons/formats/gpx.icns \
 320         icons/formats/tcx.icns \
 321         icons/formats/kml.icns \
 322         icons/formats/fit.icns \
 323         icons/formats/igc.icns \
 324         icons/formats/nmea.icns \
 325         icons/formats/plt.icns \
 326         icons/formats/rte.icns \
 327         icons/formats/wpt.icns \
 328         icons/formats/loc.icns \
 329         icons/formats/slf.icns \
 330         icons/formats/json.icns
 331     QMAKE_BUNDLE_DATA += locale maps icons csv
 332 }
 333
 334 win32 {
 335     RC_ICONS = icons/gpxsee.ico \
 336         icons/formats/gpx.ico \
 337         icons/formats/tcx.ico \
 338         icons/formats/kml.ico \
 339         icons/formats/fit.ico \
 340         icons/formats/igc.ico \
 341         icons/formats/nmea.ico \
 342         icons/formats/plt.ico \
 343         icons/formats/rte.ico \
 344         icons/formats/wpt.ico \
 345         icons/formats/loc.ico \
 346         icons/formats/slf.ico \
 347         icons/formats/json.ico
 348     DEFINES += _USE_MATH_DEFINES \
 349         NOGDI
 350 }
 351
 352 unix:!macx {
 353     isEmpty(PREFIX):PREFIX = /usr/local
 354
 355     maps.files = pkg/maps/*
 356     maps.path = $$PREFIX/share/gpxsee/maps
 357     csv.files = pkg/csv/*
 358     csv.path = $$PREFIX/share/gpxsee/csv
 359     locale.files = lang/*.qm
 360     locale.path = $$PREFIX/share/gpxsee/translations
 361     icon.files = icons/gpxsee.png
 362     icon.path = $$PREFIX/share/pixmaps
 363     desktop.files = pkg/gpxsee.desktop
 364     desktop.path = $$PREFIX/share/applications
 365     mime.files = pkg/gpxsee.xml
 366     mime.path = $$PREFIX/share/mime/packages
 367     target.path = $$PREFIX/bin
 368     INSTALLS += target maps csv locale icon desktop mime
 369 }