workbench/s/Startup-Sequence

   1 SetClock LOAD
   2
   3 FailAt 21
   4
   5 If NOT EXISTS "RAM:Clipboards"
   6     Makedir "RAM:Clipboards"
   7 EndIf
   8 If NOT EXISTS "RAM:T"
   9     Makedir "RAM:T"
  10 EndIf
  11 If NOT EXISTS "RAM:ENV"
  12     Makedir "RAM:ENV"
  13     Assign "ENV:" "RAM:ENV"
  14 EndIf
  15
  16 Assign "T:"       "RAM:T"
  17 Assign "CLIPS:"   "RAM:Clipboards"
  18
  19 Assign "KEYMAPS:" "DEVS:Keymaps"
  20 Assign "LOCALE:"  "SYS:Locale"
  21 Assign "LIBS:"    "SYS:Classes" ADD
  22 Assign "FONTS:"   "SYS:Fonts"
  23 Assign "HELP:"    "LOCALE:Help" DEFER
  24 Assign "THEMES:"  "SYS:Prefs/Presets/Themes" >NIL:
  25 Assign "IMAGES:"  "SYS:System/Images" DEFER
  26 Assign "PRINTERS:" "DEVS:Printers"
  27 Assign "WANDERER:" "SYS:System/Wanderer" DEFER
  28
  29 If EXISTS "C:SetPatch"
  30     C:SetPatch QUIET
  31 EndIf
  32
  33 If EXISTS "SYS:Classes/USB"
  34     Assign "USBCLASSES:" "SYS:Classes/USB"
  35     AddUSBClasses >NIL:
  36 EndIf
  37
  38 If EXISTS "SYS:DiskImages"
  39     Assign "FDSK:" "SYS:DiskImages"
  40 EndIf
  41
  42 Automount >NIL:
  43 Mount >NIL: "DEVS:DOSDrivers/~((.#?)|(#?.info)|(#?.dbg))"
  44
  45 Dir >NIL: "PIPE:"
  46
  47 Path "C:" "SYS:System" "S:" "SYS:Prefs" "SYS:Tools" "SYS:Utilities" QUIET
  48
  49 If EXISTS "SYS:Tools/Commodities"
  50     Path "SYS:Tools/Commodities" QUIET ADD
  51 EndIf
  52
  53 If EXISTS "SYS:Demos"
  54     Path "SYS:Demos" ADD QUIET
  55 EndIf
  56
  57 If EXISTS "Sys:RexxC"
  58     Path "Sys:RexxC" ADD QUIET
  59 Endif
  60
  61 Copy >NIL: "ENVARC:" "ENV:" ALL NOPRO NOREQ PAT "~(def_#?.info)"
  62
  63 If EXISTS "ENV:SYS/theme.var"
  64     Assign "THEME:" "${SYS/theme.var}"
  65 else
  66     Assign "THEME:" "THEMES:AROSDefault"
  67 endif
  68
  69 Touch >NIL: "FONTS:__TEST__"
  70 If WARN
  71     Makedir "RAM:Fonts"
  72     Assign "FONTS:" "RAM:Fonts"
  73     Copy >NIL: "SYS:Fonts" "FONTS:" ALL CLONE NOREQ
  74 Endif
  75 Assign >NIL: "FONTS:" "FONTS:Russian" ADD
  76
  77 IF EXISTS "FONTS:__TEST__"
  78     Delete "FONTS:__TEST__" QUIET
  79 Endif
  80
  81 If NOT EXISTS "FONTS:fixed.font"
  82     FixFonts
  83 EndIf
  84
  85 AddDatatypes REFRESH QUIET
  86 IPrefs
  87 Run <NIL: >NIL: QUIET ConClip
  88
  89 If EXISTS "C:RexxMast"
  90     Assign "REXX:" "S:"
  91     Run <NIL: >NIL: QUIET C:RexxMast
  92 EndIf
  93
  94 If EXISTS "C:Decoration"
  95     If EXISTS "ENV:SYS/theme.var"
  96         C:Decoration <NIL: >NIL:
  97         If EXISTS "THEME:global.prefs"
  98             If EXISTS "ENV:Zune/usethemeprefs"
  99                 Copy >NIL: "THEME:global.prefs" "ENV:Zune/" NOPRO NOREQ FORCEOVERWRITE
 100             EndIf
 101         EndIf
 102     EndIf
 103 Endif
 104
 105 Assign EXISTS "Extras:" >NIL:
 106 If WARN
 107     If EXISTS "$EXTRASPATH"
 108         Assign "Extras:" "$EXTRASPATH"
 109     Else
 110         Assign "Extras:" "SYS:Extras" >NIL:
 111         If WARN
 112             Assign "Extras:" "NIL:" >NIL:
 113         EndIf
 114     EndIf
 115 Endif
 116
 117 If EXISTS "ENV:SYS/Packages"
 118     List "ENV:SYS/Packages" NOHEAD FILES TO "T:P" LFORMAT="If EXISTS ${SYS/Packages/%N}*NCD ${SYS/Packages/%N}*NIf EXISTS S/Package-Startup*NExecute S/Package-Startup*NEndif*NEndif*N"
 119     Execute "T:P"
 120     Delete "T:P" QUIET
 121     CD "SYS:"
 122 EndIf
 123
 124 Protect "S:PCD" "s" ADD QUIET
 125 Protect "S:SPat" "s" ADD QUIET
 126 Protect "S:DPat" "s" ADD QUIET
 127
 128 If EXISTS "S:User-Startup"
 129     Execute "S:User-Startup"
 130 EndIf
 131
 132 If EXISTS "WANDERER:Wanderer"
 133     WANDERER:Wanderer
 134
 135     If NOT ERROR
 136         EndCLI
 137     EndIf
 138 EndIf