configure.ac

   1 dnl ============================================================================
   2 dnl
   3 dnl Window Maker autoconf input
   4 dnl
   5 AC_COPYRIGHT([Copyright (c) 2001-2015 The Window Maker Team])
   6 dnl
   7 dnl ============================================================================
   8 dnl
   9 dnl This program is free software; you can redistribute it and/or modify
  10 dnl it under the terms of the GNU General Public License as published by
  11 dnl the Free Software Foundation; either version 2 of the License, or
  12 dnl (at your option) any later version.
  13 dnl
  14 dnl This program is distributed in the hope that it will be useful,
  15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 dnl GNU General Public License for more details.
  18 dnl
  19 dnl You should have received a copy of the GNU General Public License along
  20 dnl with this program; see the file COPYING.
  21 dnl
  22 dnl ============================================================================
  23 dnl
  24 dnl Process with: ./autogen.sh
  25
  26
  27 dnl Due to a bug in Autoconf 2.68 (apparently a regression), we need at least
  28 dnl version 2.68b which includes this patch:
  29 dnl   http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commit;h=2b0d95faef68d7ed7c08b0edb9ff1c38728376fa
  30 dnl
  31 dnl Because the 2.69 was released only a few month later, let's just ask for it
  32 AC_PREREQ([2.69])
  33
  34
  35 dnl Configuration for Autoconf and Automake
  36 dnl =======================================
  37 AC_INIT([WindowMaker],[0.95.9],[wmaker-dev@googlegroups.com],[WindowMaker],[http://www.windowmaker.org/])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_HEADERS([config.h])
  40
  41 dnl We need the EXTRA_xxx_DEPENDENCIES keyword in Makefiles which have been
  42 dnl introduced in the version 1.11.3; because the 1.12 was realeased shortly
  43 dnl after, we just ask for it
  44 AM_INIT_AUTOMAKE([1.12 silent-rules])
  45
  46 dnl Reference file used by 'configure' to make sure the path to sources is valid
  47 AC_CONFIG_SRCDIR([src/WindowMaker.h])
  48
  49 dnl Include at the end of 'config.h', this file is generated by top-level Makefile
  50 AH_BOTTOM([@%:@include "config-paths.h"])
  51
  52
  53 dnl libtool library versioning
  54 dnl ==========================
  55 dnl
  56 dnl current
  57 dnl revision
  58 dnl age
  59 dnl
  60 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  61 dnl 2. Update the version information only immediately before a public
  62 dnl release of your software. More frequent updates are unnecessary, and
  63 dnl only guarantee that the current interface number gets larger faster.
  64 dnl 3. If the library source code has changed at all since the last
  65 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  66 dnl 4. If any interfaces have been added, removed, or changed since the
  67 dnl last update, increment current, and set revision to 0.
  68 dnl 5. If any interfaces have been added since the last public release,
  69 dnl then increment age.
  70 dnl 6. If any interfaces have been removed or changed since the last
  71 dnl public release, then set age to 0.
  72 dnl
  73 dnl libwraster
  74 WRASTER_CURRENT=6
  75 WRASTER_REVISION=0
  76 WRASTER_AGE=0
  77 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  78 AC_SUBST(WRASTER_VERSION)
  79 dnl
  80 dnl libWINGs
  81 WINGS_CURRENT=4
  82 WINGS_REVISION=0
  83 WINGS_AGE=1
  84 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  85 AC_SUBST(WINGS_VERSION)
  86 dnl
  87 dnl libWUtil
  88 WUTIL_CURRENT=5
  89 WUTIL_REVISION=0
  90 WUTIL_AGE=0
  91 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  92 AC_SUBST(WUTIL_VERSION)
  93
  94
  95 dnl Checks for programs
  96 dnl ===================
  97 AC_PROG_CC
  98 WM_PROG_CC_C11
  99 AC_PROG_LN_S
 100 AC_PROG_GCC_TRADITIONAL
 101 LT_INIT
 102
 103
 104 dnl Debugging Options
 105 dnl =================
 106 AC_ARG_ENABLE([debug],
 107     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
 108     [AS_CASE(["$enableval"],
 109         [yes], [debug=yes],
 110         [no],  [debug=no],
 111         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
 112     [debug=no])
 113 AS_IF([test "x$debug" = "xyes"],
 114     [dnl This flag should have already been detected and added, but if user
 115      dnl provided an explicit CFLAGS it may not be the case
 116      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
 117            [@%:@ Debug symbol already activated],
 118            [AX_CFLAGS_GCC_OPTION([-g])])
 119      dnl
 120      dnl This flag generally makes debugging nightmarish, remove it if present
 121      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
 122      dnl
 123      dnl Enable internal debug code
 124      CPPFLAGS="$CPPFLAGS -DDEBUG"
 125 ],  [dnl
 126      dnl When debug is not enabled, the user probably does not wants to keep
 127      dnl assertions in the final program
 128      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 129 ])
 130
 131
 132 AX_CFLAGS_GCC_OPTION([-Wall])
 133 AX_CFLAGS_GCC_OPTION([-Wextra -Wno-sign-compare])
 134 dnl
 135 dnl The use of trampolines cause code that can crash on some secured OS, it is
 136 dnl also known to be a source of crash if not used properly, in a more general
 137 dnl way it tends to generate binary code that may not be optimal, and it is
 138 dnl not compatible with the 'nested-func-to-macro' workaround
 139 WM_CFLAGS_CHECK_FIRST([-Wtrampolines],
 140          [-Werror=trampolines  dnl try to generate an error if possible
 141           -Wtrampolines        dnl if not, try to fall back to a simple warning
 142          ])
 143 dnl
 144 AS_IF([test "x$debug" = "xyes"],
 145     [dnl When debug is enabled, we try to activate more checks from
 146      dnl the compiler. They are on independant check because the
 147      dnl macro checks all the options at once, but we may have cases
 148      dnl where some options are not supported and we don't want to
 149      dnl loose all of them.
 150      dnl
 151      dnl clang, suggest parenthesis on bit operations that could be
 152      dnl misunderstood due to C operator precedence
 153      AX_CFLAGS_GCC_OPTION([-Wbitwise-op-parentheses])
 154      dnl
 155      dnl Points at code that gcc thinks is so complicated that gcc
 156      dnl gives up trying to optimize, which probably also means it is
 157      dnl too complicated to maintain
 158      AX_CFLAGS_GCC_OPTION([-Wdisabled-optimization])
 159      dnl
 160      dnl Because of C's type promotion, the compiler has to generate
 161      dnl less optimal code when a double constant is used in a
 162      dnl float expression
 163      AX_CFLAGS_GCC_OPTION([-Wdouble-promotion])
 164      dnl
 165      dnl Floating-point comparison is not a good idea
 166      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 167      dnl
 168      dnl clang warns about constants that may have portability issues due
 169      dnl to the endianness of the host
 170      AX_CFLAGS_GCC_OPTION([-Wfour-char-constants])
 171      dnl
 172      dnl clang warns about constant that may be too big to be portable
 173      AX_CFLAGS_GCC_OPTION([-Wliteral-range])
 174      dnl
 175      dnl Try to report misuses of '&' versus '&&' and similar
 176      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 177      dnl
 178      dnl clang, reports cases where the code assumes everyone is an
 179      dnl expert in C operator precedence... which is unlikely!
 180      AX_CFLAGS_GCC_OPTION([-Wlogical-op-parentheses])
 181      dnl
 182      dnl Reports declaration of global things that are done inside
 183      dnl a local environment, instead of using the appropriate
 184      dnl header
 185      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 186      dnl
 187      dnl Warn about constant strings that could pose portability issues
 188      AX_CFLAGS_GCC_OPTION([-Woverlength-strings])
 189      dnl
 190      dnl Use of 'sizeof()' on inappropriate pointer types
 191      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 192      dnl
 193      dnl Having more than 1 prototype for a function makes code updates
 194      dnl more difficult, so try to avoid it
 195      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 196      dnl
 197      dnl clang, detect some misuses of sizeof. We also count in our code
 198      dnl on the use of the macro 'wlength' which contains a check if the
 199      dnl compiler support C11's static_assert
 200      AX_CFLAGS_GCC_OPTION([-Wsizeof-array-argument])
 201      dnl
 202      dnl Prototype of function must be explicit, no deprecated K&R syntax
 203      dnl and no empty argument list which prevents compiler from doing
 204      dnl type checking when using the function
 205      WM_CFLAGS_GCC_OPTION_STRICTPROTO
 206      dnl
 207      dnl Proper attributes helps the compiler to produce better code
 208      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 209          [-Wsuggest-attribute=format  dnl new gcc syntax
 210           -Wmissing-format-attribute  dnl old gcc syntax, clang
 211          ])
 212      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 213          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 214           -Wmissing-noreturn            dnl clang syntax
 215          ])
 216      dnl
 217      dnl GCC provides a couple of checks to detect incorrect macro uses
 218      AX_CFLAGS_GCC_OPTION([-Wundef])
 219      WM_CFLAGS_GCC_OPTION_UNUSEDMACROS
 220      dnl
 221      dnl clang reports stuff marked unused but which is actually used
 222      AX_CFLAGS_GCC_OPTION([-Wused-but-marked-unused])
 223 ], [dnl
 224      dnl When debug not enabled, we try to avoid some non-necessary
 225      dnl messages from the compiler
 226      dnl
 227      dnl To support legacy X servers, we have sometime to use
 228      dnl functions marked as deprecated. We do not wish our users
 229      dnl to be worried about it
 230      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 231      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 232 ])
 233
 234
 235 dnl Support for Nested Functions by the compiler
 236 dnl ============================================
 237 WM_PROG_CC_NESTEDFUNC
 238
 239
 240 dnl Posix thread
 241 dnl ============
 242 dnl they are used by util/wmiv
 243 AX_PTHREAD
 244
 245
 246 dnl Tracking on what is detected for final status
 247 dnl =============================================
 248 unsupported=""
 249 supported_core=""
 250 supported_xext=""
 251 supported_gfx=""
 252
 253
 254 dnl Platform-specific Makefile setup
 255 dnl ================================
 256 AS_CASE(["$host"],
 257     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 258     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 259     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 260     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 261     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 262     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 263     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 264     [WM_OSDEP="stub"])
 265 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 266 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 267 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 268 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 269
 270
 271 dnl the prefix
 272 dnl ==========
 273 dnl
 274 dnl move this earlier in the script... anyone know why this is handled
 275 dnl in such a bizarre way?
 276
 277 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 278 dnl Let make expand exec_prefix.
 279 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 280
 281
 282 _bindir=`eval echo $bindir`
 283 _bindir=`eval echo $_bindir`
 284 _libdir=`eval echo $libdir`
 285 _libdir=`eval echo $_libdir`
 286
 287 dnl ===============================================
 288 dnl Specify paths to look for libraries and headers
 289 dnl ===============================================
 290 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 291         [lib_search_path="$withval"], [lib_search_path='-L${libdir}'])
 292
 293 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 294         [inc_search_path="$withval"], [inc_search_path='-I${includedir}'])
 295
 296
 297 dnl Features Configuration
 298 dnl ======================
 299 AC_ARG_ENABLE([animations],
 300     [AS_HELP_STRING([--disable-animations], [disable permanently animations @<:@default=enabled@:>@])],
 301     [AS_CASE(["$enableval"],
 302         [yes|no], [],
 303         [AC_MSG_ERROR([bad value $enableval for --enable-animations])])],
 304     [enable_animations="yes"])
 305 AS_IF([test "x$enable_animations" = "xno"],
 306     [unsupported="$unsupported Animations"],
 307     [AC_DEFINE([USE_ANIMATIONS], [1], [Defined when user did not request to disable animations])
 308      supported_core="$supported_core Animations"])
 309
 310
 311 AC_ARG_ENABLE([mwm-hints],
 312     [AS_HELP_STRING([--disable-mwm-hints], [disable support for Motif WM hints @<:@default=enabled@:>@])],
 313     [AS_CASE(["$enableval"],
 314         [yes|no], [],
 315         [AC_MSG_ERROR([bad value $enableval for --enable-mwm-hints])])],
 316     [enable_mwm_hints="yes"])
 317 AS_IF([test "x$enable_mwm_hints" = "xno"],
 318     [unsupported="$unsupported MWMHints"],
 319     [AC_DEFINE([USE_MWM_HINTS], [1], [Defined when used did not request to disable Motif WM hints])
 320      supported_core="$supported_core MWMHints"])
 321 AM_CONDITIONAL([USE_MWM_HINTS], [test "x$enable_mwm_hints" != "xno"])
 322
 323
 324 dnl Boehm GC
 325 dnl ========
 326 AC_ARG_ENABLE([boehm-gc],
 327     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 328     [AS_CASE(["$enableval"],
 329         [yes], [with_boehm_gc=yes],
 330         [no],  [with_boehm_gc=no],
 331         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 332     [with_boehm_gc=no])
 333 AS_IF([test "x$with_boehm_gc" = "xyes"],
 334     AC_SEARCH_LIBS([GC_malloc], [gc],
 335         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 336         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 337
 338
 339 dnl LCOV
 340 dnl ====
 341 AC_ARG_ENABLE([lcov],
 342     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 343     [],
 344     [enable_lcov=no])
 345
 346 AS_IF([test "x$enable_lcov" != "xno"],
 347     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 348     AS_IF([test "x$enable_lcov" = "xyes"],
 349         [lcov_output_directory="coverage-report"],
 350         [lcov_output_directory="${enable_lcov}/coverage-report"])
 351     AC_SUBST(lcov_output_directory)])
 352
 353 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 354
 355
 356 dnl ============================
 357 dnl Checks for library functions
 358 dnl ============================
 359 AC_FUNC_MEMCMP
 360 AC_FUNC_VPRINTF
 361 WM_FUNC_SECURE_GETENV
 362 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 363                setsid mallinfo mkstemp sysconf)
 364 AC_SEARCH_LIBS([strerror], [cposix])
 365
 366 dnl nanosleep is generally available in standard libc, although not always the
 367 dnl case. One known example is Solaris which needs -lrt
 368 AC_SEARCH_LIBS([nanosleep], [rt], [],
 369     [AC_MSG_ERROR([function 'nanosleep' not found, please report to wmaker-dev@googlegroups.com])])
 370
 371 dnl the flag 'O_NOFOLLOW' for 'open' is used in WINGs
 372 WM_FUNC_OPEN_NOFOLLOW
 373
 374
 375 dnl Check for strlcat/strlcpy
 376 dnl =========================
 377 AC_ARG_WITH([libbsd],
 378   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 379   [AS_IF([test "x$with_libbsd" != "xno"],
 380     [with_libbsd=bsd]
 381     [with_libbsd=]
 382   )],
 383   [with_libbsd=bsd])
 384
 385 tmp_libs=$LIBS
 386 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 387   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 388   [],
 389   []
 390 )
 391 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 392   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 393   [],
 394   []
 395 )
 396 LIBS=$tmp_libs
 397
 398 LIBBSD=
 399 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 400   [LIBBSD=-lbsd
 401    AC_CHECK_HEADERS([bsd/string.h])]
 402 )
 403 AC_SUBST(LIBBSD)
 404
 405
 406 dnl Check for OpenBSD kernel memory interface - kvm(3)
 407 dnl ==================================================
 408 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 409   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 410
 411
 412 dnl Check for inotify
 413 dnl =================
 414 dnl It is used by WindowMaker to reload automatically the configuration when the
 415 dnl user changed it using WPref or wdwrite
 416 AC_CHECK_HEADERS([sys/inotify.h],
 417     [AC_DEFINE([HAVE_INOTIFY], [1], [Check for inotify])])
 418
 419
 420 dnl Check for syslog
 421 dnl ================
 422 dnl It is used by WUtil to log the wwarning, werror and wfatal
 423 AC_CHECK_HEADERS([syslog.h], [AC_DEFINE([HAVE_SYSLOG], [1], [Check for syslog])])
 424
 425
 426 dnl Checks for header files
 427 dnl =======================
 428 AC_HEADER_SYS_WAIT
 429 AC_HEADER_TIME
 430 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 431                  string.h strings.h)
 432
 433
 434 dnl Checks for typedefs, structures, and compiler characteristics
 435 dnl =============================================================
 436 AC_C_CONST
 437 AC_C_INLINE
 438 WM_C_NORETURN
 439 AC_TYPE_SIZE_T
 440 AC_TYPE_PID_T
 441 WM_TYPE_SIGNAL
 442
 443
 444 dnl pkg-config
 445 dnl ==========
 446 PKG_PROG_PKG_CONFIG
 447 AS_IF([test -z "$PKG_CONFIG"],[AC_MSG_ERROR([pkg-config is required.])])
 448
 449
 450
 451 dnl Internationalization
 452 dnl ====================
 453 dnl Detect the language for translations to be installed and check
 454 dnl that the gettext environment works
 455 WM_I18N_LANGUAGES
 456 WM_I18N_XGETTEXT
 457 WM_I18N_MENUTEXTDOMAIN
 458
 459 dnl ===========================================
 460 dnl             Stuff that uses X
 461 dnl ===========================================
 462
 463 AC_PATH_XTRA
 464
 465 AS_IF([test "x$no_x" = "xyes"],
 466     [AC_MSG_ERROR([The path for the X11 files not found!
 467 Make sure you have X and it's headers and libraries (the -devel packages
 468 in Linux) installed.])])
 469
 470 X_LIBRARY_PATH=$x_libraries
 471 XCFLAGS="$X_CFLAGS"
 472 XLFLAGS="$X_LIBS"
 473 XLIBS="-lX11 $X_EXTRA_LIBS"
 474
 475 lib_search_path="$lib_search_path $XLFLAGS"
 476 inc_search_path="$inc_search_path $XCFLAGS"
 477
 478 AC_SUBST(X_LIBRARY_PATH)
 479
 480
 481 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 482 dnl by MANOME Tomonori
 483 dnl ===========================================
 484 WM_I18N_XLOCALE
 485
 486
 487
 488 dnl Check whether XInternAtoms() exist
 489 dnl ==================================
 490 AC_CHECK_LIB([X11], [XInternAtoms],
 491     [AC_DEFINE([HAVE_XINTERNATOMS], [1],
 492         [define if your X server has XInternAtoms() (set by configure)])],
 493     [], [$XLFLAGS $XLIBS])
 494
 495
 496 dnl Check whether XConvertCase() exist
 497 dnl ==================================
 498 AC_CHECK_LIB([X11], [XConvertCase],
 499     [AC_DEFINE([HAVE_XCONVERTCASE], [1],
 500         [define if your X server has XConvertCase() (set by configure)])],
 501     [], [$XLFLAGS $XLIBS])
 502
 503
 504 dnl XKB keyboard language status
 505 dnl ============================
 506 AC_ARG_ENABLE([modelock],
 507     [AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support])],
 508     [AS_CASE([$enableval],
 509         [yes|no], [],
 510         [AC_MSG_ERROR([bad value '$enableval' for --enable-modelock])])],
 511     [enable_modelock=no])
 512 AS_IF([test "x$enable_modelock" = "xyes"],
 513     [AC_DEFINE([XKB_MODELOCK], [1], [whether XKB language MODELOCK should be enabled]) ])
 514
 515
 516 dnl XDND Drag-nd-Drop support
 517 dnl =========================
 518 AC_ARG_ENABLE([xdnd],
 519     [AS_HELP_STRING([--disable-xdnd], [disable support for Drag-and-Drop on the dock @<:@default=enabled@:>@])],
 520     [AS_CASE(["$enableval"],
 521         [yes|no], [],
 522         [AC_MSG_ERROR([bad value $enableval for --disable-xdnd]) ]) ],
 523     [enable_xdnd=yes])
 524 AS_IF([test "x$enable_xdnd" = "xyes"],
 525     [supported_core="$supported_core XDnD"
 526      AC_DEFINE([USE_DOCK_XDND], [1], [whether Drag-and-Drop on the dock should be enabled])],
 527     [unsupported="$unsupported XDnd"])
 528 AM_CONDITIONAL([USE_DOCK_XDND], [test "x$enable_xdnd" != "xno"])
 529
 530
 531 dnl Support for ICCCM 2.0 Window Manager replacement
 532 dnl ================================================
 533 AC_ARG_ENABLE([wmreplace],
 534     [AS_HELP_STRING([--enable-wmreplace], [support for ICCCM window manager replacement])],
 535     [AS_CASE([$enableval],
 536         [yes|no], [],
 537         [AC_MSG_ERROR([bad value '$enableval' for --enable-wmreplace])])],
 538     [enable_wmreplace=no])
 539 AS_IF([test "x$enable_wmreplace" = "xyes"],
 540     [AC_DEFINE([USE_ICCCM_WMREPLACE], [1],
 541        [define to support ICCCM protocol for window manager replacement])
 542      supported_xext="$supported_xext WMReplace"])
 543
 544
 545 dnl XShape support
 546 dnl ==============
 547 AC_ARG_ENABLE([shape],
 548     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 549     [AS_CASE(["$enableval"],
 550         [yes|no], [],
 551         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 552     [enable_shape=auto])
 553 WM_XEXT_CHECK_XSHAPE
 554
 555
 556 dnl MIT-SHM support
 557 dnl ===============
 558 AC_ARG_ENABLE([shm],
 559     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 560     [AS_CASE(["$enableval"],
 561         [yes|no], [],
 562         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 563     [enable_shm=auto])
 564 WM_XEXT_CHECK_XSHM
 565
 566
 567 dnl X Misceleanous Utility
 568 dnl ======================
 569 dnl the libXmu is used in WRaster
 570 WM_EXT_CHECK_XMU
 571
 572
 573 dnl XINERAMA support
 574 dnl ================
 575 AC_ARG_ENABLE([xinerama],
 576     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 577     [AS_CASE(["$enableval"],
 578         [yes|no], [],
 579         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 580     [enable_xinerama=auto])
 581 WM_XEXT_CHECK_XINERAMA
 582
 583
 584 dnl RandR support
 585 dnl =============
 586 AC_ARG_ENABLE([randr],
 587     [AS_HELP_STRING([--enable-randr], [enable RandR extension support (NOT recommended, buggy)])],
 588     [AS_CASE(["$enableval"],
 589         [yes|no], [],
 590         [AC_MSG_ERROR([bad value $enableval for --enable-randr]) ]) ],
 591     [enable_randr=no])
 592 WM_XEXT_CHECK_XRANDR
 593
 594
 595 dnl Math library
 596 dnl ============
 597 dnl libWINGS uses math functions, check whether usage requires linking
 598 dnl against libm
 599 WM_CHECK_LIBM
 600
 601
 602 dnl FontConfig
 603 dnl ==========
 604 dnl libWINGS uses FcPatternDel from libfontconfig
 605 AC_MSG_CHECKING([for fontconfig library])
 606 FCLIBS=`$PKG_CONFIG fontconfig --libs`
 607 if test "x$FCLIBS" = "x" ; then
 608         AC_MSG_RESULT([not found])
 609 else
 610         AC_MSG_RESULT([found])
 611 fi
 612 AC_SUBST(FCLIBS)
 613
 614
 615 dnl Xft2 antialiased font support
 616 dnl =============================
 617
 618 xft=yes
 619 XFTLIBS=""
 620
 621 if test "x$PKG_CONFIG" != x -a "`$PKG_CONFIG xft; echo $?`" = 0; then
 622         XFTCONFIG="$PKG_CONFIG xft"
 623         pkgconfig_xft=yes
 624 else
 625         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 626 fi
 627
 628 AC_MSG_CHECKING([for the Xft2 library])
 629
 630 if test "x$XFTCONFIG" != x; then
 631         XFTLIBS=`$XFTCONFIG --libs`
 632         XFTFLAGS=`$XFTCONFIG --cflags`
 633         AC_MSG_RESULT([found])
 634 else
 635         AC_MSG_RESULT([not found])
 636         echo
 637         echo "ERROR!!! libXft2 is not installed or could not be found."
 638         echo "         Xft2 is a requirement for building Window Maker."
 639         echo "         Please install it (along with fontconfig) before continuing."
 640         echo
 641         exit 1
 642 fi
 643
 644 minXFT="2.1.0"
 645 goodxft="no"
 646
 647 dnl
 648 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 649 dnl
 650 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 651
 652 if test "$goodxft" = no; then
 653         echo
 654         echo "ERROR!!! libXft on this system is an old version."
 655         echo "         Please consider upgrading to at least version ${minXFT}."
 656         echo
 657         exit 1
 658 fi
 659
 660 AC_SUBST(XFTFLAGS)
 661 AC_SUBST(XFTLIBS)
 662
 663 dnl PANGO support
 664 dnl =============
 665 pango=no
 666 AC_ARG_ENABLE(pango, AS_HELP_STRING([--enable-pango], [enable Pango text layout support]),
 667                 pango=$enableval, pango=no)
 668
 669 PANGOFLAGS=
 670 PANGOLIBS=
 671 if test "$pango" = yes; then
 672         PANGOLIBS=`$PKG_CONFIG pangoxft --libs`
 673         PANGOFLAGS=`$PKG_CONFIG pangoxft --cflags`
 674         if test "x$PANGOLIBS" = "x" ; then
 675                 AC_MSG_RESULT([not found])
 676         else
 677                 AC_DEFINE(USE_PANGO, 1, [Define if Pango is to be used])
 678                 AC_MSG_RESULT([found])
 679         fi
 680 fi
 681 inc_search_path="$inc_search_path $PANGOFLAGS"
 682 AC_SUBST(PANGOLIBS)
 683
 684 dnl ==============================================
 685 dnl         Graphic Format Libraries
 686 dnl ==============================================
 687
 688 dnl XPM Support
 689 dnl ===========
 690 AC_ARG_ENABLE([xpm],
 691     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 692     [AS_CASE(["$enableval"],
 693         [yes|no], [],
 694         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 695     [enable_xpm=auto])
 696 WM_IMGFMT_CHECK_XPM
 697
 698
 699 # for wmlib
 700 AC_SUBST(XCFLAGS)
 701 # for test
 702 AC_SUBST(XLFLAGS)
 703 AC_SUBST(XLIBS)
 704 AC_SUBST(X_EXTRA_LIBS)
 705
 706 dnl ===============================================
 707 dnl             End of stuff that uses X
 708 dnl ===============================================
 709
 710 dnl EXIF Support
 711 dnl ============
 712 WM_CHECK_LIBEXIF
 713 AS_IF([test "x$LIBEXIF" != "x"],
 714         [AC_DEFINE(HAVE_EXIF, 1, [Define if EXIF can be used])])
 715
 716
 717 dnl PNG Support
 718 dnl ===========
 719 AC_ARG_ENABLE([png],
 720     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 721     [AS_CASE(["$enableval"],
 722         [yes|no], [],
 723         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 724     [enable_png=auto])
 725 WM_IMGFMT_CHECK_PNG
 726
 727
 728 dnl JPEG Support
 729 dnl ============
 730 AC_ARG_ENABLE([jpeg],
 731     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 732     [AS_CASE(["$enableval"],
 733         [yes|no], [],
 734         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 735     [enable_jpeg=auto])
 736 WM_IMGFMT_CHECK_JPEG
 737
 738
 739 dnl GIF Support
 740 dnl ============
 741 AC_ARG_ENABLE(gif,
 742     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 743     [AS_CASE(["$enableval"],
 744         [yes|no], [],
 745         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 746     [enable_gif=auto])
 747 WM_IMGFMT_CHECK_GIF
 748
 749
 750 dnl TIFF Support
 751 dnl ============
 752 AC_ARG_ENABLE([tiff],
 753     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 754     [AS_CASE(["$enableval"],
 755         [yes|no], [],
 756         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 757     [enable_tiff=auto])
 758 WM_IMGFMT_CHECK_TIFF
 759
 760
 761 dnl WEBP Support
 762 dnl ============
 763 AC_ARG_ENABLE([webp],
 764     [AS_HELP_STRING([--disable-webp], [disable WEBP support through libwebp])],
 765     [AS_CASE(["$enableval"],
 766         [yes|no], [],
 767         [AC_MSG_ERROR([bad value $enableval for --enable-webp])] )],
 768     [enable_webp=auto])
 769 WM_IMGFMT_CHECK_WEBP
 770
 771
 772 dnl MagicK Support
 773 dnl ==============
 774 AC_ARG_ENABLE([magick],
 775     [AS_HELP_STRING([--disable-magick], [disable MAGICK support through libMagickWand])],
 776     [AS_CASE(["$enableval"],
 777         [yes|no], [],
 778         [AC_MSG_ERROR([bad value $enableval for --enable-magick])] )],
 779     [enable_magick=auto])
 780 WM_IMGFMT_CHECK_MAGICK
 781
 782
 783 dnl PPM Support
 784 dnl ===========
 785 # The PPM format is always enabled because we have built-in support for the format
 786 # We are not using any external library like libppm
 787 supported_gfx="$supported_gfx builtin-PPM"
 788
 789
 790 # Choice of the default format for icons
 791 AS_IF([test "x$enable_tiff" != "xno"],
 792     [ICONEXT="tiff"],
 793     [ICONEXT="xpm"])
 794
 795
 796 LIBRARY_SEARCH_PATH="$lib_search_path"
 797 HEADER_SEARCH_PATH="$inc_search_path"
 798
 799 AC_SUBST(LIBRARY_SEARCH_PATH)
 800 AC_SUBST(HEADER_SEARCH_PATH)
 801
 802
 803 AC_SUBST(GFXLIBS)
 804 AC_SUBST(ICONEXT)
 805 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 806 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 807
 808
 809 dnl ==============================================
 810 dnl         End of Graphic Format Libraries
 811 dnl ==============================================
 812
 813
 814 dnl
 815 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 816 AC_CHECK_HEADERS(stdlib.h)
 817
 818
 819 dnl Support for PIXMAPDIR option
 820 dnl ============================
 821 AC_ARG_WITH([pixmapdir],
 822     [AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]])],
 823     [AS_CASE([$withval],
 824         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-pixmapdir, expected a path]) ],
 825         [/*],  [], dnl Absolute path, ok
 826         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 827         [AC_MSG_ERROR([bad path '$withval' for pixmapdir, expecting an absolute path])])],
 828     [with_pixmapdir=""])
 829
 830 AS_IF([test "x$with_pixmapdir" != "x"],
 831     [pixmapdir="$with_pixmapdir"],
 832     [pixmapdir='${datadir}/pixmaps'])
 833 AC_SUBST([pixmapdir])dnl
 834
 835
 836 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 837 dnl ==============================================
 838 AC_ARG_WITH([gnustepdir],
 839     [AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications])],
 840     [AS_CASE([$withval],
 841         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-gnustepdir, expected a path]) ],
 842         [/*],  [], dnl Absolute path, ok
 843         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 844         [AC_MSG_ERROR([bad path '$withval' for gnustepdir, expecting an absolute path])])],
 845     [dnl If no command-line option was given, we use $GNUSTEP_LOCAL_ROOT if it was set
 846      with_gnustepdir="$GNUSTEP_LOCAL_ROOT"])
 847
 848 AS_IF([test "x$with_gnustepdir" = "x"],
 849     [dnl No path specified, use default
 850      wprefs_base_dir=${prefix}
 851      wprefs_datadir="${datadir}/WPrefs"
 852      wprefs_bindir="${bindir}"],
 853     [dnl User specified base path
 854      wprefs_base_dir="$with_gnustepdir/Applications"
 855      wprefs_datadir="$wprefs_base_dir/WPrefs.app"
 856      wprefs_bindir="$wprefs_base_dir/WPrefs.app"])
 857 AC_SUBST([wprefs_datadir])dnl
 858 AC_SUBST([wprefs_bindir])dnl
 859
 860 dnl Support for DEFSDATADIR option
 861 dnl ============================
 862 AC_ARG_WITH([defsdatadir],
 863     [AS_HELP_STRING([--with-defsdatadir=PATH], [specify where global defaults are located [SYSCONFDIR/WindowMaker]])],
 864     [AS_CASE([$withval],
 865         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-defsdatadir, expected a path]) ],
 866         [/*],  [], dnl Absolute path, ok
 867         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 868         [AC_MSG_ERROR([bad path '$withval' for defsdatadir, expecting an absolute path])])],
 869     [with_defsdatadir=""])
 870
 871 AS_IF([test "x$with_defsdatadir" != "x"],
 872     [defsdatadir="$with_defsdatadir"],
 873     [defsdatadir='${sysconfdir}/WindowMaker'])
 874 AC_SUBST([defsdatadir])dnl
 875
 876 dnl Enable User Defined Menu thing
 877 dnl ==============================
 878 AC_ARG_ENABLE([usermenu],
 879     [AS_HELP_STRING([--enable-usermenu], [user defined menus for applications])],
 880     [AS_CASE([$enableval],
 881         [yes|no], [],
 882         [AC_MSG_ERROR([bad value '$enableval' for --enable-usermenu])])],
 883     [enable_usermenu=no])
 884 AS_IF([test "x$enable_usermenu" = "xyes"],
 885     [AC_DEFINE([USER_MENU], [1],
 886         [define if you want user defined menus for applications])])
 887
 888
 889 dnl Support for removing non-public symbols from a library
 890 dnl ======================================================
 891 gl_LD_VERSION_SCRIPT
 892
 893
 894 dnl Add the post-poned compilation options
 895 dnl ======================================
 896 WM_CFLAGS_GCC_OPTION_POSTPONED
 897
 898
 899 AC_SUBST(lib_search_path)
 900 AC_SUBST(inc_search_path)
 901
 902
 903 dnl Spit out the configuration
 904 dnl ==========================
 905 AC_CONFIG_FILES(
 906     Makefile
 907
 908     dnl WRaster Library
 909     wrlib/Makefile
 910     wrlib/tests/Makefile
 911
 912     dnl WINGs toolkit
 913     WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
 914     WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
 915     WINGs/Examples/Makefile WINGs/Tests/Makefile
 916
 917     dnl Window Maker's core
 918     src/Makefile src/wconfig.h po/Makefile
 919     doc/Makefile doc/build/Makefile
 920     doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
 921     WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
 922     WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
 923     WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
 924     WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
 925
 926     dnl Preference GUI
 927     WPrefs.app/Makefile WPrefs.app/po/Makefile
 928     WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
 929
 930     dnl Command-line utilities
 931     util/Makefile util/po/Makefile
 932
 933     dnl Misceleanous stuff
 934     wmlib/Makefile
 935     test/Makefile
 936 )
 937
 938 AC_OUTPUT
 939
 940
 941 dnl Provide a summary of the config
 942 dnl ===============================
 943 echo
 944 echo "Window Maker was configured as follows:"
 945 echo
 946 echo "Installation path prefix            : $prefix"
 947 echo "Installation path for binaries      : $_bindir"
 948 echo "Installation path for libraries     : $_libdir"
 949 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 950 echo "Supported core features:            :$supported_core"
 951 echo "Supported X extensions:             :$supported_xext"
 952 echo "Supported graphic format libraries  :$supported_gfx"
 953 echo "Unsupported features                :$unsupported"
 954 echo "Antialiased text support in WINGs   : $xft"
 955 echo "Pango text layout support in WINGs  : $pango"
 956 echo "Translated languages to support     :$supported_locales"
 957 AS_IF([test "x$debug" = "xyes"],
 958     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 959 echo
 960
 961 AS_IF([test "x$wm_cv_prog_cc_nestedfunc" != "xyes"],
 962     [AC_MSG_WARN([[Your compiler does not support Nested Function, work-around enabled]])])
 963
 964 AS_IF([test "x$supported_locales" = "x"],
 965     [AC_MSG_WARN([[No language from \$LINGUAS are supported]])])
 966
 967 AS_IF([test "x$enable_jpeg" = xno], [dnl
 968     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 969     AS_ECHO([])
 970     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 971     AS_ECHO(["not installed correctly or was not found. Background images"])
 972     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 973     AS_ECHO([])
 974     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 975     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 976     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 977     AS_ECHO([])
 978     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 979 ])
 980
 981
 982 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 983 dnl ================================================
 984 dnl Local Variables:
 985 dnl compile-command: "autoconf"
 986 dnl End: