configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(WindowMaker, 0.95.5, , WindowMaker, http://www.windowmaker.org/)
  15 AC_CONFIG_SRCDIR(src/WindowMaker.h)
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADERS(config.h)
  18 AM_INIT_AUTOMAKE([1.11 silent-rules])
  19
  20 AH_BOTTOM([#include "config-paths.h"])
  21
  22 dnl libtool library versioning
  23 dnl =======================
  24 dnl
  25 dnl current
  26 dnl revision
  27 dnl age
  28 dnl
  29 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  30 dnl 2. Update the version information only immediately before a public
  31 dnl release of your software. More frequent updates are unnecessary, and
  32 dnl only guarantee that the current interface number gets larger faster.
  33 dnl 3. If the library source code has changed at all since the last
  34 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  35 dnl 4. If any interfaces have been added, removed, or changed since the
  36 dnl last update, increment current, and set revision to 0.
  37 dnl 5. If any interfaces have been added since the last public release,
  38 dnl then increment age.
  39 dnl 6. If any interfaces have been removed or changed since the last
  40 dnl public release, then set age to 0.
  41 dnl
  42 dnl libwraster
  43 WRASTER_CURRENT=4
  44 WRASTER_REVISION=1
  45 WRASTER_AGE=1
  46 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  47 AC_SUBST(WRASTER_VERSION)
  48 dnl
  49 dnl libWINGs
  50 WINGS_CURRENT=2
  51 WINGS_REVISION=1
  52 WINGS_AGE=0
  53 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  54 AC_SUBST(WINGS_VERSION)
  55 dnl
  56 dnl libWUtil
  57 WUTIL_CURRENT=4
  58 WUTIL_REVISION=0
  59 WUTIL_AGE=0
  60 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  61 AC_SUBST(WUTIL_VERSION)
  62
  63
  64 dnl Checks for host/os name
  65 dnl =======================
  66 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  67
  68 dnl Checks for programs.
  69 dnl ===================
  70 AC_PROG_CC
  71 WM_PROG_CC_C11
  72 AC_PROG_LN_S
  73 AC_PROG_GCC_TRADITIONAL
  74 AC_PROG_LIBTOOL
  75
  76
  77 dnl Debugging Options
  78 dnl =================
  79 AC_ARG_ENABLE(debug,
  80     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
  81     [AS_CASE(["$enableval"],
  82         [yes], [debug=yes],
  83         [no],  [debug=no],
  84         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
  85     [debug=no])
  86 AS_IF([test "x$debug" = "xyes"],
  87     [dnl This flag should have already been detected and added, but if user
  88      dnl provided an explicit CFLAGS it may not be the case
  89      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
  90            [@%:@ Debug symbol already activated],
  91            [AX_CFLAGS_GCC_OPTION([-g])])
  92      dnl
  93      dnl This flag generally makes debugging nightmarish, remove it if present
  94      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
  95      dnl
  96      dnl Enable internal debug code
  97      CPPFLAGS="$CPPFLAGS -DDEBUG"
  98 ],  [dnl
  99      dnl When debug is not enabled, the user probably does not wants to keep
 100      dnl assertions in the final program
 101      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 102 ])
 103
 104
 105 AX_CFLAGS_GCC_OPTION(-Wall)
 106 AX_CFLAGS_GCC_OPTION(-Wextra -Wno-sign-compare)
 107 AS_IF([test "x$debug" = "xyes"],
 108     [dnl When debug is enabled, we try to activate more checks from
 109      dnl the compiler. They are on independant check because the
 110      dnl macro checks all the options at once, but we may have cases
 111      dnl where some options are not supported and we don't want to
 112      dnl loose all of them.
 113      dnl
 114      dnl Floating-point comparison is not a good idea
 115      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 116      dnl
 117      dnl Try to report misuses of '&' versus '&&' and similar
 118      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 119      dnl
 120      dnl Reports declaration of global things that are done inside
 121      dnl a local environment, instead of using the appropriate
 122      dnl header
 123      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 124      dnl
 125      dnl Use of 'sizeof()' on inappropriate pointer types
 126      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 127      dnl
 128      dnl Having more than 1 prototype for a function makes code updates
 129      dnl more difficult, so try to avoid it
 130      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 131      dnl
 132      dnl Proper attributes helps the compiler to produce better code
 133      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 134          [-Wsuggest-attribute=format  dnl new gcc syntax
 135           -Wmissing-format-attribute  dnl old gcc syntax, clang
 136          ])
 137      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 138          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 139           -Wmissing-noreturn            dnl clang syntax
 140          ])
 141      dnl
 142      dnl The use of trampolines cause code that can crash on some
 143      dnl secured OS, and in a more general way generate binary code
 144      dnl that may not be optimal
 145      AX_CFLAGS_GCC_OPTION([-Wtrampolines])
 146 ], [dnl
 147      dnl When debug not enabled, we try to avoid some non-necessary
 148      dnl messages from the compiler
 149      dnl
 150      dnl To support legacy X servers, we have sometime to use
 151      dnl functions marked as deprecated. We do not wish our users
 152      dnl to be worried about it
 153      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 154      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 155 ])
 156
 157
 158 dnl Tracking on what is detected for final status
 159 dnl =============================================
 160 unsupported=""
 161 supported_xext=""
 162 supported_gfx=""
 163
 164
 165 dnl Platform-specific Makefile setup
 166 dnl ================================
 167 AS_CASE(["$host"],
 168     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 169     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 170     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 171     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 172     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 173     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 174     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 175     [WM_OSDEP="stub"])
 176 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 177 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 178 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 179 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 180
 181
 182 dnl the prefix
 183 dnl ==========
 184 dnl
 185 dnl move this earlier in the script... anyone know why this is handled
 186 dnl in such a bizarre way?
 187
 188 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 189 dnl Let make expand exec_prefix.
 190 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 191
 192
 193 _bindir=`eval echo $bindir`
 194 _bindir=`eval echo $_bindir`
 195
 196 lib_search_path='-L${libdir}'
 197
 198 inc_search_path='-I${includedir}'
 199
 200 dnl ===============================================
 201 dnl Specify paths to look for libraries and headers
 202 dnl ===============================================
 203 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 204         [lib_search_path="$withval $lib_search_path"])
 205
 206 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 207         [inc_search_path="$withval $inc_search_path"])
 208
 209
 210 dnl Boehm GC
 211 dnl ========
 212 AC_ARG_ENABLE([boehm-gc],
 213     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 214     [AS_CASE(["$enableval"],
 215         [yes], [with_boehm_gc=yes],
 216         [no],  [with_boehm_gc=no],
 217         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 218     [with_boehm_gc=no])
 219 AS_IF([test "x$with_boehm_gc" = "xyes"],
 220     AC_SEARCH_LIBS([GC_malloc], [gc],
 221         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 222         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 223
 224
 225 dnl LCOV
 226 dnl ====
 227 AC_ARG_ENABLE([lcov],
 228     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 229     [],
 230     [enable_lcov=no])
 231
 232 AS_IF([test "x$enable_lcov" != "xno"],
 233     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 234     AS_IF([test "x$enable_lcov" = "xyes"],
 235         [lcov_output_directory="coverage-report"],
 236         [lcov_output_directory="${enable_lcov}/coverage-report"])
 237     AC_SUBST(lcov_output_directory)])
 238
 239 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 240
 241 dnl
 242 dnl ============================
 243 dnl Checks for library functions
 244 dnl ============================
 245 dnl not used anywhere
 246 AC_FUNC_MEMCMP
 247 AC_FUNC_VPRINTF
 248 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 249                setsid mallinfo mkstemp sysconf)
 250 AC_SEARCH_LIBS([strerror], [cposix])
 251
 252 dnl Check for strlcat/strlcpy
 253 dnl =========================
 254 AC_ARG_WITH([libbsd],
 255   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 256   [AS_IF([test "x$with_libbsd" != "xno"],
 257     [with_libbsd=bsd]
 258     [with_libbsd=]
 259   )],
 260   [with_libbsd=bsd])
 261
 262 tmp_libs=$LIBS
 263 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 264   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 265   [],
 266   []
 267 )
 268 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 269   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 270   [],
 271   []
 272 )
 273 LIBS=$tmp_libs
 274
 275 LIBBSD=
 276 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 277   [LIBBSD=-lbsd
 278    AC_CHECK_HEADERS([bsd/string.h])]
 279 )
 280 AC_SUBST(LIBBSD)
 281
 282 dnl Check for OpenBSD kernel memory interface - kvm(3)
 283 dnl ==================================================
 284 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 285   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 286
 287 dnl Check for inotify
 288 dnl =================
 289 AC_CHECK_HEADERS(sys/inotify.h, AC_DEFINE(HAVE_INOTIFY, 1, Check for inotify))
 290
 291
 292 dnl Checks for header files.
 293 dnl =======================
 294 AC_HEADER_SYS_WAIT
 295 AC_HEADER_TIME
 296 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 297                  string.h strings.h)
 298
 299
 300 dnl Checks for typedefs, structures, and compiler characteristics.
 301 dnl ==============================================================
 302 AC_DECL_SYS_SIGLIST
 303 AC_C_CONST
 304 AC_C_INLINE
 305 WM_C_NORETURN
 306 AC_TYPE_SIZE_T
 307 AC_TYPE_PID_T
 308 AC_TYPE_SIGNAL
 309
 310
 311 dnl pkg-config
 312 dnl ==========
 313 dnl AC_ARG_VAR(PKGCONFIG, [pkg-config command])
 314 AC_CHECK_PROG(PKGCONFIG, pkg-config, pkg-config)
 315
 316 dnl gettext
 317 dnl =======
 318
 319 dnl AM_GNU_GETTEXT
 320
 321 INTLIBS=""
 322
 323 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 324         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 325                          INTLIBS="" ))
 326
 327 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 328
 329 if test "$XGETTEXT" != ""; then
 330     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 331         echo "xgettext isn't GNU version"
 332         XGETTEXT=""
 333     fi
 334 fi
 335
 336 if test "$LINGUAS" != ""; then
 337     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 338         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 339         PO=""
 340         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 341     else
 342         LINGUAS=""
 343         PO=""
 344         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 345     fi
 346 else
 347         INTLIBS=""
 348         MOFILES=""
 349         WPMOFILES=""
 350         UTILMOFILES=""
 351         PO=""
 352 fi
 353
 354
 355 dnl The Tower of Babel
 356 dnl ==================
 357
 358 dnl List of supported locales
 359 dnl =========================
 360 supported_locales="be bg bs ca cs da de el es et fi fr gl hr hu hy it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW"
 361 supported_wprefs_locales="bg ca cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW"
 362 supported_wings_locales="bg ca cs de fr sk"
 363 supported_util_locales="de es fr pt"
 364
 365 for lang in $LINGUAS; do
 366         ok=0
 367         for l in $supported_locales; do
 368                 if test "$l" = "$lang"; then
 369                         ok=1
 370                         break
 371                 fi
 372         done
 373         if test "$ok" = 1; then
 374                 MOFILES="$MOFILES $lang.mo"
 375         else
 376                 echo "Locale $lang is not supported."
 377         fi
 378         ok=0
 379         for l in $supported_wprefs_locales; do
 380                 if test "$l" = "$lang"; then
 381                         ok=1
 382                         break
 383                 fi
 384         done
 385         if test "$ok" = 1; then
 386                 WPMOFILES="$WPMOFILES $lang.mo"
 387         fi
 388         ok=0
 389         for l in $supported_util_locales; do
 390                 if test "$l" = "$lang"; then
 391                         ok=1
 392                         break
 393                 fi
 394         done
 395         if test "$ok" = 1; then
 396                 UTILMOFILES="$UTILMOFILES $lang.mo"
 397         fi
 398         ok=0
 399         for l in $supported_wings_locales; do
 400                 if test "$l" = "$lang"; then
 401                         ok=1
 402                         break
 403                 fi
 404         done
 405         if test "$ok" = 1; then
 406                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 407         fi
 408 done
 409
 410
 411 dnl Added by Oliver - Support for NLSDIR option
 412 dnl ===========================================
 413 AC_ARG_WITH(nlsdir, AS_HELP_STRING([--with-nlsdir=PATH], [specify where the locale stuff should go]))
 414
 415 if test "x$NLSDIR" = "x"; then
 416         if test "x$with_nlsdir" != "x"; then
 417                 NLSDIR=$with_nlsdir
 418         else
 419                 NLSDIR='$(prefix)/lib/locale'
 420         fi
 421 fi
 422
 423 menutextdomain=
 424 AC_ARG_WITH(menu-textdomain, AS_HELP_STRING([--with-menu-textdomain=DOMAIN], [specify gettext domain used for menu translations]),
 425         [if test "x$withval" != "xno"; then
 426          menutextdomain=$withval
 427          fi])
 428 AC_SUBST(menutextdomain)
 429
 430 AC_SUBST(INTLIBS)
 431 AC_SUBST(NLSDIR)
 432 AC_SUBST(MOFILES)
 433 AC_SUBST(WPMOFILES)
 434 AC_SUBST(UTILMOFILES)
 435 AC_SUBST(WINGSMOFILES)
 436 AC_SUBST(supported_locales)
 437
 438 dnl ===========================================
 439 dnl             Stuff that uses X
 440 dnl ===========================================
 441
 442 AC_PATH_XTRA
 443
 444 if test $no_x; then
 445     AC_MSG_ERROR([The path for the X11 files not found!
 446 Make sure you have X and it's headers and libraries (the -devel packages
 447 in Linux) installed.])
 448 fi
 449
 450 X_LIBRARY_PATH=$x_libraries
 451 XCFLAGS="$X_CFLAGS"
 452 XLFLAGS="$X_LIBS"
 453 XLIBS="-lX11 $X_EXTRA_LIBS"
 454
 455 lib_search_path="$lib_search_path $XLFLAGS"
 456 inc_search_path="$inc_search_path $XCFLAGS"
 457
 458 AC_SUBST(X_LIBRARY_PATH)
 459
 460 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 461 dnl by MANOME Tomonori
 462 dnl ===========================================
 463 use_locale=yes
 464 AC_ARG_ENABLE(locale, AS_HELP_STRING([--disable-locale], [disable use of X locale support]),
 465               use_locale=no)
 466
 467 if test "$use_locale" = yes; then
 468         AC_CHECK_LIB(X11, _Xsetlocale,
 469                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 470                 $XLFLAGS $XLIBS)
 471 fi
 472
 473 dnl Check whether XInternAtoms() exist
 474 dnl ==================================
 475 AC_CHECK_LIB(X11, XInternAtoms,
 476              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 477              $XLFLAGS $XLIBS)
 478
 479 dnl Check whether XConvertCase() exist
 480 dnl ==================================
 481 AC_CHECK_LIB(X11, XConvertCase,
 482              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 483              $XLFLAGS $XLIBS)
 484
 485 dnl XKB keyboard language status
 486 dnl ============================
 487 AC_ARG_ENABLE(modelock, AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support]),
 488                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 489
 490 dnl XShape support
 491 dnl ==============
 492 AC_ARG_ENABLE([shape],
 493     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 494     [AS_CASE(["$enableval"],
 495         [yes|no], [],
 496         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 497     [enable_shape=auto])
 498 WM_XEXT_CHECK_XSHAPE
 499
 500 dnl MIT-SHM support
 501 dnl ===============
 502 AC_ARG_ENABLE([shm],
 503     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 504     [AS_CASE(["$enableval"],
 505         [yes|no], [],
 506         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 507     [enable_shm=auto])
 508 WM_XEXT_CHECK_XSHM
 509
 510 dnl X Misceleanous Utility
 511 dnl ======================
 512 # the libXmu is used in WRaster
 513 WM_EXT_CHECK_XMU
 514
 515 dnl XINERAMA support
 516 dnl ================
 517 AC_ARG_ENABLE([xinerama],
 518     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 519     [AS_CASE(["$enableval"],
 520         [yes|no], [],
 521         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 522     [enable_xinerama=auto])
 523 WM_XEXT_CHECK_XINERAMA
 524
 525 dnl XRandR support
 526 dnl ==============
 527 AC_ARG_ENABLE([xrandr],
 528     [AS_HELP_STRING([--enable-xrandr], [enable XRandR extension support (NOT recommended, buggy)])],
 529     [AS_CASE(["$enableval"],
 530         [yes|no], [],
 531         [AC_MSG_ERROR([bad value $enableval for --enable-xrandr]) ]) ],
 532     [enable_xrandr=no])
 533 WM_XEXT_CHECK_XRANDR
 534
 535 dnl
 536 dnl libWINGS uses math functions, check whether usage requires linking
 537 dnl against libm
 538 dnl
 539 WM_CHECK_LIBM
 540
 541 dnl
 542 dnl libWINGS uses FcPatternDel from libfontconfig
 543 dnl
 544 AC_MSG_CHECKING([for fontconfig library])
 545 FCLIBS=`$PKGCONFIG fontconfig --libs`
 546 if test "x$FCLIBS" = "x" ; then
 547         AC_MSG_RESULT([not found])
 548 else
 549         AC_MSG_RESULT([found])
 550 fi
 551 AC_SUBST(FCLIBS)
 552
 553
 554 dnl Xft2 antialiased font support
 555 dnl =============================
 556
 557 xft=yes
 558 XFTLIBS=""
 559
 560 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 561         XFTCONFIG="$PKGCONFIG xft"
 562         pkgconfig_xft=yes
 563 else
 564         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 565 fi
 566
 567 AC_MSG_CHECKING([for the Xft2 library])
 568
 569 if test "x$XFTCONFIG" != x; then
 570         XFTLIBS=`$XFTCONFIG --libs`
 571         XFTFLAGS=`$XFTCONFIG --cflags`
 572         AC_MSG_RESULT([found])
 573 else
 574         AC_MSG_RESULT([not found])
 575         echo
 576         echo "ERROR!!! libXft2 is not installed or could not be found."
 577         echo "         Xft2 is a requirement for building Window Maker."
 578         echo "         Please install it (along with fontconfig) before continuing."
 579         echo
 580         exit 1
 581 fi
 582
 583 minXFT="2.1.0"
 584 goodxft="no"
 585
 586 dnl
 587 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 588 dnl
 589 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 590
 591 if test "$goodxft" = no; then
 592         echo
 593         echo "ERROR!!! libXft on this system is an old version."
 594         echo "         Please consider upgrading to at least version ${minXFT}."
 595         echo
 596         exit 1
 597 fi
 598
 599 AC_SUBST(XFTFLAGS)
 600 AC_SUBST(XFTLIBS)
 601
 602
 603 dnl ==============================================
 604 dnl         Graphic Format Libraries
 605 dnl ==============================================
 606
 607 dnl XPM Support
 608 dnl ===========
 609 AC_ARG_ENABLE([xpm],
 610     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 611     [AS_CASE(["$enableval"],
 612         [yes|no], [],
 613         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 614     [enable_xpm=auto])
 615 WM_IMGFMT_CHECK_XPM
 616
 617
 618 # for wmlib
 619 AC_SUBST(XCFLAGS)
 620 # for test
 621 AC_SUBST(XLFLAGS)
 622 AC_SUBST(XLIBS)
 623 AC_SUBST(X_EXTRA_LIBS)
 624
 625 dnl ===============================================
 626 dnl             End of stuff that uses X
 627 dnl ===============================================
 628
 629 dnl PNG Support
 630 dnl ===========
 631 AC_ARG_ENABLE([png],
 632     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 633     [AS_CASE(["$enableval"],
 634         [yes|no], [],
 635         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 636     [enable_png=auto])
 637 WM_IMGFMT_CHECK_PNG
 638
 639
 640 dnl JPEG Support
 641 dnl ============
 642 AC_ARG_ENABLE([jpeg],
 643     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 644     [AS_CASE(["$enableval"],
 645         [yes|no], [],
 646         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 647     [enable_jpeg=auto])
 648 WM_IMGFMT_CHECK_JPEG
 649
 650
 651 dnl GIF Support
 652 dnl ============
 653 AC_ARG_ENABLE(gif,
 654     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 655     [AS_CASE(["$enableval"],
 656         [yes|no], [],
 657         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 658     [enable_gif=auto])
 659 WM_IMGFMT_CHECK_GIF
 660
 661
 662 dnl TIFF Support
 663 dnl ============
 664 AC_ARG_ENABLE([tiff],
 665     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 666     [AS_CASE(["$enableval"],
 667         [yes|no], [],
 668         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 669     [enable_tiff=auto])
 670 WM_IMGFMT_CHECK_TIFF
 671
 672
 673 dnl PPM Support
 674 dnl ===========
 675 # The PPM format is always enabled because we have built-in support for the format
 676 # We are not using any external library like libppm
 677 supported_gfx="$supported_gfx builtin-PPM"
 678
 679
 680 # Choice of the default format for icons
 681 AS_IF([test "x$enable_tiff" != "xno"],
 682     [ICONEXT="tiff"],
 683     [ICONEXT="xpm"])
 684
 685
 686 LIBRARY_SEARCH_PATH="$lib_search_path"
 687 HEADER_SEARCH_PATH="$inc_search_path"
 688
 689 AC_SUBST(LIBRARY_SEARCH_PATH)
 690 AC_SUBST(HEADER_SEARCH_PATH)
 691
 692
 693 AC_SUBST(GFXLIBS)
 694 AC_SUBST(ICONEXT)
 695 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 696 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 697
 698
 699 dnl ==============================================
 700 dnl         End of Graphic Format Libraries
 701 dnl ==============================================
 702
 703
 704 dnl
 705 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 706 AC_CHECK_HEADERS(stdlib.h)
 707
 708 # AC_PREFIX_PROGRAM(wmaker)
 709
 710 dnl Support for PIXMAPDIR option
 711 dnl ============================
 712 AC_ARG_WITH(pixmapdir, AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]]))
 713
 714 if test "x$with_pixmapdir" != "x"; then
 715         pixmapdir=$with_pixmapdir
 716 else
 717         pixmapdir='${datadir}/pixmaps'
 718 fi
 719 AC_SUBST(pixmapdir)
 720
 721
 722 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 723 dnl ==============================================
 724
 725 AC_ARG_WITH(gnustepdir, AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications]))
 726
 727 if test "x`echo $with_gnustepdir | grep ^/`" != "x"; then
 728     appspath=$with_gnustepdir
 729 fi
 730
 731 if test "x$appspath$GNUSTEP_LOCAL_ROOT" = "x"; then
 732     wprefs_base_dir=${prefix}
 733     wprefs_datadir="${datadir}/WPrefs"
 734     wprefs_bindir="${bindir}"
 735 else
 736     gnustepdir=$appspath
 737
 738     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 739         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 740         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 741     fi
 742
 743     wprefs_base_dir=$gnustepdir/Applications
 744     wprefs_datadir=$wprefs_base_dir/WPrefs.app
 745     wprefs_bindir=$wprefs_base_dir/WPrefs.app
 746 fi
 747
 748 AC_SUBST(wprefs_datadir)
 749 AC_SUBST(wprefs_bindir)
 750
 751
 752 dnl Enable User Defined Menu thing
 753 dnl ==============================
 754 AC_ARG_ENABLE(usermenu, AS_HELP_STRING([--enable-usermenu], [user defined menus for applications]),
 755 if test "$enableval" = yes; then
 756         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 757 fi
 758 )
 759
 760 gl_LD_VERSION_SCRIPT
 761
 762 AC_OUTPUT(Makefile po/Makefile util/Makefile util/po/Makefile test/Makefile \
 763         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 764         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 765         WINGs/Extras/Makefile WINGs/po/Makefile \
 766         wmlib/Makefile wrlib/Makefile wrlib/tests/Makefile \
 767         src/Makefile src/wconfig.h \
 768         doc/Makefile doc/sk/Makefile doc/cs/Makefile \
 769         doc/ru/Makefile \
 770         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 771         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 772         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 773         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 774         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 775         WPrefs.app/po/Makefile )
 776
 777
 778 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 779 dnl ===================================================================
 780
 781 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 782 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 783 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 784
 785 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 786 dnl parsed by m4
 787
 788 AC_SUBST(lib_search_path)
 789 AC_SUBST(inc_search_path)
 790
 791 dnl
 792 dnl Spit out the configuration
 793 dnl ==========================
 794
 795 if test "x$MOFILES" = "x"; then
 796         mof=None
 797 else
 798         mof=`echo $MOFILES`
 799 fi
 800
 801 if test "x$MOFILES" = "x"; then
 802         languages=None
 803 else
 804         languages=`echo $MOFILES | sed 's/.mo//g'`
 805 fi
 806
 807 echo
 808 echo "Window Maker was configured as follows:"
 809 echo
 810 echo "Installation path prefix            : $prefix"
 811 echo "Installation path for binaries      : $_bindir"
 812 echo "Installation path for libraries     : $libdir"
 813 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 814 echo "Supported X extensions:             :$supported_xext"
 815 echo "Supported graphic format libraries  :$supported_gfx"
 816 echo "Unsupported features                :$unsupported"
 817 echo "Antialiased text support in WINGs   : $xft"
 818 echo "Translated message files to install : $mof"
 819 dnl echo "Supported languages beside English  : $languages"
 820 if test "x$MOFILES" != "x"; then
 821         echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
 822 fi
 823 AS_IF([test "x$debug" = "xyes"],
 824     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 825 echo
 826
 827 dnl WM_PRINT_REDCRAP_BUG_STATUS
 828
 829 AS_IF([test "x$enable_jpeg" = xno], [dnl
 830     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 831     AS_ECHO([])
 832     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 833     AS_ECHO(["not installed correctly or was not found. Background images"])
 834     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 835     AS_ECHO([])
 836     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 837     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 838     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 839     AS_ECHO([])
 840     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 841 ])
 842
 843
 844 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 845 dnl ================================================
 846 dnl Local Variables:
 847 dnl compile-command: "autoconf"
 848 dnl End:
 849