pkg/windows/gpxsee64.nsi

   1 !include "MUI2.nsh"
   2 !include "x64.nsh"
   3 !include "WinVer.nsh"
   4
   5
   6 ; Macros
   7
   8 ; File association
   9 !macro FILE_ASSOCIATION_ADD EXT DESC ICON
  10   WriteRegStr HKCR ".${EXT}" "" "GPXSee.${EXT}"
  11   WriteRegStr HKCR "GPXSee.${EXT}" ""  "${DESC}"
  12   WriteRegStr HKCR "GPXSee.${EXT}\DefaultIcon" "" "$INSTDIR\GPXSee.exe,${ICON}"
  13   WriteRegStr HKCR "GPXSee.${EXT}\shell\open\command" "" "$\"$INSTDIR\GPXSee.exe$\" $\"%1$\""
  14 !macroend
  15
  16 !macro FILE_ASSOCIATION_REMOVE EXT
  17   DeleteRegKey HKCR "GPXSee.${EXT}"
  18   DeleteRegKey HKCR ".${EXT}"
  19 !macroend
  20
  21 ; Translations
  22 !macro LOCALIZATION LANG CODE
  23   Section "${LANG}"
  24     IfFileExists "$INSTDIR\translations" +2 0
  25       CreateDirectory "$INSTDIR\translations"
  26     File /oname=translations\gpxsee_${CODE}.qm translations\gpxsee_${CODE}.qm
  27     !if /FileExists translations\qt_${CODE}.qm
  28       File /oname=translations\qt_${CODE}.qm translations\qt_${CODE}.qm
  29     !endif
  30   SectionEnd
  31 !macroend
  32
  33 ;--------------------------------
  34
  35 Unicode true
  36
  37 ; The name of the installer
  38 Name "GPXSee"
  39 ; Program version
  40 !define VERSION "13.3"
  41
  42 ; The file to write
  43 OutFile "GPXSee-${VERSION}_x64.exe"
  44 ; Compression method
  45 SetCompressor /SOLID lzma
  46
  47 ; Required execution level
  48 RequestExecutionLevel admin
  49
  50 ; Don't let the OS scale(blur) the installer GUI
  51 ManifestDPIAware true
  52
  53 ; The default installation directory
  54 InstallDir "$PROGRAMFILES64\GPXSee"
  55
  56 ; Installer executable info
  57 VIProductVersion "${VERSION}.0.0"
  58 VIAddVersionKey "ProductVersion" ${VERSION}
  59 VIAddVersionKey "FileVersion" "${VERSION}.0.0"
  60 VIAddVersionKey "ProductName" "GPXSee"
  61 VIAddVersionKey "LegalCopyright" "GPXSee project"
  62 VIAddVersionKey "FileDescription" "GPXSee installer (x64)"
  63
  64 ; Registry key to check for directory (so if you install again, it will
  65 ; overwrite the old one automatically)
  66 InstallDirRegKey HKLM "Software\GPXSee" "Install_Dir"
  67
  68 ; Registry key for uninstaller
  69 !define REGENTRY "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPXSee"
  70
  71 ; Start menu page configuration
  72 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKLM"
  73 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GPXSee"
  74 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "GPXSee"
  75
  76 Var StartMenuFolder
  77
  78 ;--------------------------------
  79
  80 ; Pages
  81
  82 !insertmacro MUI_PAGE_WELCOME
  83 !insertmacro MUI_PAGE_LICENSE "licence.txt"
  84 !insertmacro MUI_PAGE_COMPONENTS
  85 !insertmacro MUI_PAGE_DIRECTORY
  86 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
  87 !insertmacro MUI_PAGE_INSTFILES
  88
  89 !insertmacro MUI_UNPAGE_CONFIRM
  90 !insertmacro MUI_UNPAGE_INSTFILES
  91
  92 ;--------------------------------
  93
  94 ; Languages
  95 !insertmacro MUI_LANGUAGE "English"
  96
  97 Function .onInit
  98   ${IfNot} ${AtLeastWin7}
  99     MessageBox MB_OK "GPXSee can only be installed on Windows 7 or later."
 100     Abort
 101   ${EndIf}
 102
 103   ${If} ${RunningX64}
 104     SetRegView 64
 105   ${Else}
 106     MessageBox MB_OK "The 64b version of GPXSee can not be run on 32b systems."
 107     Abort
 108   ${EndIf}
 109 FunctionEnd
 110
 111 ; The stuff to install
 112 Section "GPXSee" SEC_APP
 113
 114   SectionIn RO
 115
 116   ; Set output path to the installation directory
 117   SetOutPath $INSTDIR
 118
 119   ; Put the files there
 120   File "gpxsee.exe"
 121   File /r "maps"
 122   File /r "CRS"
 123   File /r "symbols"
 124
 125   ; Create the uninstaller
 126   WriteUninstaller "$INSTDIR\uninstall.exe"
 127
 128   ; Create start menu entry and add links
 129   SetShellVarContext all
 130   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 131     CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 132     CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk" "$INSTDIR\Uninstall.exe"
 133     CreateShortCut "$SMPROGRAMS\$StartMenuFolder\GPXSee.lnk" "$INSTDIR\gpxsee.exe"
 134   !insertmacro MUI_STARTMENU_WRITE_END
 135
 136   ; Write the installation path into the registry
 137   DetailPrint "Registering application..."
 138   WriteRegStr HKLM SOFTWARE\GPXSee "Install_Dir" "$INSTDIR"
 139
 140   ; Write the uninstall keys for Windows
 141   WriteRegStr HKLM "${REGENTRY}" "DisplayName" "GPXSee (x64)"
 142   WriteRegStr HKLM "${REGENTRY}" "Publisher" "Martin Tůma"
 143   WriteRegStr HKLM "${REGENTRY}" "DisplayVersion" "${VERSION}"
 144   WriteRegStr HKLM "${REGENTRY}" "UninstallString" '"$INSTDIR\uninstall.exe"'
 145   WriteRegStr HKLM "${REGENTRY}" "DisplayIcon" '"$INSTDIR\gpxsee.exe"'
 146   WriteRegStr HKLM "${REGENTRY}" "InstallLocation" '"$INSTDIR"'
 147   WriteRegStr HKLM "${REGENTRY}" "URLInfoAbout" "https://www.gpxsee.org"
 148   WriteRegDWORD HKLM "${REGENTRY}" "NoModify" 1
 149   WriteRegDWORD HKLM "${REGENTRY}" "NoRepair" 1
 150
 151   ; Associate file formats
 152   DetailPrint "Associating file types..."
 153   !insertmacro FILE_ASSOCIATION_ADD "wpt" "OziExplorer Waypoint File" 1
 154   !insertmacro FILE_ASSOCIATION_ADD "loc" "Geocaching.com Waypoint File" 2
 155   !insertmacro FILE_ASSOCIATION_ADD "slf" "Sigma Log File" 3
 156   !insertmacro FILE_ASSOCIATION_ADD "geojson" "GeoJSON" 4
 157   !insertmacro FILE_ASSOCIATION_ADD "cup" "SeeYou CUP File" 5
 158   !insertmacro FILE_ASSOCIATION_ADD "gpi" "Garmin POI File" 6
 159   !insertmacro FILE_ASSOCIATION_ADD "sml" "Suunto Markup Language" 7
 160   !insertmacro FILE_ASSOCIATION_ADD "img" "Garmin IMG Map" 8
 161   !insertmacro FILE_ASSOCIATION_ADD "jnx" "Garmin JNX Map" 9
 162   !insertmacro FILE_ASSOCIATION_ADD "kap" "BSB Nautical Chart" 10
 163   !insertmacro FILE_ASSOCIATION_ADD "gpx" "GPS Exchange Format" 11
 164   !insertmacro FILE_ASSOCIATION_ADD "map" "OziExplorer Map File" 12
 165   !insertmacro FILE_ASSOCIATION_ADD "mbtiles" "MBTiles Map File" 13
 166   !insertmacro FILE_ASSOCIATION_ADD "rmap" "TwoNav Raster Map File" 14
 167   !insertmacro FILE_ASSOCIATION_ADD "tba" "TrekBuddy Atlas" 15
 168   !insertmacro FILE_ASSOCIATION_ADD "aqm" "AlpineQuest Map File" 16
 169   !insertmacro FILE_ASSOCIATION_ADD "sqlite" "Osmdroid SQLite Map File" 17
 170   !insertmacro FILE_ASSOCIATION_ADD "sqlitedb" "RMaps SQLite Map File" 17
 171   !insertmacro FILE_ASSOCIATION_ADD "ov2" "TomTom POI File" 18
 172   !insertmacro FILE_ASSOCIATION_ADD "itn" "TomTom Route File" 19
 173   !insertmacro FILE_ASSOCIATION_ADD "wld" "ESRI World File" 20
 174   !insertmacro FILE_ASSOCIATION_ADD "jgw" "ESRI World File" 20
 175   !insertmacro FILE_ASSOCIATION_ADD "gfw" "ESRI World File" 20
 176   !insertmacro FILE_ASSOCIATION_ADD "pgw" "ESRI World File" 20
 177   !insertmacro FILE_ASSOCIATION_ADD "tfw" "ESRI World File" 20
 178   !insertmacro FILE_ASSOCIATION_ADD "omd" "ONmove Log File" 21
 179   !insertmacro FILE_ASSOCIATION_ADD "tcx" "Training Center XML" 22
 180   !insertmacro FILE_ASSOCIATION_ADD "ghp" "ONmove Log File" 23
 181   !insertmacro FILE_ASSOCIATION_ADD "qct" "QuickChart Map File" 24
 182   !insertmacro FILE_ASSOCIATION_ADD "trk" "TwoNav Track File" 25
 183   !insertmacro FILE_ASSOCIATION_ADD "gemf" "GEMF Map File" 26
 184   !insertmacro FILE_ASSOCIATION_ADD "000" "IHO S-57 Electronic Navigation Chart" 27
 185   !insertmacro FILE_ASSOCIATION_ADD "kml" "Keyhole Markup Language" 28
 186   !insertmacro FILE_ASSOCIATION_ADD "kmz" "KML geographic compressed data" 28
 187   !insertmacro FILE_ASSOCIATION_ADD "fit" "Flexible and Interoperable Data Transfer" 29
 188   !insertmacro FILE_ASSOCIATION_ADD "igc" "Flight Recorder Data Format" 30
 189   !insertmacro FILE_ASSOCIATION_ADD "nmea" "NMEA 0183 Data" 31
 190   !insertmacro FILE_ASSOCIATION_ADD "plt" "OziExplorer Track File" 32
 191   !insertmacro FILE_ASSOCIATION_ADD "rte" "OziExplorer Route File" 33
 192
 193   WriteRegStr HKCR "Applications\GPXSee.exe\shell\open\command" "" "$\"$INSTDIR\GPXSee.exe$\" $\"%1$\""
 194   WriteRegStr HKCR ".gpx\OpenWithList" "GPXSee.exe" ""
 195   WriteRegStr HKCR ".tcx\OpenWithList" "GPXSee.exe" ""
 196   WriteRegStr HKCR ".kml\OpenWithList" "GPXSee.exe" ""
 197   WriteRegStr HKCR ".fit\OpenWithList" "GPXSee.exe" ""
 198   WriteRegStr HKCR ".igc\OpenWithList" "GPXSee.exe" ""
 199   WriteRegStr HKCR ".nmea\OpenWithList" "GPXSee.exe" ""
 200   WriteRegStr HKCR ".plt\OpenWithList" "GPXSee.exe" ""
 201   WriteRegStr HKCR ".rte\OpenWithList" "GPXSee.exe" ""
 202   WriteRegStr HKCR ".wpt\OpenWithList" "GPXSee.exe" ""
 203   WriteRegStr HKCR ".loc\OpenWithList" "GPXSee.exe" ""
 204   WriteRegStr HKCR ".slf\OpenWithList" "GPXSee.exe" ""
 205   WriteRegStr HKCR ".geojson\OpenWithList" "GPXSee.exe" ""
 206   WriteRegStr HKCR ".cup\OpenWithList" "GPXSee.exe" ""
 207   WriteRegStr HKCR ".gpi\OpenWithList" "GPXSee.exe" ""
 208   WriteRegStr HKCR ".sml\OpenWithList" "GPXSee.exe" ""
 209   WriteRegStr HKCR ".ov2\OpenWithList" "GPXSee.exe" ""
 210   WriteRegStr HKCR ".itn\OpenWithList" "GPXSee.exe" ""
 211   WriteRegStr HKCR ".csv\OpenWithList" "GPXSee.exe" ""
 212   WriteRegStr HKCR ".json\OpenWithList" "GPXSee.exe" ""
 213   WriteRegStr HKCR ".jpg\OpenWithList" "GPXSee.exe" ""
 214   WriteRegStr HKCR ".jpeg\OpenWithList" "GPXSee.exe" ""
 215   WriteRegStr HKCR ".img\OpenWithList" "GPXSee.exe" ""
 216   WriteRegStr HKCR ".jnx\OpenWithList" "GPXSee.exe" ""
 217   WriteRegStr HKCR ".kap\OpenWithList" "GPXSee.exe" ""
 218   WriteRegStr HKCR ".map\OpenWithList" "GPXSee.exe" ""
 219   WriteRegStr HKCR ".mbtiles\OpenWithList" "GPXSee.exe" ""
 220   WriteRegStr HKCR ".rmap\OpenWithList" "GPXSee.exe" ""
 221   WriteRegStr HKCR ".rtmap\OpenWithList" "GPXSee.exe" ""
 222   WriteRegStr HKCR ".tar\OpenWithList" "GPXSee.exe" ""
 223   WriteRegStr HKCR ".tba\OpenWithList" "GPXSee.exe" ""
 224   WriteRegStr HKCR ".tif\OpenWithList" "GPXSee.exe" ""
 225   WriteRegStr HKCR ".tiff\OpenWithList" "GPXSee.exe" ""
 226   WriteRegStr HKCR ".xml\OpenWithList" "GPXSee.exe" ""
 227   WriteRegStr HKCR ".kmz\OpenWithList" "GPXSee.exe" ""
 228   WriteRegStr HKCR ".aqm\OpenWithList" "GPXSee.exe" ""
 229   WriteRegStr HKCR ".sqlite\OpenWithList" "GPXSee.exe" ""
 230   WriteRegStr HKCR ".sqlitedb\OpenWithList" "GPXSee.exe" ""
 231   WriteRegStr HKCR ".wld\OpenWithList" "GPXSee.exe" ""
 232   WriteRegStr HKCR ".jgw\OpenWithList" "GPXSee.exe" ""
 233   WriteRegStr HKCR ".gfw\OpenWithList" "GPXSee.exe" ""
 234   WriteRegStr HKCR ".pgw\OpenWithList" "GPXSee.exe" ""
 235   WriteRegStr HKCR ".tfw\OpenWithList" "GPXSee.exe" ""
 236   WriteRegStr HKCR ".omd\OpenWithList" "GPXSee.exe" ""
 237   WriteRegStr HKCR ".ghp\OpenWithList" "GPXSee.exe" ""
 238   WriteRegStr HKCR ".qct\OpenWithList" "GPXSee.exe" ""
 239   WriteRegStr HKCR ".trk\OpenWithList" "GPXSee.exe" ""
 240   WriteRegStr HKCR ".gemf\OpenWithList" "GPXSee.exe" ""
 241   WriteRegStr HKCR ".000\OpenWithList" "GPXSee.exe" ""
 242
 243   System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (0x08000000, 0, 0, 0)'
 244
 245 SectionEnd
 246
 247 Section "QT framework" SEC_QT
 248
 249   SectionIn RO
 250
 251 !ifdef QT6
 252   File "Qt6Concurrent.dll"
 253   File "Qt6Core.dll"
 254   File "Qt6Gui.dll"
 255   File "Qt6Network.dll"
 256   File "Qt6OpenGL.dll"
 257   File "Qt6OpenGLWidgets.dll"
 258   File "Qt6PrintSupport.dll"
 259   File "Qt6Sql.dll"
 260   File "Qt6Svg.dll"
 261   File "Qt6Widgets.dll"
 262   File "Qt6Core5Compat.dll"
 263   File "Qt6Positioning.dll"
 264   File "Qt6SerialPort.dll"
 265   File /r "tls"
 266 !else
 267   File "Qt5Core.dll"
 268   File "Qt5Gui.dll"
 269   File "Qt5Widgets.dll"
 270   File "Qt5PrintSupport.dll"
 271   File "Qt5Network.dll"
 272   File "Qt5Sql.dll"
 273   File "Qt5Svg.dll"
 274   File "Qt5Concurrent.dll"
 275   File "Qt5Positioning.dll"
 276   File "Qt5SerialPort.dll"
 277   File /r "printsupport"
 278 !endif
 279   File /r "platforms"
 280   File /r "imageformats"
 281   File /r "styles"
 282   File /r "sqldrivers"
 283   File /r "position"
 284
 285 SectionEnd
 286
 287 Section "MSVC runtime" SEC_MSVC
 288
 289   SectionIn RO
 290
 291   SetOutPath $TEMP
 292   File "vc_redist.x64.exe"
 293   ExecWait '"$TEMP\vc_redist.x64.exe" /install /quiet /norestart'
 294   SetOutPath $INSTDIR
 295
 296 SectionEnd
 297
 298 Section "OpenSSL" SEC_OPENSSL
 299
 300   SectionIn RO
 301
 302   File "libcrypto-1_1-x64.dll"
 303   File "libssl-1_1-x64.dll"
 304
 305 SectionEnd
 306
 307 !ifndef QT6
 308 Section "ANGLE" SEC_ANGLE
 309
 310   File "libGLESv2.dll"
 311   File "libEGL.dll"
 312   File "D3DCompiler_47.dll"
 313
 314 SectionEnd
 315 !endif
 316
 317 SectionGroup "Localization" SEC_LOCALIZATION
 318   !insertmacro LOCALIZATION "Catalan" "ca"
 319   !insertmacro LOCALIZATION "Chinese (Simplified)" "zh"
 320   !insertmacro LOCALIZATION "Czech" "cs"
 321   !insertmacro LOCALIZATION "Danish" "da"
 322   !insertmacro LOCALIZATION "Esperanto" "eo"
 323   !insertmacro LOCALIZATION "Finnish" "fi"
 324   !insertmacro LOCALIZATION "French" "fr"
 325   !insertmacro LOCALIZATION "German" "de"
 326   !insertmacro LOCALIZATION "Hungarian" "hu"
 327   !insertmacro LOCALIZATION "Italian" "it"
 328   !insertmacro LOCALIZATION "Korean" "ko"
 329   !insertmacro LOCALIZATION "Norwegian" "nb"
 330   !insertmacro LOCALIZATION "Polish" "pl"
 331   !insertmacro LOCALIZATION "Portuguese (Brazil)" "pt_BR"
 332   !insertmacro LOCALIZATION "Russian" "ru"
 333   !insertmacro LOCALIZATION "Spanish" "es"
 334   !insertmacro LOCALIZATION "Swedish" "sv"
 335   !insertmacro LOCALIZATION "Turkish" "tr"
 336   !insertmacro LOCALIZATION "Ukrainian" "uk"
 337 SectionGroupEnd
 338
 339 ;--------------------------------
 340
 341 ; Uninstaller
 342
 343 Section "Uninstall"
 344
 345   ; Remove registry keys
 346   SetRegView 64
 347   DeleteRegKey HKLM "${REGENTRY}"
 348   DeleteRegKey HKLM SOFTWARE\GPXSee
 349
 350   ; Remove directories used
 351   RMDir /r "$INSTDIR"
 352
 353   ; Remove Start menu entries
 354   SetShellVarContext all
 355   !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 356   Delete "$SMPROGRAMS\$StartMenuFolder\*.*"
 357   RMDir "$SMPROGRAMS\$StartMenuFolder"
 358
 359   ; Remove file associations
 360   !insertmacro FILE_ASSOCIATION_REMOVE "gpx"
 361   !insertmacro FILE_ASSOCIATION_REMOVE "tcx"
 362   !insertmacro FILE_ASSOCIATION_REMOVE "kml"
 363   !insertmacro FILE_ASSOCIATION_REMOVE "fit"
 364   !insertmacro FILE_ASSOCIATION_REMOVE "igc"
 365   !insertmacro FILE_ASSOCIATION_REMOVE "nmea"
 366   !insertmacro FILE_ASSOCIATION_REMOVE "plt"
 367   !insertmacro FILE_ASSOCIATION_REMOVE "rte"
 368   !insertmacro FILE_ASSOCIATION_REMOVE "wpt"
 369   !insertmacro FILE_ASSOCIATION_REMOVE "loc"
 370   !insertmacro FILE_ASSOCIATION_REMOVE "slf"
 371   !insertmacro FILE_ASSOCIATION_REMOVE "geojson"
 372   !insertmacro FILE_ASSOCIATION_REMOVE "cup"
 373   !insertmacro FILE_ASSOCIATION_REMOVE "gpi"
 374   !insertmacro FILE_ASSOCIATION_REMOVE "sml"
 375   !insertmacro FILE_ASSOCIATION_REMOVE "img"
 376   !insertmacro FILE_ASSOCIATION_REMOVE "jnx"
 377   !insertmacro FILE_ASSOCIATION_REMOVE "kap"
 378   !insertmacro FILE_ASSOCIATION_REMOVE "map"
 379   !insertmacro FILE_ASSOCIATION_REMOVE "mbtiles"
 380   !insertmacro FILE_ASSOCIATION_REMOVE "rmap"
 381   !insertmacro FILE_ASSOCIATION_REMOVE "tba"
 382   !insertmacro FILE_ASSOCIATION_REMOVE "kmz"
 383   !insertmacro FILE_ASSOCIATION_REMOVE "aqm"
 384   !insertmacro FILE_ASSOCIATION_REMOVE "sqlite"
 385   !insertmacro FILE_ASSOCIATION_REMOVE "sqlitedb"
 386   !insertmacro FILE_ASSOCIATION_REMOVE "ov2"
 387   !insertmacro FILE_ASSOCIATION_REMOVE "itn"
 388   !insertmacro FILE_ASSOCIATION_REMOVE "wld"
 389   !insertmacro FILE_ASSOCIATION_REMOVE "jgw"
 390   !insertmacro FILE_ASSOCIATION_REMOVE "gfw"
 391   !insertmacro FILE_ASSOCIATION_REMOVE "pgw"
 392   !insertmacro FILE_ASSOCIATION_REMOVE "tfw"
 393   !insertmacro FILE_ASSOCIATION_REMOVE "omd"
 394   !insertmacro FILE_ASSOCIATION_REMOVE "ghp"
 395   !insertmacro FILE_ASSOCIATION_REMOVE "qct"
 396   !insertmacro FILE_ASSOCIATION_REMOVE "trk"
 397   !insertmacro FILE_ASSOCIATION_REMOVE "gemf"
 398   !insertmacro FILE_ASSOCIATION_REMOVE "000"
 399
 400   DeleteRegValue HKCR ".gpx\OpenWithList" "GPXSee.exe"
 401   DeleteRegValue HKCR ".tcx\OpenWithList" "GPXSee.exe"
 402   DeleteRegValue HKCR ".kml\OpenWithList" "GPXSee.exe"
 403   DeleteRegValue HKCR ".fit\OpenWithList" "GPXSee.exe"
 404   DeleteRegValue HKCR ".igc\OpenWithList" "GPXSee.exe"
 405   DeleteRegValue HKCR ".nmea\OpenWithList" "GPXSee.exe"
 406   DeleteRegValue HKCR ".plt\OpenWithList" "GPXSee.exe"
 407   DeleteRegValue HKCR ".rte\OpenWithList" "GPXSee.exe"
 408   DeleteRegValue HKCR ".wpt\OpenWithList" "GPXSee.exe"
 409   DeleteRegValue HKCR ".loc\OpenWithList" "GPXSee.exe"
 410   DeleteRegValue HKCR ".slf\OpenWithList" "GPXSee.exe"
 411   DeleteRegValue HKCR ".geojson\OpenWithList" "GPXSee.exe"
 412   DeleteRegValue HKCR ".cup\OpenWithList" "GPXSee.exe"
 413   DeleteRegValue HKCR ".gpi\OpenWithList" "GPXSee.exe"
 414   DeleteRegValue HKCR ".sml\OpenWithList" "GPXSee.exe"
 415   DeleteRegValue HKCR ".ov2\OpenWithList" "GPXSee.exe"
 416   DeleteRegValue HKCR ".itn\OpenWithList" "GPXSee.exe"
 417   DeleteRegValue HKCR ".csv\OpenWithList" "GPXSee.exe"
 418   DeleteRegValue HKCR ".json\OpenWithList" "GPXSee.exe"
 419   DeleteRegValue HKCR ".jpg\OpenWithList" "GPXSee.exe"
 420   DeleteRegValue HKCR ".jpeg\OpenWithList" "GPXSee.exe"
 421   DeleteRegValue HKCR ".img\OpenWithList" "GPXSee.exe"
 422   DeleteRegValue HKCR ".jnx\OpenWithList" "GPXSee.exe"
 423   DeleteRegValue HKCR ".kap\OpenWithList" "GPXSee.exe"
 424   DeleteRegValue HKCR ".map\OpenWithList" "GPXSee.exe"
 425   DeleteRegValue HKCR ".mbtiles\OpenWithList" "GPXSee.exe"
 426   DeleteRegValue HKCR ".rmap\OpenWithList" "GPXSee.exe"
 427   DeleteRegValue HKCR ".rtmap\OpenWithList" "GPXSee.exe"
 428   DeleteRegValue HKCR ".tar\OpenWithList" "GPXSee.exe"
 429   DeleteRegValue HKCR ".tba\OpenWithList" "GPXSee.exe"
 430   DeleteRegValue HKCR ".tif\OpenWithList" "GPXSee.exe"
 431   DeleteRegValue HKCR ".tiff\OpenWithList" "GPXSee.exe"
 432   DeleteRegValue HKCR ".xml\OpenWithList" "GPXSee.exe"
 433   DeleteRegValue HKCR ".kmz\OpenWithList" "GPXSee.exe"
 434   DeleteRegValue HKCR ".aqm\OpenWithList" "GPXSee.exe"
 435   DeleteRegValue HKCR ".sqlite\OpenWithList" "GPXSee.exe"
 436   DeleteRegValue HKCR ".sqlitedb\OpenWithList" "GPXSee.exe"
 437   DeleteRegValue HKCR ".wld\OpenWithList" "GPXSee.exe"
 438   DeleteRegValue HKCR ".jgw\OpenWithList" "GPXSee.exe"
 439   DeleteRegValue HKCR ".gfw\OpenWithList" "GPXSee.exe"
 440   DeleteRegValue HKCR ".pgw\OpenWithList" "GPXSee.exe"
 441   DeleteRegValue HKCR ".tfw\OpenWithList" "GPXSee.exe"
 442   DeleteRegValue HKCR ".omd\OpenWithList" "GPXSee.exe"
 443   DeleteRegValue HKCR ".ghp\OpenWithList" "GPXSee.exe"
 444   DeleteRegValue HKCR ".qct\OpenWithList" "GPXSee.exe"
 445   DeleteRegValue HKCR ".trk\OpenWithList" "GPXSee.exe"
 446   DeleteRegValue HKCR ".gemf\OpenWithList" "GPXSee.exe"
 447   DeleteRegValue HKCR ".000\OpenWithList" "GPXSee.exe"
 448   DeleteRegKey HKCR "Applications\GPXSee.exe"
 449
 450   System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (0x08000000, 0, 0, 0)'
 451
 452 SectionEnd
 453
 454 ;-------------------------------
 455
 456 ; Descriptions
 457
 458 ; Language strings
 459 LangString DESC_QT ${LANG_ENGLISH} \
 460   "QT cross-platform application framework."
 461 LangString DESC_MSVC ${LANG_ENGLISH} \
 462   "Microsoft Visual C++ 2019 runtime. If already installed, will be skipped."
 463 LangString DESC_OPENSSL ${LANG_ENGLISH} \
 464   "OpenSSL library. Required for HTTPS to work."
 465 !ifndef QT6
 466 LangString DESC_ANGLE ${LANG_ENGLISH} \
 467   "ANGLE (OpenGL via Direct3D). Enables OpenGL on systems without native OpenGL drivers."
 468 !endif
 469 LangString DESC_APP ${LANG_ENGLISH} \
 470   "GPXSee application"
 471 LangString DESC_LOCALIZATION ${LANG_ENGLISH} \
 472   "Localization"
 473
 474 ; Assign language strings to sections
 475 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 476   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_QT} $(DESC_QT)
 477   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_OPENSSL} $(DESC_OPENSSL)
 478 !ifndef QT6
 479   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_ANGLE} $(DESC_ANGLE)
 480 !endif
 481   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_MSVC} $(DESC_MSVC)
 482   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_APP} $(DESC_APP)
 483   !insertmacro MUI_DESCRIPTION_TEXT ${SEC_LOCALIZATION} $(DESC_LOCALIZATION)
 484 !insertmacro MUI_FUNCTION_DESCRIPTION_END