V.pm

   1 #!/pro/bin/perl
   2
   3 package Config::Perl::V;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = "0.02";
   9
  10 use Config;
  11
  12 #  Characteristics of this binary (from libperl):
  13 #    Compile-time options: DEBUGGING PERL_DONT_CREATE_GVSV PERL_MALLOC_WRAP
  14 #                          USE_64_BIT_INT USE_LARGE_FILES USE_PERLIO
  15
  16 # The list are as the perl binary has stored it in PL_bincompat_options
  17 #  search for it in
  18 #   perl.c line 1768 (first  block)
  19 #   perl.h line 4454 (second block),
  20 my %BTD = map { $_ => 0 } qw(
  21
  22     DEBUGGING
  23     NO_MATHOMS
  24     PERL_DONT_CREATE_GVSV
  25     PERL_MALLOC_WRAP
  26     PERL_MEM_LOG
  27     PERL_MEM_LOG_ENV
  28     PERL_MEM_LOG_ENV_FD
  29     PERL_MEM_LOG_STDERR
  30     PERL_MEM_LOG_TIMESTAMP
  31     PERL_USE_DEVEL
  32     PERL_USE_SAFE_PUTENV
  33     USE_FAST_STDIO
  34     USE_SITECUSTOMIZE
  35
  36     DEBUG_LEAKING_SCALARS
  37     DEBUG_LEAKING_SCALARS_FORK_DUMP
  38     DECCRTL_SOCKETS
  39     FAKE_THREADS
  40     MULTIPLICITY
  41     MYMALLOC
  42     PERL_DEBUG_READONLY_OPS
  43     PERL_GLOBAL_STRUCT
  44     PERL_IMPLICIT_CONTEXT
  45     PERL_IMPLICIT_SYS
  46     PERL_MAD
  47     PERL_NEED_APPCTX
  48     PERL_NEED_TIMESBASE
  49     PERL_OLD_COPY_ON_WRITE
  50     PERL_POISON
  51     PERL_TRACK_MEMPOOL
  52     PERL_USES_PL_PIDSTATUS
  53     PL_OP_SLAB_ALLOC
  54     THREADS_HAVE_PIDS
  55     USE_64_BIT_ALL
  56     USE_64_BIT_INT
  57     USE_IEEE
  58     USE_ITHREADS
  59     USE_LARGE_FILES
  60     USE_LONG_DOUBLE
  61     USE_PERLIO
  62     USE_REENTRANT_API
  63     USE_SFIO
  64     USE_SOCKS
  65     VMS_DO_SOCKETS
  66     VMS_SYMBOL_CASE_AS_IS
  67     );
  68
  69 # These are all the keys that are
  70 # 1. Always present in %Config (first block)
  71 # 2. Reported by 'perl -V' (the rest)
  72 my @config_vars = qw(
  73
  74     api_subversion
  75     api_version
  76     api_versionstring
  77     archlibexp
  78     dont_use_nlink
  79     d_readlink
  80     d_symlink
  81     exe_ext
  82     inc_version_list
  83     ldlibpthname
  84     patchlevel
  85     path_sep
  86     perl_patchlevel
  87     privlibexp
  88     scriptdir
  89     sitearchexp
  90     sitelibexp
  91     subversion
  92     usevendorprefix
  93     version
  94
  95     git_commit_id
  96     git_describe
  97     git_branch
  98     git_uncommitted_changes
  99     git_commit_id_title
 100     git_snapshot_date
 101
 102     package revision version_patchlevel_string
 103
 104     osname osvers archname
 105     myuname
 106     config_args
 107     hint useposix d_sigaction
 108     useithreads usemultiplicity
 109     useperlio d_sfio uselargefiles usesocks
 110     use64bitint use64bitall uselongdouble
 111     usemymalloc bincompat5005
 112
 113     cc ccflags
 114     optimize
 115     cppflags
 116     ccversion gccversion gccosandvers
 117     intsize longsize ptrsize doublesize byteorder
 118     d_longlong longlongsize d_longdbl longdblsize
 119     ivtype ivsize nvtype nvsize lseektype lseeksize
 120     alignbytes prototype
 121
 122     ld ldflags
 123     libpth
 124     libs
 125     perllibs
 126     libc so useshrplib libperl
 127     gnulibc_version
 128
 129     dlsrc dlext d_dlsymun ccdlflags
 130     cccdlflags lddlflags
 131     );
 132
 133 my %empty_build = (
 134     osname  => "",
 135     stamp   => 0,
 136     options => { %BTD },
 137     patches => [],
 138     );
 139
 140 sub _make_derived
 141 {
 142     my $conf = shift;
 143
 144     exists $conf->{config}{Off_t} and
 145         $conf->{derived}{Off_t} = delete $conf->{config}{Off_t};
 146     exists $conf->{derived}{Off_t} && !exists $conf->{config}{lseektype} and
 147         $conf->{config}{lseektype} = $conf->{derived}{Off_t};
 148
 149     $conf;
 150     } # _make_derived
 151
 152 sub plv2hash
 153 {
 154     my %config;
 155     for (split m/\n+/ => join "\n", @_) {
 156
 157         if (s/^Summary of my\s+(\S+)\s+\(\s*(.*?)\s*\)//) {
 158             $config{"package"} = $1;
 159             my $rev = $2;
 160             $rev =~ s/^ revision \s+ (\S+) \s*//x and $config{revision} = $1;
 161             $rev and $config{version_patchlevel_string} = $rev;
 162             next;
 163             }
 164
 165         my %kv = m/\G,?\s*([^=]+)=('[^']+?'|\S+)/gc;
 166
 167         while (my ($k, $v) = each %kv) {
 168             $k =~ s/\s+$//;
 169             $v =~ s/,$//;
 170             $v =~ m/^'(.*)'$/ and $v = $1;
 171             $v =~ s/^\s+//;
 172             $v =~ s/\s+$//;
 173             $config{$k} = $v;
 174             }
 175         }
 176     my $build = { %empty_build };
 177     $build->{osname} = $config{osname};
 178     return _make_derived ({
 179         build           => $build,
 180         environment     => {},
 181         config          => \%config,
 182         derived         => {},
 183         inc             => [],
 184         });
 185     } # plv2hash
 186
 187 sub myconfig
 188 {
 189     my $args = shift;
 190     my %args = ref $args eq "HASH"  ? %$args :
 191                ref $args eq "ARRAY" ? @$args : ();
 192
 193     #y $pv = qx[$^X -e"sub Config::myconfig{};" -V];
 194     my $pv = qx[$^X -V];
 195        $pv =~ s{.*?\n\n}{}s;
 196        $pv =~ s{\n(?:  \s+|\t\s*)}{ }g;
 197
 198     #print $pv;
 199
 200     my $build = { %empty_build };
 201     $pv =~ m{^\s+Built under (.*)}m                and $build->{osname} = $1;
 202     $pv =~ m{^\s+Compiled at (.*)}m                and $build->{stamp}  = $1;
 203     $pv =~ m{^\s+Locally applied patches:\s+(.*)}m and $build->{patches} = [ split m/\s+/, $1 ];
 204     $pv =~ m{^\s+Compile-time options:\s+(.*)}m    and map { $build->{options}{$_} = 1 } split m/\s+/, $1;
 205
 206     my @KEYS = keys %ENV;
 207     my %env  =
 208         map {      $_ => $ENV{$_} } grep m/^PERL/      => @KEYS;
 209     $args{env} and
 210         map { $env{$_} = $ENV{$_} } grep m{$args{env}} => @KEYS;
 211
 212     my %config = map { $_ => $Config{$_} } @config_vars;
 213
 214     return _make_derived ({
 215         build           => $build,
 216         environment     => \%env,
 217         config          => \%config,
 218         derived         => {},
 219         inc             => \@INC,
 220         });
 221     } # myconfig
 222
 223 1;
 224
 225 __END__
 226
 227 =head1 NAME
 228
 229 Config::Perl::V - Structured data retreival of perl -V output
 230
 231 =head1 SYNOPSIS
 232
 233  use Config::Perl::V;
 234
 235  my $local_config = Config::Perl::V::myconfig ();
 236  print $local_config->{config}{osname};
 237
 238 =head1 DESCRIPTION
 239
 240 =head2 myconfig ()
 241
 242 This function will collect the data decribed in L<the hash structure> below,
 243
 244 =head2 plv2hash ()
 245
 246 Convert a sole 'perl -V' text block to a complete myconfig hash.
 247 All unknown entries are defaulted.
 248
 249 =head2 The hash structure
 250
 251 The returned hash consists of 4 parts:
 252
 253 =over 4
 254
 255 =item build
 256
 257 This information is extracted from the second block that is emitted by
 258 C<perl -V>, and usually looks something like
 259
 260  Characteristics of this binary (from libperl):
 261    Compile-time options: DEBUGGING USE_64_BIT_INT USE_LARGE_FILES
 262    Locally applied patches:
 263          defined-or
 264          MAINT24637
 265    Built under linux
 266    Compiled at Jun 13 2005 10:44:20
 267    @INC:
 268      /usr/lib/perl5/5.8.7/i686-linux-64int
 269      /usr/lib/perl5/5.8.7
 270      /usr/lib/perl5/site_perl/5.8.7/i686-linux-64int
 271      /usr/lib/perl5/site_perl/5.8.7
 272      /usr/lib/perl5/site_perl
 273      .
 274
 275 or
 276
 277  Characteristics of this binary (from libperl):
 278    Compile-time options: DEBUGGING MULTIPLICITY
 279                          PERL_DONT_CREATE_GVSV PERL_IMPLICIT_CONTEXT
 280                          PERL_MALLOC_WRAP PERL_TRACK_MEMPOOL
 281                          PERL_USE_SAFE_PUTENV USE_ITHREADS
 282                          USE_LARGE_FILES USE_PERLIO
 283                          USE_REENTRANT_API
 284    Built under linux
 285    Compiled at Jan 28 2009 15:26:59
 286
 287 This information is not available anywhere else, including C<%Config>,
 288 but it is the information that is only known to the perl binary.
 289
 290 The extracted information is stored in 5 entries in the C<build> hash:
 291
 292 =over 4
 293
 294 =item osname
 295
 296 This is most likely the same as C$Config{osname}>, and was the name
 297 known when perl was built. It might be different if perl was cross-compiled.
 298
 299 The default for this field, if it cannot be extracted, is to copy C<$Config{osname}>.
 300 `
 301 =item stamp
 302
 303 This is the time string for which the perl binary was compiled. The default
 304 value is 0.
 305
 306 =item options
 307
 308 This is a hash with all the known defines as keys. The value is either 0,
 309 which means unknown or unset, or 1, which means defined.
 310
 311 =item derived
 312
 313 As some verables are reported by a different name in the output of C<perl -V>
 314 than their actual name in C<%Config>, I decided to leave the C<config> entry
 315 as close to reality as possible, and put in the entries that might have been
 316 guessed by the printed output in a seperate block.
 317
 318 =item patches
 319
 320 This is a list of optionally locally applied patches. Default is an empty list.
 321
 322 =back
 323
 324 This include the flags that define the binary compatibility, like if
 325 this perl was compiled for 64bitall (C<USE_64_BIT_ALL>), and basically is
 326
 327 =item environment
 328
 329 By default this hash is only filled with the environment variables
 330 out of %ENV that start with C<PERL>, but you can pass the C<env> option
 331 to myconfig to get more
 332
 333  my $conf = Config::Perl::V::myconfig ({ env => qr/^ORACLE/ });
 334  my $conf = Config::Perl::V::myconfig ([ env => qr/^ORACLE/ ]);
 335
 336 =item config
 337
 338 This hash is filled with the variables that C<perl -V> fils it's report
 339 with, and it has the same variables that C<Config::myconfig> returns
 340 from C<%Config>.
 341
 342 =item inc
 343
 344 This is the list of default @INC.
 345
 346 =back
 347
 348 =head1 REASONING
 349
 350 This module was written to be able to return the configuration for the
 351 currently used perl as deeply as needed for the CPANTESTERS framework.
 352 Up until now they used the output of myconfig as a single text blob,
 353 and so it was missing the vital binary characteristics of the running
 354 perl and the optional applied patches.
 355
 356 =head1 BUGS
 357
 358 Please feedback what is wrong
 359
 360 =head1 TODO
 361
 362 * Implement retrieval functions/methods
 363 * Documentation
 364 * Include the perl -V parse block from Andreas
 365
 366 =head1 AUTHOR
 367
 368 H.Merijn Brand <h.m.brand@xs4all.nl>
 369
 370 =head1 COPYRIGHT AND LICENSE
 371
 372 Copyright (C) 2009 H.Merijn Brand
 373
 374 This library is free software; you can redistribute it and/or modify
 375 it under the same terms as Perl itself.
 376
 377 =cut