configure.in

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with: aclocal; autoconf; automake
   5 dnl
   6 dnl
   7
   8
   9 AC_INIT(src/WindowMaker.h)
  10
  11
  12
  13 AM_INIT_AUTOMAKE(WindowMaker, 0.51.2)
  14
  15 AM_PROG_LIBTOOL
  16
  17 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  18 # Turn around -rpath problem with libtool 1.0c
  19 # This define should be improbable enough to not conflict with anything
  20 case ${host} in
  21   *-pc-linux-gnu)
  22     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  23     sed < libtool > libtool-2 \
  24     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  25     mv libtool-2 libtool
  26     chmod 755 libtool
  27   ;;
  28 esac
  29
  30
  31
  32 AM_CONFIG_HEADER(src/config.h)
  33
  34
  35 dnl Checks for host/os name
  36 dnl =======================
  37 AC_CANONICAL_HOST
  38
  39
  40 dnl Checks for programs.
  41 dnl ===================
  42 AC_ISC_POSIX
  43 AC_PROG_CC
  44 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  45 #AC_PROG_RANLIB
  46 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  47 AC_PROG_LN_S
  48 AC_PROG_GCC_TRADITIONAL
  49
  50
  51 dnl the prefix
  52 dnl ==========
  53 dnl
  54 dnl move this earlier in the script... anyone know why this is handled
  55 dnl in such a bizarre way?
  56
  57 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  58 dnl Let make expand exec_prefix.
  59 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  60
  61
  62 _bindir=`eval echo $bindir`
  63 _bindir=`eval echo $_bindir`
  64
  65 _libdir=`eval echo $libdir`
  66 _libdir=`eval echo $_libdir`
  67 lib_search_path="-L$_libdir"
  68
  69 inc_search_path=`eval echo $includedir`
  70 inc_search_path="-I`eval echo $inc_search_path`"
  71
  72
  73 dnl
  74 dnl Check for RedHat bugs
  75 dnl =====================
  76
  77 WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  78
  79
  80 dnl
  81 dnl Specify paths to look for libraries and headers
  82 dnl ===============================================
  83 AC_ARG_WITH(libs-from,
  84 [  --with-libs-from       pass compiler flags to look for libraries],
  85         [lib_search_path="$withval $lib_search_path"])
  86
  87 AC_ARG_WITH(incs-from,
  88 [  --with-incs-from       pass compiler flags to look for header files],
  89         [inc_search_path="$withval $inc_search_path"])
  90
  91
  92
  93 dnl Checks for library functions.
  94 dnl ============================
  95 dnl not used anywhere
  96 dnl AC_FUNC_MEMCMP
  97 AC_FUNC_VPRINTF
  98 AC_FUNC_ALLOCA
  99 AC_CHECK_FUNCS(gethostname select poll strerror strncasecmp setpgid atexit)
 100
 101 if test "x$CPP_PATH" = x; then
 102     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 103                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 104 fi
 105
 106 dnl
 107 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 108 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 109 dnl standard locations
 110 dnl
 111 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 112     if test "$GCC" = "yes"; then
 113         CPP_PATH="gcc -E -x c"
 114     else
 115         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 116             CPP_PATH="$CPP_PATH -B"
 117         else
 118             echo "cpp, the C preprocessor was not found in your system."
 119             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 120             exit
 121         fi
 122     fi
 123 fi
 124 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH")
 125
 126
 127
 128 dnl Checks for header files.
 129 dnl =======================
 130 dnl AC_HEADER_STDC
 131 AC_HEADER_SYS_WAIT
 132 AC_HEADER_TIME
 133 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h\
 134                 libintl.h sys/select.h poll.h)
 135
 136
 137
 138 dnl Checks for typedefs, structures, and compiler characteristics.
 139 dnl ==============================================================
 140 AC_DECL_SYS_SIGLIST
 141 AC_C_CONST
 142 #AC_TYPE_SIZE_T
 143 #AC_TYPE_PID_T
 144 AC_TYPE_SIGNAL
 145
 146
 147 dnl gettext
 148 dnl =======
 149
 150
 151 dnl AM_GNU_GETTEXT
 152
 153
 154
 155 INTLIBS=""
 156
 157
 158 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 159         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 160                          INTLIBS="" ))
 161
 162 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 163
 164 if test "$XGETTEXT" != ""; then
 165     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 166         echo "xgettext isn't GNU version"
 167         XGETTEXT=""
 168     fi
 169 fi
 170
 171 if test "$LINGUAS" != ""; then
 172     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 173         AC_DEFINE(I18N)
 174         PO=""
 175 #       if test "$LINGUAS" = ""; then
 176 #           ling=` (cd src/po; /bin/ls *.po) `
 177 #           for l in $ling; do
 178 #               lcode=`basename $l .po`
 179 #               LINGUAS="$LINGUAS $lcode"
 180 #           done
 181 #       fi
 182         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 183     else
 184         LINGUAS=""
 185         PO=""
 186         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 187     fi
 188 else
 189         INTLIBS=""
 190         MOFILES=""
 191         WPMOFILES=""
 192         PO=""
 193 fi
 194
 195
 196 dnl The Tower of Babel
 197 dnl ==================
 198
 199 dnl List of supported locales
 200 dnl -------------------------
 201 supported_locales="cs de es fr gl it ja ko nl no pt ru se tr fi hr el pl ro dk zh_TW.Big5"
 202 supported_wprefs_locales="pt hr fr ko ja cs zh_TW.Big5"
 203
 204 for lang in $LINGUAS; do
 205         ok=0
 206         for l in $supported_locales; do
 207                 if test "$l" = "$lang"; then
 208                         ok=1
 209                         break
 210                 fi
 211         done
 212         if test "$ok" = 1; then
 213                 MOFILES="$MOFILES $lang.mo"
 214         else
 215                 echo "Locale $lang is not supported."
 216         fi
 217         ok=0
 218         for l in $supported_wprefs_locales; do
 219                 if test "$l" = "$lang"; then
 220                         ok=1
 221                         break
 222                 fi
 223         done
 224         if test "$ok" = 1; then
 225                 WPMOFILES="$WPMOFILES $lang.mo"
 226         fi
 227 done
 228
 229
 230 dnl Kanji Characters support
 231 dnl ========================
 232 I18n=no
 233 AC_ARG_ENABLE(kanji,
 234 [  --enable-kanji         multibyte character support (kanji, Korean etc.)],,
 235                 enable_kanji=no)
 236
 237 if test "$enable_kanji" = yes; then
 238         case $host_os in
 239         freebsd*)
 240                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 241         *)
 242                 ;;
 243         esac
 244         AC_DEFINE(I18N_MB)
 245 fi
 246
 247
 248
 249 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 250 dnl ===========================================
 251 AC_ARG_WITH(nlsdir,
 252         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 253
 254
 255 if test "x$NLSDIR" = "x"; then
 256         if test "x$with_nlsdir" != "x"; then
 257                 NLSDIR=$with_nlsdir
 258         else
 259                 NLSDIR='$(prefix)/lib/locale'
 260         fi
 261 fi
 262
 263 AC_SUBST(INTLIBS)
 264 AC_SUBST(NLSDIR)
 265 AC_SUBST(MOFILES)
 266 AC_SUBST(WPMOFILES)
 267
 268
 269
 270 dnl Support for various hint things
 271 dnl ===============================
 272
 273
 274 AC_ARG_ENABLE(gnome,
 275   [  --enable-gnome       enable stuff needed for GNOME ],
 276   [if test x$enableval = xyes; then
 277     AC_DEFINE(GNOME_STUFF)
 278     gnome_on=yes
 279   fi])
 280
 281
 282 AC_ARG_ENABLE(kde,
 283   [  --enable-kde                 enable support for KDE window manager (kwm) hints ],
 284   [if test x$enableval = xyes; then
 285     AC_DEFINE(KWM_HINTS)
 286     kde_on=yes
 287   fi])
 288
 289
 290 AC_ARG_ENABLE(openlook,
 291   [  --enable-openlook    enable support for OPEN LOOK(tm) (olwm) hints ],
 292   [if test x$enableval = xyes; then
 293     AC_DEFINE(OLWM_HINTS)
 294     openlook_on=yes
 295   fi])
 296
 297
 298 dnl
 299 dnl Disable some stuff that are duplicated in kde
 300 dnl ---------------------------------------------
 301 AC_ARG_ENABLE(lite,
 302   [  --enable-lite                disable stuff duplicated in KDE/GNOME ],
 303   [if test x$enableval = xyes; then
 304         LITE=yes
 305         AC_DEFINE(LITE)
 306         AC_SUBST(LITE)
 307   fi])
 308
 309
 310
 311 dnl ===========================================
 312 dnl             Stuff that uses X
 313 dnl ===========================================
 314
 315 AC_PATH_XTRA
 316
 317 XCFLAGS="$X_CFLAGS"
 318
 319 XLFLAGS="$X_LIBS"
 320
 321 XLIBS="-lX11 $X_EXTRA_LIBS"
 322
 323
 324 lib_search_path="$lib_search_path $XLFLAGS"
 325 inc_search_path="$inc_search_path $XCFLAGS"
 326
 327
 328 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 329 dnl by MANOME Tomonori
 330 dnl ===========================================
 331 use_locale=yes
 332 AC_ARG_ENABLE(locale,
 333 [  --disable-locale       disable use of X locale support],
 334                 use_locale=no)
 335
 336 if test "$use_locale" = yes; then
 337   AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE),, $XLFLAGS $XLIBS)
 338 fi
 339
 340
 341 dnl XKB keyboard language status
 342 dnl ============================
 343 AC_ARG_ENABLE(modelock,
 344 [  --enable-modelock      XKB keyboard language status support],
 345                 X_CFLAGS="$X_CFLAGS -DXKB_MODELOCK",)
 346
 347
 348
 349 dnl Shape support
 350 dnl =============
 351 shape=yes
 352 AC_ARG_ENABLE(shape,
 353 [  --disable-shape        disable shaped window extension support],
 354                 shape=$enableval, shape=yes)
 355
 356 added_xext=no
 357
 358 if test "$shape" = yes; then
 359         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 360                 added_xext=yes
 361                 AC_DEFINE(SHAPE)], shape=no, $XLFLAGS $XLIBS)
 362 fi
 363
 364
 365 dnl MIT-SHM support
 366 dnl ===============
 367 shm=yes
 368 AC_ARG_ENABLE(shm,
 369 [  --disable-shm           disable usage of MIT-SHM extension],
 370                 shm=$enableval, shm=yes)
 371
 372 if test "$shm" = yes; then
 373         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 374
 375         if test "$ok" = yes; then
 376         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 377         fi
 378
 379         if test "$ok" = yes; then
 380                 if test "$added_xext" = no; then
 381                         XLIBS="-lXext $XLIBS"
 382                 fi
 383                 AC_DEFINE(XSHM)
 384         fi
 385 fi
 386
 387
 388 dnl R6 Style Session Management Support
 389 dnl ===================================
 390
 391 #
 392 #
 393 #AC_DEFINE(R6SM)
 394 #AC_SUBST(XSMPLIBS)
 395 #
 396
 397
 398 dnl Check for libPropList
 399 dnl =====================
 400
 401 LIBPL=""
 402
 403 WM_CHECK_LIB(PropList, PLGetString, $X_EXTRA_LIBS)
 404 if test "x$ac_cv_lib_PropList_PLGetString" = xyes; then
 405     WM_CHECK_HEADER(proplist.h)
 406     if test "x$ac_cv_header_proplist_h" = xyes; then
 407         LIBPL="-lPropList"
 408     fi
 409 fi
 410
 411 if test "x$LIBPL" = "x"; then
 412    echo
 413    echo "ERROR!!! libPropList is not installed, or could not be found."
 414    echo "         Window Maker requires libPropList to build."
 415    echo "         Please read INSTALL to find where you can find libPropList,"
 416    echo "         and install it first."
 417    echo "         If you already have it installed, try using the"
 418    if test "x$ac_cv_lib_PropList_PLGetString" != xyes; then
 419    echo "         --with-libs-from flag to tell configure where the library"
 420    echo "         is installed and"
 421    fi
 422    echo "         --with-incs-from flag to tell configure where the header"
 423    echo "         files are installed"
 424    exit 1
 425 fi
 426
 427
 428 AC_SUBST(LIBPL)
 429
 430
 431 dnl ==============================================
 432 dnl         Graphic Format Libraries
 433 dnl ==============================================
 434
 435
 436
 437
 438
 439 dnl XPM Support
 440 dnl ===========
 441 xpm=yes
 442 AC_ARG_ENABLE(xpm,
 443 [  --disable-xpm                  disable use of XPM pixmaps through libXpm],
 444         xpm=$enableval, xpm=yes)
 445
 446 if test "$xpm" = yes; then
 447     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 448
 449     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 450         WM_CHECK_HEADER(X11/xpm.h)
 451         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 452                 GFXLIBS="$GFXLIBS -lXpm"
 453                 supported_gfx="XPM"
 454                 AC_DEFINE(USE_XPM)
 455         else
 456                 supported_gfx="builtin-XPM"
 457         fi
 458     fi
 459 fi
 460
 461 # for wmlib
 462 AC_SUBST(XCFLAGS)
 463 # for test
 464 AC_SUBST(XLFLAGS)
 465 AC_SUBST(XLIBS)
 466
 467 AC_SUBST(X_EXTRA_LIBS)
 468
 469 dnl ===============================================
 470 dnl             End of stuff that uses X
 471 dnl ===============================================
 472
 473
 474 dnl PNG Support
 475 dnl ===========
 476 png=yes
 477 AC_ARG_ENABLE(png,
 478 [  --disable-png                  disable PNG support through libpng],
 479         png=$enableval, png=yes, png=no)
 480
 481
 482 if test "$png" = yes ; then
 483     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 484
 485     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 486         WM_CHECK_HEADER(png.h)
 487         if test "x$ac_cv_header_png_h" = xyes; then
 488             GFXLIBS="$GFXLIBS -lpng -lz"
 489             supported_gfx="$supported_gfx PNG"
 490             AC_DEFINE(USE_PNG)
 491         fi
 492     fi
 493 fi
 494
 495
 496 dnl JPEG Support
 497 dnl ============
 498 jpeg=yes
 499 AC_ARG_ENABLE(jpeg,
 500 [  --disable-jpeg         disable JPEG support through libjpeg],
 501         jpeg=$enableval, jpeg=yes, jpeg=no)
 502
 503 if test "$jpeg" = yes; then
 504     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 505
 506     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 507         WM_CHECK_HEADER(jpeglib.h)
 508         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 509             GFXLIBS="$GFXLIBS -ljpeg"
 510             supported_gfx="$supported_gfx JPEG"
 511             AC_DEFINE(USE_JPEG)
 512         fi
 513     fi
 514 fi
 515
 516
 517 dnl GIF Support
 518 dnl ============
 519 gif=yes
 520 AC_ARG_ENABLE(gif,
 521 [  --disable-gif           disable GIF support through libgif or libungif],
 522         gif=$enableval, gif=yes, gif=no)
 523
 524 if test "$gif" = yes; then
 525     my_libname=""
 526     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 527     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 528         my_libname=ungif
 529     fi
 530 dnl
 531 dnl libungif is the same thing as libgif for all practical purposes.
 532 dnl
 533     if test "x$my_libname" = x; then
 534         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 535         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 536             my_libname=gif
 537         fi
 538     fi
 539
 540     if test "$my_libname" != x; then
 541         WM_CHECK_HEADER(gif_lib.h)
 542         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 543             GFXLIBS="$GFXLIBS -l$my_libname"
 544             supported_gfx="$supported_gfx GIF"
 545             AC_DEFINE(USE_GIF)
 546         fi
 547     fi
 548 fi
 549
 550
 551
 552 dnl TIFF Support
 553 dnl ============
 554 AC_ARG_ENABLE(tiff,
 555 [  --disable-tiff         disable use of TIFF images through libtiff],
 556         tif=$enableval, tif=yes, tif=no)
 557
 558 #
 559 # TIFF can optionally have JPEG and/or zlib support. Must find out
 560 # when they are supported so that correct library flags are passed during
 561 # detection and linkage
 562 #
 563 #
 564 # By default use xpm icons if tiff is not found.
 565 ICONEXT="xpm"
 566 #
 567
 568 if test "$tif" = yes; then
 569     my_libname=""
 570     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 571     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 572         my_libname="-ltiff"
 573     fi
 574 dnl
 575 dnl Retry with zlib
 576 dnl
 577     unset ac_cv_lib_tiff_TIFFGetVersion
 578     if test "x$my_libname" = x; then
 579         WM_CHECK_LIB(tiff, TIFFGetVersion, [-lz -lm])
 580         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 581             my_libname="-ltiff -lz"
 582         fi
 583     fi
 584
 585     if test "x$my_libname" = x; then
 586         WM_CHECK_LIB(tiff34, TIFFGetVersion, [-lm])
 587         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 588             my_libname="-ltiff34"
 589         fi
 590     fi
 591
 592
 593     if test "x$my_libname" != x; then
 594         WM_CHECK_HEADER(tiffio.h)
 595         if test "x$ac_cv_header_tiffio_h" = xyes; then
 596             GFXLIBS="$my_libname $GFXLIBS"
 597             ICONEXT="tiff"
 598             supported_gfx="$supported_gfx TIFF"
 599             AC_DEFINE(USE_TIFF)
 600         fi
 601     fi
 602 fi
 603
 604 LIBRARY_SEARCH_PATH="$lib_search_path"
 605 HEADER_SEARCH_PATH="$inc_search_path"
 606
 607 AC_SUBST(LIBRARY_SEARCH_PATH)
 608 AC_SUBST(HEADER_SEARCH_PATH)
 609
 610
 611 AC_SUBST(GFXLIBS)
 612 AC_SUBST(ICONEXT)
 613
 614
 615 dnl ==============================================
 616 dnl         End of Graphic Format Libraries
 617 dnl ==============================================
 618
 619
 620 dnl Debugging setup
 621 dnl ===============
 622 AC_ARG_ENABLE(debug,
 623 [  --enable-debug         enable debugging ],, enable_debug=no)
 624
 625 if test "$enable_debug" = yes; then
 626     DFLAGS="-g -DDEBUG"
 627 #       Efence makes things too slow. Add it by hand in the Makefiles
 628 #       if it is really needed.
 629 #    AC_CHECK_LIB(efence, malloc, LIBS="$LIBS -lefence")
 630 fi
 631 AC_SUBST(DFLAGS)
 632
 633
 634 dnl Sound support - Dan
 635 dnl =============================================
 636 sound=yes
 637 AC_ARG_ENABLE(sound,
 638 [  --disable-sound        disable sound support ],
 639                 sound=$enableval, sound=yes)
 640 if test "$sound" = yes; then
 641         AC_DEFINE(WMSOUND)
 642 fi
 643
 644
 645 # AC_PREFIX_PROGRAM(wmaker)
 646
 647 dnl Support for PIXMAPDIR option
 648 dnl ============================
 649 AC_ARG_WITH(pixmapdir,
 650 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 651
 652 if test "x$with_pixmapdir" != "x"; then
 653         pixmapdir=$with_pixmapdir
 654 else
 655         pixmapdir=`eval echo ${datadir}/pixmaps`
 656 fi
 657
 658 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir")
 659
 660 pkgdatadir=`eval echo $datadir`
 661 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker")
 662
 663 _sysconfdir=`eval echo $sysconfdir`
 664 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir/WindowMaker")
 665
 666
 667 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 668 dnl ==============================================
 669
 670 appspath=""
 671
 672 AC_ARG_WITH(appspath,
 673 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 674
 675 if test "x$appspath" = "x"; then
 676     gnustepdir='$(prefix)/GNUstep'
 677
 678     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 679         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 680         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 681     fi
 682
 683     with_appspath=$gnustepdir/Apps
 684 fi
 685
 686 wprefsdir=$with_appspath/WPrefs.app
 687
 688 AC_SUBST(wprefsdir)
 689
 690
 691
 692 dnl Enable single appicon per wm instance+class combo -cls
 693 dnl =====================================================
 694 AC_ARG_ENABLE(single-icon,
 695 [  --enable-single-icon    use single application icon per WM_INSTANCE+WM_CLASS
 696 ],
 697 if test "$enableval" = yes; then
 698         AC_DEFINE(REDUCE_APPICONS)
 699 fi
 700 )
 701
 702
 703 dnl
 704 dnl Nicolai:  Program tests for Documentation Section
 705 dnl =================================================
 706 dnl DOCTYPES=""
 707 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 708 dnl if test "x$MAKEINFO" != "x" ; then
 709 dnl       DOCTYPES="$DOCTYPES info_doc"
 710 dnl fi
 711 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 712 dnl if test "x$TEX" != "x" ; then
 713 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 714 dnl fi
 715 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 716 dnl if test "x$DVIPS" != "x" ; then
 717 dnl       DOCTYPES="$DOCTYPES ps_doc"
 718 dnl fi
 719 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 720 dnl if test "x$PERL" != "x" ; then
 721 dnl       DOCTYPES="$DOCTYPES html_doc"
 722 dnl fi
 723 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 724 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 725
 726 dnl AC_SUBST(DOCTYPES)
 727
 728 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile wmlib/Makefile \
 729         WINGs/Makefile WINGs/Resources/Makefile src/Makefile src/wconfig.h \
 730         wrlib/Makefile doc/Makefile WindowMaker/Makefile \
 731         WindowMaker/Backgrounds/Makefile WindowMaker/Defaults/Makefile \
 732         WindowMaker/IconSets/Makefile WindowMaker/Icons/Makefile \
 733         WindowMaker/Pixmaps/Makefile WindowMaker/Styles/Makefile \
 734         WindowMaker/Themes/Makefile \
 735         WindowMaker/Themes/Night.themed/Makefile \
 736         WindowMaker/Themes/LeetWM.themed/Makefile \
 737         WindowMaker/Themes/Checker.themed/Makefile \
 738         WindowMaker/Themes/STEP2000.themed/Makefile \
 739         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 740         WPrefs.app/po/Makefile )
 741
 742
 743
 744 dnl
 745 dnl Output some helpfull data for compiling WINGs apps
 746 dnl ==================================================
 747 dnl
 748
 749 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 750 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 751 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 752
 753 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 754 dnl parsed by m4
 755
 756 cat <<EOF >get-wraster-flags
 757 #!/bin/sh
 758
 759 prefix="$prefix"
 760 exec_prefix=\$prefix
 761
 762 WCFLAGS="-I\$prefix/include $inc_search_path"
 763 WLFLAGS="-L\$exec_prefix/lib $lib_search_path"
 764 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 765
 766 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--lflags#rp# #lp#--libs#rp#"
 767
 768 if test \$# -eq 0; then
 769       echo "\${usage}" 1>&2
 770       exit 1
 771 fi
 772
 773 while test \$# -gt 0; do
 774   case \$1 in
 775     --cflags)
 776         echo \$WCFLAGS
 777         ;;
 778     --lflags)
 779         echo \$WLFLAGS
 780         ;;
 781     --libs)
 782         echo \$WLIBS
 783         ;;
 784     *)
 785         echo "\${usage}" 1>&2
 786         exit 1
 787         ;;
 788   esac
 789   shift
 790 done
 791
 792
 793 EOF
 794
 795 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
 796
 797 chmod 755 wrlib/get-wraster-flags
 798 rm -f get-wraster-flags
 799
 800
 801 dnl
 802 dnl Spit out the configuration
 803 dnl ==========================
 804
 805 supported_gfx="$supported_gfx builtin-PPM"
 806
 807 if test "x$MOFILES" = "x"; then
 808         mof=none
 809 else
 810         mof=$MOFILES
 811 fi
 812
 813
 814 echo
 815 echo "Window Maker was configured as follows:"
 816 echo
 817 echo "Installation path prefix: $prefix"
 818 echo "Installation path prefix for binaries: $_bindir"
 819 echo "Installation path for WPrefs.app: $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
 820 echo "Graphic format libraries: $supported_gfx"
 821 echo "Sound support: $sound"
 822 echo "Translated message files to install: $mof"
 823 if test "x$MOFILES" != "x"; then
 824         echo "Installation path of translated messages: $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
 825 fi
 826
 827 WM_PRINT_REDCRAP_BUG_STATUS
 828
 829 if test "x$ac_cv_header_jpeglib_h" != xyes; then
 830 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
 831 echo
 832 echo "JPEG support will not be included because the JPEG library is"
 833 echo "not installed correctly or was not found. Background images"
 834 echo "from themes will not display as they usually are JPEG files."
 835 echo
 836 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
 837 fi
 838
 839
 840 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 841 dnl ================================================
 842 dnl Local Variables:
 843 dnl compile-command: "autoconf"
 844 dnl End:
 845