configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(dll,
  19 [  --disable-dll           build static libraries instead of DLLs],
  20 [if test "$enableval" = "no"; then LIBEXT="a"; fi])
  21
  22 AC_ARG_ENABLE(debug,
  23 [  --disable-debug         compile out all debugging messages],
  24 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  25
  26 AC_ARG_ENABLE(opengl,
  27 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  28 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  29
  30 AC_ARG_ENABLE(trace,
  31 [  --disable-trace         compile out TRACE messages],
  32 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  33
  34 AC_ARG_WITH(curses,
  35 [  --without-curses        do not use curses],
  36 [if test "$withval" = "no"; then CURSES="no"; fi])
  37
  38 AC_ARG_WITH(reentrant-x,
  39 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  40
  41 AC_SUBST(OPTIONS)
  42
  43 if test "$DEBUG_MSGS" = "no"
  44 then
  45     AC_DEFINE(NO_DEBUG_MSGS)
  46     AC_DEFINE(NO_TRACE_MSGS)
  47 else
  48     if test "$TRACE_MSGS" = "no"
  49     then
  50         AC_DEFINE(NO_TRACE_MSGS)
  51     fi
  52 fi
  53
  54 dnl **** Check for some programs ****
  55
  56 AC_PROG_MAKE_SET
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PATH_XTRA
  60 AC_PROG_YACC
  61 AC_PROG_LEX
  62 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  63 if test "$XLEX" = "none"
  64 then
  65         echo "*** Error: No suitable lex found. ***"
  66         echo "    Please install the 'flex' package."
  67         exit 1
  68 fi
  69 AC_DECL_YYTEXT
  70 AC_PROG_RANLIB
  71 AC_PROG_INSTALL
  72 AC_PROG_LN_S
  73 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  74 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  75
  76 dnl Check for lint
  77 AC_CHECK_PROGS(LINT, lclint lint)
  78 if test "$LINT" = "lint"
  79 then
  80   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  81   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  82 fi
  83 AC_SUBST(LINT)
  84 AC_SUBST(LINTFLAGS)
  85
  86 dnl **** Check for some libraries ****
  87
  88 dnl Check for -lm for BeOS
  89 AC_CHECK_LIB(m,sqrt)
  90 dnl Check for -li386 for NetBSD and OpenBSD
  91 AC_CHECK_LIB(i386,i386_set_ldt)
  92 dnl Check for -lossaudio for NetBSD
  93 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  94 dnl Check for -lw for Solaris
  95 AC_CHECK_LIB(w,iswalnum)
  96 dnl Check for -lnsl for Solaris
  97 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
  98 dnl Check for -lsocket for Solaris
  99 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 100 dnl Check for -lxpg4 for FreeBSD
 101 AC_CHECK_LIB(xpg4,setrunelocale)
 102 dnl Check for -lmmap for OS/2
 103 AC_CHECK_LIB(mmap,mmap)
 104 dnl Check for openpty
 105 AC_CHECK_FUNCS(openpty,,
 106         AC_CHECK_LIB(util,openpty,
 107                 AC_DEFINE(HAVE_OPENPTY)
 108                 LIBS="$LIBS -lutil"
 109         ))
 110
 111 AC_CHECK_HEADERS(dlfcn.h,
 112         AC_CHECK_FUNCS(dlopen,
 113                 AC_DEFINE(HAVE_DL_API),
 114                 AC_CHECK_LIB(dl,dlopen,
 115                         AC_DEFINE(HAVE_DL_API)
 116                         LIBS="$LIBS -ldl",
 117                         LIBEXT="a"
 118                 )
 119         ),
 120         LIBEXT="a"
 121 )
 122 AC_SUBST(XLIB)
 123 AC_SUBST(X_DLLS)
 124 X_DLLS=""
 125 AC_SUBST(XFILES)
 126 XFILES=""
 127 AC_SUBST(OPENGLFILES)
 128 OPENGLFILES=""
 129 AC_SUBST(OPENGL32_DLL)
 130 OPENGL32_DLL=""
 131 AC_SUBST(DGA_SRCS)
 132 DGA_SRCS=""
 133 AC_SUBST(DGA2_SRCS)
 134 DGA2_SRCS=""
 135 AC_SUBST(MESA_SRCS)
 136 MESA_SRCS=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X Shm extension
 171         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 172             [ dnl *** If X11/extensions/XShm.h exists...
 173               AC_CHECK_LIB(Xext, XShmQueryExtension,
 174               AC_DEFINE(HAVE_LIBXXSHM),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([Xshm extension not found!!])
 178         )
 179
 180         dnl *** Check for X shape extension
 181         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 182             [ dnl *** If X11/extensions/shape.h exists...
 183               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 184               AC_DEFINE(HAVE_LIBXSHAPE),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([XShape extension found!!])
 188         )
 189
 190         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 191         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 192             [ dnl *** If X11/extensions/xf86dga.h exists, check
 193               dnl *** for XDGAQueryExtension()...
 194               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 195                 [ dnl *** If found...
 196                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 197                   AC_DEFINE(HAVE_LIBXXF86DGA)
 198                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 199                   DGA_SRCS='$(DGA_SRCS)'
 200                   DGA2_SRCS='$(DGA2_SRCS)'
 201                ],
 202                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 203                   dnl *** instead (DGA 2.0 not found)...
 204                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 205                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 206                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 207                       DGA_SRCS='$(DGA_SRCS)'
 208                     ],,
 209                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 210                   )
 211                 ],
 212                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 213               )
 214             ],
 215             AC_MSG_WARN([DGA extension not found!!])
 216         )
 217
 218         dnl *** Check for XFree86 VMODE extension
 219         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 220             [ dnl *** If X11/extensions/xf86vmode.h exists...
 221                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 222                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 223                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 224                   ],,
 225                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 226                 )
 227             ],
 228             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 229         )
 230       ]
 231     ) dnl *** End of X11/Xlib.h check
 232
 233     dnl Check for the presence of OpenGL
 234     if test $OPENGL = "yes" -o $OPENGL = "normal"
 235     then
 236         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 237         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 238         then
 239             dnl Check for some problems due to old Mesa versions
 240             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 241               AC_TRY_COMPILE(
 242                 [#include <GL/gl.h>],
 243                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 244                 [wine_cv_opengl_version_OK="yes"],
 245                 [wine_cv_opengl_version_OK="no"]
 246               )
 247             )
 248
 249             dnl Check for the thread-safety of the OpenGL library
 250             AC_CACHE_CHECK("for thread-safe OpenGL version",
 251                            wine_cv_opengl_version_threadsafe,
 252               [saved_libs=$LIBS
 253                LIBS="$X_LIBS -lGL"
 254                AC_TRY_LINK([],[pthread_getspecific();],
 255                               [wine_cv_opengl_version_threadsafe="yes"],
 256                               [wine_cv_opengl_version_threadsafe="no"])
 257                LIBS=$saved_libs]
 258             )
 259
 260             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 261             then
 262                 dnl Check for the presence of the library
 263                 AC_CHECK_LIB(GL,glXCreateContext,
 264                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 265                              MESA_SRCS='$(MESA_SRCS)'
 266                              ,,
 267                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 268
 269
 270                 OPENGLFILES='$(OPENGLFILES)'
 271                 AC_DEFINE(HAVE_OPENGL)
 272
 273                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 274                 then
 275                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 276
 277                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 278                         then
 279                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 280                                   AC_TRY_COMPILE([#include <GL/gl.h>
 281                                                   #ifdef HAVE_GL_GLEXT_H
 282                                                   # include <GL/glext.h>
 283                                                   #endif
 284                                                   ],
 285                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 286                                                  [wine_cv_extension_prototypes="yes"],
 287                                                  [wine_cv_extension_prototypes="no"]
 288                                   )
 289                                 )
 290                                 if test $wine_cv_extension_prototypes = "yes"
 291                                 then
 292                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 293                                 fi
 294
 295                                 OPENGL32_DLL=opengl32
 296                         fi
 297                 fi
 298              fi
 299          fi
 300     fi
 301
 302     CPPFLAGS="$ac_save_CPPFLAGS"
 303     X_DLLS='$(X_DLLS)'
 304     XFILES='$(XFILES)'
 305 else
 306     XLIB=""
 307     X_CFLAGS=""
 308     X_LIBS=""
 309 fi
 310
 311 dnl **** Check which curses lib to use ***
 312 if test "$CURSES" = "yes"
 313 then
 314     AC_CHECK_HEADERS(ncurses.h)
 315     if test "$ac_cv_header_ncurses_h" = "yes"
 316     then
 317         AC_CHECK_LIB(ncurses,waddch)
 318     fi
 319     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 320     then
 321         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 322         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 323     else
 324         AC_CHECK_HEADERS(curses.h)
 325         if test "$ac_cv_header_curses_h" = "yes"
 326         then
 327             AC_CHECK_LIB(curses,waddch)
 328             if test "$ac_cv_lib_curses_waddch" = "yes"
 329             then
 330                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 331                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 332             fi
 333         fi
 334     fi
 335 fi
 336
 337 dnl **** Check for IPX (currently Linux only) ****
 338 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 339  AC_TRY_COMPILE(
 340    [#include <sys/socket.h>
 341     #include <netipx/ipx.h>],
 342    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 343    [ac_cv_c_ipx_gnu="yes"],
 344    [ac_cv_c_ipx_gnu="no"])
 345  )
 346 if test "$ac_cv_c_ipx_gnu" = "yes"
 347 then
 348     AC_DEFINE(HAVE_IPX_GNU)
 349 fi
 350
 351 if test "$ac_cv_c_ipx_gnu" = "no"
 352 then
 353  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 354   AC_TRY_COMPILE(
 355     [#include <sys/socket.h>
 356      #include <asm/types.h>
 357      #include <linux/ipx.h>],
 358     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 359     [ac_cv_c_ipx_linux="yes"],
 360     [ac_cv_c_ipx_linux="no"])
 361   )
 362   if test "$ac_cv_c_ipx_linux" = "yes"
 363   then
 364       AC_DEFINE(HAVE_IPX_LINUX)
 365   fi
 366 fi
 367
 368 dnl **** Check for Open Sound System ****
 369 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 370
 371 AC_CACHE_CHECK("for Open Sound System",
 372         ac_cv_c_opensoundsystem,
 373         AC_TRY_COMPILE([
 374         #if defined(HAVE_SYS_SOUNDCARD_H)
 375                 #include <sys/soundcard.h>
 376         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 377                 #include <machine/soundcard.h>
 378         #elif defined(HAVE_SOUNDCARD_H)
 379                 #include <soundcard.h>
 380         #endif
 381         ],[
 382
 383 /* check for one of the Open Sound System specific SNDCTL_ defines */
 384 #if !defined(SNDCTL_DSP_STEREO)
 385 #error No open sound system
 386 #endif
 387 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 388
 389 if test "$ac_cv_c_opensoundsystem" = "yes"
 390 then
 391     AC_DEFINE(HAVE_OSS)
 392 fi
 393
 394 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 395         ac_cv_c_opensoundsystem_midi,
 396         AC_TRY_COMPILE([
 397         #if defined(HAVE_SYS_SOUNDCARD_H)
 398                 #include <sys/soundcard.h>
 399         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 400                 #include <machine/soundcard.h>
 401         #elif defined(HAVE_SOUNDCARD_H)
 402                 #include <soundcard.h>
 403         #endif
 404         ],[
 405
 406 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 407 #if !defined(SNDCTL_SEQ_SYNC)
 408 #error No open sound system MIDI interface
 409 #endif
 410 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 411
 412 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 413 then
 414     AC_DEFINE(HAVE_OSS_MIDI)
 415 fi
 416
 417 dnl **** If ln -s doesn't work, use cp instead ****
 418 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 419
 420 dnl **** Check for gcc strength-reduce bug ****
 421
 422 if test "x${GCC}" = "xyes"
 423 then
 424   CFLAGS="$CFLAGS -Wall"
 425   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 426                   AC_TRY_RUN([
 427 int main(void) {
 428   static int Array[[3]];
 429   unsigned int B = 3;
 430   int i;
 431   for(i=0; i<B; i++) Array[[i]] = i - 3;
 432   exit( Array[[1]] != -2 );
 433 }],
 434     ac_cv_c_gcc_strength_bug="no",
 435     ac_cv_c_gcc_strength_bug="yes",
 436     ac_cv_c_gcc_strength_bug="yes") )
 437   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 438   then
 439     CFLAGS="$CFLAGS -fno-strength-reduce"
 440   fi
 441 fi
 442
 443 dnl **** Check for underscore on external symbols ****
 444
 445 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 446                ac_cv_c_extern_prefix,
 447 [saved_libs=$LIBS
 448 LIBS="conftest_asm.s $LIBS"
 449 cat > conftest_asm.s <<EOF
 450         .globl _ac_test
 451 _ac_test:
 452         .long 0
 453 EOF
 454 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 455             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 456 LIBS=$saved_libs])
 457 if test "$ac_cv_c_extern_prefix" = "yes"
 458 then
 459   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 460 fi
 461
 462 dnl **** Check for .string in assembler ****
 463
 464 AC_CACHE_CHECK("whether assembler accepts .string",
 465                ac_cv_c_asm_string,
 466 [saved_libs=$LIBS
 467 LIBS="conftest_asm.s $LIBS"
 468 cat > conftest_asm.s <<EOF
 469         .string "test"
 470 EOF
 471 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 472 LIBS=$saved_libs])
 473 if test "$ac_cv_c_asm_string" = "yes"
 474 then
 475   AC_DEFINE(HAVE_ASM_STRING)
 476 fi
 477
 478 dnl **** Check for working dll ****
 479
 480 LDSHARED=""
 481 if test "$LIBEXT" = "so"
 482 then
 483   AC_CACHE_CHECK("whether we can build a Linux dll",
 484                  ac_cv_c_dll_linux,
 485   [saved_cflags=$CFLAGS
 486   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 487   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 488   CFLAGS=$saved_cflags
 489   ])
 490   if test "$ac_cv_c_dll_linux" = "yes"
 491   then
 492     LDSHARED="\$(CC) -shared -Wl,-soname,\$(SONAME),-rpath,\$(libdir)"
 493   else
 494     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 495                  ac_cv_c_dll_unixware,
 496     [saved_cflags=$CFLAGS
 497     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0"
 498     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 499     CFLAGS=$saved_cflags
 500     ])
 501     if test "$ac_cv_c_dll_unixware" = "yes"
 502     then
 503       LDSHARED="\$(CC) -Wl,-G,-h,\$(libdir)/\$(SONAME)"
 504     else
 505       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 506                    ac_cv_c_dll_netbsd,
 507       [saved_cflags=$CFLAGS
 508       CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 509       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 510       CFLAGS=$saved_cflags
 511       ])
 512       if test "$ac_cv_c_dll_netbsd" = "yes"
 513       then
 514         LDSHARED="ld -Bshareable -Bforcearchive"
 515       fi
 516     fi
 517   fi
 518   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 519   then
 520     LIBEXT="a"
 521   fi
 522 fi
 523
 524 DLLFLAGS=""
 525
 526 if test "$LIBEXT" = "so"; then
 527     DLLFLAGS="-fPIC"
 528     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode"
 529 else
 530     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode \$(X_LIBS) \$(XLIB)"
 531     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 532                    ac_cv_c_whole_archive,
 533             [saved_cflags=$CFLAGS
 534             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 535             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 536             CFLAGS=$saved_cflags
 537             ])
 538     if test "$ac_cv_c_whole_archive" = "yes"
 539     then
 540         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 541     else
 542         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 543                        ac_cv_c_allextract,
 544                 [saved_cflags=$CFLAGS
 545                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 546                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 547                 CFLAGS=$saved_cflags
 548                 ])
 549         if test "$ac_cv_c_allextract" = "yes"
 550         then
 551             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 552         fi
 553     fi
 554 fi
 555
 556 AC_SUBST(DLL_LINK)
 557 AC_SUBST(DLLFLAGS)
 558 AC_SUBST(LDSHARED)
 559 AC_SUBST(LIBEXT)
 560
 561 dnl **** Check for reentrant libc ****
 562 dnl
 563 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 564 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 565
 566 wine_cv_libc_reentrant=no
 567 dnl
 568 dnl Linux style errno location
 569 dnl
 570 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 571   [AC_TRY_RUN([int myerrno = 0;
 572 char buf[256];
 573 int *__errno_location(){return &myerrno;}
 574 main(){connect(0,buf,255); exit(!myerrno);}],
 575   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 576   wine_cv_libc_r__errno_location=yes )
 577 ])
 578 if test "$wine_cv_libc_r__errno_location" = "yes"
 579 then
 580     AC_DEFINE(HAVE__ERRNO_LOCATION)
 581     wine_cv_libc_reentrant=__errno_location
 582 fi
 583 dnl
 584 dnl FreeBSD style errno location
 585 dnl
 586 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 587   [AC_TRY_RUN([int myerrno = 0;
 588 char buf[256];
 589 int *__error(){return &myerrno;}
 590 main(){connect(0,buf,255); exit(!myerrno);}],
 591     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 592     wine_cv_libc_r__error=yes )
 593 ])
 594 if test "$wine_cv_libc_r__error" = "yes"
 595 then
 596     AC_DEFINE(HAVE__ERROR)
 597     wine_cv_libc_reentrant=__error
 598 fi
 599 dnl
 600 dnl Solaris style errno location
 601 dnl
 602 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 603   [AC_TRY_RUN([int myerrno = 0;
 604 char buf[256];
 605 int *___errno(){return &myerrno;}
 606 main(){connect(0,buf,255); exit(!myerrno);}],
 607     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 608     wine_cv_libc_r___errno=yes )
 609 ])
 610 if test "$wine_cv_libc_r___errno" = "yes"
 611 then
 612     AC_DEFINE(HAVE___ERRNO)
 613     wine_cv_libc_reentrant=___errno
 614 fi
 615 dnl
 616 dnl UnixWare style errno location
 617 dnl
 618 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 619   [AC_TRY_RUN([int myerrno = 0;
 620 char buf[256];
 621 int *__thr_errno(){return &myerrno;}
 622 main(){connect(0,buf,255); exit(!myerrno);}],
 623     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 624     wine_cv_libc_r__thr_errno=yes )
 625 ])
 626 if test "$wine_cv_libc_r__thr_errno" = "yes"
 627 then
 628     AC_DEFINE(HAVE__THR_ERRNO)
 629     wine_cv_libc_reentrant=__thr_errno
 630 fi
 631 if test "$wine_cv_libc_reentrant" = "no"
 632 then
 633   AC_DEFINE(NO_REENTRANT_LIBC)
 634 fi
 635
 636 dnl **** Check for reentrant X libraries ****
 637 dnl
 638 dnl This may fail to determine whether X libraries are reentrant if
 639 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 640 dnl is possible with the --without-reentrant-x option.
 641
 642 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 643 then
 644 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 645   [ if test "x$with_reentrant_x" = "xno"
 646     then
 647         wine_cv_x_reentrant=no
 648     else
 649         libX11_check=none
 650         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 651             if test -r $dir/libX11.so; then
 652                 libX11_check="-D $dir/libX11.so"
 653                 break 1
 654             fi
 655             if test -r $dir/libX11.a; then
 656                 libX11_check="$dir/libX11.a"
 657                 break 1
 658             fi
 659         done
 660         if test "$libX11_check" != "none"; then
 661             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 662             then
 663                 wine_cv_x_reentrant=yes
 664             else
 665                 wine_cv_x_reentrant=no
 666             fi
 667         else
 668             wine_cv_x_reentrant=unknown
 669         fi
 670     fi ] )
 671 else
 672     wine_cv_x_reentrant=no
 673 fi
 674 if test "$wine_cv_x_reentrant" = "no"
 675 then
 676   AC_DEFINE(NO_REENTRANT_X11)
 677 fi
 678
 679 dnl **** Check for endianness ****
 680
 681 AC_C_BIGENDIAN
 682
 683 dnl **** Check for functions ****
 684
 685 AC_FUNC_ALLOCA()
 686 AC_CHECK_FUNCS(\
 687         __libc_fork \
 688         _lwp_create \
 689         clone \
 690         getnetbyaddr \
 691         getnetbyname \
 692         getpagesize \
 693         getprotobyname \
 694         getprotobynumber \
 695         getservbyport \
 696         getsockopt \
 697         inet_network \
 698         memmove \
 699         rfork \
 700         select \
 701         sendmsg \
 702         settimeofday \
 703         sigaltstack \
 704         statfs \
 705         strcasecmp \
 706         strerror \
 707         strncasecmp \
 708         tcgetattr \
 709         timegm \
 710         usleep \
 711         vfscanf \
 712         wait4 \
 713         waitpid \
 714 )
 715
 716 dnl **** Check for header files ****
 717
 718 AC_CHECK_HEADERS(\
 719         a.out.h \
 720         a_out.h \
 721         arpa/inet.h \
 722         arpa/nameser.h \
 723         elf.h \
 724         float.h \
 725         libio.h \
 726         libutil.h \
 727         link.h \
 728         linux/cdrom.h \
 729         linux/joystick.h \
 730         linux/ucdrom.h \
 731         net/if.h \
 732         netinet/in.h \
 733         netinet/tcp.h \
 734         pty.h \
 735         resolv.h \
 736         sched.h \
 737         socket.h \
 738         strings.h \
 739         sys/cdio.h \
 740         sys/errno.h \
 741         sys/file.h \
 742         sys/filio.h \
 743         sys/ipc.h \
 744         sys/lwp.h \
 745         sys/mman.h \
 746         sys/modem.h \
 747         sys/mount.h \
 748         sys/msg.h \
 749         sys/param.h \
 750         sys/reg.h \
 751         sys/signal.h \
 752         sys/shm.h \
 753         sys/socket.h \
 754         sys/sockio.h \
 755         sys/statfs.h \
 756         sys/strtio.h \
 757         sys/syscall.h \
 758         sys/wait.h \
 759         sys/v86.h \
 760         sys/v86intr.h \
 761         sys/vfs.h \
 762         sys/vm86.h \
 763         syscall.h \
 764         ucontext.h
 765 )
 766 AC_HEADER_STAT()
 767
 768 dnl **** Check for types ****
 769
 770 AC_C_CONST()
 771 AC_C_INLINE()
 772 AC_TYPE_SIZE_T()
 773 AC_CHECK_SIZEOF(long long,0)
 774
 775 if test "$ac_cv_header_linux_joystick_h" = "yes"
 776 then
 777    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 778         wine_cv_linux_joystick_22_api,
 779         AC_TRY_COMPILE([
 780         #include <sys/ioctl.h>
 781         #include <linux/joystick.h>
 782
 783         struct js_event blub;
 784         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 785         #error "no 2.2 header"
 786         #endif
 787         ],/*empty*/,
 788         wine_cv_linux_joystick_22_api=yes,
 789         wine_cv_linux_joystick_22_api=no,
 790         wine_cv_linux_joystick_22_api=no
 791         )
 792    )
 793    if test "$wine_cv_linux_joystick_22_api" = "yes"
 794    then
 795       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 796    fi
 797 fi
 798
 799 dnl **** statfs checks ****
 800
 801 if test "$ac_cv_header_sys_vfs_h" = "yes"
 802 then
 803     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 804                     wine_cv_sys_vfs_has_statfs,
 805         AC_TRY_COMPILE([
 806         #include <sys/types.h>
 807         #ifdef HAVE_SYS_PARAM_H
 808         # include <sys/param.h>
 809         #endif
 810         #include <sys/vfs.h>
 811         ],[
 812                 struct statfs stfs;
 813
 814                 memset(&stfs,0,sizeof(stfs));
 815         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 816         )
 817     )
 818     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 819     then
 820       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 821     fi
 822 fi
 823
 824 if test "$ac_cv_header_sys_statfs_h" = "yes"
 825 then
 826     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 827                     wine_cv_sys_statfs_has_statfs,
 828         AC_TRY_COMPILE([
 829         #include <sys/types.h>
 830         #ifdef HAVE_SYS_PARAM_H
 831         # include <sys/param.h>
 832         #endif
 833         #include <sys/statfs.h>
 834         ],[
 835                 struct statfs stfs;
 836         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 837         )
 838     )
 839     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 840     then
 841       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 842     fi
 843 fi
 844
 845 if test "$ac_cv_header_sys_mount_h" = "yes"
 846 then
 847     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 848                     wine_cv_sys_mount_has_statfs,
 849         AC_TRY_COMPILE([
 850         #include <sys/types.h>
 851         #ifdef HAVE_SYS_PARAM_H
 852         # include <sys/param.h>
 853         #endif
 854         #include <sys/mount.h>
 855         ],[
 856                 struct statfs stfs;
 857         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 858         )
 859     )
 860     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 861     then
 862       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 863     fi
 864 fi
 865
 866 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 867
 868 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 869   [ if test "x$statfs_bfree" = "xno"
 870     then
 871         wine_cv_statfs_bfree=no
 872     else
 873         AC_TRY_COMPILE([
 874         #include <sys/types.h>
 875         #ifdef HAVE_SYS_PARAM_H
 876         # include <sys/param.h>
 877         #endif
 878         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 879         # include <sys/mount.h>
 880         #else
 881         # ifdef STATFS_DEFINED_BY_SYS_VFS
 882         #  include <sys/vfs.h>
 883         # else
 884         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 885         #   include <sys/statfs.h>
 886         #  endif
 887         # endif
 888         #endif
 889         ],[
 890                 struct statfs stfs;
 891
 892                 stfs.f_bfree++;
 893         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 894         )
 895     fi ] )
 896 if test "$wine_cv_statfs_bfree" = "yes"
 897 then
 898   AC_DEFINE(STATFS_HAS_BFREE)
 899 fi
 900
 901 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 902   [ if test "x$statfs_bavail" = "xno"
 903     then
 904         wine_cv_statfs_bavail=no
 905     else
 906         AC_TRY_COMPILE([
 907         #include <sys/types.h>
 908         #ifdef HAVE_SYS_PARAM_H
 909         # include <sys/param.h>
 910         #endif
 911         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 912         # include <sys/mount.h>
 913         #else
 914         # ifdef STATFS_DEFINED_BY_SYS_VFS
 915         #  include <sys/vfs.h>
 916         # else
 917         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 918         #   include <sys/statfs.h>
 919         #  endif
 920         # endif
 921         #endif
 922         ],[
 923                 struct statfs stfs;
 924
 925                 stfs.f_bavail++;
 926         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 927         )
 928     fi ] )
 929 if test "$wine_cv_statfs_bavail" = "yes"
 930 then
 931   AC_DEFINE(STATFS_HAS_BAVAIL)
 932 fi
 933
 934 dnl *** check for file descriptor passing with msg_accrights
 935
 936 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 937  AC_TRY_COMPILE([#include <sys/types.h>
 938 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 939                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 940 if test "$ac_cv_c_msg_accrights" = "yes"
 941 then
 942     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 943 fi
 944
 945 dnl *** Check for the sun_len member in struct sockaddr_un
 946
 947 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
 948  AC_TRY_COMPILE([#include <sys/types.h>
 949 #include <sys/socket.h>
 950 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
 951                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
 952 if test "$ac_cv_c_sun_len" = "yes"
 953 then
 954     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
 955 fi
 956
 957 dnl *** check for the need to define __i386__
 958
 959 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
 960  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
 961 yes
 962 #endif],
 963  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
 964 if test "$ac_cv_cpp_def_i386" = "yes"
 965 then
 966     CFLAGS="$CFLAGS -D__i386__"
 967     LINTFLAGS="$LINTFLAGS -D__i386__"
 968 fi
 969
 970 dnl $GCC is set by autoconf
 971 GCC_NO_BUILTIN=""
 972 if test "$GCC" = "yes"
 973 then
 974     GCC_NO_BUILTIN="-fno-builtin"
 975 fi
 976 AC_SUBST(GCC_NO_BUILTIN)
 977
 978 dnl **** Generate output files ****
 979
 980 AC_OUTPUT_COMMANDS([
 981 extra_subdirs="\
 982 dlls/ddraw/d3ddevice \
 983 dlls/ddraw/dclipper \
 984 dlls/ddraw/ddraw \
 985 dlls/ddraw/direct3d \
 986 dlls/ddraw/dpalette \
 987 dlls/ddraw/dsurface \
 988 dlls/kernel/messages \
 989 "
 990 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
 991
 992 MAKE_RULES=Make.rules
 993 AC_SUBST_FILE(MAKE_RULES)
 994
 995 MAKE_DLL_RULES=dlls/Makedll.rules
 996 AC_SUBST_FILE(MAKE_DLL_RULES)
 997
 998 AC_OUTPUT([
 999 Make.rules
1000 Makefile
1001 console/Makefile
1002 controls/Makefile
1003 debugger/Makefile
1004 dlls/Makedll.rules
1005 dlls/Makefile
1006 dlls/advapi32/Makefile
1007 dlls/avifil32/Makefile
1008 dlls/comctl32/Makefile
1009 dlls/commdlg/Makefile
1010 dlls/crtdll/Makefile
1011 dlls/dciman32/Makefile
1012 dlls/ddraw/Makefile
1013 dlls/dinput/Makefile
1014 dlls/dplay/Makefile
1015 dlls/dplayx/Makefile
1016 dlls/dsound/Makefile
1017 dlls/gdi/Makefile
1018 dlls/icmp/Makefile
1019 dlls/imagehlp/Makefile
1020 dlls/imm32/Makefile
1021 dlls/kernel/Makefile
1022 dlls/lzexpand/Makefile
1023 dlls/mpr/Makefile
1024 dlls/msacm/Makefile
1025 dlls/msnet32/Makefile
1026 dlls/msvideo/Makefile
1027 dlls/ntdll/Makefile
1028 dlls/odbc32/Makefile
1029 dlls/ole32/Makefile
1030 dlls/oleaut32/Makefile
1031 dlls/olecli/Makefile
1032 dlls/oledlg/Makefile
1033 dlls/olepro32/Makefile
1034 dlls/olesvr/Makefile
1035 dlls/opengl32/Makefile
1036 dlls/psapi/Makefile
1037 dlls/rasapi32/Makefile
1038 dlls/richedit/Makefile
1039 dlls/rpcrt4/Makefile
1040 dlls/serialui/Makefile
1041 dlls/setupapi/Makefile
1042 dlls/shell32/Makefile
1043 dlls/shfolder/Makefile
1044 dlls/shlwapi/Makefile
1045 dlls/tapi32/Makefile
1046 dlls/ttydrv/Makefile
1047 dlls/urlmon/Makefile
1048 dlls/user/Makefile
1049 dlls/version/Makefile
1050 dlls/win32s/Makefile
1051 dlls/winaspi/Makefile
1052 dlls/wineps/Makefile
1053 dlls/wininet/Makefile
1054 dlls/winmm/Makefile
1055 dlls/winmm/joystick/Makefile
1056 dlls/winmm/mcianim/Makefile
1057 dlls/winmm/mciavi/Makefile
1058 dlls/winmm/mcicda/Makefile
1059 dlls/winmm/mciseq/Makefile
1060 dlls/winmm/mciwave/Makefile
1061 dlls/winmm/midimap/Makefile
1062 dlls/winmm/wavemap/Makefile
1063 dlls/winmm/wineoss/Makefile
1064 dlls/winsock/Makefile
1065 dlls/winspool/Makefile
1066 dlls/wow32/Makefile
1067 dlls/wsock32/Makefile
1068 dlls/x11drv/Makefile
1069 documentation/Makefile
1070 documentation/wine.conf.man
1071 documentation/wine.man
1072 files/Makefile
1073 graphics/Makefile
1074 graphics/enhmetafiledrv/Makefile
1075 graphics/metafiledrv/Makefile
1076 graphics/win16drv/Makefile
1077 graphics/x11drv/Makefile
1078 if1632/Makefile
1079 include/Makefile
1080 library/Makefile
1081 libtest/Makefile
1082 loader/Makefile
1083 loader/dos/Makefile
1084 loader/ne/Makefile
1085 memory/Makefile
1086 misc/Makefile
1087 miscemu/Makefile
1088 msdos/Makefile
1089 objects/Makefile
1090 ole/Makefile
1091 programs/Makefile
1092 programs/avitools/Makefile
1093 programs/clock/Makefile
1094 programs/cmdlgtst/Makefile
1095 programs/control/Makefile
1096 programs/notepad/Makefile
1097 programs/osversioncheck/Makefile
1098 programs/progman/Makefile
1099 programs/regapi/Makefile
1100 programs/regtest/Makefile
1101 programs/uninstaller/Makefile
1102 programs/view/Makefile
1103 programs/wcmd/Makefile
1104 programs/winemine/Makefile
1105 programs/winhelp/Makefile
1106 programs/winver/Makefile
1107 relay32/Makefile
1108 resources/Makefile
1109 scheduler/Makefile
1110 server/Makefile
1111 tools/Makefile
1112 tools/cvdump/Makefile
1113 tools/winebuild/Makefile
1114 tools/wmc/Makefile
1115 tools/wrc/Makefile
1116 tsx11/Makefile
1117 unicode/Makefile
1118 win32/Makefile
1119 windows/Makefile
1120 windows/x11drv/Makefile ])
1121
1122 if test "$have_x" = "no"
1123 then
1124   echo
1125   echo "*** Warning: X development files not found. Wine will be built without"
1126   echo "*** X support, which currently does not work, and would probably not be"
1127   echo "*** what you want anyway. You will need to install devel packages of"
1128   echo "*** Xlib/Xfree86 and Xpm at the very least."
1129 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1130 then
1131   echo
1132   echo "*** Warning: Xpm development files not found. Wine will be built without"
1133   echo "*** Xpm support, which currently does not work. You will need to install"
1134   echo "*** devel packages of Xpm."
1135 fi
1136
1137 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1138 then
1139   echo
1140   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1141   echo "*** terminal resize support. Consider upgrading ncurses."
1142 fi
1143
1144 if test "$wine_cv_libc_reentrant" = "no"
1145 then
1146   echo
1147   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1148   echo "*** thread support. Consider upgrading libc to a more recent"
1149   echo "*** reentrant version of libc."
1150 fi
1151
1152 if test "$wine_cv_opengl_version_OK" = "no"
1153 then
1154   echo
1155   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1156   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1157 fi
1158
1159 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1160 then
1161   echo
1162   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1163   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1164   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1165   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1166 fi
1167
1168 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1169 then
1170   echo
1171   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1172   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1173   echo "*** support before reporting bugs."
1174 fi
1175
1176
1177 echo
1178 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1179 echo
1180
1181 dnl Local Variables:
1182 dnl comment-start: "dnl "
1183 dnl comment-end: ""
1184 dnl comment-start-skip: "\\bdnl\\b\\s *"
1185 dnl compile-command: "autoconf"
1186 dnl End: