configure.ac

   1 dnl ============================================================================
   2 dnl
   3 dnl Window Maker autoconf input
   4 dnl
   5 AC_COPYRIGHT([Copyright (c) 2001-2015 The Window Maker Team])
   6 dnl
   7 dnl ============================================================================
   8 dnl
   9 dnl This program is free software; you can redistribute it and/or modify
  10 dnl it under the terms of the GNU General Public License as published by
  11 dnl the Free Software Foundation; either version 2 of the License, or
  12 dnl (at your option) any later version.
  13 dnl
  14 dnl This program is distributed in the hope that it will be useful,
  15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 dnl GNU General Public License for more details.
  18 dnl
  19 dnl You should have received a copy of the GNU General Public License along
  20 dnl with this program; see the file COPYING.
  21 dnl
  22 dnl ============================================================================
  23 dnl
  24 dnl Process with: ./autogen.sh
  25
  26
  27 dnl Due to a bug in Autoconf 2.68 (apparently a regression), we need at least
  28 dnl version 2.68b which includes this patch:
  29 dnl   http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commit;h=2b0d95faef68d7ed7c08b0edb9ff1c38728376fa
  30 dnl
  31 dnl Because the 2.69 was released only a few month later, let's just ask for it
  32 AC_PREREQ([2.69])
  33
  34
  35 dnl Configuration for Autoconf and Automake
  36 dnl =======================================
  37 AC_INIT([WindowMaker],[0.95.6],[wmaker-dev@lists.windowmaker.org],[WindowMaker],[http://www.windowmaker.org/])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_HEADERS([config.h])
  40 AM_INIT_AUTOMAKE([1.11 silent-rules])
  41
  42 dnl Reference file used by 'configure' to make sure the path to sources is valid
  43 AC_CONFIG_SRCDIR([src/WindowMaker.h])
  44
  45 dnl Include at the end of 'config.h', this file is generated by top-level Makefile
  46 AH_BOTTOM([@%:@include "config-paths.h"])
  47
  48
  49 dnl libtool library versioning
  50 dnl ==========================
  51 dnl
  52 dnl current
  53 dnl revision
  54 dnl age
  55 dnl
  56 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  57 dnl 2. Update the version information only immediately before a public
  58 dnl release of your software. More frequent updates are unnecessary, and
  59 dnl only guarantee that the current interface number gets larger faster.
  60 dnl 3. If the library source code has changed at all since the last
  61 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  62 dnl 4. If any interfaces have been added, removed, or changed since the
  63 dnl last update, increment current, and set revision to 0.
  64 dnl 5. If any interfaces have been added since the last public release,
  65 dnl then increment age.
  66 dnl 6. If any interfaces have been removed or changed since the last
  67 dnl public release, then set age to 0.
  68 dnl
  69 dnl libwraster
  70 WRASTER_CURRENT=5
  71 WRASTER_REVISION=0
  72 WRASTER_AGE=0
  73 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  74 AC_SUBST(WRASTER_VERSION)
  75 dnl
  76 dnl libWINGs
  77 WINGS_CURRENT=4
  78 WINGS_REVISION=0
  79 WINGS_AGE=1
  80 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  81 AC_SUBST(WINGS_VERSION)
  82 dnl
  83 dnl libWUtil
  84 WUTIL_CURRENT=5
  85 WUTIL_REVISION=0
  86 WUTIL_AGE=0
  87 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  88 AC_SUBST(WUTIL_VERSION)
  89
  90
  91 dnl Checks for programs
  92 dnl ===================
  93 AC_PROG_CC
  94 WM_PROG_CC_C11
  95 AC_PROG_LN_S
  96 AC_PROG_GCC_TRADITIONAL
  97 LT_INIT
  98
  99
 100 dnl Debugging Options
 101 dnl =================
 102 AC_ARG_ENABLE([debug],
 103     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
 104     [AS_CASE(["$enableval"],
 105         [yes], [debug=yes],
 106         [no],  [debug=no],
 107         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
 108     [debug=no])
 109 AS_IF([test "x$debug" = "xyes"],
 110     [dnl This flag should have already been detected and added, but if user
 111      dnl provided an explicit CFLAGS it may not be the case
 112      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
 113            [@%:@ Debug symbol already activated],
 114            [AX_CFLAGS_GCC_OPTION([-g])])
 115      dnl
 116      dnl This flag generally makes debugging nightmarish, remove it if present
 117      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
 118      dnl
 119      dnl Enable internal debug code
 120      CPPFLAGS="$CPPFLAGS -DDEBUG"
 121 ],  [dnl
 122      dnl When debug is not enabled, the user probably does not wants to keep
 123      dnl assertions in the final program
 124      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 125 ])
 126
 127
 128 AX_CFLAGS_GCC_OPTION([-Wall])
 129 AX_CFLAGS_GCC_OPTION([-Wextra -Wno-sign-compare])
 130 dnl
 131 dnl The use of trampolines cause code that can crash on some secured OS, it is
 132 dnl also known to be a source of crash if not used properly, in a more general
 133 dnl way it tends to generate binary code that may not be optimal, and it is
 134 dnl not compatible with the 'nested-func-to-macro' workaround
 135 WM_CFLAGS_CHECK_FIRST([-Wtrampolines],
 136          [-Werror=trampolines  dnl try to generate an error if possible
 137           -Wtrampolines        dnl if not, try to fall back to a simple warning
 138          ])
 139 dnl
 140 AS_IF([test "x$debug" = "xyes"],
 141     [dnl When debug is enabled, we try to activate more checks from
 142      dnl the compiler. They are on independant check because the
 143      dnl macro checks all the options at once, but we may have cases
 144      dnl where some options are not supported and we don't want to
 145      dnl loose all of them.
 146      dnl
 147      dnl clang, suggest parenthesis on bit operations that could be
 148      dnl misunderstood due to C operator precedence
 149      AX_CFLAGS_GCC_OPTION([-Wbitwise-op-parentheses])
 150      dnl
 151      dnl Points at code that gcc thinks is so complicated that gcc
 152      dnl gives up trying to optimize, which probably also means it is
 153      dnl too complicated to maintain
 154      AX_CFLAGS_GCC_OPTION([-Wdisabled-optimization])
 155      dnl
 156      dnl Floating-point comparison is not a good idea
 157      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 158      dnl
 159      dnl clang warns about constants that may have portability issues due
 160      dnl to the endianness of the host
 161      AX_CFLAGS_GCC_OPTION([-Wfour-char-constants])
 162      dnl
 163      dnl clang warns about constant that may be too big to be portable
 164      AX_CFLAGS_GCC_OPTION([-Wliteral-range])
 165      dnl
 166      dnl Try to report misuses of '&' versus '&&' and similar
 167      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 168      dnl
 169      dnl clang, reports cases where the code assumes everyone is an
 170      dnl expert in C operator precedence... which is unlikely!
 171      AX_CFLAGS_GCC_OPTION([-Wlogical-op-parentheses])
 172      dnl
 173      dnl Reports declaration of global things that are done inside
 174      dnl a local environment, instead of using the appropriate
 175      dnl header
 176      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 177      dnl
 178      dnl Warn about constant strings that could pose portability issues
 179      AX_CFLAGS_GCC_OPTION([-Woverlength-strings])
 180      dnl
 181      dnl Use of 'sizeof()' on inappropriate pointer types
 182      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 183      dnl
 184      dnl Having more than 1 prototype for a function makes code updates
 185      dnl more difficult, so try to avoid it
 186      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 187      dnl
 188      dnl clang, detect some misuses of sizeof. We also count in our code
 189      dnl on the use of the macro 'wlength' which contains a check if the
 190      dnl compiler support C11's static_assert
 191      AX_CFLAGS_GCC_OPTION([-Wsizeof-array-argument])
 192      dnl
 193      dnl Prototype of function must be explicit, no deprecated K&R syntax
 194      dnl and no empty argument list which prevents compiler from doing
 195      dnl type checking when using the function
 196      WM_CFLAGS_GCC_OPTION_STRICTPROTO
 197      dnl
 198      dnl Proper attributes helps the compiler to produce better code
 199      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 200          [-Wsuggest-attribute=format  dnl new gcc syntax
 201           -Wmissing-format-attribute  dnl old gcc syntax, clang
 202          ])
 203      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 204          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 205           -Wmissing-noreturn            dnl clang syntax
 206          ])
 207      dnl
 208      dnl GCC provides a couple of checks to detect incorrect macro uses
 209      AX_CFLAGS_GCC_OPTION([-Wundef])
 210      WM_CFLAGS_GCC_OPTION_UNUSEDMACROS
 211      dnl
 212      dnl clang reports stuff marked unused but which is actually used
 213      AX_CFLAGS_GCC_OPTION([-Wused-but-marked-unused])
 214 ], [dnl
 215      dnl When debug not enabled, we try to avoid some non-necessary
 216      dnl messages from the compiler
 217      dnl
 218      dnl To support legacy X servers, we have sometime to use
 219      dnl functions marked as deprecated. We do not wish our users
 220      dnl to be worried about it
 221      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 222      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 223 ])
 224
 225
 226 dnl Support for Nested Functions by the compiler
 227 dnl ============================================
 228 WM_PROG_CC_NESTEDFUNC
 229
 230
 231 dnl Posix thread
 232 dnl ============
 233 dnl they are used by util/wmiv
 234 AX_PTHREAD
 235
 236
 237 dnl Tracking on what is detected for final status
 238 dnl =============================================
 239 unsupported=""
 240 supported_xext=""
 241 supported_gfx=""
 242
 243
 244 dnl Platform-specific Makefile setup
 245 dnl ================================
 246 AS_CASE(["$host"],
 247     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 248     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 249     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 250     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 251     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 252     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 253     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 254     [WM_OSDEP="stub"])
 255 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 256 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 257 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 258 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 259
 260
 261 dnl the prefix
 262 dnl ==========
 263 dnl
 264 dnl move this earlier in the script... anyone know why this is handled
 265 dnl in such a bizarre way?
 266
 267 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 268 dnl Let make expand exec_prefix.
 269 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 270
 271
 272 _bindir=`eval echo $bindir`
 273 _bindir=`eval echo $_bindir`
 274
 275 lib_search_path='-L${libdir}'
 276
 277 inc_search_path='-I${includedir}'
 278
 279 dnl ===============================================
 280 dnl Specify paths to look for libraries and headers
 281 dnl ===============================================
 282 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 283         [lib_search_path="$withval $lib_search_path"])
 284
 285 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 286         [inc_search_path="$withval $inc_search_path"])
 287
 288
 289 dnl Boehm GC
 290 dnl ========
 291 AC_ARG_ENABLE([boehm-gc],
 292     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 293     [AS_CASE(["$enableval"],
 294         [yes], [with_boehm_gc=yes],
 295         [no],  [with_boehm_gc=no],
 296         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 297     [with_boehm_gc=no])
 298 AS_IF([test "x$with_boehm_gc" = "xyes"],
 299     AC_SEARCH_LIBS([GC_malloc], [gc],
 300         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 301         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 302
 303
 304 dnl LCOV
 305 dnl ====
 306 AC_ARG_ENABLE([lcov],
 307     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 308     [],
 309     [enable_lcov=no])
 310
 311 AS_IF([test "x$enable_lcov" != "xno"],
 312     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 313     AS_IF([test "x$enable_lcov" = "xyes"],
 314         [lcov_output_directory="coverage-report"],
 315         [lcov_output_directory="${enable_lcov}/coverage-report"])
 316     AC_SUBST(lcov_output_directory)])
 317
 318 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 319
 320
 321 dnl ============================
 322 dnl Checks for library functions
 323 dnl ============================
 324 AC_FUNC_MEMCMP
 325 AC_FUNC_VPRINTF
 326 WM_FUNC_SECURE_GETENV
 327 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 328                setsid mallinfo mkstemp sysconf)
 329 AC_SEARCH_LIBS([strerror], [cposix])
 330
 331 dnl nanosleep is generally available in standard libc, although not always the
 332 dnl case. One known example is Solaris which needs -lrt
 333 AC_SEARCH_LIBS([nanosleep], [rt], [],
 334     [AC_MSG_ERROR([function 'nanosleep' not found, please report to wmaker-dev@lists.windowmaker.org])])
 335
 336 dnl the flag 'O_NOFOLLOW' for 'open' is used in WINGs
 337 WM_FUNC_OPEN_NOFOLLOW
 338
 339
 340 dnl Check for strlcat/strlcpy
 341 dnl =========================
 342 AC_ARG_WITH([libbsd],
 343   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 344   [AS_IF([test "x$with_libbsd" != "xno"],
 345     [with_libbsd=bsd]
 346     [with_libbsd=]
 347   )],
 348   [with_libbsd=bsd])
 349
 350 tmp_libs=$LIBS
 351 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 352   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 353   [],
 354   []
 355 )
 356 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 357   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 358   [],
 359   []
 360 )
 361 LIBS=$tmp_libs
 362
 363 LIBBSD=
 364 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 365   [LIBBSD=-lbsd
 366    AC_CHECK_HEADERS([bsd/string.h])]
 367 )
 368 AC_SUBST(LIBBSD)
 369
 370
 371 dnl Check for OpenBSD kernel memory interface - kvm(3)
 372 dnl ==================================================
 373 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 374   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 375
 376
 377 dnl Check for inotify
 378 dnl =================
 379 dnl It is used by WindowMaker to reload automatically the configuration when the
 380 dnl user changed it using WPref or wdwrite
 381 AC_CHECK_HEADERS([sys/inotify.h],
 382     [AC_DEFINE([HAVE_INOTIFY], [1], [Check for inotify])])
 383
 384
 385 dnl Check for syslog
 386 dnl ================
 387 dnl It is used by WUtil to log the wwarning, werror and wfatal
 388 AC_CHECK_HEADERS([syslog.h], [AC_DEFINE([HAVE_SYSLOG], [1], [Check for syslog])])
 389
 390
 391 dnl Checks for header files
 392 dnl =======================
 393 AC_HEADER_SYS_WAIT
 394 AC_HEADER_TIME
 395 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 396                  string.h strings.h)
 397
 398
 399 dnl Checks for typedefs, structures, and compiler characteristics
 400 dnl =============================================================
 401 AC_C_CONST
 402 AC_C_INLINE
 403 WM_C_NORETURN
 404 AC_TYPE_SIZE_T
 405 AC_TYPE_PID_T
 406 WM_TYPE_SIGNAL
 407
 408
 409 dnl pkg-config
 410 dnl ==========
 411 AC_CHECK_PROG([PKGCONFIG], [pkg-config], [pkg-config])
 412
 413
 414
 415 dnl Internationalization
 416 dnl ====================
 417 dnl Detect the language for translations to be installed and check
 418 dnl that the gettext environment works
 419 WM_I18N_LANGUAGES
 420
 421
 422 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 423
 424 if test "$XGETTEXT" != ""; then
 425     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 426         echo "xgettext isn't GNU version"
 427         XGETTEXT=""
 428     fi
 429 fi
 430
 431 dnl Added by Oliver - Support for NLSDIR option
 432 dnl ===========================================
 433 AC_ARG_WITH(nlsdir, AS_HELP_STRING([--with-nlsdir=PATH], [specify where the locale stuff should go]))
 434
 435 if test "x$NLSDIR" = "x"; then
 436         if test "x$with_nlsdir" != "x"; then
 437                 NLSDIR=$with_nlsdir
 438         else
 439                 NLSDIR='$(prefix)/lib/locale'
 440         fi
 441 fi
 442
 443 menutextdomain=
 444 AC_ARG_WITH(menu-textdomain, AS_HELP_STRING([--with-menu-textdomain=DOMAIN], [specify gettext domain used for menu translations]),
 445         [if test "x$withval" != "xno"; then
 446          menutextdomain=$withval
 447          fi])
 448 AC_SUBST(menutextdomain)
 449
 450 AC_SUBST(NLSDIR)
 451
 452
 453 dnl ===========================================
 454 dnl             Stuff that uses X
 455 dnl ===========================================
 456
 457 AC_PATH_XTRA
 458
 459 AS_IF([test "x$no_x" = "xyes"],
 460     [AC_MSG_ERROR([The path for the X11 files not found!
 461 Make sure you have X and it's headers and libraries (the -devel packages
 462 in Linux) installed.])])
 463
 464 X_LIBRARY_PATH=$x_libraries
 465 XCFLAGS="$X_CFLAGS"
 466 XLFLAGS="$X_LIBS"
 467 XLIBS="-lX11 $X_EXTRA_LIBS"
 468
 469 lib_search_path="$lib_search_path $XLFLAGS"
 470 inc_search_path="$inc_search_path $XCFLAGS"
 471
 472 AC_SUBST(X_LIBRARY_PATH)
 473
 474
 475 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 476 dnl by MANOME Tomonori
 477 dnl ===========================================
 478 use_locale=yes
 479 AC_ARG_ENABLE(locale, AS_HELP_STRING([--disable-locale], [disable use of X locale support]),
 480               use_locale=no)
 481
 482 if test "$use_locale" = yes; then
 483         AC_CHECK_LIB(X11, _Xsetlocale,
 484                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 485                 $XLFLAGS $XLIBS)
 486 fi
 487
 488
 489 dnl Check whether XInternAtoms() exist
 490 dnl ==================================
 491 AC_CHECK_LIB([X11], [XInternAtoms],
 492     [AC_DEFINE([HAVE_XINTERNATOMS], [1],
 493         [define if your X server has XInternAtoms() (set by configure)])],
 494     [], [$XLFLAGS $XLIBS])
 495
 496
 497 dnl Check whether XConvertCase() exist
 498 dnl ==================================
 499 AC_CHECK_LIB([X11], [XConvertCase],
 500     [AC_DEFINE([HAVE_XCONVERTCASE], [1],
 501         [define if your X server has XConvertCase() (set by configure)])],
 502     [], [$XLFLAGS $XLIBS])
 503
 504
 505 dnl XKB keyboard language status
 506 dnl ============================
 507 AC_ARG_ENABLE([modelock],
 508     [AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support])],
 509     [AS_CASE([$enableval],
 510         [yes|no], [],
 511         [AC_MSG_ERROR([bad value '$enableval' for --enable-modelock])])],
 512     [enable_modelock=no])
 513 AS_IF([test "x$enable_modelock" = "xyes"],
 514     [AC_DEFINE([XKB_MODELOCK], [1], [whether XKB language MODELOCK should be enabled]) ])
 515
 516
 517 dnl XDND Drag-nd-Drop support
 518 dnl =========================
 519 AC_ARG_ENABLE([xdnd],
 520     [AS_HELP_STRING([--disable-xdnd], [disable Drag-nd-Drop support])],
 521     [AS_CASE(["$enableval"],
 522         [yes|no], [],
 523         [AC_MSG_ERROR([bad value $enableval for --disable-xdnd]) ]) ],
 524     [enable_xdnd=yes])
 525 AS_IF([test "x$enable_xdnd" = "xyes"],
 526     [supported_xext="$supported_xext XDnD"
 527      AC_DEFINE([XDND], [1], [whether Drag-nd-Drop support should be enabled])],
 528     [unsupported="$unsupported XDnd"])
 529
 530
 531 dnl XShape support
 532 dnl ==============
 533 AC_ARG_ENABLE([shape],
 534     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 535     [AS_CASE(["$enableval"],
 536         [yes|no], [],
 537         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 538     [enable_shape=auto])
 539 WM_XEXT_CHECK_XSHAPE
 540
 541
 542 dnl MIT-SHM support
 543 dnl ===============
 544 AC_ARG_ENABLE([shm],
 545     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 546     [AS_CASE(["$enableval"],
 547         [yes|no], [],
 548         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 549     [enable_shm=auto])
 550 WM_XEXT_CHECK_XSHM
 551
 552
 553 dnl X Misceleanous Utility
 554 dnl ======================
 555 dnl the libXmu is used in WRaster
 556 WM_EXT_CHECK_XMU
 557
 558
 559 dnl XINERAMA support
 560 dnl ================
 561 AC_ARG_ENABLE([xinerama],
 562     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 563     [AS_CASE(["$enableval"],
 564         [yes|no], [],
 565         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 566     [enable_xinerama=auto])
 567 WM_XEXT_CHECK_XINERAMA
 568
 569
 570 dnl RandR support
 571 dnl =============
 572 AC_ARG_ENABLE([randr],
 573     [AS_HELP_STRING([--enable-randr], [enable RandR extension support (NOT recommended, buggy)])],
 574     [AS_CASE(["$enableval"],
 575         [yes|no], [],
 576         [AC_MSG_ERROR([bad value $enableval for --enable-randr]) ]) ],
 577     [enable_randr=no])
 578 WM_XEXT_CHECK_XRANDR
 579
 580
 581 dnl Math library
 582 dnl ============
 583 dnl libWINGS uses math functions, check whether usage requires linking
 584 dnl against libm
 585 WM_CHECK_LIBM
 586
 587
 588 dnl FontConfig
 589 dnl ==========
 590 dnl libWINGS uses FcPatternDel from libfontconfig
 591 AC_MSG_CHECKING([for fontconfig library])
 592 FCLIBS=`$PKGCONFIG fontconfig --libs`
 593 if test "x$FCLIBS" = "x" ; then
 594         AC_MSG_RESULT([not found])
 595 else
 596         AC_MSG_RESULT([found])
 597 fi
 598 AC_SUBST(FCLIBS)
 599
 600
 601 dnl Xft2 antialiased font support
 602 dnl =============================
 603
 604 xft=yes
 605 XFTLIBS=""
 606
 607 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 608         XFTCONFIG="$PKGCONFIG xft"
 609         pkgconfig_xft=yes
 610 else
 611         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 612 fi
 613
 614 AC_MSG_CHECKING([for the Xft2 library])
 615
 616 if test "x$XFTCONFIG" != x; then
 617         XFTLIBS=`$XFTCONFIG --libs`
 618         XFTFLAGS=`$XFTCONFIG --cflags`
 619         AC_MSG_RESULT([found])
 620 else
 621         AC_MSG_RESULT([not found])
 622         echo
 623         echo "ERROR!!! libXft2 is not installed or could not be found."
 624         echo "         Xft2 is a requirement for building Window Maker."
 625         echo "         Please install it (along with fontconfig) before continuing."
 626         echo
 627         exit 1
 628 fi
 629
 630 minXFT="2.1.0"
 631 goodxft="no"
 632
 633 dnl
 634 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 635 dnl
 636 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 637
 638 if test "$goodxft" = no; then
 639         echo
 640         echo "ERROR!!! libXft on this system is an old version."
 641         echo "         Please consider upgrading to at least version ${minXFT}."
 642         echo
 643         exit 1
 644 fi
 645
 646 AC_SUBST(XFTFLAGS)
 647 AC_SUBST(XFTLIBS)
 648
 649 dnl PANGO support
 650 dnl =============
 651 pango=no
 652 AC_ARG_ENABLE(pango, AS_HELP_STRING([--enable-pango], [enable Pango text layout support]),
 653                 pango=$enableval, pango=no)
 654
 655 PANGOFLAGS=
 656 PANGOLIBS=
 657 if test "$pango" = yes; then
 658         PANGOLIBS=`$PKGCONFIG pangoxft --libs`
 659         PANGOFLAGS=`$PKGCONFIG pangoxft --cflags`
 660         if test "x$PANGOLIBS" = "x" ; then
 661                 AC_MSG_RESULT([not found])
 662         else
 663                 AC_DEFINE(USE_PANGO, 1, [Define if Pango is to be used])
 664                 AC_MSG_RESULT([found])
 665         fi
 666 fi
 667 inc_search_path="$inc_search_path $PANGOFLAGS"
 668 AC_SUBST(PANGOLIBS)
 669
 670 dnl ==============================================
 671 dnl         Graphic Format Libraries
 672 dnl ==============================================
 673
 674 dnl XPM Support
 675 dnl ===========
 676 AC_ARG_ENABLE([xpm],
 677     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 678     [AS_CASE(["$enableval"],
 679         [yes|no], [],
 680         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 681     [enable_xpm=auto])
 682 WM_IMGFMT_CHECK_XPM
 683
 684
 685 # for wmlib
 686 AC_SUBST(XCFLAGS)
 687 # for test
 688 AC_SUBST(XLFLAGS)
 689 AC_SUBST(XLIBS)
 690 AC_SUBST(X_EXTRA_LIBS)
 691
 692 dnl ===============================================
 693 dnl             End of stuff that uses X
 694 dnl ===============================================
 695
 696 dnl EXIF Support
 697 dnl ============
 698 WM_CHECK_LIBEXIF
 699 AS_IF([test "x$LIBEXIF" != "x"],
 700         [AC_DEFINE(HAVE_EXIF, 1, [Define if EXIF can be used])])
 701
 702
 703 dnl PNG Support
 704 dnl ===========
 705 AC_ARG_ENABLE([png],
 706     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 707     [AS_CASE(["$enableval"],
 708         [yes|no], [],
 709         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 710     [enable_png=auto])
 711 WM_IMGFMT_CHECK_PNG
 712
 713
 714 dnl JPEG Support
 715 dnl ============
 716 AC_ARG_ENABLE([jpeg],
 717     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 718     [AS_CASE(["$enableval"],
 719         [yes|no], [],
 720         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 721     [enable_jpeg=auto])
 722 WM_IMGFMT_CHECK_JPEG
 723
 724
 725 dnl GIF Support
 726 dnl ============
 727 AC_ARG_ENABLE(gif,
 728     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 729     [AS_CASE(["$enableval"],
 730         [yes|no], [],
 731         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 732     [enable_gif=auto])
 733 WM_IMGFMT_CHECK_GIF
 734
 735
 736 dnl TIFF Support
 737 dnl ============
 738 AC_ARG_ENABLE([tiff],
 739     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 740     [AS_CASE(["$enableval"],
 741         [yes|no], [],
 742         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 743     [enable_tiff=auto])
 744 WM_IMGFMT_CHECK_TIFF
 745
 746
 747 dnl WEBP Support
 748 dnl ============
 749 AC_ARG_ENABLE([webp],
 750     [AS_HELP_STRING([--disable-webp], [disable WEBP support through libwebp])],
 751     [AS_CASE(["$enableval"],
 752         [yes|no], [],
 753         [AC_MSG_ERROR([bad value $enableval for --enable-webp])] )],
 754     [enable_webp=auto])
 755 WM_IMGFMT_CHECK_WEBP
 756
 757
 758 dnl MagicK Support
 759 dnl ==============
 760 AC_ARG_ENABLE([magick],
 761     [AS_HELP_STRING([--disable-magick], [disable MAGICK support through libMagickWand])],
 762     [AS_CASE(["$enableval"],
 763         [yes|no], [],
 764         [AC_MSG_ERROR([bad value $enableval for --enable-magick])] )],
 765     [enable_magick=auto])
 766 WM_IMGFMT_CHECK_MAGICK
 767
 768
 769 dnl PPM Support
 770 dnl ===========
 771 # The PPM format is always enabled because we have built-in support for the format
 772 # We are not using any external library like libppm
 773 supported_gfx="$supported_gfx builtin-PPM"
 774
 775
 776 # Choice of the default format for icons
 777 AS_IF([test "x$enable_tiff" != "xno"],
 778     [ICONEXT="tiff"],
 779     [ICONEXT="xpm"])
 780
 781
 782 LIBRARY_SEARCH_PATH="$lib_search_path"
 783 HEADER_SEARCH_PATH="$inc_search_path"
 784
 785 AC_SUBST(LIBRARY_SEARCH_PATH)
 786 AC_SUBST(HEADER_SEARCH_PATH)
 787
 788
 789 AC_SUBST(GFXLIBS)
 790 AC_SUBST(ICONEXT)
 791 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 792 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 793
 794
 795 dnl ==============================================
 796 dnl         End of Graphic Format Libraries
 797 dnl ==============================================
 798
 799
 800 dnl
 801 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 802 AC_CHECK_HEADERS(stdlib.h)
 803
 804
 805 dnl Support for PIXMAPDIR option
 806 dnl ============================
 807 AC_ARG_WITH([pixmapdir],
 808     [AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]])],
 809     [AS_CASE([$withval],
 810         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-pixmapdir, expected a path]) ],
 811         [/*],  [], dnl Absolute path, ok
 812         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 813         [AC_MSG_ERROR([bad path '$withval' for pixmapdir, expecting an absolute path])])],
 814     [with_pixmapdir=""])
 815
 816 AS_IF([test "x$with_pixmapdir" != "x"],
 817     [pixmapdir="$with_pixmapdir"],
 818     [pixmapdir='${datadir}/pixmaps'])
 819 AC_SUBST([pixmapdir])dnl
 820
 821
 822 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 823 dnl ==============================================
 824 AC_ARG_WITH([gnustepdir],
 825     [AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications])],
 826     [AS_CASE([$withval],
 827         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-gnustepdir, expected a path]) ],
 828         [/*],  [], dnl Absolute path, ok
 829         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 830         [AC_MSG_ERROR([bad path '$withval' for gnustepdir, expecting an absolute path])])],
 831     [dnl If no command-line option was given, we use $GNUSTEP_LOCAL_ROOT if it was set
 832      with_gnustepdir="$GNUSTEP_LOCAL_ROOT"])
 833
 834 AS_IF([test "x$with_gnustepdir" = "x"],
 835     [dnl No path specified, use default
 836      wprefs_base_dir=${prefix}
 837      wprefs_datadir="${datadir}/WPrefs"
 838      wprefs_bindir="${bindir}"],
 839     [dnl User specified base path
 840      wprefs_base_dir="$with_gnustepdir/Applications"
 841      wprefs_datadir="$wprefs_base_dir/WPrefs.app"
 842      wprefs_bindir="$wprefs_base_dir/WPrefs.app"])
 843 AC_SUBST([wprefs_datadir])dnl
 844 AC_SUBST([wprefs_bindir])dnl
 845
 846
 847 dnl Enable User Defined Menu thing
 848 dnl ==============================
 849 AC_ARG_ENABLE([usermenu],
 850     [AS_HELP_STRING([--enable-usermenu], [user defined menus for applications])],
 851     [AS_CASE([$enableval],
 852         [yes|no], [],
 853         [AC_MSG_ERROR([bad value '$enableval' for --enable-usermenu])])],
 854     [enable_usermenu=no])
 855 AS_IF([test "x$enable_usermenu" = "xyes"],
 856     [AC_DEFINE([USER_MENU], [1],
 857         [define if you want user defined menus for applications])])
 858
 859
 860 dnl Support for removing non-public symbols from a library
 861 dnl ======================================================
 862 gl_LD_VERSION_SCRIPT
 863
 864
 865 dnl Add the post-poned compilation options
 866 dnl ======================================
 867 WM_CFLAGS_GCC_OPTION_POSTPONED
 868
 869
 870 AC_SUBST(lib_search_path)
 871 AC_SUBST(inc_search_path)
 872
 873
 874 dnl Spit out the configuration
 875 dnl ==========================
 876 AC_CONFIG_FILES(
 877     Makefile
 878
 879     dnl WRaster Library
 880     wrlib/Makefile
 881     wrlib/tests/Makefile
 882
 883     dnl WINGs toolkit
 884     WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
 885     WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
 886     WINGs/Examples/Makefile WINGs/Tests/Makefile
 887
 888     dnl Window Maker's core
 889     src/Makefile src/wconfig.h po/Makefile
 890     doc/Makefile doc/build/Makefile
 891     doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
 892     WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
 893     WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
 894     WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
 895     WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
 896
 897     dnl Preference GUI
 898     WPrefs.app/Makefile WPrefs.app/po/Makefile
 899     WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
 900
 901     dnl Command-line utilities
 902     util/Makefile util/po/Makefile
 903
 904     dnl Misceleanous stuff
 905     wmlib/Makefile
 906     test/Makefile
 907 )
 908
 909 AC_OUTPUT
 910
 911
 912 dnl Provide a summary of the config
 913 dnl ===============================
 914 echo
 915 echo "Window Maker was configured as follows:"
 916 echo
 917 echo "Installation path prefix            : $prefix"
 918 echo "Installation path for binaries      : $_bindir"
 919 echo "Installation path for libraries     : $libdir"
 920 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 921 echo "Supported X extensions:             :$supported_xext"
 922 echo "Supported graphic format libraries  :$supported_gfx"
 923 echo "Unsupported features                :$unsupported"
 924 echo "Antialiased text support in WINGs   : $xft"
 925 echo "Pango text layout support in WINGs  : $pango"
 926 echo "Translated languages to support     :$supported_locales"
 927 AS_IF([test "x$supported_locales" != "x disabled"],
 928         [echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"])
 929 AS_IF([test "x$debug" = "xyes"],
 930     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 931 echo
 932
 933 AS_IF([test "x$wm_cv_prog_cc_nestedfunc" != "xyes"],
 934     [AC_MSG_WARN([[Your compiler does not support Nested Function, work-around enabled]])])
 935
 936 AS_IF([test "x$supported_locales" = "x"],
 937     [AC_MSG_WARN([[No language from \$LINGUAS are supported]])])
 938
 939 AS_IF([test "x$enable_jpeg" = xno], [dnl
 940     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 941     AS_ECHO([])
 942     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 943     AS_ECHO(["not installed correctly or was not found. Background images"])
 944     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 945     AS_ECHO([])
 946     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 947     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 948     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 949     AS_ECHO([])
 950     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 951 ])
 952
 953
 954 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 955 dnl ================================================
 956 dnl Local Variables:
 957 dnl compile-command: "autoconf"
 958 dnl End: