workbench/s/Startup-Sequence

   1 SetClock LOAD
   2
   3 FailAt 21
   4
   5 Makedir "RAM:Clipboards"
   6 If NOT EXISTS "RAM:T"
   7     Makedir "RAM:T"
   8 EndIf
   9 If NOT EXISTS "RAM:ENV"
  10     Makedir "RAM:ENV"
  11     Assign "ENV:" "RAM:ENV"
  12 EndIf
  13
  14 Assign "T:"       "RAM:T"
  15 Assign "CLIPS:"   "RAM:Clipboards"
  16
  17 Assign "KEYMAPS:" "DEVS:Keymaps"
  18 Assign "LOCALE:"  "SYS:Locale"
  19 Assign "LIBS:"    "SYS:Classes" ADD
  20 Assign "FONTS:"   "SYS:Fonts"
  21 Assign "HELP:"    "LOCALE:Help" DEFER
  22 Assign "THEMES:"  "SYS:Prefs/Presets/Themes" >NIL:
  23 Assign "IMAGES:"  "SYS:System/Images" DEFER
  24 Assign "PRINTERS:" "DEVS:Printers"
  25 Assign "WANDERER:" "SYS:System/Wanderer" DEFER
  26
  27 If EXISTS "SYS:Classes/USB"
  28     Assign "USBCLASSES:" "SYS:Classes/USB"
  29     AddUSBClasses >NIL:
  30 EndIf
  31
  32 If EXISTS "SYS:DiskImages"
  33     Assign "FDSK:" "SYS:DiskImages"
  34 EndIf
  35
  36 Automount >NIL:
  37 Mount >NIL: "DEVS:DOSDrivers/~((.#?)|(#?.info))"
  38
  39 Dir >NIL: "PIPE:"
  40
  41 Path "C:" "SYS:System" "S:" "SYS:Prefs" "SYS:Tools" "SYS:Utilities" QUIET
  42
  43 If EXISTS "SYS:Tools/Commodities"
  44     Path "SYS:Tools/Commodities" QUIET ADD
  45 EndIf
  46
  47 If EXISTS "SYS:Demos"
  48     Path "SYS:Demos" ADD QUIET
  49 EndIf
  50
  51 If EXISTS "Sys:RexxC"
  52     Path "Sys:RexxC" ADD QUIET
  53 Endif
  54
  55 Copy >NIL: "ENVARC:" "ENV:" ALL NOPRO NOREQ PAT "~(def_#?.info)"
  56
  57 If EXISTS "ENV:SYS/theme.var"
  58     Assign "THEME:" "${SYS/theme.var}"
  59 else
  60     Assign "THEME:" "THEMES:AROSDefault"
  61 endif
  62
  63 Touch >NIL: "FONTS:__TEST__"
  64 If WARN
  65     Makedir "RAM:Fonts"
  66     Assign "FONTS:" "RAM:Fonts"
  67     Copy >NIL: "SYS:Fonts" "FONTS:" ALL CLONE NOREQ
  68 Endif
  69 Assign >NIL: "FONTS:" "FONTS:Russian" ADD
  70
  71 IF EXISTS "FONTS:__TEST__"
  72     Delete "FONTS:__TEST__" QUIET
  73 Endif
  74
  75 If NOT EXISTS "FONTS:fixed.font"
  76     FixFonts
  77 EndIf
  78
  79 AddDatatypes REFRESH QUIET
  80 IPrefs
  81 Run <NIL: >NIL: QUIET ConClip
  82
  83 If EXISTS "C:RexxMast"
  84     Assign "REXX:" "S:"
  85     Run <NIL: >NIL: QUIET C:RexxMast
  86 EndIf
  87
  88 If EXISTS "C:Decoration"
  89     If EXISTS "ENV:SYS/theme.var"
  90         C:Decoration <NIL: >NIL:
  91         If EXISTS "THEME:global.prefs"
  92             If EXISTS "ENV:Zune/usethemeprefs"
  93                 Copy >NIL: "THEME:global.prefs" "ENV:Zune/" NOPRO NOREQ FORCEOVERWRITE
  94             EndIf
  95         EndIf
  96     EndIf
  97 Endif
  98
  99 Assign EXISTS "Extras:" >NIL:
 100 If WARN
 101     If EXISTS "$EXTRASPATH"
 102         Assign "Extras:" "$EXTRASPATH"
 103     Else
 104         Assign "Extras:" "SYS:Extras" >NIL:
 105         If WARN
 106             Assign "Extras:" "NIL:" >NIL:
 107         EndIf
 108     EndIf
 109 Endif
 110
 111 If EXISTS "ENV:SYS/Packages"
 112     List "ENV:SYS/Packages" NOHEAD FILES TO "T:P" LFORMAT="If EXISTS ${SYS/Packages/%N}*NCD ${SYS/Packages/%N}*NIf EXISTS S/Package-Startup*NExecute S/Package-Startup*NEndif*NEndif*N"
 113     Execute "T:P"
 114     Delete "T:P" QUIET
 115     CD "SYS:"
 116 EndIf
 117
 118 Protect "S:PCD" "s" ADD QUIET
 119 Protect "S:SPat" "s" ADD QUIET
 120 Protect "S:DPat" "s" ADD QUIET
 121
 122 If EXISTS "S:User-Startup"
 123     Execute "S:User-Startup"
 124 EndIf
 125
 126 WANDERER:Wanderer
 127
 128 If NOT ERROR
 129     EndCLI
 130 EndIf