CMakeLists.txt

   1 #***********************************************************************
   2 #*                   GNU Lesser General Public License
   3 #*
   4 #* This file is part of the GFDL Flexible Modeling System (FMS).
   5 #*
   6 #* FMS is free software: you can redistribute it and/or modify it under
   7 #* the terms of the GNU Lesser General Public License as published by
   8 #* the Free Software Foundation, either version 3 of the License, or (at
   9 #* your option) any later version.
  10 #*
  11 #* FMS is distributed in the hope that it will be useful, but WITHOUT
  12 #* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 #* FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 #* for more details.
  15 #*
  16 #* You should have received a copy of the GNU Lesser General Public
  17 #* License along with FMS.  If not, see <http://www.gnu.org/licenses/>.
  18 #***********************************************************************
  19
  20 # Copyright (c) GFDL, @underwoo
  21
  22 cmake_minimum_required(VERSION 3.12 FATAL_ERROR)
  23
  24 # Define the CMake project
  25 project(FMS
  26   VERSION 2024.01.01
  27   DESCRIPTION  "GFDL FMS Library"
  28   HOMEPAGE_URL "https://www.gfdl.noaa.gov/fms"
  29   LANGUAGES C Fortran)
  30
  31 include(GNUInstallDirs)
  32
  33 if(NOT CMAKE_BUILD_TYPE MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)$")
  34   message(STATUS "Setting build type to 'Release' as none was specified.")
  35   set(CMAKE_BUILD_TYPE
  36       "Release"
  37       CACHE STRING "Choose the type of build." FORCE)
  38   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  39 endif()
  40
  41 if(NOT CMAKE_C_COMPILER_ID MATCHES "^(Intel|GNU|Clang|IntelLLVM)$")
  42   message(
  43     WARNING "Compiler not officially supported: ${CMAKE_C_COMPILER_ID}")
  44 endif()
  45
  46 if(NOT CMAKE_Fortran_COMPILER_ID MATCHES "^(Intel|GNU|IntelLLVM)$")
  47   message(
  48     WARNING "Compiler not officially supported: ${CMAKE_Fortran_COMPILER_ID}")
  49 endif()
  50
  51 # Append directory that contains CMake Modules for building FMS
  52 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  53
  54 # Build options
  55 option(OPENMP "Build FMS with OpenMP support"        OFF)
  56 option(32BIT  "Build 32-bit (r4) FMS library"         ON)
  57 option(64BIT  "Build 64-bit (r8) FMS library"        OFF)
  58 option(FPIC   "Build with position independent code" OFF)
  59
  60 # Options for compiler definitions
  61 option(INTERNAL_FILE_NML     "Enable compiler definition -DINTERNAL_FILE_NML"      ON)
  62 option(ENABLE_QUAD_PRECISION "Enable compiler definition -DENABLE_QUAD_PRECISION"  ON)
  63 option(GFS_PHYS              "Enable compiler definition -DGFS_PHYS"              OFF)
  64 option(LARGEFILE             "Enable compiler definition -Duse_LARGEFILE"         OFF)
  65 option(WITH_YAML             "Enable compiler definition -Duse_yaml"              OFF)
  66 option(USE_DEPRECATED_IO     "Enable compiler definition -Duse_deprecated_io (compile with fms_io/mpp_io)"   OFF)
  67
  68 if(32BIT)
  69   list(APPEND kinds "r4")
  70 endif()
  71 if(64BIT)
  72   list(APPEND kinds "r8")
  73 endif()
  74 if(NOT kinds)
  75   message(STATUS "Single Precision 32BIT: ${32BIT}")
  76   message(STATUS "Double Precision 64BIT: ${64BIT}")
  77   message(FATAL_ERROR "Either 32BIT or 64BIT should be ON")
  78 endif()
  79
  80 # Find dependencies
  81 find_package(MPI REQUIRED COMPONENTS C Fortran)
  82 find_package(NetCDF REQUIRED COMPONENTS C Fortran)
  83
  84 # Check for the OpenMP library and set the required compile flags
  85 if (OPENMP)
  86   find_package(OpenMP REQUIRED COMPONENTS C Fortran)
  87 endif()
  88
  89 if (WITH_YAML)
  90   find_package(libyaml REQUIRED)
  91   include_directories(${LIBYAML_INCLUDE_DIR})
  92 endif ()
  93
  94 # Enables position independent code (i.e., -fPIC)
  95 if (FPIC)
  96   set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  97 endif ()
  98
  99 # Collect FMS Fortran source files
 100 list(APPEND fms_fortran_src_files
 101   affinity/fms_affinity.F90
 102   amip_interp/amip_interp.F90
 103   astronomy/astronomy.F90
 104   axis_utils/axis_utils.F90
 105   axis_utils/axis_utils2.F90
 106   block_control/block_control.F90
 107   column_diagnostics/column_diagnostics.F90
 108   constants/constants.F90
 109   constants/fmsconstants.F90
 110   constants4/constantsr4.F90
 111   constants4/fmsconstantsr4.F90
 112   coupler/atmos_ocean_fluxes.F90
 113   coupler/coupler_types.F90
 114   coupler/ensemble_manager.F90
 115   data_override/get_grid_version.F90
 116   data_override/data_override.F90
 117   diag_integral/diag_integral.F90
 118   diag_manager/diag_axis.F90
 119   diag_manager/diag_data.F90
 120   diag_manager/diag_grid.F90
 121   diag_manager/diag_manager.F90
 122   diag_manager/diag_output.F90
 123   diag_manager/diag_table.F90
 124   diag_manager/diag_util.F90
 125   diag_manager/fms_diag_time_utils.F90
 126   diag_manager/fms_diag_object.F90
 127   diag_manager/fms_diag_yaml.F90
 128   diag_manager/fms_diag_file_object.F90
 129   diag_manager/fms_diag_field_object.F90
 130   diag_manager/fms_diag_axis_object.F90
 131   diag_manager/fms_diag_output_buffer.F90
 132   diag_manager/fms_diag_input_buffer.F90
 133   diag_manager/fms_diag_time_reduction.F90
 134   diag_manager/fms_diag_outfield.F90
 135   diag_manager/fms_diag_elem_weight_procs.F90
 136   diag_manager/fms_diag_fieldbuff_update.F90
 137   diag_manager/fms_diag_bbox.F90
 138   diag_manager/fms_diag_reduction_methods.F90
 139   drifters/cloud_interpolator.F90
 140   drifters/drifters.F90
 141   drifters/drifters_comm.F90
 142   drifters/drifters_core.F90
 143   drifters/drifters_input.F90
 144   drifters/drifters_io.F90
 145   drifters/quicksort.F90
 146   exchange/stock_constants.F90
 147   exchange/xgrid.F90
 148   field_manager/field_manager.F90
 149   field_manager/fm_util.F90
 150   field_manager/fm_yaml.F90
 151   fms/fms_io.F90
 152   fms/fms.F90
 153   fms2_io/blackboxio.F90
 154   fms2_io/fms_io_utils.F90
 155   fms2_io/fms_netcdf_domain_io.F90
 156   fms2_io/fms_netcdf_unstructured_domain_io.F90
 157   fms2_io/fms2_io.F90
 158   fms2_io/netcdf_io.F90
 159   horiz_interp/horiz_interp_bicubic.F90
 160   horiz_interp/horiz_interp_bilinear.F90
 161   horiz_interp/horiz_interp_conserve.F90
 162   horiz_interp/horiz_interp_spherical.F90
 163   horiz_interp/horiz_interp_type.F90
 164   horiz_interp/horiz_interp.F90
 165   interpolator/interpolator.F90
 166   memutils/memutils.F90
 167   monin_obukhov/monin_obukhov_inter.F90
 168   monin_obukhov/monin_obukhov.F90
 169   mosaic/gradient.F90
 170   mosaic/grid.F90
 171   mosaic/mosaic.F90
 172   mosaic2/grid2.F90
 173   mosaic2/mosaic2.F90
 174   mpp/mpp.F90
 175   mpp/mpp_data.F90
 176   mpp/mpp_domains.F90
 177   mpp/mpp_efp.F90
 178   mpp/mpp_io.F90
 179   mpp/mpp_memutils.F90
 180   mpp/mpp_parameter.F90
 181   mpp/mpp_utilities.F90
 182   parser/yaml_parser.F90
 183   parser/fms_yaml_output.F90
 184   platform/platform.F90
 185   random_numbers/mersennetwister.F90
 186   random_numbers/random_numbers.F90
 187   sat_vapor_pres/sat_vapor_pres_k.F90
 188   sat_vapor_pres/sat_vapor_pres.F90
 189   string_utils/fms_string_utils.F90
 190   time_interp/time_interp_external.F90
 191   time_interp/time_interp_external2.F90
 192   time_interp/time_interp.F90
 193   time_manager/get_cal_time.F90
 194   time_manager/time_manager.F90
 195   topography/gaussian_topog.F90
 196   topography/topography.F90
 197   tracer_manager/tracer_manager.F90
 198   tridiagonal/tridiagonal.F90
 199   libFMS.F90
 200 )
 201
 202 # Collect FMS C source files
 203 list(APPEND fms_c_src_files
 204   affinity/affinity.c
 205   fms/fms_stacksize.c
 206   mosaic/create_xgrid.c
 207   mosaic/gradient_c2l.c
 208   mosaic/interp.c
 209   mosaic/mosaic_util.c
 210   mosaic/read_mosaic.c
 211   mpp/mpp_memuse.c
 212   parser/yaml_parser_binding.c
 213   parser/yaml_output_functions.c
 214   string_utils/fms_string_utils_binding.c
 215 )
 216
 217 # Collect FMS header files
 218 list(APPEND fms_header_files
 219   include/file_version.h
 220   include/fms_platform.h
 221 )
 222
 223 # Standard FMS compiler definitions
 224 list(APPEND fms_defs
 225   use_libMPI
 226   use_netCDF)
 227
 228 # check gettid
 229 include(CheckFunctionExists)
 230 check_function_exists(gettid HAVE_GETTID)
 231 if(HAVE_GETTID)
 232   list(APPEND fms_defs HAVE_GETTID)
 233 endif()
 234
 235 # Additional (optional) compiler definitions
 236 if(NOT CONSTANTS)
 237     set(CONSTANTS GFDL)
 238 endif()
 239 if(CONSTANTS STREQUAL "GFS")
 240   list(APPEND fms_defs GFS_CONSTANTS)
 241 elseif(CONSTANTS STREQUAL "GEOS")
 242   list(APPEND fms_defs GEOS_CONSTANTS)
 243 elseif(CONSTANTS STREQUAL "GFDL")
 244   list(APPEND fms_defs GFDL_CONSTANTS)
 245 else()
 246   message(FATAL_ERROR "CONSTANTS=${CONSTANTS} option not supported")
 247 endif()
 248
 249 if(GFS_PHYS)
 250   list(APPEND fms_defs GFS_PHYS)
 251 endif()
 252
 253 if(WITH_YAML)
 254   list(APPEND fms_defs use_yaml)
 255 endif()
 256
 257 if(USE_DEPRECATED_IO)
 258   list(APPEND fms_defs use_deprecated_io)
 259 endif()
 260
 261 if(INTERNAL_FILE_NML)
 262   list(APPEND fms_defs INTERNAL_FILE_NML)
 263 endif()
 264
 265 if(ENABLE_QUAD_PRECISION)
 266   list(APPEND fms_defs ENABLE_QUAD_PRECISION)
 267 endif()
 268
 269 if(LARGEFILE)
 270   list(APPEND fms_defs use_LARGEFILE)
 271 endif()
 272
 273 # Precision-based compiler definitions
 274 if(32BIT)
 275   list(APPEND r4_defs OVERLOAD_R4 OVERLOAD_R8)
 276 endif()
 277
 278 # Add platform specific compiler definitions
 279 if(APPLE)
 280   list(APPEND fms_defs __APPLE__)
 281 endif()
 282
 283 # Obtain compiler-specific flags
 284 include(fms_compiler_flags)
 285
 286 foreach(kind ${kinds})
 287
 288   set(libTgt fms_${kind})
 289   set(includeDir "include_${kind}")
 290   set(moduleDir "${CMAKE_CURRENT_BINARY_DIR}/${includeDir}")
 291
 292   # C
 293   add_library(${libTgt}_c OBJECT ${fms_c_src_files})
 294
 295   target_include_directories(${libTgt}_c PRIVATE include)
 296   target_compile_definitions(${libTgt}_c PRIVATE "${fms_defs}")
 297
 298   target_link_libraries(${libTgt}_c PRIVATE NetCDF::NetCDF_C
 299                                             MPI::MPI_C)
 300
 301   if(OpenMP_C_FOUND)
 302     target_link_libraries(${libTgt}_c PRIVATE OpenMP::OpenMP_C)
 303   endif()
 304
 305   # Fortran
 306   add_library(${libTgt}_f OBJECT ${fms_fortran_src_files})
 307
 308   target_include_directories(${libTgt}_f PRIVATE include
 309                                                  fms
 310                                                  fms/include
 311                                                  fms2_io/include
 312                                                  string_utils/include
 313                                                  mpp/include
 314                                                  column_diagnostics/include
 315                                                  monin_obukhov/include
 316                                                  sat_vapor_pres/include
 317                                                  horiz_interp/include
 318                                                  diag_integral/include
 319                                                  random_numbers/include
 320                                                  diag_manager/include
 321                                                  constants4
 322                                                  topography/include
 323                                                  axis_utils/include
 324                                                  mosaic2/include
 325                                                  constants
 326                                                  astronomy/include
 327                                                  field_manager/include
 328                                                  time_interp/include
 329                                                  tracer_manager/include
 330                                                  tridiagonal/include
 331                                                  interpolator/include
 332                                                  coupler/include
 333                                                  data_override/include
 334                                                  amip_interp/include)
 335
 336   target_compile_definitions(${libTgt}_f PRIVATE "${fms_defs}")
 337   target_compile_definitions(${libTgt}_f PRIVATE "${${kind}_defs}")
 338
 339   set_target_properties(${libTgt}_f PROPERTIES COMPILE_FLAGS "${${kind}_flags}")
 340
 341   set_target_properties(${libTgt}_f PROPERTIES Fortran_MODULE_DIRECTORY
 342                                                ${moduleDir})
 343
 344   target_link_libraries(${libTgt}_f PRIVATE NetCDF::NetCDF_Fortran
 345                                             MPI::MPI_Fortran)
 346
 347   if(OpenMP_Fortran_FOUND)
 348     target_link_libraries(${libTgt}_f PRIVATE OpenMP::OpenMP_Fortran)
 349   endif()
 350
 351   # Check if gnu 10 or higher
 352   # this should only be needed with mpich, but wasn't able to find a good way to find the MPI flavor consistently
 353   if ( CMAKE_Fortran_COMPILER_VERSION MATCHES "1[0-9]\.[0-9]*\.[0-9]*" AND CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 354     include(CheckFortranCompilerFlag)
 355     check_fortran_compiler_flag("-fallow-argument-mismatch" _arg_mismatch_flag)
 356     if(_arg_mismatch_flag)
 357       message(STATUS "Adding -fallow-argument-mismatch flag to compile with GCC >=10 and MPICH")
 358       target_compile_options(${libTgt}_f PRIVATE "-fallow-argument-mismatch;-w")
 359     endif()
 360   endif()
 361
 362   # FMS (C + Fortran)
 363   add_library(${libTgt} STATIC $<TARGET_OBJECTS:${libTgt}_c>
 364                                $<TARGET_OBJECTS:${libTgt}_f>)
 365
 366   target_include_directories(${libTgt} PUBLIC
 367     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
 368     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms>
 369     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms/include>
 370     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms2_io/include>
 371     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/column_diagnostics/include>
 372     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/astronomy/include>
 373     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/monin_obukhov/include>
 374     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/sat_vapor_pres/include>
 375     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/field_manager/include>
 376     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/horiz_interp/include>
 377     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mosaic2/include>
 378     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/string_utils/include>
 379     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mpp/include>
 380     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_manager/include>
 381     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/topography/include>
 382     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/random_numbers/include>
 383     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_integral/include>
 384     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_manager/include>
 385     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/tracer_manager/include>
 386     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/interpolator/include>
 387     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/coupler/include>
 388     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mosaic2/include>
 389     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/data_override/include>
 390     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/tridiagonal/include>
 391     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/amip_interp/include>)
 392
 393   target_include_directories(${libTgt} INTERFACE
 394     $<BUILD_INTERFACE:${moduleDir}>
 395     $<INSTALL_INTERFACE:${includeDir}>)
 396
 397   target_compile_definitions(${libTgt} PRIVATE "${fms_defs}")
 398   target_compile_definitions(${libTgt} PRIVATE "${${kind}_defs}")
 399
 400   target_link_libraries(${libTgt} PUBLIC NetCDF::NetCDF_Fortran
 401                                          MPI::MPI_Fortran)
 402
 403   if(OpenMP_Fortran_FOUND)
 404     target_link_libraries(${libTgt} PRIVATE OpenMP::OpenMP_C OpenMP::OpenMP_Fortran)
 405   endif()
 406
 407   add_library(FMS::${libTgt} ALIAS ${libTgt})
 408
 409   list(APPEND LIB_TARGETS ${libTgt})
 410   install(DIRECTORY ${moduleDir}    DESTINATION ${CMAKE_INSTALL_PREFIX})
 411   install(FILES ${fms_header_files} DESTINATION ${CMAKE_INSTALL_PREFIX}/${includeDir})
 412
 413 endforeach()
 414
 415 install(
 416   TARGETS ${LIB_TARGETS}
 417   EXPORT FMSExports
 418   RUNTIME DESTINATION bin
 419   LIBRARY DESTINATION lib
 420   ARCHIVE DESTINATION lib)
 421
 422 ### Package config
 423 include(CMakePackageConfigHelpers)
 424 set(CONFIG_INSTALL_DESTINATION lib/cmake/fms)
 425
 426 export(EXPORT FMSExports
 427   NAMESPACE FMS::
 428   FILE fms-targets.cmake)
 429
 430 configure_package_config_file(
 431   ${CMAKE_CURRENT_SOURCE_DIR}/cmake/FMSConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/fms-config.cmake
 432   INSTALL_DESTINATION ${CONFIG_INSTALL_DESTINATION})
 433 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fms-config.cmake
 434   DESTINATION ${CONFIG_INSTALL_DESTINATION})
 435
 436 write_basic_package_version_file(
 437   ${CMAKE_CURRENT_BINARY_DIR}/fms-config-version.cmake
 438   VERSION ${PROJECT_VERSION}
 439   COMPATIBILITY AnyNewerVersion)
 440 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fms-config-version.cmake
 441   DESTINATION ${CONFIG_INSTALL_DESTINATION})
 442
 443 install(EXPORT FMSExports
 444   NAMESPACE FMS::
 445   FILE fms-targets.cmake
 446   DESTINATION ${CONFIG_INSTALL_DESTINATION})