gpxsee.pro

   1 unix:!macx {
   2     TARGET = gpxsee
   3 } else {
   4     TARGET = GPXSee
   5 }
   6 VERSION = 8.0
   7
   8 QT += core \
   9     gui \
  10     gui-private \
  11     network \
  12     sql \
  13     concurrent \
  14     widgets \
  15     printsupport
  16 greaterThan(QT_MAJOR_VERSION, 5) {QT += openglwidgets}
  17
  18 INCLUDEPATH += ./src
  19 HEADERS += src/common/config.h \
  20     src/GUI/axislabelitem.h \
  21     src/GUI/graphicsscene.h \
  22     src/GUI/mapaction.h \
  23     src/GUI/mapitem.h \
  24     src/GUI/marginswidget.h \
  25     src/GUI/planeitem.h \
  26     src/GUI/popup.h \
  27     src/common/garmin.h \
  28     src/common/coordinates.h \
  29     src/common/range.h \
  30     src/common/rectc.h \
  31     src/common/textcodec.h \
  32     src/common/wgs84.h \
  33     src/common/util.h \
  34     src/common/rtree.h \
  35     src/common/kv.h \
  36     src/common/greatcircle.h \
  37     src/common/programpaths.h \
  38     src/common/tifffile.h \
  39     src/GUI/app.h \
  40     src/GUI/icons.h \
  41     src/GUI/gui.h \
  42     src/GUI/axisitem.h \
  43     src/GUI/keys.h \
  44     src/GUI/slideritem.h \
  45     src/GUI/markeritem.h \
  46     src/GUI/infoitem.h \
  47     src/GUI/elevationgraph.h \
  48     src/GUI/speedgraph.h \
  49     src/GUI/sliderinfoitem.h \
  50     src/GUI/filebrowser.h \
  51     src/GUI/units.h \
  52     src/GUI/scaleitem.h \
  53     src/GUI/graphview.h \
  54     src/GUI/waypointitem.h \
  55     src/GUI/palette.h \
  56     src/GUI/heartrategraph.h \
  57     src/GUI/trackinfo.h \
  58     src/GUI/fileselectwidget.h \
  59     src/GUI/temperaturegraph.h \
  60     src/GUI/graphtab.h \
  61     src/GUI/trackitem.h \
  62     src/GUI/tooltip.h \
  63     src/GUI/routeitem.h \
  64     src/GUI/graphitem.h \
  65     src/GUI/pathitem.h \
  66     src/GUI/griditem.h \
  67     src/GUI/format.h \
  68     src/GUI/cadencegraph.h \
  69     src/GUI/powergraph.h \
  70     src/GUI/gearratiograph.h \
  71     src/GUI/optionsdialog.h \
  72     src/GUI/colorbox.h \
  73     src/GUI/stylecombobox.h \
  74     src/GUI/timetype.h \
  75     src/GUI/percentslider.h \
  76     src/GUI/elevationgraphitem.h \
  77     src/GUI/speedgraphitem.h \
  78     src/GUI/heartrategraphitem.h \
  79     src/GUI/temperaturegraphitem.h \
  80     src/GUI/cadencegraphitem.h \
  81     src/GUI/powergraphitem.h \
  82     src/GUI/gearratiographitem.h \
  83     src/GUI/oddspinbox.h \
  84     src/GUI/settings.h \
  85     src/GUI/searchpointer.h \
  86     src/GUI/mapview.h \
  87     src/GUI/font.h \
  88     src/GUI/areaitem.h \
  89     src/data/link.h \
  90     src/map/IMG/bitmapline.h \
  91     src/map/IMG/bitstream.h \
  92     src/map/IMG/deltastream.h \
  93     src/map/IMG/gmap.h \
  94     src/map/IMG/huffmanbuffer.h \
  95     src/map/IMG/huffmanstream.h \
  96     src/map/IMG/huffmantable.h \
  97     src/map/IMG/huffmantext.h \
  98     src/map/IMG/nodfile.h \
  99     src/map/IMG/mapdata.h \
 100     src/map/IMG/rastertile.h \
 101     src/map/IMG/textpathitem.h \
 102     src/map/IMG/textpointitem.h \
 103     src/map/bsbmap.h \
 104     src/map/invalidmap.h \
 105     src/map/kmzmap.h \
 106     src/map/polyconic.h \
 107     src/map/projection.h \
 108     src/map/ellipsoid.h \
 109     src/map/datum.h \
 110     src/map/webmercator.h \
 111     src/map/transversemercator.h \
 112     src/map/latlon.h \
 113     src/map/utm.h \
 114     src/map/lambertconic.h \
 115     src/map/lambertazimuthal.h \
 116     src/map/albersequal.h \
 117     src/map/map.h \
 118     src/map/maplist.h \
 119     src/map/onlinemap.h \
 120     src/map/downloader.h \
 121     src/map/tile.h \
 122     src/map/emptymap.h \
 123     src/map/ozimap.h \
 124     src/map/tar.h \
 125     src/map/ozf.h \
 126     src/map/atlas.h \
 127     src/map/matrix.h \
 128     src/map/geotiff.h \
 129     src/map/pcs.h \
 130     src/map/transform.h \
 131     src/map/mapfile.h \
 132     src/map/gcs.h \
 133     src/map/angularunits.h \
 134     src/map/primemeridian.h \
 135     src/map/linearunits.h \
 136     src/map/ct.h \
 137     src/map/mapsource.h \
 138     src/map/tileloader.h \
 139     src/map/wmtsmap.h \
 140     src/map/wmts.h \
 141     src/map/wmsmap.h \
 142     src/map/wms.h \
 143     src/map/crs.h \
 144     src/map/coordinatesystem.h \
 145     src/map/pointd.h \
 146     src/map/rectd.h \
 147     src/map/geocentric.h \
 148     src/map/mercator.h \
 149     src/map/jnxmap.h \
 150     src/map/krovak.h \
 151     src/map/geotiffmap.h \
 152     src/map/image.h \
 153     src/map/mbtilesmap.h \
 154     src/map/osm.h \
 155     src/map/polarstereographic.h \
 156     src/data/graph.h \
 157     src/data/poi.h \
 158     src/data/waypoint.h \
 159     src/data/track.h \
 160     src/data/route.h \
 161     src/data/trackpoint.h \
 162     src/data/data.h \
 163     src/data/parser.h \
 164     src/data/trackdata.h \
 165     src/data/routedata.h \
 166     src/data/path.h \
 167     src/data/gpxparser.h \
 168     src/data/tcxparser.h \
 169     src/data/csvparser.h \
 170     src/data/kmlparser.h \
 171     src/data/fitparser.h \
 172     src/data/igcparser.h \
 173     src/data/nmeaparser.h \
 174     src/data/oziparsers.h \
 175     src/data/locparser.h \
 176     src/data/slfparser.h \
 177     src/data/dem.h \
 178     src/data/polygon.h \
 179     src/data/area.h \
 180     src/map/obliquestereographic.h \
 181     src/GUI/coordinatesitem.h \
 182     src/map/rmap.h \
 183     src/map/calibrationpoint.h \
 184     src/map/color.h \
 185     src/data/exifparser.h \
 186     src/data/imageinfo.h \
 187     src/map/imgmap.h \
 188     src/map/IMG/img.h \
 189     src/map/IMG/subfile.h \
 190     src/map/IMG/trefile.h \
 191     src/map/IMG/rgnfile.h \
 192     src/map/IMG/lblfile.h \
 193     src/map/IMG/vectortile.h \
 194     src/map/IMG/subdiv.h \
 195     src/map/IMG/style.h \
 196     src/map/IMG/netfile.h \
 197     src/GUI/limitedcombobox.h \
 198     src/GUI/pathtickitem.h \
 199     src/map/IMG/textitem.h \
 200     src/map/IMG/label.h \
 201     src/data/csv.h \
 202     src/data/cupparser.h \
 203     src/data/gpiparser.h \
 204     src/data/address.h \
 205     src/data/smlparser.h \
 206     src/GUI/pdfexportdialog.h \
 207     src/GUI/pngexportdialog.h \
 208     src/data/geojsonparser.h \
 209     src/GUI/timezoneinfo.h
 210
 211 SOURCES += src/main.cpp \
 212     src/GUI/axislabelitem.cpp \
 213     src/GUI/mapitem.cpp \
 214     src/GUI/marginswidget.cpp \
 215     src/GUI/popup.cpp \
 216     src/common/coordinates.cpp \
 217     src/common/rectc.cpp \
 218     src/common/range.cpp \
 219     src/common/textcodec.cpp \
 220     src/common/util.cpp \
 221     src/common/greatcircle.cpp \
 222     src/common/programpaths.cpp \
 223     src/common/tifffile.cpp \
 224     src/GUI/app.cpp \
 225     src/GUI/gui.cpp \
 226     src/GUI/axisitem.cpp \
 227     src/GUI/slideritem.cpp \
 228     src/GUI/markeritem.cpp \
 229     src/GUI/infoitem.cpp \
 230     src/GUI/elevationgraph.cpp \
 231     src/GUI/speedgraph.cpp \
 232     src/GUI/sliderinfoitem.cpp \
 233     src/GUI/filebrowser.cpp \
 234     src/GUI/scaleitem.cpp \
 235     src/GUI/graphview.cpp \
 236     src/GUI/waypointitem.cpp \
 237     src/GUI/palette.cpp \
 238     src/GUI/heartrategraph.cpp \
 239     src/GUI/trackinfo.cpp \
 240     src/GUI/fileselectwidget.cpp \
 241     src/GUI/temperaturegraph.cpp \
 242     src/GUI/trackitem.cpp \
 243     src/GUI/tooltip.cpp \
 244     src/GUI/routeitem.cpp \
 245     src/GUI/graphitem.cpp \
 246     src/GUI/pathitem.cpp \
 247     src/GUI/griditem.cpp \
 248     src/GUI/format.cpp \
 249     src/GUI/cadencegraph.cpp \
 250     src/GUI/powergraph.cpp \
 251     src/GUI/gearratiograph.cpp \
 252     src/GUI/optionsdialog.cpp \
 253     src/GUI/colorbox.cpp \
 254     src/GUI/stylecombobox.cpp \
 255     src/GUI/oddspinbox.cpp \
 256     src/GUI/percentslider.cpp \
 257     src/GUI/elevationgraphitem.cpp \
 258     src/GUI/speedgraphitem.cpp \
 259     src/GUI/heartrategraphitem.cpp \
 260     src/GUI/temperaturegraphitem.cpp \
 261     src/GUI/cadencegraphitem.cpp \
 262     src/GUI/powergraphitem.cpp \
 263     src/GUI/gearratiographitem.cpp \
 264     src/GUI/mapview.cpp \
 265     src/GUI/areaitem.cpp \
 266     src/data/waypoint.cpp \
 267     src/map/IMG/bitmapline.cpp \
 268     src/map/IMG/bitstream.cpp \
 269     src/map/IMG/deltastream.cpp \
 270     src/map/IMG/gmap.cpp \
 271     src/map/IMG/huffmanbuffer.cpp \
 272     src/map/IMG/huffmanstream.cpp \
 273     src/map/IMG/huffmantable.cpp \
 274     src/map/IMG/huffmantext.cpp \
 275     src/map/IMG/nodfile.cpp \
 276     src/map/IMG/mapdata.cpp \
 277     src/map/IMG/rastertile.cpp \
 278     src/map/IMG/textpathitem.cpp \
 279     src/map/IMG/textpointitem.cpp \
 280     src/map/bsbmap.cpp \
 281     src/map/kmzmap.cpp \
 282     src/map/maplist.cpp \
 283     src/map/onlinemap.cpp \
 284     src/map/downloader.cpp \
 285     src/map/emptymap.cpp \
 286     src/map/ozimap.cpp \
 287     src/map/polyconic.cpp \
 288     src/map/tar.cpp \
 289     src/map/atlas.cpp \
 290     src/map/ozf.cpp \
 291     src/map/matrix.cpp \
 292     src/map/ellipsoid.cpp \
 293     src/map/datum.cpp \
 294     src/map/webmercator.cpp \
 295     src/map/transversemercator.cpp \
 296     src/map/utm.cpp \
 297     src/map/lambertconic.cpp \
 298     src/map/albersequal.cpp \
 299     src/map/lambertazimuthal.cpp \
 300     src/map/geotiff.cpp \
 301     src/map/pcs.cpp \
 302     src/map/transform.cpp \
 303     src/map/mapfile.cpp \
 304     src/map/projection.cpp \
 305     src/map/gcs.cpp \
 306     src/map/angularunits.cpp \
 307     src/map/primemeridian.cpp \
 308     src/map/linearunits.cpp \
 309     src/map/mapsource.cpp \
 310     src/map/tileloader.cpp \
 311     src/map/wmtsmap.cpp \
 312     src/map/wmts.cpp \
 313     src/map/wmsmap.cpp \
 314     src/map/wms.cpp \
 315     src/map/crs.cpp \
 316     src/map/coordinatesystem.cpp \
 317     src/map/geocentric.cpp \
 318     src/map/mercator.cpp \
 319     src/map/jnxmap.cpp \
 320     src/map/krovak.cpp \
 321     src/map/map.cpp \
 322     src/map/geotiffmap.cpp \
 323     src/map/image.cpp \
 324     src/map/mbtilesmap.cpp \
 325     src/map/osm.cpp \
 326     src/map/polarstereographic.cpp \
 327     src/map/rectd.cpp \
 328     src/data/data.cpp \
 329     src/data/poi.cpp \
 330     src/data/track.cpp \
 331     src/data/route.cpp \
 332     src/data/path.cpp \
 333     src/data/gpxparser.cpp \
 334     src/data/tcxparser.cpp \
 335     src/data/csvparser.cpp \
 336     src/data/kmlparser.cpp \
 337     src/data/fitparser.cpp \
 338     src/data/igcparser.cpp \
 339     src/data/nmeaparser.cpp \
 340     src/data/oziparsers.cpp \
 341     src/data/locparser.cpp \
 342     src/data/slfparser.cpp \
 343     src/data/dem.cpp \
 344     src/data/polygon.cpp \
 345     src/map/obliquestereographic.cpp \
 346     src/GUI/coordinatesitem.cpp \
 347     src/map/rmap.cpp \
 348     src/data/exifparser.cpp \
 349     src/map/imgmap.cpp \
 350     src/map/IMG/img.cpp \
 351     src/map/IMG/subfile.cpp \
 352     src/map/IMG/trefile.cpp \
 353     src/map/IMG/rgnfile.cpp \
 354     src/map/IMG/lblfile.cpp \
 355     src/map/IMG/vectortile.cpp \
 356     src/map/IMG/style.cpp \
 357     src/map/IMG/netfile.cpp \
 358     src/GUI/pathtickitem.cpp \
 359     src/map/IMG/textitem.cpp \
 360     src/data/csv.cpp \
 361     src/data/cupparser.cpp \
 362     src/GUI/graphicsscene.cpp \
 363     src/data/gpiparser.cpp \
 364     src/data/smlparser.cpp \
 365     src/GUI/pdfexportdialog.cpp \
 366     src/GUI/pngexportdialog.cpp \
 367     src/data/geojsonparser.cpp
 368
 369 DEFINES += APP_VERSION=\\\"$$VERSION\\\" \
 370     QT_NO_DEPRECATED_WARNINGS
 371
 372 RESOURCES += gpxsee.qrc
 373 TRANSLATIONS = lang/gpxsee_en.ts \
 374     lang/gpxsee_cs.ts \
 375     lang/gpxsee_sv.ts \
 376     lang/gpxsee_de.ts \
 377     lang/gpxsee_ru.ts \
 378     lang/gpxsee_fi.ts \
 379     lang/gpxsee_fr.ts \
 380     lang/gpxsee_pl.ts \
 381     lang/gpxsee_nb.ts \
 382     lang/gpxsee_da.ts \
 383     lang/gpxsee_tr.ts \
 384     lang/gpxsee_es.ts \
 385     lang/gpxsee_pt_BR.ts \
 386     lang/gpxsee_uk.ts \
 387     lang/gpxsee_hu.ts \
 388     lang/gpxsee_it.ts
 389
 390 macx {
 391     ICON = icons/app/gpxsee.icns
 392     QMAKE_INFO_PLIST = pkg/Info.plist
 393     locale.path = Contents/Resources/translations
 394     locale.files = lang/gpxsee_en.qm \
 395         lang/gpxsee_cs.qm \
 396         lang/gpxsee_de.qm \
 397         lang/gpxsee_fi.qm \
 398         lang/gpxsee_fr.qm \
 399         lang/gpxsee_ru.qm \
 400         lang/gpxsee_sv.qm \
 401         lang/gpxsee_pl.qm \
 402         lang/gpxsee_nb.qm \
 403         lang/gpxsee_da.qm \
 404         lang/gpxsee_tr.qm \
 405         lang/gpxsee_es.qm \
 406         lang/gpxsee_pt_BR.qm \
 407         lang/gpxsee_uk.qm \
 408         lang/gpxsee_hu.qm \
 409         lang/gpxsee_it.qm
 410     csv.path = Contents/Resources
 411     csv.files = pkg/csv
 412     maps.path = Contents/Resources
 413     maps.files = pkg/maps
 414     icons.path = Contents/Resources/icons
 415     icons.files = icons/formats/gpx.icns \
 416         icons/formats/tcx.icns \
 417         icons/formats/kml.icns \
 418         icons/formats/fit.icns \
 419         icons/formats/igc.icns \
 420         icons/formats/nmea.icns \
 421         icons/formats/plt.icns \
 422         icons/formats/rte.icns \
 423         icons/formats/wpt.icns \
 424         icons/formats/loc.icns \
 425         icons/formats/slf.icns \
 426         icons/formats/json.icns \
 427         icons/formats/cup.icns \
 428         icons/formats/gpi.icns \
 429         icons/formats/sml.icns \
 430         icons/formats/img.icns \
 431         icons/formats/jnx.icns \
 432         icons/formats/kap.icns \
 433         icons/formats/mbts.icns \
 434         icons/formats/rmap.icns \
 435         icons/formats/tba.icns
 436     QMAKE_BUNDLE_DATA += locale maps icons csv
 437 }
 438
 439 win32 {
 440     RC_ICONS = icons/app/gpxsee.ico \
 441         icons/formats/gpx.ico \
 442         icons/formats/tcx.ico \
 443         icons/formats/kml.ico \
 444         icons/formats/fit.ico \
 445         icons/formats/igc.ico \
 446         icons/formats/nmea.ico \
 447         icons/formats/plt.ico \
 448         icons/formats/rte.ico \
 449         icons/formats/wpt.ico \
 450         icons/formats/loc.ico \
 451         icons/formats/slf.ico \
 452         icons/formats/json.ico \
 453         icons/formats/cup.ico \
 454         icons/formats/gpi.ico \
 455         icons/formats/sml.ico \
 456         icons/formats/img.ico \
 457         icons/formats/jnx.ico \
 458         icons/formats/kap.ico \
 459         icons/formats/map.ico \
 460         icons/formats/mbts.ico \
 461         icons/formats/rmap.ico \
 462         icons/formats/tba.ico \
 463         icons/formats/kmz.ico
 464     DEFINES += _USE_MATH_DEFINES \
 465         NOGDI
 466 }
 467
 468 unix:!macx {
 469     isEmpty(PREFIX):PREFIX = /usr/local
 470     DEFINES += PREFIX=\\\"$$PREFIX\\\"
 471
 472     maps.files = pkg/maps/*
 473     maps.path = $$PREFIX/share/gpxsee/maps
 474     csv.files = pkg/csv/*
 475     csv.path = $$PREFIX/share/gpxsee/csv
 476     locale.files = lang/*.qm
 477     locale.path = $$PREFIX/share/gpxsee/translations
 478     icon.files = icons/app/hicolor/*
 479     icon.path = $$PREFIX/share/icons/hicolor
 480     desktop.files = pkg/gpxsee.desktop
 481     desktop.path = $$PREFIX/share/applications
 482     mime.files = pkg/gpxsee.xml
 483     mime.path = $$PREFIX/share/mime/packages
 484     target.path = $$PREFIX/bin
 485     INSTALLS += target maps csv locale icon desktop mime
 486 }