configure.ac

   1 dnl ============================================================================
   2 dnl
   3 dnl Window Maker autoconf input
   4 dnl
   5 AC_COPYRIGHT([Copyright (c) 2001-2015 The Window Maker Team])
   6 dnl
   7 dnl ============================================================================
   8 dnl
   9 dnl This program is free software; you can redistribute it and/or modify
  10 dnl it under the terms of the GNU General Public License as published by
  11 dnl the Free Software Foundation; either version 2 of the License, or
  12 dnl (at your option) any later version.
  13 dnl
  14 dnl This program is distributed in the hope that it will be useful,
  15 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 dnl GNU General Public License for more details.
  18 dnl
  19 dnl You should have received a copy of the GNU General Public License along
  20 dnl with this program; see the file COPYING.
  21 dnl
  22 dnl ============================================================================
  23 dnl
  24 dnl Process with: ./autogen.sh
  25
  26
  27 dnl Due to a bug in Autoconf 2.68 (apparently a regression), we need at least
  28 dnl version 2.68b which includes this patch:
  29 dnl   http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commit;h=2b0d95faef68d7ed7c08b0edb9ff1c38728376fa
  30 dnl
  31 dnl Because the 2.69 was released only a few month later, let's just ask for it
  32 AC_PREREQ([2.69])
  33
  34
  35 dnl Configuration for Autoconf and Automake
  36 dnl =======================================
  37 AC_INIT([WindowMaker],[0.95.6],[wmaker-dev@lists.windowmaker.org],[WindowMaker],[http://www.windowmaker.org/])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_HEADERS([config.h])
  40 AM_INIT_AUTOMAKE([1.11 silent-rules])
  41
  42 dnl Reference file used by 'configure' to make sure the path to sources is valid
  43 AC_CONFIG_SRCDIR([src/WindowMaker.h])
  44
  45 dnl Include at the end of 'config.h', this file is generated by top-level Makefile
  46 AH_BOTTOM([@%:@include "config-paths.h"])
  47
  48
  49 dnl libtool library versioning
  50 dnl ==========================
  51 dnl
  52 dnl current
  53 dnl revision
  54 dnl age
  55 dnl
  56 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  57 dnl 2. Update the version information only immediately before a public
  58 dnl release of your software. More frequent updates are unnecessary, and
  59 dnl only guarantee that the current interface number gets larger faster.
  60 dnl 3. If the library source code has changed at all since the last
  61 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  62 dnl 4. If any interfaces have been added, removed, or changed since the
  63 dnl last update, increment current, and set revision to 0.
  64 dnl 5. If any interfaces have been added since the last public release,
  65 dnl then increment age.
  66 dnl 6. If any interfaces have been removed or changed since the last
  67 dnl public release, then set age to 0.
  68 dnl
  69 dnl libwraster
  70 WRASTER_CURRENT=5
  71 WRASTER_REVISION=0
  72 WRASTER_AGE=0
  73 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  74 AC_SUBST(WRASTER_VERSION)
  75 dnl
  76 dnl libWINGs
  77 WINGS_CURRENT=4
  78 WINGS_REVISION=0
  79 WINGS_AGE=1
  80 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  81 AC_SUBST(WINGS_VERSION)
  82 dnl
  83 dnl libWUtil
  84 WUTIL_CURRENT=5
  85 WUTIL_REVISION=0
  86 WUTIL_AGE=0
  87 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  88 AC_SUBST(WUTIL_VERSION)
  89
  90
  91 dnl Checks for programs
  92 dnl ===================
  93 AC_PROG_CC
  94 WM_PROG_CC_C11
  95 AC_PROG_LN_S
  96 AC_PROG_GCC_TRADITIONAL
  97 LT_INIT
  98
  99
 100 dnl Debugging Options
 101 dnl =================
 102 AC_ARG_ENABLE([debug],
 103     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
 104     [AS_CASE(["$enableval"],
 105         [yes], [debug=yes],
 106         [no],  [debug=no],
 107         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
 108     [debug=no])
 109 AS_IF([test "x$debug" = "xyes"],
 110     [dnl This flag should have already been detected and added, but if user
 111      dnl provided an explicit CFLAGS it may not be the case
 112      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
 113            [@%:@ Debug symbol already activated],
 114            [AX_CFLAGS_GCC_OPTION([-g])])
 115      dnl
 116      dnl This flag generally makes debugging nightmarish, remove it if present
 117      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
 118      dnl
 119      dnl Enable internal debug code
 120      CPPFLAGS="$CPPFLAGS -DDEBUG"
 121 ],  [dnl
 122      dnl When debug is not enabled, the user probably does not wants to keep
 123      dnl assertions in the final program
 124      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 125 ])
 126
 127
 128 AX_CFLAGS_GCC_OPTION([-Wall])
 129 AX_CFLAGS_GCC_OPTION([-Wextra -Wno-sign-compare])
 130 dnl
 131 dnl The use of trampolines cause code that can crash on some secured OS, it is
 132 dnl also known to be a source of crash if not used properly, in a more general
 133 dnl way it tends to generate binary code that may not be optimal, and it is
 134 dnl not compatible with the 'nested-func-to-macro' workaround
 135 WM_CFLAGS_CHECK_FIRST([-Wtrampolines],
 136          [-Werror=trampolines  dnl try to generate an error if possible
 137           -Wtrampolines        dnl if not, try to fall back to a simple warning
 138          ])
 139 dnl
 140 AS_IF([test "x$debug" = "xyes"],
 141     [dnl When debug is enabled, we try to activate more checks from
 142      dnl the compiler. They are on independant check because the
 143      dnl macro checks all the options at once, but we may have cases
 144      dnl where some options are not supported and we don't want to
 145      dnl loose all of them.
 146      dnl
 147      dnl clang, suggest parenthesis on bit operations that could be
 148      dnl misunderstood due to C operator precedence
 149      AX_CFLAGS_GCC_OPTION([-Wbitwise-op-parentheses])
 150      dnl
 151      dnl Points at code that gcc thinks is so complicated that gcc
 152      dnl gives up trying to optimize, which probably also means it is
 153      dnl too complicated to maintain
 154      AX_CFLAGS_GCC_OPTION([-Wdisabled-optimization])
 155      dnl
 156      dnl Floating-point comparison is not a good idea
 157      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 158      dnl
 159      dnl clang warns about constants that may have portability issues due
 160      dnl to the endianness of the host
 161      AX_CFLAGS_GCC_OPTION([-Wfour-char-constants])
 162      dnl
 163      dnl clang warns about constant that may be too big to be portable
 164      AX_CFLAGS_GCC_OPTION([-Wliteral-range])
 165      dnl
 166      dnl Try to report misuses of '&' versus '&&' and similar
 167      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 168      dnl
 169      dnl clang, reports cases where the code assumes everyone is an
 170      dnl expert in C operator precedence... which is unlikely!
 171      AX_CFLAGS_GCC_OPTION([-Wlogical-op-parentheses])
 172      dnl
 173      dnl Reports declaration of global things that are done inside
 174      dnl a local environment, instead of using the appropriate
 175      dnl header
 176      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 177      dnl
 178      dnl Warn about constant strings that could pose portability issues
 179      AX_CFLAGS_GCC_OPTION([-Woverlength-strings])
 180      dnl
 181      dnl Use of 'sizeof()' on inappropriate pointer types
 182      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 183      dnl
 184      dnl Having more than 1 prototype for a function makes code updates
 185      dnl more difficult, so try to avoid it
 186      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 187      dnl
 188      dnl clang, detect some misuses of sizeof. We also count in our code
 189      dnl on the use of the macro 'wlength' which contains a check if the
 190      dnl compiler support C11's static_assert
 191      AX_CFLAGS_GCC_OPTION([-Wsizeof-array-argument])
 192      dnl
 193      dnl Prototype of function must be explicit, no deprecated K&R syntax
 194      dnl and no empty argument list which prevents compiler from doing
 195      dnl type checking when using the function
 196      WM_CFLAGS_GCC_OPTION_STRICTPROTO
 197      dnl
 198      dnl Proper attributes helps the compiler to produce better code
 199      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 200          [-Wsuggest-attribute=format  dnl new gcc syntax
 201           -Wmissing-format-attribute  dnl old gcc syntax, clang
 202          ])
 203      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 204          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 205           -Wmissing-noreturn            dnl clang syntax
 206          ])
 207      dnl
 208      dnl GCC provides a couple of checks to detect incorrect macro uses
 209      AX_CFLAGS_GCC_OPTION([-Wundef])
 210      WM_CFLAGS_GCC_OPTION_UNUSEDMACROS
 211      dnl
 212      dnl clang reports stuff marked unused but which is actually used
 213      AX_CFLAGS_GCC_OPTION([-Wused-but-marked-unused])
 214 ], [dnl
 215      dnl When debug not enabled, we try to avoid some non-necessary
 216      dnl messages from the compiler
 217      dnl
 218      dnl To support legacy X servers, we have sometime to use
 219      dnl functions marked as deprecated. We do not wish our users
 220      dnl to be worried about it
 221      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 222      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 223 ])
 224
 225
 226 dnl Support for Nested Functions by the compiler
 227 dnl ============================================
 228 WM_PROG_CC_NESTEDFUNC
 229
 230
 231 dnl Posix thread
 232 dnl ============
 233 dnl they are used by util/wmiv
 234 AX_PTHREAD
 235
 236
 237 dnl Tracking on what is detected for final status
 238 dnl =============================================
 239 unsupported=""
 240 supported_core=""
 241 supported_xext=""
 242 supported_gfx=""
 243
 244
 245 dnl Platform-specific Makefile setup
 246 dnl ================================
 247 AS_CASE(["$host"],
 248     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 249     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 250     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 251     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 252     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 253     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 254     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 255     [WM_OSDEP="stub"])
 256 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 257 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 258 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 259 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 260
 261
 262 dnl the prefix
 263 dnl ==========
 264 dnl
 265 dnl move this earlier in the script... anyone know why this is handled
 266 dnl in such a bizarre way?
 267
 268 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 269 dnl Let make expand exec_prefix.
 270 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 271
 272
 273 _bindir=`eval echo $bindir`
 274 _bindir=`eval echo $_bindir`
 275
 276 lib_search_path='-L${libdir}'
 277
 278 inc_search_path='-I${includedir}'
 279
 280 dnl ===============================================
 281 dnl Specify paths to look for libraries and headers
 282 dnl ===============================================
 283 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 284         [lib_search_path="$withval $lib_search_path"])
 285
 286 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 287         [inc_search_path="$withval $inc_search_path"])
 288
 289
 290 dnl Features Configuration
 291 dnl ======================
 292 AC_ARG_ENABLE([animations],
 293     [AS_HELP_STRING([--disable-animations], [disable permanently animations @<:@default=enabled@:>@])],
 294     [AS_CASE(["$enableval"],
 295         [yes|no], [],
 296         [AC_MSG_ERROR([bad value $enableval for --enable-animations])])],
 297     [enable_animations="yes"])
 298 AS_IF([test "x$enable_animations" = "xno"],
 299     [unsupported="$unsupported Animations"],
 300     [AC_DEFINE([USE_ANIMATIONS], [1], [Defined when user did not request to disable animations])
 301      supported_core="$supported_core Animations"])
 302
 303
 304 AC_ARG_ENABLE([mwm-hints],
 305     [AS_HELP_STRING([--disable-mwm-hints], [disable support for Motif WM hints @<:@default=enabled@:>@])],
 306     [AS_CASE(["$enableval"],
 307         [yes|no], [],
 308         [AC_MSG_ERROR([bad value $enableval for --enable-mwm-hints])])],
 309     [enable_mwm_hints="yes"])
 310 AS_IF([test "x$enable_mwm_hints" = "xno"],
 311     [unsupported="$unsupported MWMHints"],
 312     [AC_DEFINE([USE_MWM_HINTS], [1], [Defined when used did not request to disable Motif WM hints])
 313      supported_core="$supported_core MWMHints"])
 314 AM_CONDITIONAL([USE_MWM_HINTS], [test "x$enable_mwm_hints" != "xno"])
 315
 316
 317 dnl Boehm GC
 318 dnl ========
 319 AC_ARG_ENABLE([boehm-gc],
 320     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 321     [AS_CASE(["$enableval"],
 322         [yes], [with_boehm_gc=yes],
 323         [no],  [with_boehm_gc=no],
 324         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 325     [with_boehm_gc=no])
 326 AS_IF([test "x$with_boehm_gc" = "xyes"],
 327     AC_SEARCH_LIBS([GC_malloc], [gc],
 328         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 329         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 330
 331
 332 dnl LCOV
 333 dnl ====
 334 AC_ARG_ENABLE([lcov],
 335     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 336     [],
 337     [enable_lcov=no])
 338
 339 AS_IF([test "x$enable_lcov" != "xno"],
 340     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 341     AS_IF([test "x$enable_lcov" = "xyes"],
 342         [lcov_output_directory="coverage-report"],
 343         [lcov_output_directory="${enable_lcov}/coverage-report"])
 344     AC_SUBST(lcov_output_directory)])
 345
 346 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 347
 348
 349 dnl ============================
 350 dnl Checks for library functions
 351 dnl ============================
 352 AC_FUNC_MEMCMP
 353 AC_FUNC_VPRINTF
 354 WM_FUNC_SECURE_GETENV
 355 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 356                setsid mallinfo mkstemp sysconf)
 357 AC_SEARCH_LIBS([strerror], [cposix])
 358
 359 dnl nanosleep is generally available in standard libc, although not always the
 360 dnl case. One known example is Solaris which needs -lrt
 361 AC_SEARCH_LIBS([nanosleep], [rt], [],
 362     [AC_MSG_ERROR([function 'nanosleep' not found, please report to wmaker-dev@lists.windowmaker.org])])
 363
 364 dnl the flag 'O_NOFOLLOW' for 'open' is used in WINGs
 365 WM_FUNC_OPEN_NOFOLLOW
 366
 367
 368 dnl Check for strlcat/strlcpy
 369 dnl =========================
 370 AC_ARG_WITH([libbsd],
 371   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 372   [AS_IF([test "x$with_libbsd" != "xno"],
 373     [with_libbsd=bsd]
 374     [with_libbsd=]
 375   )],
 376   [with_libbsd=bsd])
 377
 378 tmp_libs=$LIBS
 379 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 380   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 381   [],
 382   []
 383 )
 384 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 385   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 386   [],
 387   []
 388 )
 389 LIBS=$tmp_libs
 390
 391 LIBBSD=
 392 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 393   [LIBBSD=-lbsd
 394    AC_CHECK_HEADERS([bsd/string.h])]
 395 )
 396 AC_SUBST(LIBBSD)
 397
 398
 399 dnl Check for OpenBSD kernel memory interface - kvm(3)
 400 dnl ==================================================
 401 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 402   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 403
 404
 405 dnl Check for inotify
 406 dnl =================
 407 dnl It is used by WindowMaker to reload automatically the configuration when the
 408 dnl user changed it using WPref or wdwrite
 409 AC_CHECK_HEADERS([sys/inotify.h],
 410     [AC_DEFINE([HAVE_INOTIFY], [1], [Check for inotify])])
 411
 412
 413 dnl Check for syslog
 414 dnl ================
 415 dnl It is used by WUtil to log the wwarning, werror and wfatal
 416 AC_CHECK_HEADERS([syslog.h], [AC_DEFINE([HAVE_SYSLOG], [1], [Check for syslog])])
 417
 418
 419 dnl Checks for header files
 420 dnl =======================
 421 AC_HEADER_SYS_WAIT
 422 AC_HEADER_TIME
 423 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 424                  string.h strings.h)
 425
 426
 427 dnl Checks for typedefs, structures, and compiler characteristics
 428 dnl =============================================================
 429 AC_C_CONST
 430 AC_C_INLINE
 431 WM_C_NORETURN
 432 AC_TYPE_SIZE_T
 433 AC_TYPE_PID_T
 434 WM_TYPE_SIGNAL
 435
 436
 437 dnl pkg-config
 438 dnl ==========
 439 AC_CHECK_PROG([PKGCONFIG], [pkg-config], [pkg-config])
 440
 441
 442
 443 dnl Internationalization
 444 dnl ====================
 445 dnl Detect the language for translations to be installed and check
 446 dnl that the gettext environment works
 447 WM_I18N_LANGUAGES
 448 WM_I18N_XGETTEXT
 449 WM_I18N_MENUTEXTDOMAIN
 450
 451 dnl 2014/12/29: The option is deprecated, we should keep this message for at
 452 dnl least 2 years to ensure users see it and update their build scripts
 453 AC_ARG_WITH([nlsdir], [],
 454     [AC_MSG_ERROR([option '--with-nlsdir' is deprecated, please use autoconf's standard '--localedir' instead])])
 455
 456
 457 dnl ===========================================
 458 dnl             Stuff that uses X
 459 dnl ===========================================
 460
 461 AC_PATH_XTRA
 462
 463 AS_IF([test "x$no_x" = "xyes"],
 464     [AC_MSG_ERROR([The path for the X11 files not found!
 465 Make sure you have X and it's headers and libraries (the -devel packages
 466 in Linux) installed.])])
 467
 468 X_LIBRARY_PATH=$x_libraries
 469 XCFLAGS="$X_CFLAGS"
 470 XLFLAGS="$X_LIBS"
 471 XLIBS="-lX11 $X_EXTRA_LIBS"
 472
 473 lib_search_path="$lib_search_path $XLFLAGS"
 474 inc_search_path="$inc_search_path $XCFLAGS"
 475
 476 AC_SUBST(X_LIBRARY_PATH)
 477
 478
 479 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 480 dnl by MANOME Tomonori
 481 dnl ===========================================
 482 WM_I18N_XLOCALE
 483
 484
 485
 486 dnl Check whether XInternAtoms() exist
 487 dnl ==================================
 488 AC_CHECK_LIB([X11], [XInternAtoms],
 489     [AC_DEFINE([HAVE_XINTERNATOMS], [1],
 490         [define if your X server has XInternAtoms() (set by configure)])],
 491     [], [$XLFLAGS $XLIBS])
 492
 493
 494 dnl Check whether XConvertCase() exist
 495 dnl ==================================
 496 AC_CHECK_LIB([X11], [XConvertCase],
 497     [AC_DEFINE([HAVE_XCONVERTCASE], [1],
 498         [define if your X server has XConvertCase() (set by configure)])],
 499     [], [$XLFLAGS $XLIBS])
 500
 501
 502 dnl XKB keyboard language status
 503 dnl ============================
 504 AC_ARG_ENABLE([modelock],
 505     [AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support])],
 506     [AS_CASE([$enableval],
 507         [yes|no], [],
 508         [AC_MSG_ERROR([bad value '$enableval' for --enable-modelock])])],
 509     [enable_modelock=no])
 510 AS_IF([test "x$enable_modelock" = "xyes"],
 511     [AC_DEFINE([XKB_MODELOCK], [1], [whether XKB language MODELOCK should be enabled]) ])
 512
 513
 514 dnl XDND Drag-nd-Drop support
 515 dnl =========================
 516 AC_ARG_ENABLE([xdnd],
 517     [AS_HELP_STRING([--disable-xdnd], [disable support for Drag-and-Drop on the dock @<:@default=enabled@:>@])],
 518     [AS_CASE(["$enableval"],
 519         [yes|no], [],
 520         [AC_MSG_ERROR([bad value $enableval for --disable-xdnd]) ]) ],
 521     [enable_xdnd=yes])
 522 AS_IF([test "x$enable_xdnd" = "xyes"],
 523     [supported_core="$supported_core XDnD"
 524      AC_DEFINE([USE_DOCK_XDND], [1], [whether Drag-and-Drop on the dock should be enabled])],
 525     [unsupported="$unsupported XDnd"])
 526 AM_CONDITIONAL([USE_DOCK_XDND], [test "x$enable_dock_xdnd" != "xno"])
 527
 528
 529 dnl XShape support
 530 dnl ==============
 531 AC_ARG_ENABLE([shape],
 532     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 533     [AS_CASE(["$enableval"],
 534         [yes|no], [],
 535         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 536     [enable_shape=auto])
 537 WM_XEXT_CHECK_XSHAPE
 538
 539
 540 dnl MIT-SHM support
 541 dnl ===============
 542 AC_ARG_ENABLE([shm],
 543     [AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension])],
 544     [AS_CASE(["$enableval"],
 545         [yes|no], [],
 546         [AC_MSG_ERROR([bad value $enableval for --enable-shm]) ]) ],
 547     [enable_shm=auto])
 548 WM_XEXT_CHECK_XSHM
 549
 550
 551 dnl X Misceleanous Utility
 552 dnl ======================
 553 dnl the libXmu is used in WRaster
 554 WM_EXT_CHECK_XMU
 555
 556
 557 dnl XINERAMA support
 558 dnl ================
 559 AC_ARG_ENABLE([xinerama],
 560     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 561     [AS_CASE(["$enableval"],
 562         [yes|no], [],
 563         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 564     [enable_xinerama=auto])
 565 WM_XEXT_CHECK_XINERAMA
 566
 567
 568 dnl RandR support
 569 dnl =============
 570 AC_ARG_ENABLE([randr],
 571     [AS_HELP_STRING([--enable-randr], [enable RandR extension support (NOT recommended, buggy)])],
 572     [AS_CASE(["$enableval"],
 573         [yes|no], [],
 574         [AC_MSG_ERROR([bad value $enableval for --enable-randr]) ]) ],
 575     [enable_randr=no])
 576 WM_XEXT_CHECK_XRANDR
 577
 578
 579 dnl Math library
 580 dnl ============
 581 dnl libWINGS uses math functions, check whether usage requires linking
 582 dnl against libm
 583 WM_CHECK_LIBM
 584
 585
 586 dnl FontConfig
 587 dnl ==========
 588 dnl libWINGS uses FcPatternDel from libfontconfig
 589 AC_MSG_CHECKING([for fontconfig library])
 590 FCLIBS=`$PKGCONFIG fontconfig --libs`
 591 if test "x$FCLIBS" = "x" ; then
 592         AC_MSG_RESULT([not found])
 593 else
 594         AC_MSG_RESULT([found])
 595 fi
 596 AC_SUBST(FCLIBS)
 597
 598
 599 dnl Xft2 antialiased font support
 600 dnl =============================
 601
 602 xft=yes
 603 XFTLIBS=""
 604
 605 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 606         XFTCONFIG="$PKGCONFIG xft"
 607         pkgconfig_xft=yes
 608 else
 609         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 610 fi
 611
 612 AC_MSG_CHECKING([for the Xft2 library])
 613
 614 if test "x$XFTCONFIG" != x; then
 615         XFTLIBS=`$XFTCONFIG --libs`
 616         XFTFLAGS=`$XFTCONFIG --cflags`
 617         AC_MSG_RESULT([found])
 618 else
 619         AC_MSG_RESULT([not found])
 620         echo
 621         echo "ERROR!!! libXft2 is not installed or could not be found."
 622         echo "         Xft2 is a requirement for building Window Maker."
 623         echo "         Please install it (along with fontconfig) before continuing."
 624         echo
 625         exit 1
 626 fi
 627
 628 minXFT="2.1.0"
 629 goodxft="no"
 630
 631 dnl
 632 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 633 dnl
 634 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 635
 636 if test "$goodxft" = no; then
 637         echo
 638         echo "ERROR!!! libXft on this system is an old version."
 639         echo "         Please consider upgrading to at least version ${minXFT}."
 640         echo
 641         exit 1
 642 fi
 643
 644 AC_SUBST(XFTFLAGS)
 645 AC_SUBST(XFTLIBS)
 646
 647 dnl PANGO support
 648 dnl =============
 649 pango=no
 650 AC_ARG_ENABLE(pango, AS_HELP_STRING([--enable-pango], [enable Pango text layout support]),
 651                 pango=$enableval, pango=no)
 652
 653 PANGOFLAGS=
 654 PANGOLIBS=
 655 if test "$pango" = yes; then
 656         PANGOLIBS=`$PKGCONFIG pangoxft --libs`
 657         PANGOFLAGS=`$PKGCONFIG pangoxft --cflags`
 658         if test "x$PANGOLIBS" = "x" ; then
 659                 AC_MSG_RESULT([not found])
 660         else
 661                 AC_DEFINE(USE_PANGO, 1, [Define if Pango is to be used])
 662                 AC_MSG_RESULT([found])
 663         fi
 664 fi
 665 inc_search_path="$inc_search_path $PANGOFLAGS"
 666 AC_SUBST(PANGOLIBS)
 667
 668 dnl ==============================================
 669 dnl         Graphic Format Libraries
 670 dnl ==============================================
 671
 672 dnl XPM Support
 673 dnl ===========
 674 AC_ARG_ENABLE([xpm],
 675     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 676     [AS_CASE(["$enableval"],
 677         [yes|no], [],
 678         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 679     [enable_xpm=auto])
 680 WM_IMGFMT_CHECK_XPM
 681
 682
 683 # for wmlib
 684 AC_SUBST(XCFLAGS)
 685 # for test
 686 AC_SUBST(XLFLAGS)
 687 AC_SUBST(XLIBS)
 688 AC_SUBST(X_EXTRA_LIBS)
 689
 690 dnl ===============================================
 691 dnl             End of stuff that uses X
 692 dnl ===============================================
 693
 694 dnl EXIF Support
 695 dnl ============
 696 WM_CHECK_LIBEXIF
 697 AS_IF([test "x$LIBEXIF" != "x"],
 698         [AC_DEFINE(HAVE_EXIF, 1, [Define if EXIF can be used])])
 699
 700
 701 dnl PNG Support
 702 dnl ===========
 703 AC_ARG_ENABLE([png],
 704     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 705     [AS_CASE(["$enableval"],
 706         [yes|no], [],
 707         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 708     [enable_png=auto])
 709 WM_IMGFMT_CHECK_PNG
 710
 711
 712 dnl JPEG Support
 713 dnl ============
 714 AC_ARG_ENABLE([jpeg],
 715     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 716     [AS_CASE(["$enableval"],
 717         [yes|no], [],
 718         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 719     [enable_jpeg=auto])
 720 WM_IMGFMT_CHECK_JPEG
 721
 722
 723 dnl GIF Support
 724 dnl ============
 725 AC_ARG_ENABLE(gif,
 726     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 727     [AS_CASE(["$enableval"],
 728         [yes|no], [],
 729         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 730     [enable_gif=auto])
 731 WM_IMGFMT_CHECK_GIF
 732
 733
 734 dnl TIFF Support
 735 dnl ============
 736 AC_ARG_ENABLE([tiff],
 737     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 738     [AS_CASE(["$enableval"],
 739         [yes|no], [],
 740         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 741     [enable_tiff=auto])
 742 WM_IMGFMT_CHECK_TIFF
 743
 744
 745 dnl WEBP Support
 746 dnl ============
 747 AC_ARG_ENABLE([webp],
 748     [AS_HELP_STRING([--disable-webp], [disable WEBP support through libwebp])],
 749     [AS_CASE(["$enableval"],
 750         [yes|no], [],
 751         [AC_MSG_ERROR([bad value $enableval for --enable-webp])] )],
 752     [enable_webp=auto])
 753 WM_IMGFMT_CHECK_WEBP
 754
 755
 756 dnl MagicK Support
 757 dnl ==============
 758 AC_ARG_ENABLE([magick],
 759     [AS_HELP_STRING([--disable-magick], [disable MAGICK support through libMagickWand])],
 760     [AS_CASE(["$enableval"],
 761         [yes|no], [],
 762         [AC_MSG_ERROR([bad value $enableval for --enable-magick])] )],
 763     [enable_magick=auto])
 764 WM_IMGFMT_CHECK_MAGICK
 765
 766
 767 dnl PPM Support
 768 dnl ===========
 769 # The PPM format is always enabled because we have built-in support for the format
 770 # We are not using any external library like libppm
 771 supported_gfx="$supported_gfx builtin-PPM"
 772
 773
 774 # Choice of the default format for icons
 775 AS_IF([test "x$enable_tiff" != "xno"],
 776     [ICONEXT="tiff"],
 777     [ICONEXT="xpm"])
 778
 779
 780 LIBRARY_SEARCH_PATH="$lib_search_path"
 781 HEADER_SEARCH_PATH="$inc_search_path"
 782
 783 AC_SUBST(LIBRARY_SEARCH_PATH)
 784 AC_SUBST(HEADER_SEARCH_PATH)
 785
 786
 787 AC_SUBST(GFXLIBS)
 788 AC_SUBST(ICONEXT)
 789 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 790 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 791
 792
 793 dnl ==============================================
 794 dnl         End of Graphic Format Libraries
 795 dnl ==============================================
 796
 797
 798 dnl
 799 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 800 AC_CHECK_HEADERS(stdlib.h)
 801
 802
 803 dnl Support for PIXMAPDIR option
 804 dnl ============================
 805 AC_ARG_WITH([pixmapdir],
 806     [AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]])],
 807     [AS_CASE([$withval],
 808         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-pixmapdir, expected a path]) ],
 809         [/*],  [], dnl Absolute path, ok
 810         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 811         [AC_MSG_ERROR([bad path '$withval' for pixmapdir, expecting an absolute path])])],
 812     [with_pixmapdir=""])
 813
 814 AS_IF([test "x$with_pixmapdir" != "x"],
 815     [pixmapdir="$with_pixmapdir"],
 816     [pixmapdir='${datadir}/pixmaps'])
 817 AC_SUBST([pixmapdir])dnl
 818
 819
 820 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 821 dnl ==============================================
 822 AC_ARG_WITH([gnustepdir],
 823     [AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications])],
 824     [AS_CASE([$withval],
 825         [yes|no], [AC_MSG_ERROR([bad value '$withval' for --with-gnustepdir, expected a path]) ],
 826         [/*],  [], dnl Absolute path, ok
 827         [\$*], [], dnl Assumes it starts with a reference to $prefix or a similar variable, ok
 828         [AC_MSG_ERROR([bad path '$withval' for gnustepdir, expecting an absolute path])])],
 829     [dnl If no command-line option was given, we use $GNUSTEP_LOCAL_ROOT if it was set
 830      with_gnustepdir="$GNUSTEP_LOCAL_ROOT"])
 831
 832 AS_IF([test "x$with_gnustepdir" = "x"],
 833     [dnl No path specified, use default
 834      wprefs_base_dir=${prefix}
 835      wprefs_datadir="${datadir}/WPrefs"
 836      wprefs_bindir="${bindir}"],
 837     [dnl User specified base path
 838      wprefs_base_dir="$with_gnustepdir/Applications"
 839      wprefs_datadir="$wprefs_base_dir/WPrefs.app"
 840      wprefs_bindir="$wprefs_base_dir/WPrefs.app"])
 841 AC_SUBST([wprefs_datadir])dnl
 842 AC_SUBST([wprefs_bindir])dnl
 843
 844
 845 dnl Enable User Defined Menu thing
 846 dnl ==============================
 847 AC_ARG_ENABLE([usermenu],
 848     [AS_HELP_STRING([--enable-usermenu], [user defined menus for applications])],
 849     [AS_CASE([$enableval],
 850         [yes|no], [],
 851         [AC_MSG_ERROR([bad value '$enableval' for --enable-usermenu])])],
 852     [enable_usermenu=no])
 853 AS_IF([test "x$enable_usermenu" = "xyes"],
 854     [AC_DEFINE([USER_MENU], [1],
 855         [define if you want user defined menus for applications])])
 856
 857
 858 dnl Support for removing non-public symbols from a library
 859 dnl ======================================================
 860 gl_LD_VERSION_SCRIPT
 861
 862
 863 dnl Add the post-poned compilation options
 864 dnl ======================================
 865 WM_CFLAGS_GCC_OPTION_POSTPONED
 866
 867
 868 AC_SUBST(lib_search_path)
 869 AC_SUBST(inc_search_path)
 870
 871
 872 dnl Spit out the configuration
 873 dnl ==========================
 874 AC_CONFIG_FILES(
 875     Makefile
 876
 877     dnl WRaster Library
 878     wrlib/Makefile
 879     wrlib/tests/Makefile
 880
 881     dnl WINGs toolkit
 882     WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
 883     WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
 884     WINGs/Examples/Makefile WINGs/Tests/Makefile
 885
 886     dnl Window Maker's core
 887     src/Makefile src/wconfig.h po/Makefile
 888     doc/Makefile doc/build/Makefile
 889     doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
 890     WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
 891     WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
 892     WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
 893     WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
 894
 895     dnl Preference GUI
 896     WPrefs.app/Makefile WPrefs.app/po/Makefile
 897     WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
 898
 899     dnl Command-line utilities
 900     util/Makefile util/po/Makefile
 901
 902     dnl Misceleanous stuff
 903     wmlib/Makefile
 904     test/Makefile
 905 )
 906
 907 AC_OUTPUT
 908
 909
 910 dnl Provide a summary of the config
 911 dnl ===============================
 912 echo
 913 echo "Window Maker was configured as follows:"
 914 echo
 915 echo "Installation path prefix            : $prefix"
 916 echo "Installation path for binaries      : $_bindir"
 917 echo "Installation path for libraries     : $libdir"
 918 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 919 echo "Supported core features:            :$supported_core"
 920 echo "Supported X extensions:             :$supported_xext"
 921 echo "Supported graphic format libraries  :$supported_gfx"
 922 echo "Unsupported features                :$unsupported"
 923 echo "Antialiased text support in WINGs   : $xft"
 924 echo "Pango text layout support in WINGs  : $pango"
 925 echo "Translated languages to support     :$supported_locales"
 926 AS_IF([test "x$debug" = "xyes"],
 927     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 928 echo
 929
 930 AS_IF([test "x$wm_cv_prog_cc_nestedfunc" != "xyes"],
 931     [AC_MSG_WARN([[Your compiler does not support Nested Function, work-around enabled]])])
 932
 933 AS_IF([test "x$supported_locales" = "x"],
 934     [AC_MSG_WARN([[No language from \$LINGUAS are supported]])])
 935
 936 AS_IF([test "x$enable_jpeg" = xno], [dnl
 937     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 938     AS_ECHO([])
 939     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 940     AS_ECHO(["not installed correctly or was not found. Background images"])
 941     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 942     AS_ECHO([])
 943     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 944     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 945     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 946     AS_ECHO([])
 947     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 948 ])
 949
 950
 951 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 952 dnl ================================================
 953 dnl Local Variables:
 954 dnl compile-command: "autoconf"
 955 dnl End: