workbench/s/Startup-Sequence

   1 SetClock LOAD
   2
   3 FailAt 21
   4
   5 If NOT EXISTS "RAM:Clipboards"
   6     Makedir "RAM:Clipboards"
   7 EndIf
   8 If NOT EXISTS "RAM:T"
   9     Makedir "RAM:T"
  10 EndIf
  11 If NOT EXISTS "RAM:ENV"
  12     Makedir "RAM:ENV"
  13     Assign "ENV:" "RAM:ENV"
  14 EndIf
  15
  16 Assign "T:"       "RAM:T"
  17 Assign "CLIPS:"   "RAM:Clipboards"
  18
  19 Assign "KEYMAPS:" "DEVS:Keymaps"
  20 Assign "LOCALE:"  "SYS:Locale"
  21 Assign "LIBS:"    "SYS:Classes" ADD
  22 Assign "FONTS:"   "SYS:Fonts"
  23 Assign "HELP:"    "LOCALE:Help" DEFER
  24 Assign "THEMES:"  "SYS:Prefs/Presets/Themes" >NIL:
  25 Assign "IMAGES:"  "SYS:System/Images" DEFER
  26 Assign "PRINTERS:" "DEVS:Printers"
  27 Assign "WANDERER:" "SYS:System/Wanderer" DEFER
  28
  29 If EXISTS "C:SetPatch"
  30     C:SetPatch QUIET
  31 EndIf
  32
  33 If EXISTS "SYS:Classes/USB"
  34     Assign "USBCLASSES:" "SYS:Classes/USB"
  35     AddUSBClasses >NIL:
  36 EndIf
  37
  38 If EXISTS "SYS:DiskImages"
  39     Assign "FDSK:" "SYS:DiskImages"
  40 EndIf
  41
  42 Automount >NIL:
  43 Mount >NIL: "DEVS:DOSDrivers/~((.#?)|(#?.info)|(#?.dbg))"
  44
  45 Dir >NIL: "PIPE:"
  46
  47 Path "C:" "SYS:System" "S:" "SYS:Prefs" "SYS:Tools" "SYS:Utilities" QUIET
  48
  49 If EXISTS "SYS:Tools/Commodities"
  50     Path "SYS:Tools/Commodities" QUIET ADD
  51 EndIf
  52
  53 If EXISTS "SYS:Demos"
  54     Path "SYS:Demos" ADD QUIET
  55 EndIf
  56
  57 If EXISTS "Sys:RexxC"
  58     Path "Sys:RexxC" ADD QUIET
  59 Endif
  60
  61 Copy >NIL: "ENVARC:" "ENV:" ALL NOPRO NOREQ PAT "~(def_#?.info)"
  62
  63 If EXISTS "ENV:SYS/theme.var"
  64     Assign "THEME:" "${SYS/theme.var}"
  65 else
  66     Assign "THEME:" "THEMES:AROSDefault"
  67 endif
  68
  69 Touch >NIL: "FONTS:__TEST__"
  70 If WARN
  71     Makedir "RAM:Fonts"
  72     Assign "FONTS:" "RAM:Fonts"
  73     Copy >NIL: "SYS:Fonts" "FONTS:" ALL CLONE NOREQ
  74 Endif
  75 Assign >NIL: "FONTS:" "FONTS:Russian" ADD
  76
  77 IF EXISTS "FONTS:__TEST__"
  78     Delete "FONTS:__TEST__" QUIET
  79 Endif
  80
  81 If NOT EXISTS "FONTS:fixed.font"
  82     FixFonts
  83 EndIf
  84
  85 AddDatatypes REFRESH QUIET
  86 IPrefs
  87 PsdStackLoader >NIL:
  88 Run <NIL: >NIL: QUIET ConClip
  89
  90 If EXISTS "C:RexxMast"
  91     Assign "REXX:" "S:"
  92     Run <NIL: >NIL: QUIET C:RexxMast
  93 EndIf
  94
  95 If EXISTS "C:Decoration"
  96     If EXISTS "ENV:SYS/theme.var"
  97         C:Decoration <NIL: >NIL:
  98         If EXISTS "THEME:global.prefs"
  99             If EXISTS "ENV:Zune/usethemeprefs"
 100                 Copy >NIL: "THEME:global.prefs" "ENV:Zune/" NOPRO NOREQ FORCEOVERWRITE
 101             EndIf
 102         EndIf
 103     EndIf
 104 Endif
 105
 106 Assign EXISTS "Extras:" >NIL:
 107 If WARN
 108     If EXISTS "$EXTRASPATH"
 109         Assign "Extras:" "$EXTRASPATH"
 110     Else
 111         Assign "Extras:" "SYS:Extras" >NIL:
 112         If WARN
 113             Assign "Extras:" "NIL:" >NIL:
 114         EndIf
 115     EndIf
 116 Endif
 117
 118 If EXISTS "ENV:SYS/Packages"
 119     List "ENV:SYS/Packages" NOHEAD FILES TO "T:P" LFORMAT="If EXISTS ${SYS/Packages/%N}*NCD ${SYS/Packages/%N}*NIf EXISTS S/%N-Startup*NExecute S/%N-Startup*NElse*NIf EXISTS S/Package-Startup*NExecute S/Package-Startup*NEndif*NEndif*NEndif*N"
 120     Execute "T:P"
 121     Delete "T:P" QUIET
 122     CD "SYS:"
 123 EndIf
 124
 125 Protect "S:PCD" "s" ADD QUIET
 126 Protect "S:SPat" "s" ADD QUIET
 127 Protect "S:DPat" "s" ADD QUIET
 128
 129 If EXISTS "S:User-Startup"
 130     Execute "S:User-Startup"
 131 EndIf
 132
 133 If EXISTS "WANDERER:Wanderer"
 134     WANDERER:Wanderer
 135
 136     If NOT ERROR
 137         EndCLI
 138     EndIf
 139 EndIf