arch/m68k-amiga/boot/aros-dbg.ld

   1 MEMORY {
   2  valid  (rwx)    : org = 0x00000000 , l = 2M
   3  tempstack (rwx) : org = 0x0003f800, l = 0x800
   4  invalid (rwx) : org = 0xdead0000 , l = 0x0
   5 }
   6
   7 SECTIONS
   8 {
   9  .start.MEMF_LOCAL           : { _ext_start = .;
  10 INCLUDE ../../../bin/amiga-m68k/gen/start_objs.ld
  11                                } >valid
  12  .kick.MEMF_KICK             : { _kick_start = .;
  13 INCLUDE ../../../bin/amiga-m68k/gen/any_objs.ld
  14                                  _kick_end = .;
  15                                  _ext_end = .;
  16                                } >valid
  17  .rom.MEMF_LOCAL             : { _rom_start = .;
  18 INCLUDE ../../../bin/amiga-m68k/gen/local_objs.ld
  19                                   /* This is for the static libs */
  20                                  *(.text .text.* .rodata .rodata.*)
  21                                  *(.eh_frame)
  22                                  _rom_end = .;
  23                                } >valid
  24  /* Supervisor stack, only used until after all autoconfig boards have
  25   * been initialized, at which point we'll allocate a faster location for it.
  26   */
  27 .ss                          : {
  28                                 _ss = .;
  29                                 . = . + 0x800;
  30                                 _ss_end = .;
  31                                } >tempstack
  32
  33  /* This should cause angry complaints if .data exists
  34   * We don't want .bss, and we don't need it.
  35   */
  36  .bss                        : { *(.bss)              } >invalid
  37
  38  /* This should cause angry complaints if .data exists
  39   * We don't want .data, and we don't need it.
  40   */
  41  .data                       : { *(.data)             } >invalid
  42
  43 }