V.pm

   1 #!/pro/bin/perl
   2
   3 package Config::Perl::V;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = "0.02";
   9
  10 use Config;
  11
  12 #  Characteristics of this binary (from libperl):
  13 #    Compile-time options: DEBUGGING PERL_DONT_CREATE_GVSV PERL_MALLOC_WRAP
  14 #                          USE_64_BIT_INT USE_LARGE_FILES USE_PERLIO
  15
  16 # The list are as the perl binary has stored it in PL_bincompat_options
  17 #  search for it in
  18 #   perl.c line 1768 (first  block)
  19 #   perl.h line 4454 (second block),
  20 my %BTD = map { $_ => 0 } qw(
  21
  22     DEBUGGING
  23     NO_MATHOMS
  24     PERL_DONT_CREATE_GVSV
  25     PERL_MALLOC_WRAP
  26     PERL_MEM_LOG
  27     PERL_MEM_LOG_ENV
  28     PERL_MEM_LOG_ENV_FD
  29     PERL_MEM_LOG_STDERR
  30     PERL_MEM_LOG_TIMESTAMP
  31     PERL_USE_DEVEL
  32     PERL_USE_SAFE_PUTENV
  33     USE_FAST_STDIO
  34     USE_SITECUSTOMIZE
  35
  36     DEBUG_LEAKING_SCALARS
  37     DEBUG_LEAKING_SCALARS_FORK_DUMP
  38     DECCRTL_SOCKETS
  39     FAKE_THREADS
  40     MULTIPLICITY
  41     MYMALLOC
  42     PERL_DEBUG_READONLY_OPS
  43     PERL_GLOBAL_STRUCT
  44     PERL_IMPLICIT_CONTEXT
  45     PERL_IMPLICIT_SYS
  46     PERL_MAD
  47     PERL_NEED_APPCTX
  48     PERL_NEED_TIMESBASE
  49     PERL_OLD_COPY_ON_WRITE
  50     PERL_POISON
  51     PERL_TRACK_MEMPOOL
  52     PERL_USES_PL_PIDSTATUS
  53     PL_OP_SLAB_ALLOC
  54     THREADS_HAVE_PIDS
  55     USE_64_BIT_ALL
  56     USE_64_BIT_INT
  57     USE_IEEE
  58     USE_ITHREADS
  59     USE_LARGE_FILES
  60     USE_LONG_DOUBLE
  61     USE_PERLIO
  62     USE_REENTRANT_API
  63     USE_SFIO
  64     USE_SOCKS
  65     VMS_DO_SOCKETS
  66     VMS_SYMBOL_CASE_AS_IS
  67     );
  68
  69 # These are all the keys that are
  70 # 1. Always present in %Config (first block)
  71 # 2. Reported by 'perl -V' (the rest)
  72 my @config_vars = qw(
  73
  74     api_subversion
  75     api_version
  76     api_versionstring
  77     archlibexp
  78     dont_use_nlink
  79     d_readlink
  80     d_symlink
  81     exe_ext
  82     inc_version_list
  83     ldlibpthname
  84     patchlevel
  85     path_sep
  86     perl_patchlevel
  87     privlibexp
  88     scriptdir
  89     sitearchexp
  90     sitelibexp
  91     subversion
  92     usevendorprefix
  93     version
  94
  95     git_commit_id
  96     git_describe
  97     git_branch
  98     git_uncommitted_changes
  99     git_commit_id_title
 100     git_snapshot_date
 101
 102     package revision version_patchlevel_string
 103
 104     osname osvers archname
 105     myuname
 106     config_args
 107     hint useposix d_sigaction
 108     useithreads usemultiplicity
 109     useperlio d_sfio uselargefiles usesocks
 110     use64bitint use64bitall uselongdouble
 111     usemymalloc bincompat5005
 112
 113     cc ccflags
 114     optimize
 115     cppflags
 116     ccversion gccversion gccosandvers
 117     intsize longsize ptrsize doublesize byteorder
 118     d_longlong longlongsize d_longdbl longdblsize
 119     ivtype ivsize nvtype nvsize lseektype lseeksize
 120     alignbytes prototype
 121
 122     ld ldflags
 123     libpth
 124     libs
 125     perllibs
 126     libc so useshrplib libperl
 127     gnulibc_version
 128
 129     dlsrc dlext d_dlsymun ccdlflags
 130     cccdlflags lddlflags
 131     );
 132
 133 my %empty_build = (
 134     osname  => "",
 135     stamp   => 0,
 136     options => { %BTD },
 137     patches => [],
 138     );
 139
 140 sub _make_derived
 141 {
 142     my $conf = shift;
 143
 144     for ( [ lseektype   => "Off_t"      ],
 145           [ myuname     => "uname"      ],
 146           ) {
 147         my ($official, $derived) = @$_;
 148         $conf->{config}{$derived}  ||= $conf->{config}{$official};
 149         $conf->{config}{$official} ||= $conf->{config}{$derived};
 150         $conf->{derived}{$derived} = delete $conf->{config}{$derived};
 151         }
 152
 153     $conf;
 154     } # _make_derived
 155
 156 sub plv2hash
 157 {
 158     my %config;
 159     for (split m/\n+/ => join "\n", @_) {
 160
 161         if (s/^Summary of my\s+(\S+)\s+\(\s*(.*?)\s*\)//) {
 162             $config{"package"} = $1;
 163             my $rev = $2;
 164             $rev =~ s/^ revision \s+ (\S+) \s*//x and $config{revision} = $1;
 165             $rev and $config{version_patchlevel_string} = $rev;
 166             next;
 167             }
 168
 169         my %kv = m/\G,?\s*([^=]+)=('[^']+?'|\S+)/gc;
 170
 171         while (my ($k, $v) = each %kv) {
 172             $k =~ s/\s+$//;
 173             $v =~ s/,$//;
 174             $v =~ m/^'(.*)'$/ and $v = $1;
 175             $v =~ s/^\s+//;
 176             $v =~ s/\s+$//;
 177             $config{$k} = $v;
 178             }
 179         }
 180     my $build = { %empty_build };
 181     $build->{osname} = $config{osname};
 182     return _make_derived ({
 183         build           => $build,
 184         environment     => {},
 185         config          => \%config,
 186         derived         => {},
 187         inc             => [],
 188         });
 189     } # plv2hash
 190
 191 sub myconfig
 192 {
 193     my $args = shift;
 194     my %args = ref $args eq "HASH"  ? %$args :
 195                ref $args eq "ARRAY" ? @$args : ();
 196
 197     #y $pv = qx[$^X -e"sub Config::myconfig{};" -V];
 198     my $pv = qx[$^X -V];
 199        $pv =~ s{.*?\n\n}{}s;
 200        $pv =~ s{\n(?:  \s+|\t\s*)}{ }g;
 201
 202     #print $pv;
 203
 204     my $build = { %empty_build };
 205     $pv =~ m{^\s+Built under (.*)}m                and $build->{osname} = $1;
 206     $pv =~ m{^\s+Compiled at (.*)}m                and $build->{stamp}  = $1;
 207     $pv =~ m{^\s+Locally applied patches:\s+(.*)}m and $build->{patches} = [ split m/\s+/, $1 ];
 208     $pv =~ m{^\s+Compile-time options:\s+(.*)}m    and map { $build->{options}{$_} = 1 } split m/\s+/, $1;
 209
 210     my @KEYS = keys %ENV;
 211     my %env  =
 212         map {      $_ => $ENV{$_} } grep m/^PERL/      => @KEYS;
 213     $args{env} and
 214         map { $env{$_} = $ENV{$_} } grep m{$args{env}} => @KEYS;
 215
 216     my %config = map { $_ => $Config{$_} } @config_vars;
 217
 218     return _make_derived ({
 219         build           => $build,
 220         environment     => \%env,
 221         config          => \%config,
 222         derived         => {},
 223         inc             => \@INC,
 224         });
 225     } # myconfig
 226
 227 1;
 228
 229 __END__
 230
 231 =head1 NAME
 232
 233 Config::Perl::V - Structured data retreival of perl -V output
 234
 235 =head1 SYNOPSIS
 236
 237  use Config::Perl::V;
 238
 239  my $local_config = Config::Perl::V::myconfig ();
 240  print $local_config->{config}{osname};
 241
 242 =head1 DESCRIPTION
 243
 244 =head2 myconfig ()
 245
 246 This function will collect the data decribed in L<the hash structure> below,
 247
 248 =head2 plv2hash ()
 249
 250 Convert a sole 'perl -V' text block to a complete myconfig hash.
 251 All unknown entries are defaulted.
 252
 253 =head2 The hash structure
 254
 255 The returned hash consists of 4 parts:
 256
 257 =over 4
 258
 259 =item build
 260
 261 This information is extracted from the second block that is emitted by
 262 C<perl -V>, and usually looks something like
 263
 264  Characteristics of this binary (from libperl):
 265    Compile-time options: DEBUGGING USE_64_BIT_INT USE_LARGE_FILES
 266    Locally applied patches:
 267          defined-or
 268          MAINT24637
 269    Built under linux
 270    Compiled at Jun 13 2005 10:44:20
 271    @INC:
 272      /usr/lib/perl5/5.8.7/i686-linux-64int
 273      /usr/lib/perl5/5.8.7
 274      /usr/lib/perl5/site_perl/5.8.7/i686-linux-64int
 275      /usr/lib/perl5/site_perl/5.8.7
 276      /usr/lib/perl5/site_perl
 277      .
 278
 279 or
 280
 281  Characteristics of this binary (from libperl):
 282    Compile-time options: DEBUGGING MULTIPLICITY
 283                          PERL_DONT_CREATE_GVSV PERL_IMPLICIT_CONTEXT
 284                          PERL_MALLOC_WRAP PERL_TRACK_MEMPOOL
 285                          PERL_USE_SAFE_PUTENV USE_ITHREADS
 286                          USE_LARGE_FILES USE_PERLIO
 287                          USE_REENTRANT_API
 288    Built under linux
 289    Compiled at Jan 28 2009 15:26:59
 290
 291 This information is not available anywhere else, including C<%Config>,
 292 but it is the information that is only known to the perl binary.
 293
 294 The extracted information is stored in 5 entries in the C<build> hash:
 295
 296 =over 4
 297
 298 =item osname
 299
 300 This is most likely the same as C$Config{osname}>, and was the name
 301 known when perl was built. It might be different if perl was cross-compiled.
 302
 303 The default for this field, if it cannot be extracted, is to copy C<$Config{osname}>.
 304 `
 305 =item stamp
 306
 307 This is the time string for which the perl binary was compiled. The default
 308 value is 0.
 309
 310 =item options
 311
 312 This is a hash with all the known defines as keys. The value is either 0,
 313 which means unknown or unset, or 1, which means defined.
 314
 315 =item derived
 316
 317 As some verables are reported by a different name in the output of C<perl -V>
 318 than their actual name in C<%Config>, I decided to leave the C<config> entry
 319 as close to reality as possible, and put in the entries that might have been
 320 guessed by the printed output in a seperate block.
 321
 322 =item patches
 323
 324 This is a list of optionally locally applied patches. Default is an empty list.
 325
 326 =back
 327
 328 This include the flags that define the binary compatibility, like if
 329 this perl was compiled for 64bitall (C<USE_64_BIT_ALL>), and basically is
 330
 331 =item environment
 332
 333 By default this hash is only filled with the environment variables
 334 out of %ENV that start with C<PERL>, but you can pass the C<env> option
 335 to myconfig to get more
 336
 337  my $conf = Config::Perl::V::myconfig ({ env => qr/^ORACLE/ });
 338  my $conf = Config::Perl::V::myconfig ([ env => qr/^ORACLE/ ]);
 339
 340 =item config
 341
 342 This hash is filled with the variables that C<perl -V> fils it's report
 343 with, and it has the same variables that C<Config::myconfig> returns
 344 from C<%Config>.
 345
 346 =item inc
 347
 348 This is the list of default @INC.
 349
 350 =back
 351
 352 =head1 REASONING
 353
 354 This module was written to be able to return the configuration for the
 355 currently used perl as deeply as needed for the CPANTESTERS framework.
 356 Up until now they used the output of myconfig as a single text blob,
 357 and so it was missing the vital binary characteristics of the running
 358 perl and the optional applied patches.
 359
 360 =head1 BUGS
 361
 362 Please feedback what is wrong
 363
 364 =head1 TODO
 365
 366 * Implement retrieval functions/methods
 367 * Documentation
 368 * Include the perl -V parse block from Andreas
 369
 370 =head1 AUTHOR
 371
 372 H.Merijn Brand <h.m.brand@xs4all.nl>
 373
 374 =head1 COPYRIGHT AND LICENSE
 375
 376 Copyright (C) 2009 H.Merijn Brand
 377
 378 This library is free software; you can redistribute it and/or modify
 379 it under the same terms as Perl itself.
 380
 381 =cut