| blob | 9e0a42f61f569519d2ebeba81905065998c2dccc |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
19 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
20 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
25 if test "x$enable_win16" = "xno"
26 then
27 WIN16_FILES=""
28 WIN16_INSTALL=""
29 fi
30 if test "x$enable_debug" = "xno"
31 then
32 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
33 fi
34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
35 then
36 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
37 fi
39 dnl **** Check for some programs ****
41 AC_CANONICAL_HOST
42 AC_PROG_MAKE_SET
43 AC_PROG_CC
44 AC_PROG_CXX
45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
49 [if test -z "$with_wine_tools"; then
50 if test "$cross_compiling" = "yes"; then
51 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
52 else
53 wine_cv_toolsdir="\$(TOPOBJDIR)"
54 fi
55 elif test -d "$with_wine_tools/tools/winebuild"; then
56 case $with_wine_tools in
57 /*) wine_cv_toolsdir="$with_wine_tools" ;;
58 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
59 esac
60 else
61 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
62 fi])
63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
65 AC_PATH_XTRA
66 AC_PROG_LEX
68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
69 dnl **** without one present.
70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
71 if test "$XLEX" = "none"
72 then
73 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
74 fi
76 dnl Check for bison
77 AC_CHECK_PROGS(BISON,bison,none)
78 if test "$BISON" = "none"
79 then
80 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
81 fi
83 AC_CHECK_TOOLS(AS,[gas as],as)
84 AC_CHECK_TOOL(LD,ld,ld)
85 AC_CHECK_TOOL(AR,ar,ar)
86 AC_PROG_RANLIB
87 AC_CHECK_TOOL(STRIP,strip,strip)
88 AC_CHECK_TOOL(WINDRES,windres,false)
89 AC_PROG_LN_S
90 WINE_PROG_LN
91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
92 AC_PROG_INSTALL
93 dnl Prepend src dir to install path dir if it's a relative path
94 case "$INSTALL" in
95 [[\\/$]]* | ?:[[\\/]]* ) ;;
96 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
97 esac
99 dnl Check for lint
100 AC_CHECK_PROGS(LINT, lclint lint)
101 if test "$LINT" = "lint"
102 then
103 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
104 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
105 fi
106 AC_SUBST(LINT)
107 AC_SUBST(LINTFLAGS)
109 dnl Check for db2html
110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
111 AC_SUBST(DB2HTML)
113 dnl Check for db2pdf
114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
115 AC_SUBST(DB2PDF)
117 dnl Check for db2ps
118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
119 AC_SUBST(DB2PS)
121 dnl Check for db2txt
122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
123 AC_SUBST(DB2TXT)
125 dnl **** Check for some libraries ****
127 dnl Check for -li386 for NetBSD and OpenBSD
128 AC_CHECK_LIB(i386,i386_set_ldt)
129 dnl Check for -lossaudio for NetBSD
130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
131 dnl Check for -lw for Solaris
132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
133 dnl Check for -lnsl for Solaris
134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
135 dnl Check for -lsocket for Solaris
136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
137 dnl Check for -lresolv for Solaris
138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
139 dnl Check for -lxpg4 for FreeBSD
140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
141 dnl Check for -lpoll for Mac OS X/Darwin
142 AC_CHECK_LIB(poll,poll)
143 dnl Check for -lresolv for Mac OS X/Darwin
144 AC_CHECK_LIB(resolv,res_9_init)
145 dnl Check for -lpthread
146 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
148 JPEGLIB=""
149 AC_SUBST(JPEGLIB)
150 AC_CHECK_HEADERS(jpeglib.h,
151 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
152 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
153 JPEGLIB="-ljpeg"
154 )
155 )
157 AC_SUBST(GIFLIB,"")
158 AC_CHECK_HEADERS(gif_lib.h,
159 AC_CHECK_LIB(ungif,DGifOpen,
160 [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
161 GIFLIB="-lungif"],
162 [AC_CHECK_LIB(gif,DGifOpen,
163 [AC_DEFINE(HAVE_LIBGIF,1)
164 GIFLIB="-lgif"])]))
166 AC_SUBST(XLIB)
167 AC_SUBST(XFILES)
168 XFILES=""
169 AC_SUBST(OPENGLFILES)
170 OPENGLFILES=""
171 AC_SUBST(GLU32FILES)
172 GLU32FILES=""
173 AC_SUBST(OPENGL_LIBS)
174 OPENGL_LIBS=""
175 if test "$have_x" = "yes"
176 then
177 XLIB="-lXext -lX11"
178 ac_save_CPPFLAGS="$CPPFLAGS"
179 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
181 dnl *** All of the following tests require X11/Xlib.h
182 AC_CHECK_HEADERS(X11/Xlib.h,
183 [
184 AC_CHECK_HEADERS([X11/XKBlib.h \
185 X11/Xutil.h \
186 X11/extensions/shape.h \
187 X11/extensions/XInput.h \
188 X11/extensions/XShm.h \
189 X11/extensions/Xrandr.h \
190 X11/extensions/Xrender.h \
191 X11/extensions/Xvlib.h \
192 X11/extensions/xf86dga.h \
193 X11/extensions/xf86vmode.h],,,
194 [#include <X11/Xlib.h>
195 #ifdef HAVE_X11_XUTIL_H
196 # include <X11/Xutil.h>
197 #endif])
199 dnl *** Check for X keyboard extension
200 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
201 then
202 AC_CHECK_LIB(X11, XkbQueryExtension,
203 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
204 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
205 fi
207 dnl *** Check for X Shm extension
208 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
209 then
210 AC_CHECK_LIB(Xext, XShmQueryExtension,
211 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
212 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
213 fi
215 dnl *** Check for X shape extension
216 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
217 then
218 AC_CHECK_LIB(Xext,XShapeQueryExtension,
219 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
220 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
221 fi
223 dnl *** Check for XFree86 DGA / DGA 2.0 extension
224 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
225 then
226 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
227 [ dnl *** If found...
228 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
229 [Define if you have the Xxf86dga library version 2])
230 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
231 ],
232 [ dnl *** If not found, look for XF86DGAQueryExtension()
233 dnl *** instead (DGA 2.0 not found)...
234 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
235 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
236 [Define if you have the Xxf86dga library version 1])
237 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
238 ],,
239 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
240 )
241 ],
242 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
243 fi
245 dnl *** Check for XFree86 VMODE extension
246 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
247 then
248 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
249 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
250 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
251 ],,
252 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
253 fi
255 dnl *** Check for X RandR extension
256 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
257 then
258 AC_TRY_COMPILE([#include <X11/Xlib.h>
259 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
260 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
261 fi
263 dnl *** Check for XVideo extension supporting XvImages
264 if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
265 then
266 AC_CHECK_LIB(Xv, XvShmCreateImage,
267 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
268 X_PRE_LIBS="$X_PRE_LIBS -lXv"
269 ],,
270 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
271 fi
272 ]
273 ) dnl *** End of X11/Xlib.h check
275 dnl Check for the presence of OpenGL
276 if test "x$with_opengl" != "xno"
277 then
278 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
279 then
280 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
281 This prevents linking to OpenGL. Delete the file and restart configure.])
282 fi
284 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
285 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
286 then
287 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
288 dnl Check for some problems due to old Mesa versions
289 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
290 AC_TRY_COMPILE(
291 [#include <GL/gl.h>],
292 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
293 [wine_cv_opengl_version_OK="yes"],
294 [wine_cv_opengl_version_OK="no"]
295 )
296 )
298 if test "$wine_cv_opengl_version_OK" = "yes"
299 then
300 dnl Check for the presence of the library
301 AC_CHECK_LIB(GL,glXCreateContext,
302 OPENGL_LIBS="-lGL"
303 ,,
304 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
306 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
307 then
308 OPENGLFILES='$(OPENGLFILES)'
309 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
311 AC_CHECK_LIB(GL,glXGetProcAddressARB,
312 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
313 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
314 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
316 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
317 then
318 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
319 [AC_TRY_COMPILE([#include <GL/gl.h>
320 #ifdef HAVE_GL_GLEXT_H
321 # include <GL/glext.h>
322 #endif
323 ],
324 [PFNGLCOLORTABLEEXTPROC test_proc;],
325 [wine_cv_extension_prototypes="yes"],
326 [wine_cv_extension_prototypes="no"]
327 )]
328 )
329 if test "$wine_cv_extension_prototypes" = "yes"
330 then
331 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
332 [Define if the OpenGL headers define extension typedefs])
333 fi
334 fi
336 fi
337 dnl Check for GLU32 library.
338 AC_CHECK_LIB(GLU,gluLookAt,
339 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
340 GLU32FILES='$(GLU32FILES)']
341 ,,
342 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
343 )
344 fi
346 dnl Check for glut32 library.
347 AC_CHECK_LIB(glut,glutMainLoop,
348 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
349 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
350 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
351 fi
352 fi
354 dnl **** Check for NAS ****
355 AC_SUBST(NASLIBS,"")
356 AC_CHECK_HEADERS(audio/audiolib.h,
357 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
358 AC_CHECK_LIB(audio,AuCreateFlow,
359 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
360 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
361 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
363 CPPFLAGS="$ac_save_CPPFLAGS"
364 XFILES='$(XFILES)'
365 else
366 XLIB=""
367 X_CFLAGS=""
368 X_LIBS=""
369 fi
371 dnl **** Check which curses lib to use ***
372 CURSESLIBS=""
373 if test "x$with_curses" != "xno"
374 then
375 AC_CHECK_HEADERS(ncurses.h,
376 [AC_CHECK_LIB(ncurses,waddch,
377 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
378 CURSESLIBS="-lncurses"],
379 [AC_CHECK_HEADERS(curses.h,
380 [AC_CHECK_LIB(curses,waddch,
381 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
382 CURSESLIBS="-lcurses"])])])])
383 saved_libs="$LIBS"
384 LIBS="$CURSESLIBS $LIBS"
385 AC_CHECK_FUNCS(getbkgd resizeterm)
386 LIBS="$saved_libs"
387 fi
388 AC_SUBST(CURSESLIBS)
390 dnl **** Check for SANE ****
391 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
392 if test "$sane_devel" = "no"
393 then
394 SANELIBS=""
395 SANEINCL=""
396 else
397 SANELIBS="`$sane_devel --libs`"
398 SANEINCL="`$sane_devel --cflags`"
399 ac_save_CPPFLAGS="$CPPFLAGS"
400 ac_save_LIBS="$LIBS"
401 CPPFLAGS="$CPPFLAGS $SANEINCL"
402 LIBS="$LIBS $SANELIBS"
403 AC_CHECK_HEADER(sane/sane.h,
404 [AC_CHECK_LIB(sane,sane_open,
405 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
406 [SANELIBS=""
407 SANEINCL=""])],
408 [SANELIBS=""
409 SANEINCL=""])
410 LIBS="$ac_save_LIBS"
411 CPPFLAGS="$ac_save_CPPFLAGS"
412 fi
413 AC_SUBST(SANELIBS)
414 AC_SUBST(SANEINCL)
416 dnl **** Check for the ICU library ****
417 AC_CHECK_HEADERS(unicode/ubidi.h)
418 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
419 then
420 saved_libs="$LIBS"
421 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
422 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
423 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
424 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
425 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
426 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
427 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
428 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
429 AC_MSG_RESULT(yes)],
430 [AC_MSG_RESULT(no)])
431 LIBS="$saved_libs"
432 fi
434 dnl **** Check for FreeType 2 ****
435 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
436 if test "$ft_lib" = "no"
437 then
438 FREETYPEINCL=""
439 wine_cv_msg_freetype=no
440 else
441 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
442 if test "$ft_devel" = "no"
443 then
444 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
445 if test "$ft_devel2" = "freetype2-config"
446 then
447 ft_devel=$ft_devel2
448 fi
449 fi
450 if test "$ft_devel" = "no"
451 then
452 FREETYPEINCL=""
453 wine_cv_msg_freetype=yes
454 else
455 FREETYPEINCL=`$ft_devel --cflags`
456 ac_save_CPPFLAGS="$CPPFLAGS"
457 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
458 AC_CHECK_HEADERS(ft2build.h \
459 freetype/freetype.h \
460 freetype/ftglyph.h \
461 freetype/tttables.h \
462 freetype/ftnames.h \
463 freetype/ftsnames.h \
464 freetype/ttnameid.h \
465 freetype/ftoutln.h \
466 freetype/ftwinfnt.h \
467 freetype/internal/sfnt.h,,,
468 [#if HAVE_FT2BUILD_H
469 #include <ft2build.h>
470 #endif])
471 AC_TRY_CPP([#include <ft2build.h>
472 #include <freetype/fttrigon.h>],
473 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
474 [Define if you have the <freetype/fttrigon.h> header file.])
475 wine_cv_fttrigon=yes],
476 wine_cv_fttrigon=no)
477 CPPFLAGS="$ac_save_CPPFLAGS"
478 dnl Check that we have at least freetype/freetype.h
479 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
480 then
481 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
482 wine_cv_msg_freetype=no
483 else
484 FREETYPEINCL=""
485 wine_cv_msg_freetype=yes
486 fi
487 fi
488 fi
489 AC_SUBST(FREETYPEINCL)
491 dnl **** Check for parport (currently Linux only) ****
492 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
493 AC_TRY_COMPILE(
494 [#include <linux/ppdev.h>],
495 [ioctl (1,PPCLAIM,0)],
496 [ac_cv_c_ppdev="yes"],
497 [ac_cv_c_ppdev="no"])
498 )
499 if test "$ac_cv_c_ppdev" = "yes"
500 then
501 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
502 fi
504 dnl **** Check for va_copy ****
505 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
506 AC_TRY_LINK(
507 [#include <stdarg.h>],
508 [va_list ap1, ap2;
509 va_copy(ap1,ap2);
510 ],
511 [ac_cv_c_va_copy="yes"],
512 [ac_cv_c_va_copy="no"])
513 )
514 if test "$ac_cv_c_va_copy" = "yes"
515 then
516 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
517 fi
518 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
519 AC_TRY_LINK(
520 [#include <stdarg.h>],
521 [va_list ap1, ap2;
522 __va_copy(ap1,ap2);
523 ],
524 [ac_cv_c___va_copy="yes"],
525 [ac_cv_c___va_copy="no"])
526 )
527 if test "$ac_cv_c___va_copy" = "yes"
528 then
529 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
530 fi
532 dnl **** Check for sigsetjmp ****
533 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
534 AC_TRY_LINK(
535 [#include <setjmp.h>],
536 [sigjmp_buf buf;
537 sigsetjmp( buf, 1 );
538 siglongjmp( buf, 1 );],
539 [ac_cv_c_sigsetjmp="yes"],
540 [ac_cv_c_sigsetjmp="no"])
541 )
542 if test "$ac_cv_c_sigsetjmp" = "yes"
543 then
544 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
545 fi
547 dnl **** Check for pthread_rwlock_t ****
548 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
549 #include <pthread.h>])
551 dnl **** Check for pthread_getattr_np ****
552 ac_save_LIBS="$LIBS"
553 LIBS="$LIBS $LIBPTHREAD"
554 AC_CHECK_FUNCS(pthread_getattr_np)
555 LIBS="$ac_save_LIBS"
557 dnl **** Check for Open Sound System ****
558 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
560 AC_CACHE_CHECK([for Open Sound System],
561 ac_cv_c_opensoundsystem,
562 AC_TRY_COMPILE([
563 #if defined(HAVE_SYS_SOUNDCARD_H)
564 #include <sys/soundcard.h>
565 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
566 #include <machine/soundcard.h>
567 #elif defined(HAVE_SOUNDCARD_H)
568 #include <soundcard.h>
569 #endif
570 ],[
572 /* check for one of the Open Sound System specific SNDCTL_ defines */
573 #if !defined(SNDCTL_DSP_STEREO)
574 #error No open sound system
575 #endif
576 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
578 if test "$ac_cv_c_opensoundsystem" = "yes"
579 then
580 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
581 fi
583 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
584 ac_cv_c_opensoundsystem_midi,
585 AC_TRY_COMPILE([
586 #if defined(HAVE_SYS_SOUNDCARD_H)
587 #include <sys/soundcard.h>
588 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
589 #include <machine/soundcard.h>
590 #elif defined(HAVE_SOUNDCARD_H)
591 #include <soundcard.h>
592 #endif
593 ],[
595 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
596 #if !defined(SNDCTL_SEQ_SYNC)
597 #error No open sound system MIDI interface
598 #endif
599 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
601 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
602 then
603 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
604 fi
606 dnl **** Check for aRts Sound Server ****
607 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
608 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
609 then
610 ARTSC_CFLAGS=""
611 for i in `$ARTSCCONFIG --cflags`
612 do
613 case "$i" in
614 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
615 esac
616 done
617 ARTSC_LIBS=`$ARTSCCONFIG --libs`
618 save_CFLAGS="$CFLAGS"
619 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
620 AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
621 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
622 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
623 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
624 CFLAGS="$save_CFLAGS"
625 fi
627 dnl **** Check for ALSA ****
628 AC_SUBST(ALSALIBS,"")
629 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
630 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
631 then
632 AC_CHECK_LIB(asound,snd_pcm_open,
633 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
634 ALSALIBS="-lasound")
635 fi
637 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
639 AC_SUBST(AUDIOIOLIBS,"")
640 AC_CHECK_HEADERS(libaudioio.h,
641 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
642 [AUDIOIOLIBS="-laudioio"
643 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
645 dnl **** Check for capi4linux ****
647 AC_CHECK_HEADERS(capi20.h,[
648 AC_CHECK_HEADERS(linux/capi.h,[
649 AC_CHECK_LIB(capi20,capi20_register,[
650 AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
651 AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
652 ])
653 ])
654 ])
656 dnl **** Check for broken glibc mmap64 ****
658 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
659 AC_TRY_RUN([
660 #define _FILE_OFFSET_BITS 64
661 #include <stdio.h>
662 #include <unistd.h>
663 #include <fcntl.h>
664 #include <sys/mman.h>
665 #include <errno.h>
667 int main(int argc,char **argv) {
668 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
669 if (fd == -1) exit(1);
671 unlink("conftest.map");
673 write(fd,"test",4);
675 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
676 (errno == EINVAL)
677 ) {
678 exit(1);
679 }
680 close(fd);
681 fprintf(stderr,"success!\n");
682 exit(0);
683 }
685 ],
686 ac_cv_mmap64_works="yes",
687 ac_cv_mmap64_works="no",
688 ac_cv_mmap64_works="no") )
690 if test "$ac_cv_mmap64_works" = "yes"
691 then
692 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
693 fi
695 dnl **** Check for gcc specific options ****
697 AC_SUBST(EXTRACFLAGS,"")
698 if test "x${GCC}" = "xyes"
699 then
700 EXTRACFLAGS="-Wall -pipe"
702 dnl Check for strength-reduce bug
703 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
704 AC_TRY_RUN([
705 int L[[4]] = {0,1,2,3};
706 int main(void) {
707 static int Array[[3]];
708 unsigned int B = 3;
709 int i;
710 for(i=0; i<B; i++) Array[[i]] = i - 3;
711 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
712 L[[i]] = 4;
714 exit( Array[[1]] != -2 || L[[2]] != 3);
715 }],
716 ac_cv_c_gcc_strength_bug="no",
717 ac_cv_c_gcc_strength_bug="yes",
718 ac_cv_c_gcc_strength_bug="yes") )
719 if test "$ac_cv_c_gcc_strength_bug" = "yes"
720 then
721 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
722 fi
724 dnl Check for -fshort-wchar
725 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
726 [WINE_TRY_CFLAGS([-fshort-wchar],
727 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
728 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
729 then
730 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
731 fi
733 dnl Check for -mpreferred-stack-boundary
734 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
735 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
736 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
737 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
738 then
739 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
740 fi
742 dnl Check for -fno-strict-aliasing
743 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
744 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
745 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
746 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
747 then
748 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
749 fi
751 dnl Check for -gstabs+ option
752 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
753 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
754 if test "$ac_cv_c_gcc_gstabs" = "yes"
755 then
756 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
757 fi
759 dnl Check for noisy string.h
760 saved_CFLAGS="$CFLAGS"
761 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
762 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
763 AC_TRY_COMPILE([#include <string.h>],[],
764 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
765 CFLAGS="$saved_CFLAGS"
766 if test "$ac_cv_c_string_h_warnings" = "no"
767 then
768 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
769 fi
770 fi
772 dnl **** Check how to define a function in assembly code ****
774 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
775 WINE_TRY_ASM_LINK(
776 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
777 ac_cv_asm_func_def=".def",
778 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
779 ac_cv_asm_func_def=".type @function",
780 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
781 ac_cv_asm_func_def=".type 2",
782 ac_cv_asm_func_def="unknown")])]))
784 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
785 case "$ac_cv_asm_func_def" in
786 ".def")
787 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
788 ".type @function")
789 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
790 ".type 2")
791 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
792 *)
793 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
794 esac
796 dnl **** Check for underscore on external symbols ****
798 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
799 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
800 [extern int ac_test;],
801 [if (ac_test) return 1],
802 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
804 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
805 if test "$ac_cv_c_extern_prefix" = "yes"
806 then
807 AC_DEFINE([__ASM_NAME(name)], ["_" name])
808 else
809 AC_DEFINE([__ASM_NAME(name)], [name])
810 fi
812 dnl **** Check how to do strings in assembler ****
814 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
815 WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
816 WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
817 WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
818 AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
820 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
821 [Define to the assembler keyword used to specify an ASCII string])
823 dnl **** Check for .short in assembler ****
825 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
826 WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
827 WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
828 AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
830 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
831 [Define to the assembler keyword used to specify a word value])
833 dnl **** Check for .size in assembler ****
835 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
836 WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
837 ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
839 if test "$ac_cv_c_asm_size" = "yes"
840 then
841 AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
842 fi
844 dnl **** Check for working dll ****
846 AC_SUBST(DLLEXT,"")
847 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
848 AC_SUBST(DLLIBS,"")
849 AC_SUBST(LDSHARED,"")
850 AC_SUBST(LDDLLFLAGS,"")
851 AC_SUBST(LIBEXT,"so")
852 AC_SUBST(IMPLIBEXT,"def")
854 case $host_os in
855 cygwin*|mingw32*)
856 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
857 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
858 if test "$DLLWRAP" = "false"; then
859 LIBEXT="a"
860 else
861 dnl FIXME - check whether dllwrap works correctly...
862 LIBEXT="dll"
863 fi
864 IMPLIBEXT="a"
865 ;;
866 *)
867 AC_CHECK_HEADERS(dlfcn.h,
868 [AC_CHECK_FUNCS(dlopen,,
869 [AC_CHECK_LIB(dl,dlopen,
870 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
871 DLLIBS="-ldl"],
872 [LIBEXT="a"])])],
873 [LIBEXT="a"])
875 if test "$LIBEXT" = "so"
876 then
877 DLLFLAGS="$DLLFLAGS -fPIC"
878 DLLEXT=".so"
879 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
880 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
881 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
882 if test "$ac_cv_c_dll_gnuelf" = "yes"
883 then
884 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
885 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
886 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
887 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
888 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
889 if test "$ac_cv_c_dll_zdefs" = "yes"
890 then
891 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
892 fi
894 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
895 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
896 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
897 if test "$ac_cv_c_dll_init_fini" = "yes"
898 then
899 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
900 fi
902 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
903 [echo '{ global: *; };' >conftest.map
904 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
905 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
906 rm -f conftest.map])
907 if test "$ac_cv_c_ld_version_scripts" = "yes"
908 then
909 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
910 fi
912 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
913 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
914 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
915 if test "$ac_cv_c_export_dynamic" = "yes"
916 then
917 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
918 fi
920 case $host_cpu in
921 *i[[3456789]]86*)
922 AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
923 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
924 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
925 if test "$ac_cv_ld_reloc_exec" = "yes"
926 then
927 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
928 fi
929 ;;
930 esac
932 else
933 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
934 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
935 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
936 if test "$ac_cv_c_dll_unixware" = "yes"
937 then
938 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
939 LDDLLFLAGS="-Wl,-G,-B,symbolic"
941 else
942 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
943 [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
944 if test "$ac_cv_c_dll_macho" = "yes"
945 then
946 LIBEXT="dylib"
947 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
948 LDSHARED="\$(CC) -dynamiclib"
949 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
950 STRIP="$STRIP -u -r"
951 fi
952 fi
953 fi
954 fi
956 dnl Check for cross compiler to build test programs
957 AC_SUBST(CROSSTEST,"")
958 if test "$cross_compiling" = "no"
959 then
960 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
961 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
962 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
963 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
964 fi
965 ;;
966 esac
968 if test "$LIBEXT" = "a"; then
969 AC_MSG_ERROR(
970 [could not find a way to build shared libraries.
971 It is currently not possible to build Wine without shared library
972 (.so) support to allow transparent switch between .so and .dll files.
973 If you are using Linux, you will need a newer binutils.]
974 )
975 fi
977 case $build_os in
978 cygwin*|mingw32*)
979 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
980 darwin*|macosx*)
981 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
982 *)
983 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
984 esac
986 dnl Mingw needs explicit msvcrt for linking libwine
987 case $host_os in
988 mingw32*)
989 AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
990 esac
992 case $host_os in
993 linux*)
994 AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
995 AC_SUBST(MAIN_BINARY,"wine-glibc")
996 ;;
997 darwin*)
998 AC_SUBST(WINE_BINARIES,"wine-pthread")
999 AC_SUBST(MAIN_BINARY,"wine-pthread")
1000 ;;
1001 *)
1002 AC_SUBST(WINE_BINARIES,"wine-kthread")
1003 AC_SUBST(MAIN_BINARY,"wine-kthread")
1004 ;;
1005 esac
1007 dnl **** Get the soname for libraries that we load dynamically ****
1009 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1010 then
1011 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1012 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1013 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1014 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1015 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1016 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1017 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1018 WINE_GET_SONAME(cups,cupsGetDefault)
1019 WINE_GET_SONAME(jack,jack_client_new)
1020 WINE_GET_SONAME(fontconfig,FcInit)
1021 WINE_GET_SONAME(ssl,SSL_library_init)
1022 WINE_GET_SONAME(crypto,BIO_new_socket)
1023 WINE_GET_SONAME(ncurses,waddch)
1024 WINE_GET_SONAME(curses,waddch)
1025 fi
1028 dnl **** Check for functions ****
1030 AC_FUNC_ALLOCA()
1031 AC_CHECK_FUNCS(\
1032 _lwp_create \
1033 _lwp_self \
1034 _pclose \
1035 _popen \
1036 _snprintf \
1037 _spawnvp \
1038 _stricmp \
1039 _strnicmp \
1040 _vsnprintf \
1041 chsize \
1042 clone \
1043 finite \
1044 fpclass \
1045 fstatfs \
1046 fstatvfs \
1047 ftruncate \
1048 ftruncate64 \
1049 futimes \
1050 getnetbyaddr \
1051 getnetbyname \
1052 getopt_long \
1053 getpagesize \
1054 getprotobyname \
1055 getprotobynumber \
1056 getpwuid \
1057 getservbyport \
1058 gettid \
1059 gettimeofday \
1060 inet_network \
1061 lseek64 \
1062 lstat \
1063 memmove \
1064 mmap \
1065 pclose \
1066 popen \
1067 pread \
1068 pwrite \
1069 readlink \
1070 rfork \
1071 select \
1072 sendmsg \
1073 settimeofday \
1074 sigaltstack \
1075 snprintf \
1076 spawnvp \
1077 statfs \
1078 statvfs \
1079 strcasecmp \
1080 strerror \
1081 strncasecmp \
1082 tcgetattr \
1083 timegm \
1084 usleep \
1085 vfscanf \
1086 vsnprintf \
1087 wait4 \
1088 waitpid \
1089 )
1091 dnl **** Check for header files ****
1093 AC_CHECK_HEADERS(\
1094 arpa/inet.h \
1095 arpa/nameser.h \
1096 cups/cups.h \
1097 direct.h \
1098 elf.h \
1099 float.h \
1100 fontconfig/fontconfig.h \
1101 getopt.h \
1102 ieeefp.h \
1103 io.h \
1104 jack/jack.h \
1105 libio.h \
1106 libutil.h \
1107 link.h \
1108 linux/cdrom.h \
1109 linux/hdreg.h \
1110 linux/input.h \
1111 linux/ioctl.h \
1112 linux/joystick.h \
1113 linux/major.h \
1114 linux/param.h \
1115 linux/serial.h \
1116 linux/ucdrom.h \
1117 machine/cpu.h \
1118 mntent.h \
1119 netdb.h \
1120 netinet/in.h \
1121 netinet/in_systm.h \
1122 netinet/tcp.h \
1123 netinet/tcp_fsm.h \
1124 openssl/ssl.h \
1125 process.h \
1126 pthread.h \
1127 pty.h \
1128 pwd.h \
1129 regex.h \
1130 sched.h \
1131 scsi/sg.h \
1132 scsi/scsi.h \
1133 scsi/scsi_ioctl.h \
1134 socket.h \
1135 stdint.h \
1136 strings.h \
1137 sys/cdio.h \
1138 sys/elf32.h \
1139 sys/errno.h \
1140 sys/exec_elf.h \
1141 sys/file.h \
1142 sys/filio.h \
1143 sys/inttypes.h \
1144 sys/ioctl.h \
1145 sys/ipc.h \
1146 sys/link.h \
1147 sys/lwp.h \
1148 sys/mman.h \
1149 sys/modem.h \
1150 sys/msg.h \
1151 sys/param.h \
1152 sys/poll.h \
1153 sys/ptrace.h \
1154 sys/reg.h \
1155 sys/scsiio.h \
1156 sys/shm.h \
1157 sys/signal.h \
1158 sys/socket.h \
1159 sys/sockio.h \
1160 sys/statfs.h \
1161 sys/statvfs.h \
1162 sys/strtio.h \
1163 sys/syscall.h \
1164 sys/sysctl.h \
1165 sys/time.h \
1166 sys/times.h \
1167 sys/uio.h \
1168 sys/un.h \
1169 sys/v86.h \
1170 sys/v86intr.h \
1171 sys/vfs.h \
1172 sys/vm86.h \
1173 sys/wait.h \
1174 syscall.h \
1175 termios.h \
1176 unistd.h \
1177 utime.h \
1178 valgrind/memcheck.h
1179 )
1180 AC_HEADER_STAT()
1182 dnl **** Checks for headers that depend on other ones ****
1184 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1185 [#include <sys/types.h>
1186 #if HAVE_SYS_PARAM_H
1187 # include <sys/param.h>
1188 #endif])
1190 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1191 [#include <sys/types.h>
1192 #if HAVE_SYS_SOCKET_H
1193 # include <sys/socket.h>
1194 #endif])
1196 AC_CHECK_HEADERS([resolv.h],,,
1197 [#include <sys/types.h>
1198 #if HAVE_SYS_SOCKET_H
1199 # include <sys/socket.h>
1200 #endif
1201 #if HAVE_NETINET_IN_H
1202 # include <netinet/in.h>
1203 #endif
1204 #if HAVE_ARPA_NAMESER_H
1205 # include <arpa/nameser.h>
1206 #endif])
1208 AC_CHECK_HEADERS(netinet/ip.h,,,
1209 [#include <sys/types.h>
1210 #if HAVE_SYS_SOCKET_H
1211 # include <sys/socket.h>
1212 #endif
1213 #if HAVE_NETINET_IN_SYSTM_H
1214 # include <netinet/in_systm.h>
1215 #endif])
1217 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1219 dnl **** Check for IPX headers (currently Linux only) ****
1221 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1222 AC_TRY_COMPILE(
1223 [#include <sys/types.h>
1224 #ifdef HAVE_SYS_SOCKET_H
1225 # include <sys/socket.h>
1226 #endif
1227 #include <netipx/ipx.h>],
1228 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1229 [ac_cv_c_ipx_gnu="yes"],
1230 [ac_cv_c_ipx_gnu="no"])
1231 )
1232 if test "$ac_cv_c_ipx_gnu" = "yes"
1233 then
1234 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1235 fi
1237 if test "$ac_cv_c_ipx_gnu" = "no"
1238 then
1239 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1240 AC_TRY_COMPILE(
1241 [#include <sys/types.h>
1242 #ifdef HAVE_SYS_SOCKET_H
1243 # include <sys/socket.h>
1244 #endif
1245 #include <asm/types.h>
1246 #include <linux/ipx.h>],
1247 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1248 [ac_cv_c_ipx_linux="yes"],
1249 [ac_cv_c_ipx_linux="no"])
1250 )
1251 if test "$ac_cv_c_ipx_linux" = "yes"
1252 then
1253 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1254 fi
1255 fi
1257 dnl **** Check for types ****
1259 AC_C_CONST
1260 AC_C_INLINE
1261 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1263 AC_CACHE_CHECK([whether linux/input.h is for real],
1264 wine_cv_linux_input_h,
1265 AC_TRY_COMPILE([
1266 #include <linux/input.h>
1267 ] , [
1268 int foo = EVIOCGBIT(EV_ABS,42);
1269 int bar = BTN_PINKIE;
1270 int fortytwo = 42;
1271 ],
1272 wine_cv_linux_input_h=yes,
1273 wine_cv_linux_input_h=no,
1274 no
1275 )
1276 )
1277 if test "$wine_cv_linux_input_h" = "yes"
1278 then
1279 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1280 [Define if we have linux/input.h AND it contains the INPUT event API])
1281 fi
1284 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1285 wine_cv_linux_gethostbyname_r_6,
1286 AC_TRY_LINK([
1287 #include <netdb.h>
1288 ], [
1289 char *name=NULL;
1290 struct hostent he;
1291 struct hostent *result;
1292 char *buf=NULL;
1293 int bufsize=0;
1294 int res,errnr;
1295 char *addr=NULL;
1296 int addrlen=0;
1297 int addrtype=0;
1298 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1299 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1300 ],
1301 wine_cv_linux_gethostbyname_r_6=yes,
1302 wine_cv_linux_gethostbyname_r_6=no
1303 )
1304 )
1305 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1306 then
1307 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1308 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1309 fi
1311 if test "$ac_cv_header_linux_joystick_h" = "yes"
1312 then
1313 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1314 wine_cv_linux_joystick_22_api,
1315 AC_TRY_COMPILE([
1316 #include <sys/ioctl.h>
1317 #include <linux/joystick.h>
1319 struct js_event blub;
1320 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1321 #error "no 2.2 header"
1322 #endif
1323 ],/*empty*/,
1324 wine_cv_linux_joystick_22_api=yes,
1325 wine_cv_linux_joystick_22_api=no,
1326 wine_cv_linux_joystick_22_api=no
1327 )
1328 )
1329 if test "$wine_cv_linux_joystick_22_api" = "yes"
1330 then
1331 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1332 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1333 fi
1334 fi
1336 dnl **** statfs checks ****
1338 if test "$ac_cv_header_sys_vfs_h" = "yes"
1339 then
1340 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1341 wine_cv_sys_vfs_has_statfs,
1342 AC_TRY_COMPILE([
1343 #include <sys/types.h>
1344 #ifdef HAVE_SYS_PARAM_H
1345 # include <sys/param.h>
1346 #endif
1347 #include <sys/vfs.h>
1348 ],[
1349 struct statfs stfs;
1351 memset(&stfs,0,sizeof(stfs));
1352 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1353 )
1354 )
1355 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1356 then
1357 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1358 [Define if the struct statfs is defined by <sys/vfs.h>])
1359 fi
1360 fi
1362 if test "$ac_cv_header_sys_statfs_h" = "yes"
1363 then
1364 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1365 wine_cv_sys_statfs_has_statfs,
1366 AC_TRY_COMPILE([
1367 #include <sys/types.h>
1368 #ifdef HAVE_SYS_PARAM_H
1369 # include <sys/param.h>
1370 #endif
1371 #include <sys/statfs.h>
1372 ],[
1373 struct statfs stfs;
1374 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1375 )
1376 )
1377 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1378 then
1379 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1380 [Define if the struct statfs is defined by <sys/statfs.h>])
1381 fi
1382 fi
1384 if test "$ac_cv_header_sys_mount_h" = "yes"
1385 then
1386 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1387 wine_cv_sys_mount_has_statfs,
1388 AC_TRY_COMPILE([
1389 #include <sys/types.h>
1390 #ifdef HAVE_SYS_PARAM_H
1391 # include <sys/param.h>
1392 #endif
1393 #include <sys/mount.h>
1394 ],[
1395 struct statfs stfs;
1396 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1397 )
1398 )
1399 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1400 then
1401 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1402 [Define if the struct statfs is defined by <sys/mount.h>])
1403 fi
1404 fi
1406 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1408 dnl Check for statfs members
1409 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1410 [#include <sys/types.h>
1411 #ifdef HAVE_SYS_PARAM_H
1412 # include <sys/param.h>
1413 #endif
1414 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1415 # include <sys/mount.h>
1416 #else
1417 # ifdef STATFS_DEFINED_BY_SYS_VFS
1418 # include <sys/vfs.h>
1419 # else
1420 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1421 # include <sys/statfs.h>
1422 # endif
1423 # endif
1424 #endif])
1426 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1427 [#ifdef HAVE_SYS_STATVFS_H
1428 #include <sys/statvfs.h>
1429 #endif])
1431 dnl Check for socket structure members
1432 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1433 [#include <sys/types.h>
1434 #ifdef HAVE_SYS_SOCKET_H
1435 # include <sys/socket.h>
1436 #endif
1437 #ifdef HAVE_SYS_UN_H
1438 # include <sys/un.h>
1439 #endif])
1441 dnl Check for siginfo_t members
1442 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1444 dnl Check for struct option
1445 AC_CHECK_MEMBERS([struct option.name],,,
1446 [#ifdef HAVE_GETOPT_H
1447 #include <getopt.h>
1448 #endif])
1450 dnl Check for stat.st_blocks
1451 AC_CHECK_MEMBERS([struct stat.st_blocks])
1453 dnl *** check for the need to define platform-specific symbols
1455 case $host_cpu in
1456 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1457 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1458 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1459 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1460 esac
1462 case $host_vendor in
1463 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1464 esac
1466 dnl **** Generate output files ****
1468 AH_TOP([#define __WINE_CONFIG_H])
1470 WINE_CONFIG_EXTRA_DIR(controls)
1471 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1472 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1473 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1476 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1477 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1478 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1479 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1480 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1481 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1482 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1483 WINE_CONFIG_EXTRA_DIR(include/wine)
1484 WINE_CONFIG_EXTRA_DIR(misc)
1485 WINE_CONFIG_EXTRA_DIR(objects)
1486 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1487 WINE_CONFIG_EXTRA_DIR(windows)
1489 MAKE_RULES=Make.rules
1490 AC_SUBST_FILE(MAKE_RULES)
1492 MAKE_DLL_RULES=dlls/Makedll.rules
1493 AC_SUBST_FILE(MAKE_DLL_RULES)
1495 MAKE_TEST_RULES=dlls/Maketest.rules
1496 AC_SUBST_FILE(MAKE_TEST_RULES)
1498 MAKE_LIB_RULES=libs/Makelib.rules
1499 AC_SUBST_FILE(MAKE_LIB_RULES)
1501 MAKE_PROG_RULES=programs/Makeprog.rules
1502 AC_SUBST_FILE(MAKE_PROG_RULES)
1504 AC_CONFIG_FILES([
1505 Make.rules
1506 dlls/Makedll.rules
1507 dlls/Maketest.rules
1508 libs/Makelib.rules
1509 programs/Makeprog.rules
1510 Makefile
1511 dlls/Makefile
1512 dlls/advapi32/Makefile
1513 dlls/advapi32/tests/Makefile
1514 dlls/amstream/Makefile
1515 dlls/atl/Makefile
1516 dlls/avicap32/Makefile
1517 dlls/avifil32/Makefile
1518 dlls/cabinet/Makefile
1519 dlls/capi2032/Makefile
1520 dlls/cards/Makefile
1521 dlls/cfgmgr32/Makefile
1522 dlls/comcat/Makefile
1523 dlls/comctl32/Makefile
1524 dlls/comctl32/tests/Makefile
1525 dlls/commdlg/Makefile
1526 dlls/crtdll/Makefile
1527 dlls/crypt32/Makefile
1528 dlls/ctl3d/Makefile
1529 dlls/d3d8/Makefile
1530 dlls/d3d9/Makefile
1531 dlls/d3dim/Makefile
1532 dlls/d3drm/Makefile
1533 dlls/d3dx8/Makefile
1534 dlls/d3dxof/Makefile
1535 dlls/dbghelp/Makefile
1536 dlls/dciman32/Makefile
1537 dlls/ddraw/Makefile
1538 dlls/ddraw/tests/Makefile
1539 dlls/devenum/Makefile
1540 dlls/dinput/Makefile
1541 dlls/dinput8/Makefile
1542 dlls/dmband/Makefile
1543 dlls/dmcompos/Makefile
1544 dlls/dmime/Makefile
1545 dlls/dmloader/Makefile
1546 dlls/dmscript/Makefile
1547 dlls/dmstyle/Makefile
1548 dlls/dmsynth/Makefile
1549 dlls/dmusic/Makefile
1550 dlls/dmusic32/Makefile
1551 dlls/dplay/Makefile
1552 dlls/dplayx/Makefile
1553 dlls/dpnet/Makefile
1554 dlls/dpnhpast/Makefile
1555 dlls/dsound/Makefile
1556 dlls/dsound/tests/Makefile
1557 dlls/dswave/Makefile
1558 dlls/dxdiagn/Makefile
1559 dlls/dxerr8/Makefile
1560 dlls/dxerr9/Makefile
1561 dlls/dxguid/Makefile
1562 dlls/gdi/Makefile
1563 dlls/gdi/tests/Makefile
1564 dlls/glu32/Makefile
1565 dlls/glut32/Makefile
1566 dlls/hhctrl.ocx/Makefile
1567 dlls/iccvid/Makefile
1568 dlls/icmp/Makefile
1569 dlls/ifsmgr.vxd/Makefile
1570 dlls/imagehlp/Makefile
1571 dlls/imm32/Makefile
1572 dlls/iphlpapi/Makefile
1573 dlls/iphlpapi/tests/Makefile
1574 dlls/kernel/Makefile
1575 dlls/kernel/tests/Makefile
1576 dlls/lzexpand/Makefile
1577 dlls/mapi32/Makefile
1578 dlls/mapi32/tests/Makefile
1579 dlls/mmdevldr.vxd/Makefile
1580 dlls/monodebg.vxd/Makefile
1581 dlls/mpr/Makefile
1582 dlls/msacm/Makefile
1583 dlls/msacm/imaadp32/Makefile
1584 dlls/msacm/msadp32/Makefile
1585 dlls/msacm/msg711/Makefile
1586 dlls/msacm/winemp3/Makefile
1587 dlls/msacm/tests/Makefile
1588 dlls/msdmo/Makefile
1589 dlls/mshtml/Makefile
1590 dlls/msi/Makefile
1591 dlls/msimg32/Makefile
1592 dlls/msisys/Makefile
1593 dlls/msnet32/Makefile
1594 dlls/msrle32/Makefile
1595 dlls/msvcrt/Makefile
1596 dlls/msvcrt/tests/Makefile
1597 dlls/msvcrt20/Makefile
1598 dlls/msvcrt40/Makefile
1599 dlls/msvcrtd/Makefile
1600 dlls/msvcrtd/tests/Makefile
1601 dlls/msvidc32/Makefile
1602 dlls/msvideo/Makefile
1603 dlls/mswsock/Makefile
1604 dlls/netapi32/Makefile
1605 dlls/netapi32/tests/Makefile
1606 dlls/newdev/Makefile
1607 dlls/ntdll/Makefile
1608 dlls/ntdll/tests/Makefile
1609 dlls/odbc32/Makefile
1610 dlls/ole32/Makefile
1611 dlls/oleacc/Makefile
1612 dlls/oleaut32/Makefile
1613 dlls/oleaut32/tests/Makefile
1614 dlls/olecli/Makefile
1615 dlls/oledlg/Makefile
1616 dlls/olepro32/Makefile
1617 dlls/olesvr/Makefile
1618 dlls/opengl32/Makefile
1619 dlls/psapi/Makefile
1620 dlls/psapi/tests/Makefile
1621 dlls/qcap/Makefile
1622 dlls/quartz/Makefile
1623 dlls/rasapi32/Makefile
1624 dlls/richedit/Makefile
1625 dlls/rpcrt4/Makefile
1626 dlls/rpcrt4/tests/Makefile
1627 dlls/rsabase/Makefile
1628 dlls/secur32/Makefile
1629 dlls/serialui/Makefile
1630 dlls/setupapi/Makefile
1631 dlls/shdocvw/Makefile
1632 dlls/shell32/Makefile
1633 dlls/shell32/tests/Makefile
1634 dlls/shfolder/Makefile
1635 dlls/shlwapi/Makefile
1636 dlls/shlwapi/tests/Makefile
1637 dlls/snmpapi/Makefile
1638 dlls/sti/Makefile
1639 dlls/tapi32/Makefile
1640 dlls/ttydrv/Makefile
1641 dlls/twain/Makefile
1642 dlls/unicows/Makefile
1643 dlls/url/Makefile
1644 dlls/urlmon/Makefile
1645 dlls/urlmon/tests/Makefile
1646 dlls/user/Makefile
1647 dlls/user/tests/Makefile
1648 dlls/uuid/Makefile
1649 dlls/uxtheme/Makefile
1650 dlls/vdhcp.vxd/Makefile
1651 dlls/vdmdbg/Makefile
1652 dlls/version/Makefile
1653 dlls/version/tests/Makefile
1654 dlls/vmm.vxd/Makefile
1655 dlls/vnbt.vxd/Makefile
1656 dlls/vnetbios.vxd/Makefile
1657 dlls/vtdapi.vxd/Makefile
1658 dlls/vwin32.vxd/Makefile
1659 dlls/win32s/Makefile
1660 dlls/winaspi/Makefile
1661 dlls/wined3d/Makefile
1662 dlls/winedos/Makefile
1663 dlls/wineps/Makefile
1664 dlls/wininet/Makefile
1665 dlls/wininet/tests/Makefile
1666 dlls/winmm/Makefile
1667 dlls/winmm/joystick/Makefile
1668 dlls/winmm/mcianim/Makefile
1669 dlls/winmm/mciavi/Makefile
1670 dlls/winmm/mcicda/Makefile
1671 dlls/winmm/mciseq/Makefile
1672 dlls/winmm/mciwave/Makefile
1673 dlls/winmm/midimap/Makefile
1674 dlls/winmm/tests/Makefile
1675 dlls/winmm/wavemap/Makefile
1676 dlls/winmm/winealsa/Makefile
1677 dlls/winmm/winearts/Makefile
1678 dlls/winmm/wineaudioio/Makefile
1679 dlls/winmm/winejack/Makefile
1680 dlls/winmm/winenas/Makefile
1681 dlls/winmm/wineoss/Makefile
1682 dlls/winnls/Makefile
1683 dlls/winsock/Makefile
1684 dlls/winsock/tests/Makefile
1685 dlls/winspool/Makefile
1686 dlls/winspool/tests/Makefile
1687 dlls/wintab32/Makefile
1688 dlls/wintrust/Makefile
1689 dlls/wow32/Makefile
1690 dlls/wsock32/Makefile
1691 dlls/x11drv/Makefile
1692 documentation/Makefile
1693 include/Makefile
1694 libs/Makefile
1695 libs/port/Makefile
1696 libs/unicode/Makefile
1697 libs/wine/Makefile
1698 libs/wpp/Makefile
1699 loader/Makefile
1700 programs/Makefile
1701 programs/avitools/Makefile
1702 programs/clock/Makefile
1703 programs/cmdlgtst/Makefile
1704 programs/control/Makefile
1705 programs/expand/Makefile
1706 programs/msiexec/Makefile
1707 programs/notepad/Makefile
1708 programs/progman/Makefile
1709 programs/regedit/Makefile
1710 programs/regsvr32/Makefile
1711 programs/rpcss/Makefile
1712 programs/rundll32/Makefile
1713 programs/start/Makefile
1714 programs/taskmgr/Makefile
1715 programs/uninstaller/Makefile
1716 programs/view/Makefile
1717 programs/wcmd/Makefile
1718 programs/wineboot/Makefile
1719 programs/winebrowser/Makefile
1720 programs/winecfg/Makefile
1721 programs/wineconsole/Makefile
1722 programs/winedbg/Makefile
1723 programs/winefile/Makefile
1724 programs/winemenubuilder/Makefile
1725 programs/winemine/Makefile
1726 programs/winepath/Makefile
1727 programs/winetest/Makefile
1728 programs/winevdm/Makefile
1729 programs/winhelp/Makefile
1730 programs/winver/Makefile
1731 server/Makefile
1732 tools/Makefile
1733 tools/widl/Makefile
1734 tools/winapi/Makefile
1735 tools/winebuild/Makefile
1736 tools/winedump/Makefile
1737 tools/winegcc/Makefile
1738 tools/wmc/Makefile
1739 tools/wrc/Makefile])
1741 AC_OUTPUT
1743 if test "$have_x" = "no"
1744 then
1745 echo
1746 echo "*** Warning: X development files not found. Wine will be built without"
1747 echo "*** X support, which currently does not work, and would probably not be"
1748 echo "*** what you want anyway. You will need to install devel packages of"
1749 echo "*** Xlib/Xfree86 at the very least."
1750 fi
1752 if test "$wine_cv_opengl_version_OK" = "no"
1753 then
1754 echo
1755 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1756 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1757 fi
1759 if test "$wine_cv_msg_freetype" = "yes"
1760 then
1761 echo
1762 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1763 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1764 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1765 echo "*** enable Wine to use TrueType fonts."
1766 fi
1768 echo
1769 echo "Configure finished. Do 'make depend && make' to compile Wine."
1770 echo
1772 dnl Local Variables:
1773 dnl comment-start: "dnl "
1774 dnl comment-end: ""
1775 dnl comment-start-skip: "\\bdnl\\b\\s *"
1776 dnl compile-command: "autoconf"
1777 dnl End: