configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.81.0)
  19
  20 AC_PROG_LIBTOOL
  21
  22 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  23 # Turn around -rpath problem with libtool 1.0c
  24 # This define should be improbable enough to not conflict with anything
  25 case ${host} in
  26   *-pc-linux-gnu)
  27     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  28     sed < libtool > libtool-2 \
  29     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  30     mv libtool-2 libtool
  31     chmod 755 libtool
  32   ;;
  33 esac
  34
  35
  36 AM_CONFIG_HEADER(src/config.h)
  37
  38
  39 dnl Checks for host/os name
  40 dnl =======================
  41 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  42
  43
  44 dnl Checks for programs.
  45 dnl ===================
  46 AC_ISC_POSIX
  47 AC_PROG_CC
  48 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  49 #AC_PROG_RANLIB
  50 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  51 AC_PROG_LN_S
  52 AC_PROG_GCC_TRADITIONAL
  53
  54
  55 dnl the prefix
  56 dnl ==========
  57 dnl
  58 dnl move this earlier in the script... anyone know why this is handled
  59 dnl in such a bizarre way?
  60
  61 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  62 dnl Let make expand exec_prefix.
  63 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  64
  65
  66 _bindir=`eval echo $bindir`
  67 _bindir=`eval echo $_bindir`
  68
  69 _libdir=`eval echo $libdir`
  70 _libdir=`eval echo $_libdir`
  71 lib_search_path="-L$_libdir"
  72
  73 inc_search_path=`eval echo $includedir`
  74 inc_search_path="-I`eval echo $inc_search_path`"
  75
  76
  77 dnl
  78 dnl Check for RedHat bugs
  79 dnl =====================
  80
  81 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  82
  83
  84 dnl
  85 dnl Specify paths to look for libraries and headers
  86 dnl ===============================================
  87 AC_ARG_WITH(libs-from,
  88 [  --with-libs-from        pass compiler flags to look for libraries],
  89         [lib_search_path="$withval $lib_search_path"])
  90
  91 AC_ARG_WITH(incs-from,
  92 [  --with-incs-from        pass compiler flags to look for header files],
  93         [inc_search_path="$withval $inc_search_path"])
  94
  95
  96
  97 dnl Checks for library functions.
  98 dnl ============================
  99 dnl not used anywhere
 100 dnl AC_FUNC_MEMCMP
 101 AC_FUNC_VPRINTF
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp setsid atexit mallinfo mkstemp snprintf vsnprintf asprintf vasprintf)
 104
 105
 106 dnl ripped from samba
 107 dnl
 108 AC_CACHE_CHECK([for C99 vsnprintf],_cv_HAVE_C99_VSNPRINTF,[
 109 AC_TRY_RUN([
 110 #include <sys/types.h>
 111 #include <stdarg.h>
 112 void foo(const char *format, ...) {
 113        va_list ap;
 114        int len;
 115        char buf[5];
 116
 117        va_start(ap, format);
 118        len = vsnprintf(0, 0, format, ap);
 119        va_end(ap);
 120        if (len != 5) exit(1);
 121
 122        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 123
 124        exit(0);
 125 }
 126 main() { foo("hello"); }
 127 ],
 128 _cv_HAVE_C99_VSNPRINTF=yes,_cv_HAVE_C99_VSNPRINTF=no,_cv_HAVE_C99_VSNPRINTF=cross)])
 129 if test x"$_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 130     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [define if you have vsnprintf with C99 semantics (set by configure)])
 131 fi
 132
 133 dnl Loading of dynamic libraries at runtime
 134 dnl =======================================
 135 DLLIBS=""
 136
 137 AC_CHECK_FUNC(dlopen, [HAVEDL="yes"],
 138         AC_CHECK_LIB(dl, dlopen, [DLLIBS="-ldl" HAVEDL="yes"],
 139                          DLLIBS="" ))
 140
 141 if test "x$HAVEDL" = xyes; then
 142     AC_CHECK_HEADERS(dlfcn.h)
 143 fi
 144
 145
 146
 147 dnl Check CPP
 148 dnl =========
 149 if test "x$CPP_PATH" = x; then
 150     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 151                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 152 fi
 153
 154 dnl
 155 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 156 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 157 dnl standard locations
 158 dnl
 159 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 160     if test "$GCC" = "yes"; then
 161         CPP_PATH="gcc -E -x c"
 162     else
 163         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 164             CPP_PATH="$CPP_PATH -B"
 165         else
 166             echo "cpp, the C preprocessor was not found in your system."
 167             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 168             exit
 169         fi
 170     fi
 171 fi
 172 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH", [define to the path to cpp])
 173
 174
 175
 176 dnl Checks for header files.
 177 dnl =======================
 178 AC_HEADER_SYS_WAIT
 179 AC_HEADER_TIME
 180 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h libintl.h sys/select.h poll.h malloc.h ctype.h string.h strings.h)
 181
 182
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 dnl ==============================================================
 186 AC_DECL_SYS_SIGLIST
 187 AC_C_CONST
 188 #AC_TYPE_SIZE_T
 189 #AC_TYPE_PID_T
 190 AC_TYPE_SIGNAL
 191
 192
 193
 194 dnl Compiler/architecture specific optimizations
 195 dnl ============================================
 196
 197
 198 dnl GCC/as with MMX support
 199 dnl -----------------------
 200
 201 # until we fix it, leave it disabled
 202 asm_support=no
 203 mmx_support=no
 204 if test "$ac_cv_prog_gcc" = yes; then
 205     x86=0
 206     changequote(,)dnl
 207     case "$host_cpu" in
 208        i[3456]86) x86=1
 209        ;;
 210     esac
 211     changequote([,])dnl
 212
 213     if test "$host_os" != "linux" -a "$host_os" != "linux-gnu" ; then
 214        x86=0
 215     fi
 216
 217     if test $x86 = 1; then
 218        AC_DEFINE(ASM_X86, 1, [define if processor is x86 (normally detected by configure)])
 219        asm_support=yes
 220
 221        AC_CACHE_CHECK(whether gcc supports MMX(tm) inline asm,
 222                       ac_cv_c_inline_mmx,
 223                       [AC_TRY_LINK(,[asm ("movq %mm0, %mm1");],
 224                       ac_cv_c_inline_mmx=yes,
 225                       ac_cv_c_inline_mmx=no)])
 226
 227        if test "x$ac_cv_c_inline_mmx" = xyes; then
 228           AC_DEFINE(ASM_X86_MMX, 1, [define if processor is x86 with MMX(tm) support (normally autodetected by configure)])
 229           mmx_support=yes
 230        fi
 231     fi
 232 fi
 233
 234
 235
 236 dnl gettext
 237 dnl =======
 238
 239
 240 dnl AM_GNU_GETTEXT
 241
 242
 243
 244 INTLIBS=""
 245
 246 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 247         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 248                          INTLIBS="" ))
 249
 250 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 251
 252 if test "$XGETTEXT" != ""; then
 253     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 254         echo "xgettext isn't GNU version"
 255         XGETTEXT=""
 256     fi
 257 fi
 258
 259 if test "$LINGUAS" != ""; then
 260     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 261         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 262         PO=""
 263 #       if test "$LINGUAS" = ""; then
 264 #           ling=` (cd src/po; /bin/ls *.po) `
 265 #           for l in $ling; do
 266 #               lcode=`basename $l .po`
 267 #               LINGUAS="$LINGUAS $lcode"
 268 #           done
 269 #       fi
 270         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 271     else
 272         LINGUAS=""
 273         PO=""
 274         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 275     fi
 276 else
 277         INTLIBS=""
 278         MOFILES=""
 279         WPMOFILES=""
 280         PO=""
 281 fi
 282
 283
 284 dnl The Tower of Babel
 285 dnl ==================
 286
 287 dnl List of supported locales
 288 dnl -------------------------
 289 supported_locales="be bg ca cs da de el es et fi fr gl hr hu it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW.Big5"
 290 supported_wprefs_locales="bg ca cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW.Big5"
 291 supported_wings_locales="bg ca cs de fr sk"
 292
 293 for lang in $LINGUAS; do
 294         ok=0
 295         for l in $supported_locales; do
 296                 if test "$l" = "$lang"; then
 297                         ok=1
 298                         break
 299                 fi
 300         done
 301         if test "$ok" = 1; then
 302                 MOFILES="$MOFILES $lang.mo"
 303         else
 304                 echo "Locale $lang is not supported."
 305         fi
 306         ok=0
 307         for l in $supported_wprefs_locales; do
 308                 if test "$l" = "$lang"; then
 309                         ok=1
 310                         break
 311                 fi
 312         done
 313         if test "$ok" = 1; then
 314                 WPMOFILES="$WPMOFILES $lang.mo"
 315         fi
 316         ok=0
 317         for l in $supported_wings_locales; do
 318                 if test "$l" = "$lang"; then
 319                         ok=1
 320                         break
 321                 fi
 322         done
 323         if test "$ok" = 1; then
 324                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 325         fi
 326 done
 327
 328
 329 dnl Kanji Characters support
 330 dnl ========================
 331
 332 case $host_os in
 333         freebsd*)
 334                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 335         *)
 336         ;;
 337 esac
 338
 339
 340
 341 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 342 dnl ===========================================
 343 AC_ARG_WITH(nlsdir,
 344         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 345
 346
 347 if test "x$NLSDIR" = "x"; then
 348         if test "x$with_nlsdir" != "x"; then
 349                 NLSDIR=$with_nlsdir
 350         else
 351                 NLSDIR='$(prefix)/lib/locale'
 352         fi
 353 fi
 354
 355
 356
 357 AC_SUBST(DLLIBS)
 358 AC_SUBST(INTLIBS)
 359 AC_SUBST(NLSDIR)
 360 AC_SUBST(MOFILES)
 361 AC_SUBST(WPMOFILES)
 362 AC_SUBST(WINGSMOFILES)
 363 AC_SUBST(supported_locales)
 364
 365
 366
 367 dnl Support for various hint things
 368 dnl ===============================
 369
 370
 371 AC_ARG_ENABLE(gnome,
 372   [  --enable-gnome          enable stuff needed for GNOME ],
 373   [if test x$enableval = xyes; then
 374     AC_DEFINE(GNOME_STUFF, 1, [define if you want GNOME stuff support])
 375     gnome_on=yes
 376   fi])
 377
 378
 379 AC_ARG_ENABLE(kde,
 380   [  --enable-kde            enable support for KDE window manager (kwm) hints ],
 381   [if test x$enableval = xyes; then
 382     AC_DEFINE(KWM_HINTS, 1, [define if you want KDE hint support])
 383     kde_on=yes
 384   fi])
 385
 386
 387 AC_ARG_ENABLE(openlook,
 388   [  --enable-openlook       enable support for OPEN LOOK(tm) (olwm) hints ],
 389   [if test x$enableval = xyes; then
 390     AC_DEFINE(OLWM_HINTS, 1, [define if you want OPEN LOOK(tm) hint support])
 391     openlook_on=yes
 392   fi])
 393
 394
 395 dnl
 396 dnl Disable some stuff that are duplicated in kde
 397 dnl ---------------------------------------------
 398 AC_ARG_ENABLE(lite,
 399   [  --enable-lite           disable some stuff (dont use it) ],
 400   [if test x$enableval = xyes; then
 401         LITE=yes
 402         AC_DEFINE(LITE, 1, [define if you want the 'lite' version])
 403         AC_SUBST(LITE)
 404   fi])
 405
 406
 407
 408 dnl
 409 dnl Networking stuff
 410 dnl
 411
 412 NETLIBS=""
 413
 414 AC_CHECK_FUNC(connect,,
 415         AC_CHECK_LIB(socket, connect, NETLIBS="$NETLIBS -lsocket"))
 416
 417 AC_CHECK_FUNC(gethostbyname,,
 418         AC_CHECK_LIB(nsl, gethostbyname, NETLIBS="$NETLIBS -lnsl"))
 419
 420 AC_CHECK_FUNC(inet_aton, AC_DEFINE(HAVE_INET_ATON, 1, [define if you have then inet_aton function (set by configure)]),
 421      for lib in resolv socket inet bsd; do
 422         AC_CHECK_LIB($lib, inet_aton, [AC_DEFINE(HAVE_INET_ATON)
 423                      NETLIBS="$NETLIBS -l$lib"; break],, $NETLIBS)
 424      done)
 425
 426 AC_SUBST(NETLIBS)
 427
 428
 429 dnl ===========================================
 430 dnl             Stuff that uses X
 431 dnl ===========================================
 432
 433 AC_PATH_XTRA
 434
 435 if test $no_x; then
 436     AC_MSG_ERROR([The path for the X11 files not found!
 437 Make sure you have X and it's headers and libraries (the -devel packages
 438 in Linux) installed.])
 439 fi
 440
 441 X_LIBRARY_PATH=$x_libraries
 442
 443 XCFLAGS="$X_CFLAGS"
 444
 445 XLFLAGS="$X_LIBS"
 446
 447 XLIBS="-lX11 $X_EXTRA_LIBS"
 448
 449
 450 lib_search_path="$lib_search_path $XLFLAGS"
 451 inc_search_path="$inc_search_path $XCFLAGS"
 452
 453
 454 AC_SUBST(X_LIBRARY_PATH)
 455
 456
 457
 458 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 459 dnl by MANOME Tomonori
 460 dnl ===========================================
 461 use_locale=yes
 462 AC_ARG_ENABLE(locale,
 463 [  --disable-locale        disable use of X locale support],
 464                 use_locale=no)
 465
 466 if test "$use_locale" = yes; then
 467         AC_CHECK_LIB(X11, _Xsetlocale,
 468                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 469                 $XLFLAGS $XLIBS)
 470 fi
 471
 472
 473 dnl Check whether XInternAtoms() exist
 474 dnl ==================================
 475 AC_CHECK_LIB(X11, XInternAtoms,
 476              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 477              $XLFLAGS $XLIBS)
 478
 479 dnl Check whether XConvertCase() exist
 480 dnl ==================================
 481 AC_CHECK_LIB(X11, XConvertCase,
 482              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 483              $XLFLAGS $XLIBS)
 484
 485
 486 dnl XKB keyboard language status
 487 dnl ============================
 488 AC_ARG_ENABLE(modelock,
 489 [  --enable-modelock       XKB keyboard language status support],
 490                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 491
 492
 493
 494 dnl Shape support
 495 dnl =============
 496 shape=yes
 497 AC_ARG_ENABLE(shape,
 498 [  --disable-shape         disable shaped window extension support],
 499                 shape=$enableval, shape=yes)
 500
 501 added_xext=no
 502
 503 if test "$shape" = yes; then
 504         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 505                 added_xext=yes
 506                 AC_DEFINE(SHAPE, 1, [define if you want support for shaped windows (set by configure)])],
 507                 shape=no, $XLFLAGS $XLIBS)
 508 fi
 509
 510
 511 dnl Xft antialiased font support
 512 dnl ============================
 513 xft=yes
 514 XFTLIBS=""
 515 AC_ARG_ENABLE(xft,
 516 [  --disable-xft           disable Xft antialiased font support],
 517                 xft=$enableval, xft=yes)
 518
 519 if test "$xft" = yes; then
 520         AC_CHECK_LIB(Xft, XftDrawCreate, [XFTLIBS="-lXft"
 521                 AC_SUBST(XFTLIBS)
 522                 AC_DEFINE(XFT, 1, [define if you want support for antialiased fonts (set by configure)])],
 523                 xft=no, $XLFLAGS $XLIBS)
 524 fi
 525
 526
 527 dnl XINERAMA support
 528 dnl ================
 529 xinerama=no
 530 AC_ARG_ENABLE(xinerama,
 531 [  --enable-xinerama       enable Xinerama extension support],
 532                 xinerama=$enableval, xinerama=no)
 533
 534 if test "$xinerama" = yes; then
 535         AC_CHECK_LIB(Xinerama, XineramaQueryScreens,
 536                 [XLIBS="-lXinerama $XLIBS"
 537                 xfxine=yes],
 538                 xfxine=no, $XLFLAGS $XLIBS)
 539
 540         AC_CHECK_LIB(Xext, XineramaGetInfo,
 541                 [sunxine=yes
 542                 ], sunxine=no, $XLFLAGS $XLIBS)
 543
 544         if test "$xfxine" = yes; then
 545                 xine=1
 546         fi
 547
 548         if test "$sunxine" = yes; then
 549             xine=1
 550             AC_DEFINE(SOLARIS_XINERAMA, 1,
 551                 [define if you want support for the XINERAMA extension and are in Solaris (set by configure)])
 552         fi
 553
 554         if test "$xine" = 1; then
 555             AC_DEFINE(XINERAMA, 1,
 556                 [define if you want support for the XINERAMA extension (set by configure)])
 557         fi
 558 fi
 559
 560
 561
 562 dnl MIT-SHM support
 563 dnl ===============
 564 shm=yes
 565 AC_ARG_ENABLE(shm,
 566 [  --disable-shm           disable usage of MIT-SHM extension],
 567                 shm=$enableval, shm=yes)
 568
 569 if test "$shm" = yes; then
 570         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 571
 572         if test "$ok" = yes; then
 573         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 574         fi
 575
 576         if test "$ok" = yes; then
 577                 if test "$added_xext" = no; then
 578                         XLIBS="-lXext $XLIBS"
 579                 fi
 580                 AC_DEFINE(XSHM, 1, [define if X's shared memory extension is available (set by configure)])
 581         fi
 582 fi
 583
 584
 585 dnl R6 Style Session Management Support
 586 dnl ===================================
 587
 588 #
 589 #
 590 #AC_DEFINE(R6SM)
 591 #AC_SUBST(XSMPLIBS)
 592 #
 593
 594
 595 dnl ==============================================
 596 dnl         Graphic Format Libraries
 597 dnl ==============================================
 598
 599
 600
 601
 602
 603 dnl XPM Support
 604 dnl ===========
 605 xpm=yes
 606 AC_ARG_ENABLE(xpm,
 607 [  --disable-xpm           disable use of XPM pixmaps through libXpm],
 608         xpm=$enableval, xpm=yes)
 609
 610 if test "$xpm" = yes; then
 611     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 612
 613     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 614         WM_CHECK_HEADER(X11/xpm.h)
 615         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 616                 GFXLIBS="$GFXLIBS -lXpm"
 617                 supported_gfx="XPM"
 618                 AC_DEFINE(USE_XPM, 1, [define if XPM libraries are available (set by configure)])
 619         else
 620                 supported_gfx="builtin-XPM"
 621         fi
 622     fi
 623 fi
 624
 625 # for wmlib
 626 AC_SUBST(XCFLAGS)
 627 # for test
 628 AC_SUBST(XLFLAGS)
 629 AC_SUBST(XLIBS)
 630
 631 AC_SUBST(X_EXTRA_LIBS)
 632
 633 dnl ===============================================
 634 dnl             End of stuff that uses X
 635 dnl ===============================================
 636
 637
 638
 639 dnl PNG Support
 640 dnl ===========
 641 png=yes
 642 AC_ARG_ENABLE(png,
 643 [  --disable-png           disable PNG support through libpng],
 644         png=$enableval, png=yes, png=no)
 645
 646
 647 if test "$png" = yes ; then
 648     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 649
 650     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 651         WM_CHECK_HEADER(png.h)
 652         if test "x$ac_cv_header_png_h" = xyes; then
 653             GFXLIBS="$GFXLIBS -lpng -lz"
 654             supported_gfx="$supported_gfx PNG"
 655             AC_DEFINE(USE_PNG, 1, [define if PNG libraries are available (set by configure)])
 656         fi
 657     fi
 658 fi
 659
 660
 661 dnl JPEG Support
 662 dnl ============
 663 jpeg=yes
 664 ljpeg=""
 665 AC_ARG_ENABLE(jpeg,
 666 [  --disable-jpeg          disable JPEG support through libjpeg],
 667         jpeg=$enableval, jpeg=yes, jpeg=no)
 668
 669 if test "$jpeg" = yes; then
 670     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 671
 672     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 673
 674         ljpeg="-ljpeg"
 675
 676         WM_CHECK_HEADER(jpeglib.h)
 677         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 678             GFXLIBS="$GFXLIBS -ljpeg"
 679             supported_gfx="$supported_gfx JPEG"
 680             AC_DEFINE(USE_JPEG, 1, [define if JPEG libraries are available (set by configure)])
 681         fi
 682     fi
 683 fi
 684
 685
 686 dnl GIF Support
 687 dnl ============
 688 gif=yes
 689 AC_ARG_ENABLE(gif,
 690 [  --disable-gif           disable GIF support through libgif or libungif],
 691         gif=$enableval, gif=yes, gif=no)
 692
 693 if test "$gif" = yes; then
 694     my_libname=""
 695     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 696     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 697         my_libname=-lungif
 698     fi
 699 dnl
 700 dnl libungif is the same thing as libgif for all practical purposes.
 701 dnl
 702     if test "x$my_libname" = x; then
 703         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 704         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 705             my_libname=-lgif
 706         fi
 707     fi
 708
 709     if test "$my_libname" != x; then
 710         WM_CHECK_HEADER(gif_lib.h)
 711         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 712             GFXLIBS="$GFXLIBS $my_libname"
 713             supported_gfx="$supported_gfx GIF"
 714             AC_DEFINE(USE_GIF, 1, [define if GIF libraries are available (set by configure)])
 715         fi
 716     fi
 717 fi
 718
 719
 720
 721 dnl TIFF Support
 722 dnl ============
 723 AC_ARG_ENABLE(tiff,
 724 [  --disable-tiff          disable use of TIFF images through libtiff],
 725         tif=$enableval, tif=yes, tif=no)
 726
 727 #
 728 # TIFF can optionally have JPEG and/or zlib support. Must find out
 729 # when they are supported so that correct library flags are passed during
 730 # detection and linkage
 731 #
 732 #
 733 # By default use xpm icons if tiff is not found.
 734 ICONEXT="xpm"
 735 #
 736
 737 if test "$tif" = yes; then
 738     my_libname=""
 739     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 740     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 741         my_libname="-ltiff"
 742     fi
 743 dnl
 744 dnl Retry with zlib
 745 dnl
 746     unset ac_cv_lib_tiff_TIFFGetVersion
 747     if test "x$my_libname" = x; then
 748         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 749         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 750             my_libname="-ltiff -lz"
 751         fi
 752     fi
 753
 754     if test "x$my_libname" = x; then
 755         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 756         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 757             my_libname="-ltiff34"
 758         fi
 759     fi
 760
 761
 762     if test "x$my_libname" != x; then
 763         WM_CHECK_HEADER(tiffio.h)
 764         if test "x$ac_cv_header_tiffio_h" = xyes; then
 765             GFXLIBS="$my_libname $GFXLIBS"
 766             ICONEXT="tiff"
 767             supported_gfx="$supported_gfx TIFF"
 768             AC_DEFINE(USE_TIFF, 1, [define if TIFF libraries are available (set by configure)])
 769         fi
 770     fi
 771 fi
 772
 773 LIBRARY_SEARCH_PATH="$lib_search_path"
 774 HEADER_SEARCH_PATH="$inc_search_path"
 775
 776 AC_SUBST(LIBRARY_SEARCH_PATH)
 777 AC_SUBST(HEADER_SEARCH_PATH)
 778
 779
 780 AC_SUBST(GFXLIBS)
 781 AC_SUBST(ICONEXT)
 782
 783
 784 dnl ==============================================
 785 dnl         End of Graphic Format Libraries
 786 dnl ==============================================
 787
 788
 789 dnl
 790 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 791 AC_CHECK_HEADERS(stdlib.h)
 792
 793 # AC_PREFIX_PROGRAM(wmaker)
 794
 795 dnl Support for PIXMAPDIR option
 796 dnl ============================
 797 AC_ARG_WITH(pixmapdir,
 798 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 799
 800 if test "x$with_pixmapdir" != "x"; then
 801         pixmapdir=$with_pixmapdir
 802 else
 803         pixmapdir=`eval echo ${datadir}/pixmaps`
 804 fi
 805
 806 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir", [define an extra path for pixmaps (set by configure)])
 807
 808 pkgdatadir=`eval echo $datadir`
 809 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker", [where shared data is stored (defined by configure)])
 810
 811 _sysconfdir=`eval echo $sysconfdir`
 812 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir", [where the configuration is stored (defined by configure)])
 813
 814
 815 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 816 dnl ==============================================
 817
 818 appspath=""
 819
 820 AC_ARG_WITH(appspath,
 821 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 822
 823 if test "x$appspath" = "x"; then
 824     gnustepdir='$(prefix)/GNUstep'
 825
 826     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 827         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 828         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 829     fi
 830
 831     with_appspath=$gnustepdir/Apps
 832 fi
 833
 834 wprefsdir=$with_appspath/WPrefs.app
 835
 836 AC_SUBST(wprefsdir)
 837
 838
 839 dnl Enable User Defined Menu thing
 840 dnl ==================================
 841 AC_ARG_ENABLE(usermenu,
 842 [  --enable-usermenu       user defined menus for applications
 843 ],
 844 if test "$enableval" = yes; then
 845         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 846 fi
 847 )
 848
 849
 850 dnl
 851 dnl Nicolai:  Program tests for Documentation Section
 852 dnl =================================================
 853 dnl DOCTYPES=""
 854 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 855 dnl if test "x$MAKEINFO" != "x" ; then
 856 dnl       DOCTYPES="$DOCTYPES info_doc"
 857 dnl fi
 858 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 859 dnl if test "x$TEX" != "x" ; then
 860 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 861 dnl fi
 862 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 863 dnl if test "x$DVIPS" != "x" ; then
 864 dnl       DOCTYPES="$DOCTYPES ps_doc"
 865 dnl fi
 866 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 867 dnl if test "x$PERL" != "x" ; then
 868 dnl       DOCTYPES="$DOCTYPES html_doc"
 869 dnl fi
 870 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 871 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 872
 873 dnl AC_SUBST(DOCTYPES)
 874
 875 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile \
 876         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 877         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 878         WINGs/Extras/Makefile WINGs/po/Makefile \
 879         wmlib/Makefile wrlib/Makefile src/Makefile src/wconfig.h \
 880         doc/Makefile doc/sk/Makefile \
 881         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 882         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 883         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 884         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 885         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 886         WPrefs.app/po/Makefile \
 887         contrib/Makefile contrib/WindowMaker.spec )
 888 #       plugins/Makefile plugins/libwmfun/Makefile)
 889
 890
 891
 892 dnl
 893 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 894 dnl ===================================================================
 895 dnl
 896
 897 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 898 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 899 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 900
 901 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 902 dnl parsed by m4
 903
 904 cat <<EOF >get-wraster-flags
 905 #!/bin/sh
 906
 907 WCFLAGS="$inc_search_path"
 908 WLFLAGS="$lib_search_path"
 909 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 910
 911 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 912
 913 if test \$# -eq 0; then
 914       echo "\${usage}" 1>&2
 915       exit 1
 916 fi
 917
 918 while test \$# -gt 0; do
 919   case \$1 in
 920     --cflags)
 921         echo \$WCFLAGS
 922         ;;
 923     --ldflags|--lflags)
 924         echo \$WLFLAGS
 925         ;;
 926     --libs)
 927         echo \$WLIBS
 928         ;;
 929     *)
 930         echo "\${usage}" 1>&2
 931         exit 1
 932         ;;
 933   esac
 934   shift
 935 done
 936
 937
 938 EOF
 939
 940 cat <<EOF > wrlib/wrlib.pc
 941 Name: wrlib
 942 Description: Image manipulation and conversion library
 943 Version: $VERSION
 944 Libs: $lib_search_path -lwraster $GFXLIBS $XLIBS -lm
 945 Cflags: $inc_search_path
 946 EOF
 947
 948 cat <<EOF >get-wings-flags
 949 #!/bin/sh
 950
 951 WCFLAGS="$inc_search_path"
 952 WLFLAGS="$lib_search_path"
 953 WLIBS="-lWINGs -lwraster $GFXLIBS $XFTLIBS $XLIBS -lm $NETLIBS $INTLIBS"
 954
 955 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 956
 957 if test \$# -eq 0; then
 958       echo "\${usage}" 1>&2
 959       exit 1
 960 fi
 961
 962 while test \$# -gt 0; do
 963   case \$1 in
 964     --cflags)
 965         echo \$WCFLAGS
 966         ;;
 967     --ldflags|--lflags)
 968         echo \$WLFLAGS
 969         ;;
 970     --libs)
 971         echo \$WLIBS
 972         ;;
 973     *)
 974         echo "\${usage}" 1>&2
 975         exit 1
 976         ;;
 977   esac
 978   shift
 979 done
 980
 981
 982 EOF
 983
 984 cat <<EOF > WINGs/WINGs.pc
 985 Name: WINGs
 986 Description: Small widget set with the NeXTStep(TM) look and feel
 987 Version: $VERSION
 988 Requires: wrlib
 989 Libs: $lib_search_path -lWINGs $XFTLIBS $XLIBS -lm $NETLIBS $INTLIBS
 990 Cflags: $inc_search_path
 991 EOF
 992
 993 cat <<EOF >get-wutil-flags
 994 #!/bin/sh
 995
 996 WCFLAGS="-I`eval echo ${includedir}`"
 997 WLFLAGS="-L${_libdir}"
 998 WLIBS="-lWUtil $NETLIBS $INTLIBS"
 999
1000 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
1001
1002 if test \$# -eq 0; then
1003       echo "\${usage}" 1>&2
1004       exit 1
1005 fi
1006
1007 while test \$# -gt 0; do
1008   case \$1 in
1009     --cflags)
1010         echo \$WCFLAGS
1011         ;;
1012     --ldflags|--lflags)
1013         echo \$WLFLAGS
1014         ;;
1015     --libs)
1016         echo \$WLIBS
1017         ;;
1018     *)
1019         echo "\${usage}" 1>&2
1020         exit 1
1021         ;;
1022   esac
1023   shift
1024 done
1025
1026
1027 EOF
1028
1029 cat <<EOF > wmlib/wmlib.pc
1030 Name: wmlib
1031 Description: FIXME: What do I write here?
1032 Version: $VERSION
1033 Requires: wrlib
1034 Libs: $lib_search_path -lWUtil $NETLIBS $INTLIBS
1035 Cflags: $inc_search_path
1036 EOF
1037
1038 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
1039 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
1040 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
1041
1042 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
1043
1044 rm -f get-wraster-flags get-wings-flags get-wutil-flags
1045
1046
1047 dnl
1048 dnl Spit out the configuration
1049 dnl ==========================
1050
1051 supported_gfx="$supported_gfx builtin-PPM"
1052
1053 if test "x$MOFILES" = "x"; then
1054         mof=none
1055 else
1056         mof=`echo $MOFILES`
1057 fi
1058
1059 if test "x$MOFILES" = "x"; then
1060         languages=none
1061 else
1062         languages=`echo $MOFILES | sed 's/.mo//g'`
1063 fi
1064
1065
1066 echo
1067 echo "Window Maker was configured as follows:"
1068 echo
1069 echo "Installation path prefix            : $prefix"
1070 echo "Installation path for binaries      : $_bindir"
1071 echo "Installation path for WPrefs.app    : $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
1072 echo "Supported graphic format libraries  : $supported_gfx"
1073 echo "Antialiased font support for WINGs  : $xft"
1074 echo "Xinerama extension support          : $xinerama"
1075 echo "Use assembly routines for wrlib     : $asm_support"
1076 echo "Use inline MMX(tm) x86 assembly     : $mmx_support"
1077 echo "Translated message files to install : $mof"
1078 dnl echo "Supported languages beside English  : $languages"
1079 if test "x$MOFILES" != "x"; then
1080         echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
1081 fi
1082 echo
1083
1084 dnl WM_PRINT_REDCRAP_BUG_STATUS
1085
1086 if test "x$ac_cv_header_jpeglib_h" != xyes; then
1087 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1088 echo
1089 echo "JPEG support will not be included because the JPEG library is"
1090 echo "not installed correctly or was not found. Background images"
1091 echo "from themes will not display as they usually are JPEG files."
1092 echo
1093 echo "To fix, download and install the jpeg library and/or make sure you"
1094 echo "installed all jpeg related packages, SPECIALLY the development packages"
1095 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
1096 echo
1097 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1098 fi
1099
1100
1101 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1102 dnl ================================================
1103 dnl Local Variables:
1104 dnl compile-command: "autoconf"
1105 dnl End:
1106