gpxsee.pro

   1 unix:!macx:!android {
   2     TARGET = gpxsee
   3 } else {
   4     TARGET = GPXSee
   5 }
   6 VERSION = 13.10
   7
   8
   9 QT += core \
  10     gui \
  11     gui-private \
  12     network \
  13     sql \
  14     concurrent \
  15     widgets \
  16     printsupport \
  17     positioning \
  18     svg \
  19     serialport
  20 greaterThan(QT_MAJOR_VERSION, 5) {
  21     QT += openglwidgets \
  22           core5compat
  23 }
  24
  25 CONFIG += object_parallel_to_source
  26 INCLUDEPATH += ./src
  27 HEADERS += src/common/config.h \
  28     src/GUI/crosshairitem.h \
  29     src/GUI/motioninfoitem.h \
  30     src/GUI/pluginparameters.h \
  31     src/common/garmin.h \
  32     src/common/coordinates.h \
  33     src/common/hash.h \
  34     src/common/linec.h \
  35     src/common/range.h \
  36     src/common/rectc.h \
  37     src/common/textcodec.h \
  38     src/common/treenode.h \
  39     src/common/wgs84.h \
  40     src/common/util.h \
  41     src/common/rtree.h \
  42     src/common/kv.h \
  43     src/common/greatcircle.h \
  44     src/common/programpaths.h \
  45     src/common/tifffile.h \
  46     src/common/downloader.h \
  47     src/common/polygon.h \
  48     src/common/color.h \
  49     src/common/csv.h \
  50     src/GUI/authenticationwidget.h \
  51     src/GUI/axislabelitem.h \
  52     src/GUI/dirselectwidget.h \
  53     src/GUI/flowlayout.h \
  54     src/GUI/graphicsscene.h \
  55     src/GUI/infolabel.h \
  56     src/GUI/mapaction.h \
  57     src/GUI/mapitem.h \
  58     src/GUI/marginswidget.h \
  59     src/GUI/markerinfoitem.h \
  60     src/GUI/planeitem.h \
  61     src/GUI/poiaction.h \
  62     src/GUI/popup.h \
  63     src/GUI/thumbnail.h \
  64     src/GUI/app.h \
  65     src/GUI/icons.h \
  66     src/GUI/gui.h \
  67     src/GUI/axisitem.h \
  68     src/GUI/keys.h \
  69     src/GUI/slideritem.h \
  70     src/GUI/markeritem.h \
  71     src/GUI/infoitem.h \
  72     src/GUI/elevationgraph.h \
  73     src/GUI/speedgraph.h \
  74     src/GUI/sliderinfoitem.h \
  75     src/GUI/filebrowser.h \
  76     src/GUI/units.h \
  77     src/GUI/scaleitem.h \
  78     src/GUI/graphview.h \
  79     src/GUI/waypointitem.h \
  80     src/GUI/palette.h \
  81     src/GUI/heartrategraph.h \
  82     src/GUI/trackinfo.h \
  83     src/GUI/fileselectwidget.h \
  84     src/GUI/temperaturegraph.h \
  85     src/GUI/graphtab.h \
  86     src/GUI/trackitem.h \
  87     src/GUI/tooltip.h \
  88     src/GUI/routeitem.h \
  89     src/GUI/graphitem.h \
  90     src/GUI/pathitem.h \
  91     src/GUI/griditem.h \
  92     src/GUI/format.h \
  93     src/GUI/cadencegraph.h \
  94     src/GUI/powergraph.h \
  95     src/GUI/gearratiograph.h \
  96     src/GUI/optionsdialog.h \
  97     src/GUI/colorbox.h \
  98     src/GUI/stylecombobox.h \
  99     src/GUI/timetype.h \
 100     src/GUI/percentslider.h \
 101     src/GUI/elevationgraphitem.h \
 102     src/GUI/speedgraphitem.h \
 103     src/GUI/heartrategraphitem.h \
 104     src/GUI/temperaturegraphitem.h \
 105     src/GUI/cadencegraphitem.h \
 106     src/GUI/powergraphitem.h \
 107     src/GUI/gearratiographitem.h \
 108     src/GUI/oddspinbox.h \
 109     src/GUI/settings.h \
 110     src/GUI/searchpointer.h \
 111     src/GUI/mapview.h \
 112     src/GUI/font.h \
 113     src/GUI/areaitem.h \
 114     src/GUI/coordinatesitem.h \
 115     src/GUI/projectioncombobox.h \
 116     src/GUI/pathtickitem.h \
 117     src/GUI/pdfexportdialog.h \
 118     src/GUI/pngexportdialog.h \
 119     src/GUI/timezoneinfo.h \
 120     src/GUI/passwordedit.h \
 121     src/data/style.h \
 122     src/data/twonavparser.h \
 123     src/map/ENC/attributes.h \
 124     src/map/ENC/mapdata.h \
 125     src/map/ENC/atlasdata.h \
 126     src/map/ENC/objects.h \
 127     src/map/ENC/rastertile.h \
 128     src/map/ENC/style.h \
 129     src/map/IMG/section.h \
 130     src/map/IMG/zoom.h \
 131     src/map/conversion.h \
 132     src/map/encatlas.h \
 133     src/map/encjob.h \
 134     src/map/encmap.h \
 135     src/map/ENC/iso8211.h \
 136     src/map/gemfmap.h \
 137     src/map/gmifile.h \
 138     src/map/oruxmap.h \
 139     src/map/osmdroidmap.h \
 140     src/map/proj/polyconic.h \
 141     src/map/proj/webmercator.h \
 142     src/map/proj/transversemercator.h \
 143     src/map/proj/latlon.h \
 144     src/map/proj/lambertconic.h \
 145     src/map/proj/lambertazimuthal.h \
 146     src/map/proj/albersequal.h \
 147     src/map/proj/mercator.h \
 148     src/map/proj/krovak.h \
 149     src/map/proj/polarstereographic.h \
 150     src/map/proj/obliquestereographic.h \
 151     src/map/bitmapline.h \
 152     src/map/IMG/bitstream.h \
 153     src/map/IMG/deltastream.h \
 154     src/map/IMG/gmapdata.h \
 155     src/map/IMG/huffmanbuffer.h \
 156     src/map/IMG/huffmanstream.h \
 157     src/map/IMG/huffmantable.h \
 158     src/map/IMG/huffmantext.h \
 159     src/map/IMG/nodfile.h \
 160     src/map/IMG/mapdata.h \
 161     src/map/IMG/raster.h \
 162     src/map/IMG/rastertile.h \
 163     src/map/IMG/shield.h \
 164     src/map/IMG/imgdata.h \
 165     src/map/IMG/subfile.h \
 166     src/map/IMG/trefile.h \
 167     src/map/IMG/rgnfile.h \
 168     src/map/IMG/lblfile.h \
 169     src/map/IMG/vectortile.h \
 170     src/map/IMG/subdiv.h \
 171     src/map/IMG/style.h \
 172     src/map/IMG/netfile.h \
 173     src/map/IMG/label.h \
 174     src/map/mapsforge/style.h \
 175     src/map/mapsforge/mapdata.h \
 176     src/map/mapsforge/rastertile.h \
 177     src/map/mapsforge/subfile.h \
 178     src/map/qctmap.h \
 179     src/map/textpathitem.h \
 180     src/map/textpointitem.h \
 181     src/map/prjfile.h \
 182     src/map/bsbmap.h \
 183     src/map/invalidmap.h \
 184     src/map/kmzmap.h \
 185     src/map/projection.h \
 186     src/map/ellipsoid.h \
 187     src/map/datum.h \
 188     src/map/sqlitemap.h \
 189     src/map/utm.h \
 190     src/map/map.h \
 191     src/map/maplist.h \
 192     src/map/onlinemap.h \
 193     src/map/tile.h \
 194     src/map/emptymap.h \
 195     src/map/ozimap.h \
 196     src/map/tar.h \
 197     src/map/ozf.h \
 198     src/map/atlas.h \
 199     src/map/matrix.h \
 200     src/map/geotiff.h \
 201     src/map/pcs.h \
 202     src/map/transform.h \
 203     src/map/mapfile.h \
 204     src/map/gcs.h \
 205     src/map/angularunits.h \
 206     src/map/primemeridian.h \
 207     src/map/linearunits.h \
 208     src/map/ct.h \
 209     src/map/mapsource.h \
 210     src/map/tileloader.h \
 211     src/map/wldfile.h \
 212     src/map/wmtsmap.h \
 213     src/map/wmts.h \
 214     src/map/wmsmap.h \
 215     src/map/wms.h \
 216     src/map/crs.h \
 217     src/map/coordinatesystem.h \
 218     src/map/pointd.h \
 219     src/map/rectd.h \
 220     src/map/geocentric.h \
 221     src/map/jnxmap.h \
 222     src/map/geotiffmap.h \
 223     src/map/image.h \
 224     src/map/mbtilesmap.h \
 225     src/map/osm.h \
 226     src/map/rmap.h \
 227     src/map/calibrationpoint.h \
 228     src/map/textitem.h \
 229     src/map/aqmmap.h \
 230     src/map/mapsforgemap.h \
 231     src/map/worldfilemap.h \
 232     src/map/imgmap.h \
 233     src/data/itnparser.h \
 234     src/data/link.h \
 235     src/data/onmoveparsers.h \
 236     src/data/ov2parser.h \
 237     src/data/graph.h \
 238     src/data/poi.h \
 239     src/data/waypoint.h \
 240     src/data/track.h \
 241     src/data/route.h \
 242     src/data/trackpoint.h \
 243     src/data/data.h \
 244     src/data/parser.h \
 245     src/data/trackdata.h \
 246     src/data/routedata.h \
 247     src/data/path.h \
 248     src/data/gpxparser.h \
 249     src/data/tcxparser.h \
 250     src/data/csvparser.h \
 251     src/data/kmlparser.h \
 252     src/data/fitparser.h \
 253     src/data/igcparser.h \
 254     src/data/nmeaparser.h \
 255     src/data/oziparsers.h \
 256     src/data/locparser.h \
 257     src/data/slfparser.h \
 258     src/data/dem.h \
 259     src/data/demloader.h \
 260     src/data/area.h \
 261     src/data/exifparser.h \
 262     src/data/cupparser.h \
 263     src/data/gpiparser.h \
 264     src/data/address.h \
 265     src/data/smlparser.h \
 266     src/data/geojsonparser.h
 267
 268 SOURCES += src/main.cpp \
 269     src/GUI/crosshairitem.cpp \
 270     src/GUI/motioninfoitem.cpp \
 271     src/GUI/pluginparameters.cpp \
 272     src/GUI/settings.cpp \
 273     src/common/coordinates.cpp \
 274     src/common/rectc.cpp \
 275     src/common/range.cpp \
 276     src/common/textcodec.cpp \
 277     src/common/util.cpp \
 278     src/common/greatcircle.cpp \
 279     src/common/programpaths.cpp \
 280     src/common/tifffile.cpp \
 281     src/common/downloader.cpp \
 282     src/common/csv.cpp \
 283     src/GUI/authenticationwidget.cpp \
 284     src/GUI/axislabelitem.cpp \
 285     src/GUI/dirselectwidget.cpp \
 286     src/GUI/flowlayout.cpp \
 287     src/GUI/infolabel.cpp \
 288     src/GUI/mapitem.cpp \
 289     src/GUI/marginswidget.cpp \
 290     src/GUI/markerinfoitem.cpp \
 291     src/GUI/popup.cpp \
 292     src/GUI/thumbnail.cpp \
 293     src/GUI/app.cpp \
 294     src/GUI/gui.cpp \
 295     src/GUI/axisitem.cpp \
 296     src/GUI/slideritem.cpp \
 297     src/GUI/markeritem.cpp \
 298     src/GUI/infoitem.cpp \
 299     src/GUI/elevationgraph.cpp \
 300     src/GUI/speedgraph.cpp \
 301     src/GUI/sliderinfoitem.cpp \
 302     src/GUI/filebrowser.cpp \
 303     src/GUI/scaleitem.cpp \
 304     src/GUI/graphview.cpp \
 305     src/GUI/waypointitem.cpp \
 306     src/GUI/palette.cpp \
 307     src/GUI/heartrategraph.cpp \
 308     src/GUI/trackinfo.cpp \
 309     src/GUI/fileselectwidget.cpp \
 310     src/GUI/temperaturegraph.cpp \
 311     src/GUI/trackitem.cpp \
 312     src/GUI/routeitem.cpp \
 313     src/GUI/graphitem.cpp \
 314     src/GUI/pathitem.cpp \
 315     src/GUI/griditem.cpp \
 316     src/GUI/format.cpp \
 317     src/GUI/cadencegraph.cpp \
 318     src/GUI/powergraph.cpp \
 319     src/GUI/gearratiograph.cpp \
 320     src/GUI/optionsdialog.cpp \
 321     src/GUI/colorbox.cpp \
 322     src/GUI/stylecombobox.cpp \
 323     src/GUI/oddspinbox.cpp \
 324     src/GUI/percentslider.cpp \
 325     src/GUI/elevationgraphitem.cpp \
 326     src/GUI/speedgraphitem.cpp \
 327     src/GUI/heartrategraphitem.cpp \
 328     src/GUI/temperaturegraphitem.cpp \
 329     src/GUI/cadencegraphitem.cpp \
 330     src/GUI/powergraphitem.cpp \
 331     src/GUI/gearratiographitem.cpp \
 332     src/GUI/mapview.cpp \
 333     src/GUI/areaitem.cpp \
 334     src/GUI/coordinatesitem.cpp \
 335     src/GUI/pathtickitem.cpp \
 336     src/GUI/graphicsscene.cpp \
 337     src/GUI/pdfexportdialog.cpp \
 338     src/GUI/pngexportdialog.cpp \
 339     src/GUI/projectioncombobox.cpp \
 340     src/GUI/passwordedit.cpp \
 341     src/data/twonavparser.cpp \
 342     src/map/ENC/atlasdata.cpp \
 343     src/map/ENC/mapdata.cpp \
 344     src/map/ENC/rastertile.cpp \
 345     src/map/ENC/style.cpp \
 346     src/map/conversion.cpp \
 347     src/map/encatlas.cpp \
 348     src/map/encmap.cpp \
 349     src/map/ENC/iso8211.cpp \
 350     src/map/gemfmap.cpp \
 351     src/map/gmifile.cpp \
 352     src/map/oruxmap.cpp \
 353     src/map/osmdroidmap.cpp \
 354     src/map/proj/polyconic.cpp \
 355     src/map/proj/webmercator.cpp \
 356     src/map/proj/transversemercator.cpp \
 357     src/map/proj/lambertconic.cpp \
 358     src/map/proj/albersequal.cpp \
 359     src/map/proj/lambertazimuthal.cpp \
 360     src/map/proj/mercator.cpp \
 361     src/map/proj/krovak.cpp \
 362     src/map/proj/polarstereographic.cpp \
 363     src/map/proj/obliquestereographic.cpp \
 364     src/map/bitmapline.cpp \
 365     src/map/IMG/bitstream.cpp \
 366     src/map/IMG/deltastream.cpp \
 367     src/map/IMG/gmapdata.cpp \
 368     src/map/IMG/huffmanbuffer.cpp \
 369     src/map/IMG/huffmanstream.cpp \
 370     src/map/IMG/huffmantable.cpp \
 371     src/map/IMG/huffmantext.cpp \
 372     src/map/IMG/nodfile.cpp \
 373     src/map/IMG/mapdata.cpp \
 374     src/map/IMG/rastertile.cpp \
 375     src/map/IMG/imgdata.cpp \
 376     src/map/IMG/subfile.cpp \
 377     src/map/IMG/trefile.cpp \
 378     src/map/IMG/rgnfile.cpp \
 379     src/map/IMG/lblfile.cpp \
 380     src/map/IMG/vectortile.cpp \
 381     src/map/IMG/style.cpp \
 382     src/map/IMG/netfile.cpp \
 383     src/map/mapsforge/style.cpp \
 384     src/map/mapsforge/mapdata.cpp \
 385     src/map/mapsforge/rastertile.cpp \
 386     src/map/mapsforge/subfile.cpp \
 387     src/map/imgmap.cpp \
 388     src/map/prjfile.cpp \
 389     src/map/qctmap.cpp \
 390     src/map/textpathitem.cpp \
 391     src/map/textpointitem.cpp \
 392     src/map/bsbmap.cpp \
 393     src/map/kmzmap.cpp \
 394     src/map/maplist.cpp \
 395     src/map/onlinemap.cpp \
 396     src/map/emptymap.cpp \
 397     src/map/ozimap.cpp \
 398     src/map/sqlitemap.cpp \
 399     src/map/tar.cpp \
 400     src/map/atlas.cpp \
 401     src/map/ozf.cpp \
 402     src/map/matrix.cpp \
 403     src/map/ellipsoid.cpp \
 404     src/map/datum.cpp \
 405     src/map/utm.cpp \
 406     src/map/geotiff.cpp \
 407     src/map/pcs.cpp \
 408     src/map/transform.cpp \
 409     src/map/mapfile.cpp \
 410     src/map/projection.cpp \
 411     src/map/gcs.cpp \
 412     src/map/angularunits.cpp \
 413     src/map/primemeridian.cpp \
 414     src/map/linearunits.cpp \
 415     src/map/mapsource.cpp \
 416     src/map/tileloader.cpp \
 417     src/map/wldfile.cpp \
 418     src/map/wmtsmap.cpp \
 419     src/map/wmts.cpp \
 420     src/map/wmsmap.cpp \
 421     src/map/wms.cpp \
 422     src/map/crs.cpp \
 423     src/map/coordinatesystem.cpp \
 424     src/map/geocentric.cpp \
 425     src/map/jnxmap.cpp \
 426     src/map/map.cpp \
 427     src/map/geotiffmap.cpp \
 428     src/map/image.cpp \
 429     src/map/mbtilesmap.cpp \
 430     src/map/osm.cpp \
 431     src/map/rectd.cpp \
 432     src/map/rmap.cpp \
 433     src/map/textitem.cpp \
 434     src/map/aqmmap.cpp \
 435     src/map/mapsforgemap.cpp \
 436     src/map/worldfilemap.cpp \
 437     src/data/address.cpp \
 438     src/data/itnparser.cpp \
 439     src/data/onmoveparsers.cpp \
 440     src/data/ov2parser.cpp \
 441     src/data/waypoint.cpp \
 442     src/data/data.cpp \
 443     src/data/poi.cpp \
 444     src/data/track.cpp \
 445     src/data/route.cpp \
 446     src/data/path.cpp \
 447     src/data/gpxparser.cpp \
 448     src/data/tcxparser.cpp \
 449     src/data/csvparser.cpp \
 450     src/data/kmlparser.cpp \
 451     src/data/fitparser.cpp \
 452     src/data/igcparser.cpp \
 453     src/data/nmeaparser.cpp \
 454     src/data/oziparsers.cpp \
 455     src/data/locparser.cpp \
 456     src/data/slfparser.cpp \
 457     src/data/dem.cpp \
 458     src/data/demloader.cpp \
 459     src/data/exifparser.cpp \
 460     src/data/cupparser.cpp \
 461     src/data/gpiparser.cpp \
 462     src/data/smlparser.cpp \
 463     src/data/geojsonparser.cpp
 464
 465 DEFINES += APP_VERSION=\\\"$$VERSION\\\" \
 466     QT_NO_DEPRECATED_WARNINGS
 467
 468 RESOURCES += gpxsee.qrc
 469 TRANSLATIONS = lang/gpxsee_en.ts \
 470     lang/gpxsee_cs.ts \
 471     lang/gpxsee_sv.ts \
 472     lang/gpxsee_de.ts \
 473     lang/gpxsee_ru.ts \
 474     lang/gpxsee_fi.ts \
 475     lang/gpxsee_fr.ts \
 476     lang/gpxsee_pl.ts \
 477     lang/gpxsee_nb.ts \
 478     lang/gpxsee_da.ts \
 479     lang/gpxsee_tr.ts \
 480     lang/gpxsee_es.ts \
 481     lang/gpxsee_pt_BR.ts \
 482     lang/gpxsee_uk.ts \
 483     lang/gpxsee_hu.ts \
 484     lang/gpxsee_it.ts \
 485     lang/gpxsee_eo.ts \
 486     lang/gpxsee_zh.ts \
 487     lang/gpxsee_ca.ts \
 488     lang/gpxsee_ko.ts
 489
 490 macx {
 491     ICON = icons/app/gpxsee.icns
 492     QMAKE_INFO_PLIST = pkg/mac/Info.plist
 493     locale.path = Contents/Resources/translations
 494     locale.files = $$files(lang/*.qm)
 495     crs.path = Contents/Resources
 496     crs.files = data/CRS
 497     maps.path = Contents/Resources
 498     maps.files = data/maps
 499     symbols.path = Contents/Resources/symbols
 500     symbols.files = $$files(icons/symbols/*.png)
 501     icons.path = Contents/Resources/icons
 502     icons.files = $$files(icons/formats/*.icns)
 503     lproj.path = Contents/Resources
 504     lproj.files = $$files(pkg/mac/lproj/*)
 505
 506     QMAKE_BUNDLE_DATA += locale maps symbols icons crs lproj
 507 }
 508
 509 win32 {
 510     QMAKE_TARGET_DESCRIPTION = GPXSee
 511     QMAKE_TARGET_COPYRIGHT = Copyright (c) 2023 Martin Tůma
 512     RC_ICONS = icons/app/gpxsee.ico \
 513         icons/formats/gpx.ico \
 514         icons/formats/tcx.ico \
 515         icons/formats/kml.ico \
 516         icons/formats/fit.ico \
 517         icons/formats/igc.ico \
 518         icons/formats/nmea.ico \
 519         icons/formats/plt.ico \
 520         icons/formats/rte.ico \
 521         icons/formats/wpt.ico \
 522         icons/formats/loc.ico \
 523         icons/formats/slf.ico \
 524         icons/formats/json.ico \
 525         icons/formats/cup.ico \
 526         icons/formats/gpi.ico \
 527         icons/formats/sml.ico \
 528         icons/formats/img.ico \
 529         icons/formats/jnx.ico \
 530         icons/formats/kap.ico \
 531         icons/formats/map.ico \
 532         icons/formats/mbts.ico \
 533         icons/formats/rmap.ico \
 534         icons/formats/tba.ico \
 535         icons/formats/aqm.ico \
 536         icons/formats/sqlt.ico \
 537         icons/formats/ov2.ico \
 538         icons/formats/itn.ico \
 539         icons/formats/wld.ico \
 540         icons/formats/omd.ico \
 541         icons/formats/ghp.ico \
 542         icons/formats/qct.ico \
 543         icons/formats/trk.ico \
 544         icons/formats/gemf.ico \
 545         icons/formats/000.ico \
 546         icons/formats/031.ico
 547     DEFINES += _USE_MATH_DEFINES \
 548         NOGDI
 549 }
 550
 551 unix:!macx:!android {
 552     isEmpty(PREFIX):PREFIX = /usr/local
 553
 554     maps.files = $$files(data/maps/*)
 555     maps.path = $$PREFIX/share/gpxsee/maps
 556     crs.files = $$files(data/CRS/*)
 557     crs.path = $$PREFIX/share/gpxsee/CRS
 558     symbols.files = $$files(icons/symbols/*.png)
 559     symbols.path = $$PREFIX/share/gpxsee/symbols
 560     locale.files = $$files(lang/*.qm)
 561     locale.path = $$PREFIX/share/gpxsee/translations
 562     icon.files = $$files(icons/app/hicolor/*)
 563     icon.path = $$PREFIX/share/icons/hicolor
 564     desktop.files = pkg/linux/gpxsee.desktop
 565     desktop.path = $$PREFIX/share/applications
 566     mime.files = pkg/linux/gpxsee.xml
 567     mime.path = $$PREFIX/share/mime/packages
 568     appdata.files = pkg/linux/gpxsee.appdata.xml
 569     appdata.path = $$PREFIX/share/metainfo
 570     target.path = $$PREFIX/bin
 571     INSTALLS += target maps crs symbols locale icon desktop mime appdata
 572 }
 573
 574 android {
 575     HEADERS += src/GUI/navigationwidget.h
 576     SOURCES += src/GUI/navigationwidget.cpp
 577
 578     defineReplace(versionCode) {
 579         segments = $$split(1, ".")
 580         for (segment, segments): \
 581             vCode = "$$first(vCode)$$format_number($$segment, width=3 zeropad)"
 582         contains(ANDROID_TARGET_ARCH, armeabi-v7a): \
 583             suffix = 0
 584         contains(ANDROID_TARGET_ARCH, arm64-v8a): \
 585             suffix = 1
 586         contains(ANDROID_TARGET_ARCH, x86): \
 587             suffix = 2
 588         contains(ANDROID_TARGET_ARCH, x86_64): \
 589             suffix = 3
 590
 591         return($$first(vCode)$$first(suffix))
 592     }
 593
 594     !include($$OPENSSL_PATH/openssl.pri) {
 595         message("OpenSSL not found, building without HTTPS support!")
 596     }
 597
 598     ANDROID_TARGET_SDK_VERSION = 33
 599     ANDROID_VERSION_NAME = $$VERSION
 600     ANDROID_VERSION_CODE = $$versionCode($$ANDROID_VERSION_NAME)
 601     ANDROID_PACKAGE_SOURCE_DIR = $$PWD/pkg/android
 602     DISTFILES += \
 603         pkg/android/AndroidManifest.xml \
 604         pkg/android/build.gradle \
 605         pkg/android/res/values/libs.xml
 606
 607     maps.files = $$files(data/maps/*)
 608     maps.path = /assets/maps
 609     crs.files = $$files(data/CRS/*)
 610     crs.path = /assets/CRS
 611     symbols.files = $$files(icons/symbols/*.png)
 612     symbols.path = /assets/symbols
 613     translations.files = $$files(lang/*.qm)
 614     translations.path = /assets/translations
 615     INSTALLS += maps crs symbols translations
 616 }