gpxsee.pro

   1 unix:!macx:!android {
   2     TARGET = gpxsee
   3 } else {
   4     TARGET = GPXSee
   5 }
   6 VERSION = 13.4
   7
   8 QT += core \
   9     gui \
  10     gui-private \
  11     network \
  12     sql \
  13     concurrent \
  14     widgets \
  15     printsupport \
  16     positioning \
  17     svg \
  18     serialport
  19 greaterThan(QT_MAJOR_VERSION, 5) {
  20     QT += openglwidgets \
  21           core5compat
  22 }
  23
  24 CONFIG += object_parallel_to_source
  25 INCLUDEPATH += ./src
  26 HEADERS += src/common/config.h \
  27     src/GUI/crosshairitem.h \
  28     src/GUI/motioninfoitem.h \
  29     src/GUI/pluginparameters.h \
  30     src/common/garmin.h \
  31     src/common/coordinates.h \
  32     src/common/hash.h \
  33     src/common/linec.h \
  34     src/common/range.h \
  35     src/common/rectc.h \
  36     src/common/textcodec.h \
  37     src/common/treenode.h \
  38     src/common/wgs84.h \
  39     src/common/util.h \
  40     src/common/rtree.h \
  41     src/common/kv.h \
  42     src/common/greatcircle.h \
  43     src/common/programpaths.h \
  44     src/common/tifffile.h \
  45     src/common/downloader.h \
  46     src/common/polygon.h \
  47     src/common/color.h \
  48     src/common/csv.h \
  49     src/GUI/authenticationwidget.h \
  50     src/GUI/axislabelitem.h \
  51     src/GUI/dirselectwidget.h \
  52     src/GUI/flowlayout.h \
  53     src/GUI/graphicsscene.h \
  54     src/GUI/infolabel.h \
  55     src/GUI/mapaction.h \
  56     src/GUI/mapitem.h \
  57     src/GUI/marginswidget.h \
  58     src/GUI/markerinfoitem.h \
  59     src/GUI/planeitem.h \
  60     src/GUI/poiaction.h \
  61     src/GUI/popup.h \
  62     src/GUI/thumbnail.h \
  63     src/GUI/app.h \
  64     src/GUI/icons.h \
  65     src/GUI/gui.h \
  66     src/GUI/axisitem.h \
  67     src/GUI/keys.h \
  68     src/GUI/slideritem.h \
  69     src/GUI/markeritem.h \
  70     src/GUI/infoitem.h \
  71     src/GUI/elevationgraph.h \
  72     src/GUI/speedgraph.h \
  73     src/GUI/sliderinfoitem.h \
  74     src/GUI/filebrowser.h \
  75     src/GUI/units.h \
  76     src/GUI/scaleitem.h \
  77     src/GUI/graphview.h \
  78     src/GUI/waypointitem.h \
  79     src/GUI/palette.h \
  80     src/GUI/heartrategraph.h \
  81     src/GUI/trackinfo.h \
  82     src/GUI/fileselectwidget.h \
  83     src/GUI/temperaturegraph.h \
  84     src/GUI/graphtab.h \
  85     src/GUI/trackitem.h \
  86     src/GUI/tooltip.h \
  87     src/GUI/routeitem.h \
  88     src/GUI/graphitem.h \
  89     src/GUI/pathitem.h \
  90     src/GUI/griditem.h \
  91     src/GUI/format.h \
  92     src/GUI/cadencegraph.h \
  93     src/GUI/powergraph.h \
  94     src/GUI/gearratiograph.h \
  95     src/GUI/optionsdialog.h \
  96     src/GUI/colorbox.h \
  97     src/GUI/stylecombobox.h \
  98     src/GUI/timetype.h \
  99     src/GUI/percentslider.h \
 100     src/GUI/elevationgraphitem.h \
 101     src/GUI/speedgraphitem.h \
 102     src/GUI/heartrategraphitem.h \
 103     src/GUI/temperaturegraphitem.h \
 104     src/GUI/cadencegraphitem.h \
 105     src/GUI/powergraphitem.h \
 106     src/GUI/gearratiographitem.h \
 107     src/GUI/oddspinbox.h \
 108     src/GUI/settings.h \
 109     src/GUI/searchpointer.h \
 110     src/GUI/mapview.h \
 111     src/GUI/font.h \
 112     src/GUI/areaitem.h \
 113     src/GUI/coordinatesitem.h \
 114     src/GUI/projectioncombobox.h \
 115     src/GUI/pathtickitem.h \
 116     src/GUI/pdfexportdialog.h \
 117     src/GUI/pngexportdialog.h \
 118     src/GUI/timezoneinfo.h \
 119     src/GUI/passwordedit.h \
 120     src/data/style.h \
 121     src/data/twonavparser.h \
 122     src/map/ENC/attributes.h \
 123     src/map/ENC/mapdata.h \
 124     src/map/ENC/objects.h \
 125     src/map/ENC/rastertile.h \
 126     src/map/ENC/style.h \
 127     src/map/IMG/section.h \
 128     src/map/IMG/zoom.h \
 129     src/map/conversion.h \
 130     src/map/encmap.h \
 131     src/map/ENC/iso8211.h \
 132     src/map/gemfmap.h \
 133     src/map/oruxmap.h \
 134     src/map/osmdroidmap.h \
 135     src/map/proj/polyconic.h \
 136     src/map/proj/webmercator.h \
 137     src/map/proj/transversemercator.h \
 138     src/map/proj/latlon.h \
 139     src/map/proj/lambertconic.h \
 140     src/map/proj/lambertazimuthal.h \
 141     src/map/proj/albersequal.h \
 142     src/map/proj/mercator.h \
 143     src/map/proj/krovak.h \
 144     src/map/proj/polarstereographic.h \
 145     src/map/proj/obliquestereographic.h \
 146     src/map/bitmapline.h \
 147     src/map/IMG/bitstream.h \
 148     src/map/IMG/deltastream.h \
 149     src/map/IMG/gmapdata.h \
 150     src/map/IMG/huffmanbuffer.h \
 151     src/map/IMG/huffmanstream.h \
 152     src/map/IMG/huffmantable.h \
 153     src/map/IMG/huffmantext.h \
 154     src/map/IMG/nodfile.h \
 155     src/map/IMG/mapdata.h \
 156     src/map/IMG/raster.h \
 157     src/map/IMG/rastertile.h \
 158     src/map/IMG/shield.h \
 159     src/map/IMG/imgdata.h \
 160     src/map/IMG/subfile.h \
 161     src/map/IMG/trefile.h \
 162     src/map/IMG/rgnfile.h \
 163     src/map/IMG/lblfile.h \
 164     src/map/IMG/vectortile.h \
 165     src/map/IMG/subdiv.h \
 166     src/map/IMG/style.h \
 167     src/map/IMG/netfile.h \
 168     src/map/IMG/label.h \
 169     src/map/mapsforge/style.h \
 170     src/map/mapsforge/mapdata.h \
 171     src/map/mapsforge/rastertile.h \
 172     src/map/mapsforge/subfile.h \
 173     src/map/qctmap.h \
 174     src/map/textpathitem.h \
 175     src/map/textpointitem.h \
 176     src/map/prjfile.h \
 177     src/map/bsbmap.h \
 178     src/map/invalidmap.h \
 179     src/map/kmzmap.h \
 180     src/map/projection.h \
 181     src/map/ellipsoid.h \
 182     src/map/datum.h \
 183     src/map/sqlitemap.h \
 184     src/map/utm.h \
 185     src/map/map.h \
 186     src/map/maplist.h \
 187     src/map/onlinemap.h \
 188     src/map/tile.h \
 189     src/map/emptymap.h \
 190     src/map/ozimap.h \
 191     src/map/tar.h \
 192     src/map/ozf.h \
 193     src/map/atlas.h \
 194     src/map/matrix.h \
 195     src/map/geotiff.h \
 196     src/map/pcs.h \
 197     src/map/transform.h \
 198     src/map/mapfile.h \
 199     src/map/gcs.h \
 200     src/map/angularunits.h \
 201     src/map/primemeridian.h \
 202     src/map/linearunits.h \
 203     src/map/ct.h \
 204     src/map/mapsource.h \
 205     src/map/tileloader.h \
 206     src/map/wldfile.h \
 207     src/map/wmtsmap.h \
 208     src/map/wmts.h \
 209     src/map/wmsmap.h \
 210     src/map/wms.h \
 211     src/map/crs.h \
 212     src/map/coordinatesystem.h \
 213     src/map/pointd.h \
 214     src/map/rectd.h \
 215     src/map/geocentric.h \
 216     src/map/jnxmap.h \
 217     src/map/geotiffmap.h \
 218     src/map/image.h \
 219     src/map/mbtilesmap.h \
 220     src/map/osm.h \
 221     src/map/rmap.h \
 222     src/map/calibrationpoint.h \
 223     src/map/textitem.h \
 224     src/map/aqmmap.h \
 225     src/map/mapsforgemap.h \
 226     src/map/worldfilemap.h \
 227     src/map/imgmap.h \
 228     src/data/itnparser.h \
 229     src/data/link.h \
 230     src/data/onmoveparsers.h \
 231     src/data/ov2parser.h \
 232     src/data/graph.h \
 233     src/data/poi.h \
 234     src/data/waypoint.h \
 235     src/data/track.h \
 236     src/data/route.h \
 237     src/data/trackpoint.h \
 238     src/data/data.h \
 239     src/data/parser.h \
 240     src/data/trackdata.h \
 241     src/data/routedata.h \
 242     src/data/path.h \
 243     src/data/gpxparser.h \
 244     src/data/tcxparser.h \
 245     src/data/csvparser.h \
 246     src/data/kmlparser.h \
 247     src/data/fitparser.h \
 248     src/data/igcparser.h \
 249     src/data/nmeaparser.h \
 250     src/data/oziparsers.h \
 251     src/data/locparser.h \
 252     src/data/slfparser.h \
 253     src/data/dem.h \
 254     src/data/demloader.h \
 255     src/data/area.h \
 256     src/data/exifparser.h \
 257     src/data/cupparser.h \
 258     src/data/gpiparser.h \
 259     src/data/address.h \
 260     src/data/smlparser.h \
 261     src/data/geojsonparser.h
 262
 263 SOURCES += src/main.cpp \
 264     src/GUI/crosshairitem.cpp \
 265     src/GUI/motioninfoitem.cpp \
 266     src/GUI/pluginparameters.cpp \
 267     src/GUI/settings.cpp \
 268     src/common/coordinates.cpp \
 269     src/common/rectc.cpp \
 270     src/common/range.cpp \
 271     src/common/textcodec.cpp \
 272     src/common/util.cpp \
 273     src/common/greatcircle.cpp \
 274     src/common/programpaths.cpp \
 275     src/common/tifffile.cpp \
 276     src/common/downloader.cpp \
 277     src/common/csv.cpp \
 278     src/GUI/authenticationwidget.cpp \
 279     src/GUI/axislabelitem.cpp \
 280     src/GUI/dirselectwidget.cpp \
 281     src/GUI/flowlayout.cpp \
 282     src/GUI/infolabel.cpp \
 283     src/GUI/mapitem.cpp \
 284     src/GUI/marginswidget.cpp \
 285     src/GUI/markerinfoitem.cpp \
 286     src/GUI/popup.cpp \
 287     src/GUI/thumbnail.cpp \
 288     src/GUI/app.cpp \
 289     src/GUI/gui.cpp \
 290     src/GUI/axisitem.cpp \
 291     src/GUI/slideritem.cpp \
 292     src/GUI/markeritem.cpp \
 293     src/GUI/infoitem.cpp \
 294     src/GUI/elevationgraph.cpp \
 295     src/GUI/speedgraph.cpp \
 296     src/GUI/sliderinfoitem.cpp \
 297     src/GUI/filebrowser.cpp \
 298     src/GUI/scaleitem.cpp \
 299     src/GUI/graphview.cpp \
 300     src/GUI/waypointitem.cpp \
 301     src/GUI/palette.cpp \
 302     src/GUI/heartrategraph.cpp \
 303     src/GUI/trackinfo.cpp \
 304     src/GUI/fileselectwidget.cpp \
 305     src/GUI/temperaturegraph.cpp \
 306     src/GUI/trackitem.cpp \
 307     src/GUI/routeitem.cpp \
 308     src/GUI/graphitem.cpp \
 309     src/GUI/pathitem.cpp \
 310     src/GUI/griditem.cpp \
 311     src/GUI/format.cpp \
 312     src/GUI/cadencegraph.cpp \
 313     src/GUI/powergraph.cpp \
 314     src/GUI/gearratiograph.cpp \
 315     src/GUI/optionsdialog.cpp \
 316     src/GUI/colorbox.cpp \
 317     src/GUI/stylecombobox.cpp \
 318     src/GUI/oddspinbox.cpp \
 319     src/GUI/percentslider.cpp \
 320     src/GUI/elevationgraphitem.cpp \
 321     src/GUI/speedgraphitem.cpp \
 322     src/GUI/heartrategraphitem.cpp \
 323     src/GUI/temperaturegraphitem.cpp \
 324     src/GUI/cadencegraphitem.cpp \
 325     src/GUI/powergraphitem.cpp \
 326     src/GUI/gearratiographitem.cpp \
 327     src/GUI/mapview.cpp \
 328     src/GUI/areaitem.cpp \
 329     src/GUI/coordinatesitem.cpp \
 330     src/GUI/pathtickitem.cpp \
 331     src/GUI/graphicsscene.cpp \
 332     src/GUI/pdfexportdialog.cpp \
 333     src/GUI/pngexportdialog.cpp \
 334     src/GUI/projectioncombobox.cpp \
 335     src/GUI/passwordedit.cpp \
 336     src/data/twonavparser.cpp \
 337     src/map/ENC/mapdata.cpp \
 338     src/map/ENC/rastertile.cpp \
 339     src/map/ENC/style.cpp \
 340     src/map/conversion.cpp \
 341     src/map/encmap.cpp \
 342     src/map/ENC/iso8211.cpp \
 343     src/map/gemfmap.cpp \
 344     src/map/oruxmap.cpp \
 345     src/map/osmdroidmap.cpp \
 346     src/map/proj/polyconic.cpp \
 347     src/map/proj/webmercator.cpp \
 348     src/map/proj/transversemercator.cpp \
 349     src/map/proj/lambertconic.cpp \
 350     src/map/proj/albersequal.cpp \
 351     src/map/proj/lambertazimuthal.cpp \
 352     src/map/proj/mercator.cpp \
 353     src/map/proj/krovak.cpp \
 354     src/map/proj/polarstereographic.cpp \
 355     src/map/proj/obliquestereographic.cpp \
 356     src/map/bitmapline.cpp \
 357     src/map/IMG/bitstream.cpp \
 358     src/map/IMG/deltastream.cpp \
 359     src/map/IMG/gmapdata.cpp \
 360     src/map/IMG/huffmanbuffer.cpp \
 361     src/map/IMG/huffmanstream.cpp \
 362     src/map/IMG/huffmantable.cpp \
 363     src/map/IMG/huffmantext.cpp \
 364     src/map/IMG/nodfile.cpp \
 365     src/map/IMG/mapdata.cpp \
 366     src/map/IMG/rastertile.cpp \
 367     src/map/IMG/imgdata.cpp \
 368     src/map/IMG/subfile.cpp \
 369     src/map/IMG/trefile.cpp \
 370     src/map/IMG/rgnfile.cpp \
 371     src/map/IMG/lblfile.cpp \
 372     src/map/IMG/vectortile.cpp \
 373     src/map/IMG/style.cpp \
 374     src/map/IMG/netfile.cpp \
 375     src/map/mapsforge/style.cpp \
 376     src/map/mapsforge/mapdata.cpp \
 377     src/map/mapsforge/rastertile.cpp \
 378     src/map/mapsforge/subfile.cpp \
 379     src/map/imgmap.cpp \
 380     src/map/prjfile.cpp \
 381     src/map/qctmap.cpp \
 382     src/map/textpathitem.cpp \
 383     src/map/textpointitem.cpp \
 384     src/map/bsbmap.cpp \
 385     src/map/kmzmap.cpp \
 386     src/map/maplist.cpp \
 387     src/map/onlinemap.cpp \
 388     src/map/emptymap.cpp \
 389     src/map/ozimap.cpp \
 390     src/map/sqlitemap.cpp \
 391     src/map/tar.cpp \
 392     src/map/atlas.cpp \
 393     src/map/ozf.cpp \
 394     src/map/matrix.cpp \
 395     src/map/ellipsoid.cpp \
 396     src/map/datum.cpp \
 397     src/map/utm.cpp \
 398     src/map/geotiff.cpp \
 399     src/map/pcs.cpp \
 400     src/map/transform.cpp \
 401     src/map/mapfile.cpp \
 402     src/map/projection.cpp \
 403     src/map/gcs.cpp \
 404     src/map/angularunits.cpp \
 405     src/map/primemeridian.cpp \
 406     src/map/linearunits.cpp \
 407     src/map/mapsource.cpp \
 408     src/map/tileloader.cpp \
 409     src/map/wldfile.cpp \
 410     src/map/wmtsmap.cpp \
 411     src/map/wmts.cpp \
 412     src/map/wmsmap.cpp \
 413     src/map/wms.cpp \
 414     src/map/crs.cpp \
 415     src/map/coordinatesystem.cpp \
 416     src/map/geocentric.cpp \
 417     src/map/jnxmap.cpp \
 418     src/map/map.cpp \
 419     src/map/geotiffmap.cpp \
 420     src/map/image.cpp \
 421     src/map/mbtilesmap.cpp \
 422     src/map/osm.cpp \
 423     src/map/rectd.cpp \
 424     src/map/rmap.cpp \
 425     src/map/textitem.cpp \
 426     src/map/aqmmap.cpp \
 427     src/map/mapsforgemap.cpp \
 428     src/map/worldfilemap.cpp \
 429     src/data/address.cpp \
 430     src/data/itnparser.cpp \
 431     src/data/onmoveparsers.cpp \
 432     src/data/ov2parser.cpp \
 433     src/data/waypoint.cpp \
 434     src/data/data.cpp \
 435     src/data/poi.cpp \
 436     src/data/track.cpp \
 437     src/data/route.cpp \
 438     src/data/path.cpp \
 439     src/data/gpxparser.cpp \
 440     src/data/tcxparser.cpp \
 441     src/data/csvparser.cpp \
 442     src/data/kmlparser.cpp \
 443     src/data/fitparser.cpp \
 444     src/data/igcparser.cpp \
 445     src/data/nmeaparser.cpp \
 446     src/data/oziparsers.cpp \
 447     src/data/locparser.cpp \
 448     src/data/slfparser.cpp \
 449     src/data/dem.cpp \
 450     src/data/demloader.cpp \
 451     src/data/exifparser.cpp \
 452     src/data/cupparser.cpp \
 453     src/data/gpiparser.cpp \
 454     src/data/smlparser.cpp \
 455     src/data/geojsonparser.cpp
 456
 457 DEFINES += APP_VERSION=\\\"$$VERSION\\\" \
 458     QT_NO_DEPRECATED_WARNINGS
 459
 460 RESOURCES += gpxsee.qrc
 461 TRANSLATIONS = lang/gpxsee_en.ts \
 462     lang/gpxsee_cs.ts \
 463     lang/gpxsee_sv.ts \
 464     lang/gpxsee_de.ts \
 465     lang/gpxsee_ru.ts \
 466     lang/gpxsee_fi.ts \
 467     lang/gpxsee_fr.ts \
 468     lang/gpxsee_pl.ts \
 469     lang/gpxsee_nb.ts \
 470     lang/gpxsee_da.ts \
 471     lang/gpxsee_tr.ts \
 472     lang/gpxsee_es.ts \
 473     lang/gpxsee_pt_BR.ts \
 474     lang/gpxsee_uk.ts \
 475     lang/gpxsee_hu.ts \
 476     lang/gpxsee_it.ts \
 477     lang/gpxsee_eo.ts \
 478     lang/gpxsee_zh.ts \
 479     lang/gpxsee_ca.ts \
 480     lang/gpxsee_ko.ts
 481
 482 macx {
 483     ICON = icons/app/gpxsee.icns
 484     QMAKE_INFO_PLIST = pkg/mac/Info.plist
 485     locale.path = Contents/Resources/translations
 486     locale.files = $$files(lang/*.qm)
 487     crs.path = Contents/Resources
 488     crs.files = data/CRS
 489     maps.path = Contents/Resources
 490     maps.files = data/maps
 491     symbols.path = Contents/Resources/symbols
 492     symbols.files = $$files(icons/symbols/*.png)
 493     icons.path = Contents/Resources/icons
 494     icons.files = $$files(icons/formats/*.icns)
 495     lproj.path = Contents/Resources
 496     lproj.files = $$files(pkg/mac/lproj/*)
 497
 498     QMAKE_BUNDLE_DATA += locale maps symbols icons crs lproj
 499 }
 500
 501 win32 {
 502     RC_ICONS = icons/app/gpxsee.ico \
 503         icons/formats/gpx.ico \
 504         icons/formats/tcx.ico \
 505         icons/formats/kml.ico \
 506         icons/formats/fit.ico \
 507         icons/formats/igc.ico \
 508         icons/formats/nmea.ico \
 509         icons/formats/plt.ico \
 510         icons/formats/rte.ico \
 511         icons/formats/wpt.ico \
 512         icons/formats/loc.ico \
 513         icons/formats/slf.ico \
 514         icons/formats/json.ico \
 515         icons/formats/cup.ico \
 516         icons/formats/gpi.ico \
 517         icons/formats/sml.ico \
 518         icons/formats/img.ico \
 519         icons/formats/jnx.ico \
 520         icons/formats/kap.ico \
 521         icons/formats/map.ico \
 522         icons/formats/mbts.ico \
 523         icons/formats/rmap.ico \
 524         icons/formats/tba.ico \
 525         icons/formats/aqm.ico \
 526         icons/formats/sqlt.ico \
 527         icons/formats/ov2.ico \
 528         icons/formats/itn.ico \
 529         icons/formats/wld.ico \
 530         icons/formats/omd.ico \
 531         icons/formats/ghp.ico \
 532         icons/formats/qct.ico \
 533         icons/formats/trk.ico \
 534         icons/formats/gemf.ico \
 535         icons/formats/000.ico
 536     DEFINES += _USE_MATH_DEFINES \
 537         NOGDI
 538 }
 539
 540 unix:!macx:!android {
 541     isEmpty(PREFIX):PREFIX = /usr/local
 542
 543     maps.files = $$files(data/maps/*)
 544     maps.path = $$PREFIX/share/gpxsee/maps
 545     crs.files = $$files(data/CRS/*)
 546     crs.path = $$PREFIX/share/gpxsee/CRS
 547     symbols.files = $$files(icons/symbols/*.png)
 548     symbols.path = $$PREFIX/share/gpxsee/symbols
 549     locale.files = $$files(lang/*.qm)
 550     locale.path = $$PREFIX/share/gpxsee/translations
 551     icon.files = $$files(icons/app/hicolor/*)
 552     icon.path = $$PREFIX/share/icons/hicolor
 553     desktop.files = pkg/linux/gpxsee.desktop
 554     desktop.path = $$PREFIX/share/applications
 555     mime.files = pkg/linux/gpxsee.xml
 556     mime.path = $$PREFIX/share/mime/packages
 557     appdata.files = pkg/linux/gpxsee.appdata.xml
 558     appdata.path = $$PREFIX/share/metainfo
 559     target.path = $$PREFIX/bin
 560     INSTALLS += target maps crs symbols locale icon desktop mime appdata
 561 }
 562
 563 android {
 564     HEADERS += src/GUI/navigationwidget.h
 565     SOURCES += src/GUI/navigationwidget.cpp
 566
 567     defineReplace(versionCode) {
 568         segments = $$split(1, ".")
 569         for (segment, segments): \
 570             vCode = "$$first(vCode)$$format_number($$segment, width=3 zeropad)"
 571         contains(ANDROID_TARGET_ARCH, armeabi-v7a): \
 572             suffix = 0
 573         contains(ANDROID_TARGET_ARCH, arm64-v8a): \
 574             suffix = 1
 575         contains(ANDROID_TARGET_ARCH, x86): \
 576             suffix = 2
 577         contains(ANDROID_TARGET_ARCH, x86_64): \
 578             suffix = 3
 579
 580         return($$first(vCode)$$first(suffix))
 581     }
 582
 583     !include($$OPENSSL_PATH/openssl.pri) {
 584         message("OpenSSL not found, building without HTTPS support!")
 585     }
 586
 587     ANDROID_TARGET_SDK_VERSION = 31
 588     ANDROID_VERSION_NAME = $$VERSION
 589     ANDROID_VERSION_CODE = $$versionCode($$ANDROID_VERSION_NAME)
 590     ANDROID_PACKAGE_SOURCE_DIR = $$PWD/pkg/android
 591     DISTFILES += \
 592         pkg/android/AndroidManifest.xml \
 593         pkg/android/build.gradle \
 594         pkg/android/res/values/libs.xml
 595
 596     maps.files = $$files(data/maps/*)
 597     maps.path = /assets/maps
 598     crs.files = $$files(data/CRS/*)
 599     crs.path = /assets/CRS
 600     symbols.files = $$files(icons/symbols/*.png)
 601     symbols.path = /assets/symbols
 602     translations.files = $$files(lang/*.qm)
 603     translations.path = /assets/translations
 604     INSTALLS += maps crs symbols translations
 605 }