V.pm

   1 #!/pro/bin/perl
   2
   3 package Config::Perl::V;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = "0.02";
   9
  10 use Config;
  11
  12 #  Characteristics of this binary (from libperl):
  13 #    Compile-time options: DEBUGGING PERL_DONT_CREATE_GVSV PERL_MALLOC_WRAP
  14 #                          USE_64_BIT_INT USE_LARGE_FILES USE_PERLIO
  15
  16 # The list are as the perl binary has stored it in PL_bincompat_options
  17 #  search for it in
  18 #   perl.c line 1768 (first  block)
  19 #   perl.h line 4454 (second block),
  20 my %BTD = map { $_ => 0 } qw(
  21
  22     DEBUGGING
  23     NO_MATHOMS
  24     PERL_DONT_CREATE_GVSV
  25     PERL_MALLOC_WRAP
  26     PERL_MEM_LOG
  27     PERL_MEM_LOG_ENV
  28     PERL_MEM_LOG_ENV_FD
  29     PERL_MEM_LOG_STDERR
  30     PERL_MEM_LOG_TIMESTAMP
  31     PERL_USE_DEVEL
  32     PERL_USE_SAFE_PUTENV
  33     USE_FAST_STDIO
  34     USE_SITECUSTOMIZE
  35
  36     DEBUG_LEAKING_SCALARS
  37     DEBUG_LEAKING_SCALARS_FORK_DUMP
  38     DECCRTL_SOCKETS
  39     FAKE_THREADS
  40     MULTIPLICITY
  41     MYMALLOC
  42     PERL_DEBUG_READONLY_OPS
  43     PERL_GLOBAL_STRUCT
  44     PERL_IMPLICIT_CONTEXT
  45     PERL_IMPLICIT_SYS
  46     PERL_MAD
  47     PERL_NEED_APPCTX
  48     PERL_NEED_TIMESBASE
  49     PERL_OLD_COPY_ON_WRITE
  50     PERL_POISON
  51     PERL_TRACK_MEMPOOL
  52     PERL_USES_PL_PIDSTATUS
  53     PL_OP_SLAB_ALLOC
  54     THREADS_HAVE_PIDS
  55     USE_64_BIT_ALL
  56     USE_64_BIT_INT
  57     USE_IEEE
  58     USE_ITHREADS
  59     USE_LARGE_FILES
  60     USE_LONG_DOUBLE
  61     USE_PERLIO
  62     USE_REENTRANT_API
  63     USE_SFIO
  64     USE_SOCKS
  65     VMS_DO_SOCKETS
  66     VMS_SYMBOL_CASE_AS_IS
  67     );
  68
  69 # These are all the keys that are
  70 # 1. Always present in %Config (first block)
  71 # 2. Reported by 'perl -V' (the rest)
  72 my @config_vars = qw(
  73
  74     api_subversion
  75     api_version
  76     api_versionstring
  77     archlibexp
  78     dont_use_nlink
  79     d_readlink
  80     d_symlink
  81     exe_ext
  82     inc_version_list
  83     ldlibpthname
  84     patchlevel
  85     path_sep
  86     perl_patchlevel
  87     privlibexp
  88     scriptdir
  89     sitearchexp
  90     sitelibexp
  91     subversion
  92     usevendorprefix
  93     version
  94
  95     git_commit_id
  96     git_describe
  97     git_branch
  98     git_uncommitted_changes
  99     git_commit_id_title
 100     git_snapshot_date
 101
 102     package revision version_patchlevel_string
 103
 104     osname osvers archname
 105     myuname
 106     config_args
 107     hint useposix d_sigaction
 108     useithreads usemultiplicity
 109     useperlio d_sfio uselargefiles usesocks
 110     use64bitint use64bitall uselongdouble
 111     usemymalloc bincompat5005
 112
 113     cc ccflags
 114     optimize
 115     cppflags
 116     ccversion gccversion gccosandvers
 117     intsize longsize ptrsize doublesize byteorder
 118     d_longlong longlongsize d_longdbl longdblsize
 119     ivtype ivsize nvtype nvsize lseektype lseeksize
 120     alignbytes prototype
 121
 122     ld ldflags
 123     libpth
 124     libs
 125     perllibs
 126     libc so useshrplib libperl
 127     gnulibc_version
 128
 129     dlsrc dlext d_dlsymun ccdlflags
 130     cccdlflags lddlflags
 131     );
 132
 133 my %empty_build = (
 134     osname  => "",
 135     stamp   => 0,
 136     options => { %BTD },
 137     patches => [],
 138     );
 139
 140 sub _make_derived
 141 {
 142     my $conf = shift;
 143
 144     for ( [ lseektype           => "Off_t"      ],
 145           [ myuname             => "uname"      ],
 146           [ perl_patchlevel     => "patch"      ],
 147           ) {
 148         my ($official, $derived) = @$_;
 149         $conf->{config}{$derived}  ||= $conf->{config}{$official};
 150         $conf->{config}{$official} ||= $conf->{config}{$derived};
 151         $conf->{derived}{$derived} = delete $conf->{config}{$derived};
 152         }
 153
 154     if (exists $conf->{config}{version_patchlevel_string} &&
 155        !exists $conf->{config}{api_version}) {
 156         my $vps = $conf->{config}{version_patchlevel_string};
 157         $vps =~ s{\b revision   \s+ (\S+) }{}x and
 158             $conf->{config}{revision}        ||= $1;
 159
 160         $vps =~ s{\b version    \s+ (\S+) }{}x and
 161             $conf->{config}{api_version}     ||= $1;
 162         $vps =~ s{\b subversion \s+ (\S+) }{}x and
 163             $conf->{config}{subversion}      ||= $1;
 164         $vps =~ s{\b patch      \s+ (\S+) }{}x and
 165             $conf->{config}{perl_patchlevel} ||= $1;
 166         }
 167
 168     ($conf->{config}{version_patchlevel_string} ||= join " ",
 169         map  { ($_, $conf->{config}{$_} ) }
 170         grep {      $conf->{config}{$_}   }
 171         qw( api_version subversion perl_patchlevel )) =~ s/\bperl_//;
 172
 173     $conf->{config}{perl_patchlevel}  ||= "";   # 0 is not a valid patchlevel
 174
 175     if ($conf->{config}{perl_patchlevel} =~ m{^git\w*-([^-]+)}i) {
 176         $conf->{config}{git_branch}   ||= $1;
 177         $conf->{config}{git_describe} ||= $conf->{config}{perl_patchlevel};
 178         }
 179
 180     $conf;
 181     } # _make_derived
 182
 183 sub plv2hash
 184 {
 185     my %config;
 186     for (split m/\n+/ => join "\n", @_) {
 187
 188         if (s/^Summary of my\s+(\S+)\s+\(\s*(.*?)\s*\)//) {
 189             $config{"package"} = $1;
 190             my $rev = $2;
 191             $rev =~ s/^ revision \s+ (\S+) \s*//x and $config{revision} = $1;
 192             $rev and $config{version_patchlevel_string} = $rev;
 193             next;
 194             }
 195
 196         if (s/^\s+(Snapshot of:)\s+(\S+)//) {
 197             $config{git_commit_id_title} = $1;
 198             $config{git_commit_id}       = $2;
 199             next;
 200             }
 201
 202         my %kv = m/\G,?\s*([^=]+)=('[^']+?'|\S+)/gc;
 203
 204         while (my ($k, $v) = each %kv) {
 205             $k =~ s/\s+$//;
 206             $v =~ s/,$//;
 207             $v =~ m/^'(.*)'$/ and $v = $1;
 208             $v =~ s/^\s+//;
 209             $v =~ s/\s+$//;
 210             $config{$k} = $v;
 211             }
 212         }
 213     my $build = { %empty_build };
 214     $build->{osname} = $config{osname};
 215     return _make_derived ({
 216         build           => $build,
 217         environment     => {},
 218         config          => \%config,
 219         derived         => {},
 220         inc             => [],
 221         });
 222     } # plv2hash
 223
 224 sub myconfig
 225 {
 226     my $args = shift;
 227     my %args = ref $args eq "HASH"  ? %$args :
 228                ref $args eq "ARRAY" ? @$args : ();
 229
 230     #y $pv = qx[$^X -e"sub Config::myconfig{};" -V];
 231     my $pv = qx[$^X -V];
 232        $pv =~ s{.*?\n\n}{}s;
 233        $pv =~ s{\n(?:  \s+|\t\s*)}{ }g;
 234
 235     #print $pv;
 236
 237     my $build = { %empty_build };
 238     $pv =~ m{^\s+Built under (.*)}m                and $build->{osname} = $1;
 239     $pv =~ m{^\s+Compiled at (.*)}m                and $build->{stamp}  = $1;
 240     $pv =~ m{^\s+Locally applied patches:\s+(.*)}m and $build->{patches} = [ split m/\s+/, $1 ];
 241     $pv =~ m{^\s+Compile-time options:\s+(.*)}m    and map { $build->{options}{$_} = 1 } split m/\s+/, $1;
 242
 243     my @KEYS = keys %ENV;
 244     my %env  =
 245         map {      $_ => $ENV{$_} } grep m/^PERL/      => @KEYS;
 246     $args{env} and
 247         map { $env{$_} = $ENV{$_} } grep m{$args{env}} => @KEYS;
 248
 249     my %config = map { $_ => $Config{$_} } @config_vars;
 250
 251     return _make_derived ({
 252         build           => $build,
 253         environment     => \%env,
 254         config          => \%config,
 255         derived         => {},
 256         inc             => \@INC,
 257         });
 258     } # myconfig
 259
 260 1;
 261
 262 __END__
 263
 264 =head1 NAME
 265
 266 Config::Perl::V - Structured data retreival of perl -V output
 267
 268 =head1 SYNOPSIS
 269
 270  use Config::Perl::V;
 271
 272  my $local_config = Config::Perl::V::myconfig ();
 273  print $local_config->{config}{osname};
 274
 275 =head1 DESCRIPTION
 276
 277 =head2 myconfig ()
 278
 279 This function will collect the data decribed in L<the hash structure> below,
 280
 281 =head2 plv2hash ()
 282
 283 Convert a sole 'perl -V' text block to a complete myconfig hash.
 284 All unknown entries are defaulted.
 285
 286 =head2 The hash structure
 287
 288 The returned hash consists of 4 parts:
 289
 290 =over 4
 291
 292 =item build
 293
 294 This information is extracted from the second block that is emitted by
 295 C<perl -V>, and usually looks something like
 296
 297  Characteristics of this binary (from libperl):
 298    Compile-time options: DEBUGGING USE_64_BIT_INT USE_LARGE_FILES
 299    Locally applied patches:
 300          defined-or
 301          MAINT24637
 302    Built under linux
 303    Compiled at Jun 13 2005 10:44:20
 304    @INC:
 305      /usr/lib/perl5/5.8.7/i686-linux-64int
 306      /usr/lib/perl5/5.8.7
 307      /usr/lib/perl5/site_perl/5.8.7/i686-linux-64int
 308      /usr/lib/perl5/site_perl/5.8.7
 309      /usr/lib/perl5/site_perl
 310      .
 311
 312 or
 313
 314  Characteristics of this binary (from libperl):
 315    Compile-time options: DEBUGGING MULTIPLICITY
 316                          PERL_DONT_CREATE_GVSV PERL_IMPLICIT_CONTEXT
 317                          PERL_MALLOC_WRAP PERL_TRACK_MEMPOOL
 318                          PERL_USE_SAFE_PUTENV USE_ITHREADS
 319                          USE_LARGE_FILES USE_PERLIO
 320                          USE_REENTRANT_API
 321    Built under linux
 322    Compiled at Jan 28 2009 15:26:59
 323
 324 This information is not available anywhere else, including C<%Config>,
 325 but it is the information that is only known to the perl binary.
 326
 327 The extracted information is stored in 5 entries in the C<build> hash:
 328
 329 =over 4
 330
 331 =item osname
 332
 333 This is most likely the same as C$Config{osname}>, and was the name
 334 known when perl was built. It might be different if perl was cross-compiled.
 335
 336 The default for this field, if it cannot be extracted, is to copy C<$Config{osname}>.
 337 `
 338 =item stamp
 339
 340 This is the time string for which the perl binary was compiled. The default
 341 value is 0.
 342
 343 =item options
 344
 345 This is a hash with all the known defines as keys. The value is either 0,
 346 which means unknown or unset, or 1, which means defined.
 347
 348 =item derived
 349
 350 As some verables are reported by a different name in the output of C<perl -V>
 351 than their actual name in C<%Config>, I decided to leave the C<config> entry
 352 as close to reality as possible, and put in the entries that might have been
 353 guessed by the printed output in a seperate block.
 354
 355 =item patches
 356
 357 This is a list of optionally locally applied patches. Default is an empty list.
 358
 359 =back
 360
 361 This include the flags that define the binary compatibility, like if
 362 this perl was compiled for 64bitall (C<USE_64_BIT_ALL>), and basically is
 363
 364 =item environment
 365
 366 By default this hash is only filled with the environment variables
 367 out of %ENV that start with C<PERL>, but you can pass the C<env> option
 368 to myconfig to get more
 369
 370  my $conf = Config::Perl::V::myconfig ({ env => qr/^ORACLE/ });
 371  my $conf = Config::Perl::V::myconfig ([ env => qr/^ORACLE/ ]);
 372
 373 =item config
 374
 375 This hash is filled with the variables that C<perl -V> fils it's report
 376 with, and it has the same variables that C<Config::myconfig> returns
 377 from C<%Config>.
 378
 379 =item inc
 380
 381 This is the list of default @INC.
 382
 383 =back
 384
 385 =head1 REASONING
 386
 387 This module was written to be able to return the configuration for the
 388 currently used perl as deeply as needed for the CPANTESTERS framework.
 389 Up until now they used the output of myconfig as a single text blob,
 390 and so it was missing the vital binary characteristics of the running
 391 perl and the optional applied patches.
 392
 393 =head1 BUGS
 394
 395 Please feedback what is wrong
 396
 397 =head1 TODO
 398
 399 * Implement retrieval functions/methods
 400 * Documentation
 401 * Include the perl -V parse block from Andreas
 402
 403 =head1 AUTHOR
 404
 405 H.Merijn Brand <h.m.brand@xs4all.nl>
 406
 407 =head1 COPYRIGHT AND LICENSE
 408
 409 Copyright (C) 2009 H.Merijn Brand
 410
 411 This library is free software; you can redistribute it and/or modify
 412 it under the same terms as Perl itself.
 413
 414 =cut