configure.in

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.65.0)
  19
  20 AM_PROG_LIBTOOL
  21
  22 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  23 # Turn around -rpath problem with libtool 1.0c
  24 # This define should be improbable enough to not conflict with anything
  25 case ${host} in
  26   *-pc-linux-gnu)
  27     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  28     sed < libtool > libtool-2 \
  29     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  30     mv libtool-2 libtool
  31     chmod 755 libtool
  32   ;;
  33 esac
  34
  35
  36 AM_CONFIG_HEADER(src/config.h)
  37
  38
  39 dnl Checks for host/os name
  40 dnl =======================
  41 AC_CANONICAL_HOST
  42
  43
  44 dnl Checks for programs.
  45 dnl ===================
  46 AC_ISC_POSIX
  47 AC_PROG_CC
  48 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  49 #AC_PROG_RANLIB
  50 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  51 AC_PROG_LN_S
  52 AC_PROG_GCC_TRADITIONAL
  53
  54
  55 dnl the prefix
  56 dnl ==========
  57 dnl
  58 dnl move this earlier in the script... anyone know why this is handled
  59 dnl in such a bizarre way?
  60
  61 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  62 dnl Let make expand exec_prefix.
  63 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  64
  65
  66 _bindir=`eval echo $bindir`
  67 _bindir=`eval echo $_bindir`
  68
  69 _libdir=`eval echo $libdir`
  70 _libdir=`eval echo $_libdir`
  71 lib_search_path="-L$_libdir"
  72
  73 inc_search_path=`eval echo $includedir`
  74 inc_search_path="-I`eval echo $inc_search_path`"
  75
  76
  77 dnl
  78 dnl Check for RedHat bugs
  79 dnl =====================
  80
  81 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  82
  83
  84 dnl
  85 dnl Specify paths to look for libraries and headers
  86 dnl ===============================================
  87 AC_ARG_WITH(libs-from,
  88 [  --with-libs-from       pass compiler flags to look for libraries],
  89         [lib_search_path="$withval $lib_search_path"])
  90
  91 AC_ARG_WITH(incs-from,
  92 [  --with-incs-from       pass compiler flags to look for header files],
  93         [inc_search_path="$withval $inc_search_path"])
  94
  95
  96
  97 dnl Checks for library functions.
  98 dnl ============================
  99 dnl not used anywhere
 100 dnl AC_FUNC_MEMCMP
 101 AC_FUNC_VPRINTF
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp setpgid atexit mallinfo)
 104
 105
 106
 107 dnl Loading of dynamic libraries at runtime
 108 dnl =======================================
 109 DLLIBS=""
 110
 111 AC_CHECK_FUNC(dlopen, [HAVEDL="yes"],
 112         AC_CHECK_LIB(dl, dlopen, [DLLIBS="-ldl" HAVEDL="yes"],
 113                          DLLIBS="" ))
 114
 115 if test "x$HAVEDL" = xyes; then
 116     AC_CHECK_HEADERS(dlfcn.h)
 117 fi
 118
 119
 120
 121 dnl Check CPP
 122 dnl =========
 123 if test "x$CPP_PATH" = x; then
 124     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 125                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 126 fi
 127
 128 dnl
 129 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 130 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 131 dnl standard locations
 132 dnl
 133 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 134     if test "$GCC" = "yes"; then
 135         CPP_PATH="gcc -E -x c"
 136     else
 137         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 138             CPP_PATH="$CPP_PATH -B"
 139         else
 140             echo "cpp, the C preprocessor was not found in your system."
 141             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 142             exit
 143         fi
 144     fi
 145 fi
 146 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH")
 147
 148
 149
 150 dnl Checks for header files.
 151 dnl =======================
 152 dnl AC_HEADER_STDC
 153 AC_HEADER_SYS_WAIT
 154 AC_HEADER_TIME
 155 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h\
 156                 libintl.h sys/select.h poll.h malloc.h)
 157
 158
 159
 160 dnl Checks for typedefs, structures, and compiler characteristics.
 161 dnl ==============================================================
 162 AC_DECL_SYS_SIGLIST
 163 AC_C_CONST
 164 #AC_TYPE_SIZE_T
 165 #AC_TYPE_PID_T
 166 AC_TYPE_SIGNAL
 167
 168
 169
 170 dnl gettext
 171 dnl =======
 172
 173
 174 dnl AM_GNU_GETTEXT
 175
 176
 177
 178 INTLIBS=""
 179
 180 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 181         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 182                          INTLIBS="" ))
 183
 184 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 185
 186 if test "$XGETTEXT" != ""; then
 187     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 188         echo "xgettext isn't GNU version"
 189         XGETTEXT=""
 190     fi
 191 fi
 192
 193 if test "$LINGUAS" != ""; then
 194     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 195         AC_DEFINE(I18N)
 196         PO=""
 197 #       if test "$LINGUAS" = ""; then
 198 #           ling=` (cd src/po; /bin/ls *.po) `
 199 #           for l in $ling; do
 200 #               lcode=`basename $l .po`
 201 #               LINGUAS="$LINGUAS $lcode"
 202 #           done
 203 #       fi
 204         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 205     else
 206         LINGUAS=""
 207         PO=""
 208         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 209     fi
 210 else
 211         INTLIBS=""
 212         MOFILES=""
 213         WPMOFILES=""
 214         PO=""
 215 fi
 216
 217
 218 dnl The Tower of Babel
 219 dnl ==================
 220
 221 dnl List of supported locales
 222 dnl -------------------------
 223 supported_locales="cs de es et fr gl it ja ko nl no pt ru sv tr fi hr el pl ro da zh_TW.Big5 zh_CN sk bg hu"
 224 supported_wprefs_locales="pt hr fr ko ja cs zh_TW.Big5 es zh_CN fi it ru de bg hu sk"
 225
 226 for lang in $LINGUAS; do
 227         ok=0
 228         for l in $supported_locales; do
 229                 if test "$l" = "$lang"; then
 230                         ok=1
 231                         break
 232                 fi
 233         done
 234         if test "$ok" = 1; then
 235                 MOFILES="$MOFILES $lang.mo"
 236         else
 237                 echo "Locale $lang is not supported."
 238         fi
 239         ok=0
 240         for l in $supported_wprefs_locales; do
 241                 if test "$l" = "$lang"; then
 242                         ok=1
 243                         break
 244                 fi
 245         done
 246         if test "$ok" = 1; then
 247                 WPMOFILES="$WPMOFILES $lang.mo"
 248         fi
 249 done
 250
 251
 252 dnl Kanji Characters support
 253 dnl ========================
 254
 255 case $host_os in
 256         freebsd*)
 257                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 258         *)
 259         ;;
 260 esac
 261
 262
 263
 264 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 265 dnl ===========================================
 266 AC_ARG_WITH(nlsdir,
 267         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 268
 269
 270 if test "x$NLSDIR" = "x"; then
 271         if test "x$with_nlsdir" != "x"; then
 272                 NLSDIR=$with_nlsdir
 273         else
 274                 NLSDIR='$(prefix)/lib/locale'
 275         fi
 276 fi
 277
 278
 279
 280 AC_SUBST(DLLIBS)
 281 AC_SUBST(INTLIBS)
 282 AC_SUBST(NLSDIR)
 283 AC_SUBST(MOFILES)
 284 AC_SUBST(WPMOFILES)
 285 AC_SUBST(supported_locales)
 286
 287
 288
 289 dnl Support for various hint things
 290 dnl ===============================
 291
 292
 293 AC_ARG_ENABLE(gnome,
 294   [  --enable-gnome       enable stuff needed for GNOME ],
 295   [if test x$enableval = xyes; then
 296     AC_DEFINE(GNOME_STUFF)
 297     gnome_on=yes
 298   fi])
 299
 300
 301 AC_ARG_ENABLE(kde,
 302   [  --enable-kde                 enable support for KDE window manager (kwm) hints ],
 303   [if test x$enableval = xyes; then
 304     AC_DEFINE(KWM_HINTS)
 305     kde_on=yes
 306   fi])
 307
 308
 309 AC_ARG_ENABLE(openlook,
 310   [  --enable-openlook    enable support for OPEN LOOK(tm) (olwm) hints ],
 311   [if test x$enableval = xyes; then
 312     AC_DEFINE(OLWM_HINTS)
 313     openlook_on=yes
 314   fi])
 315
 316
 317 dnl
 318 dnl Disable some stuff that are duplicated in kde
 319 dnl ---------------------------------------------
 320 AC_ARG_ENABLE(lite,
 321   [  --enable-lite                disable some stuff (dont use it) ],
 322   [if test x$enableval = xyes; then
 323         LITE=yes
 324         AC_DEFINE(LITE)
 325         AC_SUBST(LITE)
 326   fi])
 327
 328
 329
 330 dnl
 331 dnl Networking stuff
 332 dnl
 333
 334 NETLIBS=""
 335
 336 AC_CHECK_FUNC(connect,,
 337         AC_CHECK_LIB(socket, connect, NETLIBS="$NETLIBS -lsocket"))
 338
 339 AC_CHECK_FUNC(gethostbyname,,
 340         AC_CHECK_LIB(nsl, gethostbyname, NETLIBS="$NETLIBS -lnsl"))
 341
 342 AC_CHECK_FUNC(inet_aton, AC_DEFINE(HAVE_INET_ATON),
 343      for lib in resolv socket inet bsd; do
 344         AC_CHECK_LIB($lib, inet_aton, [AC_DEFINE(HAVE_INET_ATON)
 345                      NETLIBS="$NETLIBS -l$lib"; break],, $NETLIBS)
 346      done)
 347
 348 AC_SUBST(NETLIBS)
 349
 350
 351 dnl ===========================================
 352 dnl             Stuff that uses X
 353 dnl ===========================================
 354
 355 AC_PATH_XTRA
 356
 357 if test $no_x; then
 358     AC_MSG_ERROR([The path for the X11 files not found!
 359 Make sure you have X and it's headers and libraries (the -devel packages
 360 in Linux) installed.])
 361 fi
 362
 363 X_LIBRARY_PATH=$x_libraries
 364
 365 XCFLAGS="$X_CFLAGS"
 366
 367 XLFLAGS="$X_LIBS"
 368
 369 XLIBS="-lX11 $X_EXTRA_LIBS"
 370
 371
 372 lib_search_path="$lib_search_path $XLFLAGS"
 373 inc_search_path="$inc_search_path $XCFLAGS"
 374
 375
 376 AC_SUBST(X_LIBRARY_PATH)
 377
 378
 379
 380 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 381 dnl by MANOME Tomonori
 382 dnl ===========================================
 383 use_locale=yes
 384 AC_ARG_ENABLE(locale,
 385 [  --disable-locale       disable use of X locale support],
 386                 use_locale=no)
 387
 388 if test "$use_locale" = yes; then
 389   AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE),, $XLFLAGS $XLIBS)
 390 fi
 391
 392
 393 dnl Check whether XInternAtoms() exist
 394 dnl ==================================
 395 AC_CHECK_LIB(X11, XInternAtoms, AC_DEFINE(HAVE_XINTERNATOMS),,$XLFLAGS $XLIBS)
 396
 397
 398 dnl XKB keyboard language status
 399 dnl ============================
 400 AC_ARG_ENABLE(modelock,
 401 [  --enable-modelock      XKB keyboard language status support],
 402                 AC_DEFINE(XKB_MODELOCK))
 403
 404
 405
 406 dnl Shape support
 407 dnl =============
 408 shape=yes
 409 AC_ARG_ENABLE(shape,
 410 [  --disable-shape        disable shaped window extension support],
 411                 shape=$enableval, shape=yes)
 412
 413 added_xext=no
 414
 415 if test "$shape" = yes; then
 416         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 417                 added_xext=yes
 418                 AC_DEFINE(SHAPE)], shape=no, $XLFLAGS $XLIBS)
 419 fi
 420
 421
 422 dnl XINERAMA support
 423 dnl ================
 424 xinerama=yes
 425 AC_ARG_ENABLE(xinerama,
 426 [  --disable-xinerama     disable XInerama extension support],
 427                 xinerama=$enableval, xinerama=yes)
 428
 429 if test "$xinerama" = yes; then
 430         AC_CHECK_LIB(Xext, XineramaQueryScreens, [XLIBS="-lXext $XLIBS"
 431                 added_xext=yes
 432                 AC_DEFINE(XINERAMA)], xinerama=no, $XLFLAGS $XLIBS)
 433 fi
 434
 435
 436
 437 dnl MIT-SHM support
 438 dnl ===============
 439 shm=yes
 440 AC_ARG_ENABLE(shm,
 441 [  --disable-shm           disable usage of MIT-SHM extension],
 442                 shm=$enableval, shm=yes)
 443
 444 if test "$shm" = yes; then
 445         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 446
 447         if test "$ok" = yes; then
 448         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 449         fi
 450
 451         if test "$ok" = yes; then
 452                 if test "$added_xext" = no; then
 453                         XLIBS="-lXext $XLIBS"
 454                 fi
 455                 AC_DEFINE(XSHM)
 456         fi
 457 fi
 458
 459
 460 dnl R6 Style Session Management Support
 461 dnl ===================================
 462
 463 #
 464 #
 465 #AC_DEFINE(R6SM)
 466 #AC_SUBST(XSMPLIBS)
 467 #
 468
 469
 470 dnl Check for libPropList
 471 dnl =====================
 472
 473 LIBPL=""
 474
 475 WM_CHECK_LIB(PropList, PLGetString, $X_EXTRA_LIBS)
 476 if test "x$ac_cv_lib_PropList_PLGetString" = xyes; then
 477     WM_CHECK_HEADER(proplist.h)
 478     if test "x$ac_cv_header_proplist_h" = xyes; then
 479         LIBPL="-lPropList"
 480     fi
 481 fi
 482
 483 if test "x$LIBPL" = "x"; then
 484    echo
 485    echo "ERROR!!! libPropList is not installed, or could not be found."
 486    echo "         Window Maker requires libPropList to build."
 487    echo "         Please read INSTALL to find where you can find libPropList,"
 488    echo "         and install it first."
 489    if test x$host_os = xlinux; then
 490    echo "         If you're using some prepackaged version of libPropList,"
 491    echo "         make sure you install it's \"development\" package as well."
 492    fi
 493    echo "         If you already have it installed, try using the"
 494    if test "x$ac_cv_lib_PropList_PLGetString" != xyes; then
 495    echo "         --with-libs-from flag to tell configure where the library"
 496    echo "         is installed and"
 497    fi
 498    echo "         --with-incs-from flag to tell configure where the header"
 499    echo "         files are installed"
 500    exit 1
 501 fi
 502
 503 lPLVersion="0.10.1"
 504
 505 WM_CHECK_PROPLIST_VERSION($lPLVersion, goodlPL=yes, goodlPL=no)
 506
 507 if test "$goodlPL" = no; then
 508    echo
 509    echo "ERROR!!! libPropList is an old version. Please consider upgrading"
 510    echo "         to at least version ${lPLVersion}. Older versions have bugs that"
 511    echo "         may cause Window Maker to crash randomly."
 512    echo "         If your libPropList is older than 0.9.2 it will also prevent"
 513    echo "         Window Maker from compiling because new functions were"
 514    echo "         introduced since that version."
 515    echo "         Please read INSTALL to find where you can find libPropList,"
 516    echo "         and upgrade it before you proceed."
 517    exit 1
 518 fi
 519
 520 AC_SUBST(LIBPL)
 521
 522
 523 dnl ==============================================
 524 dnl         Graphic Format Libraries
 525 dnl ==============================================
 526
 527
 528
 529
 530
 531 dnl XPM Support
 532 dnl ===========
 533 xpm=yes
 534 AC_ARG_ENABLE(xpm,
 535 [  --disable-xpm                  disable use of XPM pixmaps through libXpm],
 536         xpm=$enableval, xpm=yes)
 537
 538 if test "$xpm" = yes; then
 539     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 540
 541     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 542         WM_CHECK_HEADER(X11/xpm.h)
 543         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 544                 GFXLIBS="$GFXLIBS -lXpm"
 545                 supported_gfx="XPM"
 546                 AC_DEFINE(USE_XPM)
 547         else
 548                 supported_gfx="builtin-XPM"
 549         fi
 550     fi
 551 fi
 552
 553 # for wmlib
 554 AC_SUBST(XCFLAGS)
 555 # for test
 556 AC_SUBST(XLFLAGS)
 557 AC_SUBST(XLIBS)
 558
 559 AC_SUBST(X_EXTRA_LIBS)
 560
 561 dnl ===============================================
 562 dnl             End of stuff that uses X
 563 dnl ===============================================
 564
 565
 566
 567 dnl Hermes Support
 568 dnl ==============
 569
 570 AC_ARG_ENABLE(hermes,
 571   [  --disable-hermes     disable Hermes support for wrlib ],
 572      hermes=$enableval, hermes=yes)
 573
 574 if test x$hermes = xyes; then
 575    WM_CHECK_LIB(Hermes, Hermes_ConverterRequest, [])
 576
 577    if test x$ac_cv_lib_Hermes_Hermes_ConverterRequest = xyes; then
 578       WM_CHECK_HEADER(Hermes/Hermes.h)
 579       if test x$ac_cv_header_Hermes_Hermes_h = xyes; then
 580          GFXLIBS="$GFXLIBS -lHermes"
 581          AC_DEFINE(HAVE_HERMES)
 582          hermes_support=yes
 583       fi
 584    fi
 585 fi
 586
 587
 588
 589 dnl PNG Support
 590 dnl ===========
 591 png=yes
 592 AC_ARG_ENABLE(png,
 593 [  --disable-png                  disable PNG support through libpng],
 594         png=$enableval, png=yes, png=no)
 595
 596
 597 if test "$png" = yes ; then
 598     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 599
 600     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 601         WM_CHECK_HEADER(png.h)
 602         if test "x$ac_cv_header_png_h" = xyes; then
 603             GFXLIBS="$GFXLIBS -lpng -lz"
 604             supported_gfx="$supported_gfx PNG"
 605             AC_DEFINE(USE_PNG)
 606         fi
 607     fi
 608 fi
 609
 610
 611 dnl JPEG Support
 612 dnl ============
 613 jpeg=yes
 614 ljpeg=""
 615 AC_ARG_ENABLE(jpeg,
 616 [  --disable-jpeg         disable JPEG support through libjpeg],
 617         jpeg=$enableval, jpeg=yes, jpeg=no)
 618
 619 if test "$jpeg" = yes; then
 620     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 621
 622     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 623
 624         ljpeg="-ljpeg"
 625
 626         WM_CHECK_HEADER(jpeglib.h)
 627         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 628             GFXLIBS="$GFXLIBS -ljpeg"
 629             supported_gfx="$supported_gfx JPEG"
 630             AC_DEFINE(USE_JPEG)
 631         fi
 632     fi
 633 fi
 634
 635
 636 dnl GIF Support
 637 dnl ============
 638 gif=yes
 639 AC_ARG_ENABLE(gif,
 640 [  --disable-gif           disable GIF support through libgif or libungif],
 641         gif=$enableval, gif=yes, gif=no)
 642
 643 if test "$gif" = yes; then
 644     my_libname=""
 645     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 646     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 647         my_libname=-lungif
 648     fi
 649 dnl
 650 dnl libungif is the same thing as libgif for all practical purposes.
 651 dnl
 652     if test "x$my_libname" = x; then
 653         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 654         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 655             my_libname=-lgif
 656         fi
 657     fi
 658
 659     if test "$my_libname" != x; then
 660         WM_CHECK_HEADER(gif_lib.h)
 661         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 662             GFXLIBS="$GFXLIBS $my_libname"
 663             supported_gfx="$supported_gfx GIF"
 664             AC_DEFINE(USE_GIF)
 665         fi
 666     fi
 667 fi
 668
 669
 670
 671 dnl TIFF Support
 672 dnl ============
 673 AC_ARG_ENABLE(tiff,
 674 [  --disable-tiff         disable use of TIFF images through libtiff],
 675         tif=$enableval, tif=yes, tif=no)
 676
 677 #
 678 # TIFF can optionally have JPEG and/or zlib support. Must find out
 679 # when they are supported so that correct library flags are passed during
 680 # detection and linkage
 681 #
 682 #
 683 # By default use xpm icons if tiff is not found.
 684 ICONEXT="xpm"
 685 #
 686
 687 if test "$tif" = yes; then
 688     my_libname=""
 689     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 690     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 691         my_libname="-ltiff"
 692     fi
 693 dnl
 694 dnl Retry with zlib
 695 dnl
 696     unset ac_cv_lib_tiff_TIFFGetVersion
 697     if test "x$my_libname" = x; then
 698         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 699         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 700             my_libname="-ltiff -lz"
 701         fi
 702     fi
 703
 704     if test "x$my_libname" = x; then
 705         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 706         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 707             my_libname="-ltiff34"
 708         fi
 709     fi
 710
 711
 712     if test "x$my_libname" != x; then
 713         WM_CHECK_HEADER(tiffio.h)
 714         if test "x$ac_cv_header_tiffio_h" = xyes; then
 715             GFXLIBS="$my_libname $GFXLIBS"
 716             ICONEXT="tiff"
 717             supported_gfx="$supported_gfx TIFF"
 718             AC_DEFINE(USE_TIFF)
 719         fi
 720     fi
 721 fi
 722
 723 LIBRARY_SEARCH_PATH="$lib_search_path"
 724 HEADER_SEARCH_PATH="$inc_search_path"
 725
 726 AC_SUBST(LIBRARY_SEARCH_PATH)
 727 AC_SUBST(HEADER_SEARCH_PATH)
 728
 729
 730 AC_SUBST(GFXLIBS)
 731 AC_SUBST(ICONEXT)
 732
 733
 734 dnl ==============================================
 735 dnl         End of Graphic Format Libraries
 736 dnl ==============================================
 737
 738
 739 # AC_PREFIX_PROGRAM(wmaker)
 740
 741 dnl Support for PIXMAPDIR option
 742 dnl ============================
 743 AC_ARG_WITH(pixmapdir,
 744 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 745
 746 if test "x$with_pixmapdir" != "x"; then
 747         pixmapdir=$with_pixmapdir
 748 else
 749         pixmapdir=`eval echo ${datadir}/pixmaps`
 750 fi
 751
 752 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir")
 753
 754 pkgdatadir=`eval echo $datadir`
 755 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker")
 756
 757 _sysconfdir=`eval echo $sysconfdir`
 758 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir")
 759
 760
 761 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 762 dnl ==============================================
 763
 764 appspath=""
 765
 766 AC_ARG_WITH(appspath,
 767 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 768
 769 if test "x$appspath" = "x"; then
 770     gnustepdir='$(prefix)/GNUstep'
 771
 772     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 773         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 774         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 775     fi
 776
 777     with_appspath=$gnustepdir/Apps
 778 fi
 779
 780 wprefsdir=$with_appspath/WPrefs.app
 781
 782 AC_SUBST(wprefsdir)
 783
 784
 785 dnl Enable User Defined Menu thing
 786 dnl ==================================
 787 AC_ARG_ENABLE(usermenu,
 788 [  --enable-usermenu       user defined menus for applications
 789 ],
 790 if test "$enableval" = yes; then
 791         AC_DEFINE(USER_MENU)
 792 fi
 793 )
 794
 795
 796 dnl
 797 dnl Nicolai:  Program tests for Documentation Section
 798 dnl =================================================
 799 dnl DOCTYPES=""
 800 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 801 dnl if test "x$MAKEINFO" != "x" ; then
 802 dnl       DOCTYPES="$DOCTYPES info_doc"
 803 dnl fi
 804 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 805 dnl if test "x$TEX" != "x" ; then
 806 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 807 dnl fi
 808 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 809 dnl if test "x$DVIPS" != "x" ; then
 810 dnl       DOCTYPES="$DOCTYPES ps_doc"
 811 dnl fi
 812 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 813 dnl if test "x$PERL" != "x" ; then
 814 dnl       DOCTYPES="$DOCTYPES html_doc"
 815 dnl fi
 816 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 817 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 818
 819 dnl AC_SUBST(DOCTYPES)
 820
 821 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile \
 822         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 823         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 824         WINGs/Extras/Makefile \
 825         wmlib/Makefile wrlib/Makefile src/Makefile src/wconfig.h doc/Makefile \
 826         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 827         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 828         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 829         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 830         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 831         WPrefs.app/po/Makefile \
 832         contrib/Makefile contrib/WindowMaker.spec )
 833 #       plugins/Makefile plugins/libwmfun/Makefile)
 834
 835
 836
 837 dnl
 838 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 839 dnl ===================================================================
 840 dnl
 841
 842 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 843 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 844 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 845
 846 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 847 dnl parsed by m4
 848
 849 cat <<EOF >get-wraster-flags
 850 #!/bin/sh
 851
 852 prefix="$prefix"
 853 exec_prefix=\$prefix
 854
 855 WCFLAGS="-I\$prefix/include $inc_search_path"
 856 WLFLAGS="-L\$exec_prefix/lib $lib_search_path"
 857 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 858
 859 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 860
 861 if test \$# -eq 0; then
 862       echo "\${usage}" 1>&2
 863       exit 1
 864 fi
 865
 866 while test \$# -gt 0; do
 867   case \$1 in
 868     --cflags)
 869         echo \$WCFLAGS
 870         ;;
 871     --ldflags|--lflags)
 872         echo \$WLFLAGS
 873         ;;
 874     --libs)
 875         echo \$WLIBS
 876         ;;
 877     *)
 878         echo "\${usage}" 1>&2
 879         exit 1
 880         ;;
 881   esac
 882   shift
 883 done
 884
 885
 886 EOF
 887
 888 cat <<EOF >get-wings-flags
 889 #!/bin/sh
 890
 891 prefix="$prefix"
 892 exec_prefix=\$prefix
 893
 894 WCFLAGS="-I\$prefix/include $inc_search_path"
 895 WLFLAGS="-L\$exec_prefix/lib $lib_search_path"
 896 WLIBS="-lWINGs -lwraster $GFXLIBS $XLIBS -lm $NETLIBS -lPropList"
 897
 898 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 899
 900 if test \$# -eq 0; then
 901       echo "\${usage}" 1>&2
 902       exit 1
 903 fi
 904
 905 while test \$# -gt 0; do
 906   case \$1 in
 907     --cflags)
 908         echo \$WCFLAGS
 909         ;;
 910     --ldflags|--lflags)
 911         echo \$WLFLAGS
 912         ;;
 913     --libs)
 914         echo \$WLIBS
 915         ;;
 916     *)
 917         echo "\${usage}" 1>&2
 918         exit 1
 919         ;;
 920   esac
 921   shift
 922 done
 923
 924
 925 EOF
 926
 927 cat <<EOF >get-wutil-flags
 928 #!/bin/sh
 929
 930 prefix="$prefix"
 931 exec_prefix=\$prefix
 932
 933 WCFLAGS="-I\$prefix/include $inc_search_path"
 934 WLFLAGS="-L\$exec_prefix/lib $lib_search_path"
 935 WLIBS="-lWUtil $NETLIBS -lPropList"
 936
 937 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 938
 939 if test \$# -eq 0; then
 940       echo "\${usage}" 1>&2
 941       exit 1
 942 fi
 943
 944 while test \$# -gt 0; do
 945   case \$1 in
 946     --cflags)
 947         echo \$WCFLAGS
 948         ;;
 949     --ldflags|--lflags)
 950         echo \$WLFLAGS
 951         ;;
 952     --libs)
 953         echo \$WLIBS
 954         ;;
 955     *)
 956         echo "\${usage}" 1>&2
 957         exit 1
 958         ;;
 959   esac
 960   shift
 961 done
 962
 963
 964 EOF
 965
 966 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
 967 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
 968 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
 969
 970 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
 971
 972 rm -f get-wraster-flags get-wings-flags get-wutil-flags
 973
 974
 975 dnl
 976 dnl Spit out the configuration
 977 dnl ==========================
 978
 979 supported_gfx="$supported_gfx builtin-PPM"
 980
 981 if test "x$MOFILES" = "x"; then
 982         mof=none
 983 else
 984         mof=$MOFILES
 985 fi
 986
 987
 988 echo
 989 echo "Window Maker was configured as follows:"
 990 echo
 991 echo "Installation path prefix: $prefix"
 992 echo "Installation path prefix for binaries: $_bindir"
 993 echo "Installation path for WPrefs.app: $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
 994 echo "Graphic format libraries: $supported_gfx"
 995 if test x$hermes_support = xyes; then
 996     echo "Hermes support for wrlib enabled"
 997 fi
 998 dnl echo "Sound support: yes"
 999 echo "Translated message files to install: $mof"
1000 if test "x$MOFILES" != "x"; then
1001         echo "Installation path of translated messages: $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
1002 fi
1003
1004 dnl WM_PRINT_REDCRAP_BUG_STATUS
1005
1006 if test "x$ac_cv_header_jpeglib_h" != xyes; then
1007 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1008 echo
1009 echo "JPEG support will not be included because the JPEG library is"
1010 echo "not installed correctly or was not found. Background images"
1011 echo "from themes will not display as they usually are JPEG files."
1012 echo
1013 echo "To fix, download and install the jpeg library and/or make sure you"
1014 echo "installed all jpeg related packages, SPECIALLY the development packages"
1015 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
1016 echo
1017 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1018 fi
1019
1020
1021 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1022 dnl ================================================
1023 dnl Local Variables:
1024 dnl compile-command: "autoconf"
1025 dnl End:
1026