lib/Fumo/Queue.pm

   1 package Fumo::Queue;
   2
   3 use Carp;
   4
   5 =head1 NAME
   6
   7 Fumo::Queue - Manipulate a queue of smoke server runs.
   8
   9 =head1 DESCRIPTION
  10
  11 Queue holds a queue of test runs that are to be run. It allows
  12 manipulation of a weight field so that users can change which runs
  13 happen when.
  14
  15 =head1 METHODS
  16
  17 =head2 new
  18
  19 =over 4
  20
  21 =item Arguments: $dbh
  22
  23 =item Return Value: $self
  24
  25 =back
  26
  27 Initialises a new Fumo::Queue object.
  28
  29 =cut
  30
  31 sub new {
  32     my ($class, $dbh) = @_;
  33     my $self = {
  34         dbh     => $dbh,
  35         all_sth => undef
  36     };
  37
  38     bless($self, $class);
  39
  40     return $self;
  41 }
  42
  43 =head2 empty
  44
  45 =over 4
  46
  47 =item Arguments: none
  48
  49 =item Return Value: none
  50
  51 =back
  52
  53 Empties the queue completely. Will croak on failure.
  54
  55 =cut
  56
  57 sub all_runs {
  58     my $self = shift;
  59
  60     if (not defined $self->{all_sth}) {
  61         $self->{all_sth} = $self->{dbh}->prepare(qq(
  62             SELECT
  63                 *
  64             FROM
  65                 queue
  66             ORDER BY
  67                 weight DESC
  68         ));
  69
  70         $self->{all_sth}->execute()
  71             or croak $self->{dbh}->errstr();
  72     }
  73
  74     my $details = $self->{all_sth}->fetchrow_hashref();
  75
  76     if (defined $details) {
  77         return Fumo::Queue::Run->new($details)
  78     }
  79     else {
  80         return $self->{all_sth} = undef;
  81     }
  82 }
  83
  84 =head2 empty
  85
  86 =over 4
  87
  88 =item Arguments: none
  89
  90 =item Return Value: none
  91
  92 =back
  93
  94 Empties the queue completely. Will croak on failure.
  95
  96 =cut
  97
  98 sub empty {
  99     my $self = shift;
 100
 101     $self->{dbh}->do(q(
 102         DELETE
 103         FROM
 104             queue
 105     )) or croak $self->{dbh}->errstr();
 106 }
 107
 108 =head2 count
 109
 110 =over 4
 111
 112 =item Arguments: none
 113
 114 =item Return Value: Queue count
 115
 116 =back
 117
 118 Returns the number of runs in the queue. Croaks should there be a problem.
 119
 120 =cut
 121
 122 sub count {
 123     my $self = shift;
 124
 125     my $sth = $self->{dbh}->prepare(q(
 126         SELECT
 127             count(project) as count
 128         FROM
 129             queue
 130     )) or croak $self->{dbh}->errstr();
 131
 132     $sth->execute()
 133         or croak $self->{dbh}->errstr();
 134
 135     return $sth->fetchrow_hashref->{count};
 136 }
 137
 138 =head2 put_run
 139
 140 =over 4
 141
 142 =item Arguments: Queue::Run object
 143
 144 =item Return Value: none
 145
 146 =back
 147
 148 Add a Queue::Run object to the queue.
 149
 150 =cut
 151
 152 sub put_run {
 153     my ($self, $run) = @_;
 154
 155     # does it this run already exist?
 156     if (not $self->get_run($run->project, $run->branch, $run->revision)) {
 157         my $sth = $self->{dbh}->prepare(q(
 158             INSERT INTO
 159                 queue (project, branch, revision, created)
 160             VALUES
 161                 (?, ?, ?, now())
 162         )) or croak $self->{dbh}->errstr;
 163
 164         $sth->execute($run->project, $run->branch, $run->revision)
 165             or croak $self->{dbh}->errstr;
 166     }
 167     else {
 168         my $sth = $self->{dbh}->prepare(q(
 169             UPDATE
 170                queue
 171             SET
 172                created = ?, run_start = ?, weight = ?, status = ?, comment = ?
 173             WHERE
 174                project = ? AND branch = ? AND revision = ?
 175         ));
 176
 177         # grab the argument from the Fumo::Queue::Run
 178         my @args;
 179         {
 180             no strict 'refs';
 181
 182             @args = map {
 183                 $run->$_
 184             } qw(created run_start weight status comment project branch
 185                  revision);
 186         }
 187
 188         $sth->execute(@args)
 189             or croak $self->{dbh}->errstr;
 190     }
 191 }
 192
 193 =head2 delete
 194
 195 =over 4
 196
 197 =item Arguments: Queue::Run
 198
 199 =item Return Value: none
 200
 201 =back
 202
 203 Delete the Queue::Run object given (it must have at least project,
 204 branch and revision attributes).
 205
 206 =cut
 207
 208 sub delete {
 209     my ($self, $run) = @_;
 210
 211     my $sth = $self->{dbh}->prepare(q(
 212         DELETE
 213         FROM
 214             queue
 215         WHERE
 216             project = ? AND branch = ? AND revision = ?
 217     )) or croak $self->{dbh}->errstr();
 218
 219     $sth->execute($run->project, $run->branch, $run->revision)
 220         or croak $self->{dbh}->errstr;
 221 }
 222
 223 =head2 get_run
 224
 225 =over 4
 226
 227 =item Arguments: $project, $branch, $revision
 228
 229 =item Return Value: Queue::Run
 230
 231 =back
 232
 233 Grab the Queue::Run object with the project, branch and revision.
 234
 235 =cut
 236
 237 sub get_run {
 238     my ($self, $project, $branch, $revision) = @_;
 239
 240     my $sth = $self->{dbh}->prepare(q(
 241         SELECT
 242             *
 243         FROM
 244             queue
 245         WHERE
 246             project = ? AND branch = ? AND revision = ?
 247     )) or croak $self->{dbh}->errstr;
 248
 249     $sth->execute($project, $branch, $revision)
 250         or croak $self->{dbh}->errstr;
 251
 252     my $details = $sth->fetchrow_hashref();
 253
 254     return (defined $details)
 255         ? Fumo::Queue::Run->new($details)
 256         : undef;
 257 }
 258
 259 return 1;