configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXpm -lXext -lX11"
 100     dnl Check for -lXpm
 101     dnl FIXME: should be done once we can compile without -lXpm
 102     dnl AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 103     dnl Check for X Shm extension
 104     AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 105     dnl Check for XFree86 DGA extension
 106     AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 107     dnl Check for XFree86 VMODE extension
 108     AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 109 else
 110     XLIB=""
 111     X_CFLAGS=""
 112     X_LIBS=""
 113 fi
 114
 115 dnl **** Check which curses lib to use ***
 116 AC_CHECK_LIB(ncurses,waddch)
 117 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 118 then :
 119 else
 120     AC_CHECK_LIB(curses,waddch)
 121 fi
 122
 123 dnl **** Check for IPX (currently Linux only) ****
 124 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 125  AC_TRY_COMPILE(
 126    [#include <sys/socket.h>
 127     #include <netipx/ipx.h>],
 128    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 129    [AC_DEFINE(HAVE_IPX_GNU)
 130     ac_cv_c_ipx_gnu="yes"],
 131    [ac_cv_c_ipx_gnu="no"])
 132  )
 133
 134 if test "$ac_cv_c_ipx_gnu" = "no"
 135 then
 136  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 137   AC_TRY_COMPILE(
 138     [#include <sys/socket.h>
 139      #include <asm/types.h>
 140      #include <linux/ipx.h>],
 141     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 142     [AC_DEFINE(HAVE_IPX_LINUX)
 143      ac_cv_c_ipx_linux="yes"],
 144     [ac_cv_c_ipx_linux="no"])
 145   )
 146 fi
 147
 148 dnl **** Check for Open Sound System ****
 149 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 150
 151 AC_CACHE_CHECK("for Open Sound System",
 152         ac_cv_c_opensoundsystem,
 153         AC_TRY_COMPILE([
 154         #if defined(HAVE_SYS_SOUNDCARD_H)
 155                 #include <sys/soundcard.h>
 156         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 157                 #include <machine/soundcard.h>
 158         #elif defined(HAVE_SOUNDCARD_H)
 159                 #include <soundcard.h>
 160         #endif
 161         ],[
 162
 163 /* check for one of the Open Sound System specific SNDCTL_ defines */
 164 #if !defined(SNDCTL_DSP_STEREO)
 165 #error No open sound system
 166 #endif
 167 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 168
 169 if test "$ac_cv_c_opensoundsystem" = "yes"
 170 then
 171     AC_DEFINE(HAVE_OSS)
 172 fi
 173
 174 dnl **** Check for union semun ****
 175
 176 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 177  AC_TRY_COMPILE([#include <sys/types.h>
 178 #include <sys/sem.h>],[union semun foo],
 179                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 180 if test "$ac_cv_c_union_semun" = "yes"
 181 then
 182     AC_DEFINE(HAVE_UNION_SEMUN)
 183 fi
 184
 185 dnl **** If ln -s doesn't work, use cp instead ****
 186 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 187
 188 dnl **** Check for gcc strength-reduce bug ****
 189
 190 if test "x${GCC}" = "xyes"
 191 then
 192   CFLAGS="$CFLAGS -Wall"
 193   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 194                   AC_TRY_RUN([
 195 int main(void) {
 196   static int Array[[3]];
 197   unsigned int B = 3;
 198   int i;
 199   for(i=0; i<B; i++) Array[[i]] = i - 3;
 200   exit( Array[[1]] != -2 );
 201 }],
 202     ac_cv_c_gcc_strength_bug="no",
 203     ac_cv_c_gcc_strength_bug="yes",
 204     ac_cv_c_gcc_strength_bug="yes") )
 205   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 206   then
 207     CFLAGS="$CFLAGS -fno-strength-reduce"
 208   fi
 209 fi
 210
 211 dnl **** Check for underscore on external symbols ****
 212
 213 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 214                ac_cv_c_extern_prefix,
 215 [saved_libs=$LIBS
 216 LIBS="conftest_asm.s $LIBS"
 217 cat > conftest_asm.s <<EOF
 218         .globl _ac_test
 219 _ac_test:
 220         .long 0
 221 EOF
 222 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 223             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 224 LIBS=$saved_libs])
 225 if test "$ac_cv_c_extern_prefix" = "yes"
 226 then
 227   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 228 fi
 229
 230 dnl **** Check for .string in assembler ****
 231
 232 AC_CACHE_CHECK("whether assembler accepts .string",
 233                ac_cv_c_asm_string,
 234 [saved_libs=$LIBS
 235 LIBS="conftest_asm.s $LIBS"
 236 cat > conftest_asm.s <<EOF
 237         .string "test"
 238 EOF
 239 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 240 LIBS=$saved_libs])
 241 if test "$ac_cv_c_asm_string" = "yes"
 242 then
 243   AC_DEFINE(HAVE_ASM_STRING)
 244 fi
 245
 246 dnl **** Check for working dll ****
 247
 248 DLLFLAGS=""
 249 LDSHARED=""
 250 if test "$LIB_TARGET" = "libwine.so.1.0"
 251 then
 252   AC_CACHE_CHECK("whether we can build a Linux dll",
 253                  ac_cv_c_dll_linux,
 254   [saved_cflags=$CFLAGS
 255   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 256   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 257   CFLAGS=$saved_cflags
 258   ])
 259   if test "$ac_cv_c_dll_linux" = "yes"
 260   then
 261     DLLFLAGS="-fPIC"
 262     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 263   else
 264     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 265                    ac_cv_c_dll_netbsd,
 266     [saved_cflags=$CFLAGS
 267     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 268     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 269     CFLAGS=$saved_cflags
 270     ])
 271     if test "$ac_cv_c_dll_netbsd" = "yes"
 272     then
 273       DLLFLAGS="-fPIC"
 274       LDSHARED="ld -Bshareable -Bforcearchive"
 275     fi
 276   fi
 277   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 278   then
 279     LIB_TARGET="libwine.a"
 280   fi
 281 fi
 282 AC_SUBST(DLLFLAGS)
 283 AC_SUBST(LDSHARED)
 284
 285 dnl **** Check for reentrant libc ****
 286 dnl
 287 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 288 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 289
 290 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 291   [AC_TRY_RUN([int myerrno = 0;
 292 char buf[256];
 293 int *__errno_location(){return &myerrno;}
 294 main(){connect(0,buf,255); exit(!myerrno);}],
 295   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 296   wine_cv_libc_reentrant=yes ) ] )
 297 if test "$wine_cv_libc_reentrant" = "no"
 298 then
 299   AC_DEFINE(NO_REENTRANT_LIBC)
 300 fi
 301
 302 dnl **** Check for reentrant X libraries ****
 303 dnl
 304 dnl This may fail to determine whether X libraries are reentrant if
 305 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 306 dnl is possible with the --without-reentrant-x option.
 307
 308 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 309   [ if test "x$with_reentrant_x" = "xno"
 310     then
 311         wine_cv_x_reentrant=no
 312     else
 313         libX11_ckeck=none
 314         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 315             if test -r $dir/libX11.so; then
 316                 libX11_check="-D $dir/libX11.so"
 317                 break 1
 318             fi
 319             if test -r $dir/libX11.a; then
 320                 libX11_check="$dir/libX11.a"
 321                 break 1
 322             fi
 323         done
 324         if test "$libX11_check" != "none"; then
 325             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 326             then
 327                 wine_cv_x_reentrant=yes
 328             else
 329                 wine_cv_x_reentrant=no
 330             fi
 331         else
 332             wine_cv_x_reentrant=unknown
 333         fi
 334     fi ] )
 335 if test "$wine_cv_x_reentrant" = "no"
 336 then
 337   AC_DEFINE(NO_REENTRANT_X11)
 338 fi
 339
 340 dnl **** Check for functions and header files ****
 341
 342 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 343 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h)
 344 AC_HEADER_STAT()
 345 AC_C_CONST()
 346 AC_TYPE_SIZE_T()
 347 AC_CHECK_SIZEOF(long long,0)
 348
 349 dnl **** Check for sendmsg in -lsocket if not found above ****
 350
 351 if test $ac_cv_func_sendmsg = no; then
 352     AC_CHECK_LIB(socket,sendmsg)
 353 fi
 354
 355 dnl **** statfs checks ****
 356
 357 if test "$ac_cv_header_sys_vfs_h" = "yes"
 358 then
 359     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 360                     wine_cv_sys_vfs_has_statfs,
 361         AC_TRY_COMPILE([
 362         #include <sys/types.h>
 363         #ifdef HAVE_SYS_PARAM_H
 364         # include <sys/param.h>
 365         #endif
 366         #include <sys/vfs.h>
 367         ],[
 368                 struct statfs stfs;
 369
 370                 memset(&stfs,0,sizeof(stfs));
 371         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 372         )
 373     )
 374     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 375     then
 376       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 377     fi
 378 fi
 379
 380 if test "$ac_cv_header_sys_statfs_h" = "yes"
 381 then
 382     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 383                     wine_cv_sys_statfs_has_statfs,
 384         AC_TRY_COMPILE([
 385         #include <sys/types.h>
 386         #ifdef HAVE_SYS_PARAM_H
 387         # include <sys/param.h>
 388         #endif
 389         #include <sys/statfs.h>
 390         ],[
 391                 struct statfs stfs;
 392         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 393         )
 394     )
 395     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 396     then
 397       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 398     fi
 399 fi
 400
 401 if test "$ac_cv_header_sys_mount_h" = "yes"
 402 then
 403     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 404                     wine_cv_sys_mount_has_statfs,
 405         AC_TRY_COMPILE([
 406         #include <sys/types.h>
 407         #ifdef HAVE_SYS_PARAM_H
 408         # include <sys/param.h>
 409         #endif
 410         #include <sys/mount.h>
 411         ],[
 412                 struct statfs stfs;
 413         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 414         )
 415     )
 416     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 417     then
 418       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 419     fi
 420 fi
 421
 422 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 423
 424 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 425   [ if test "x$statfs_bfree" = "xno"
 426     then
 427         wine_cv_statfs_bfree=no
 428     else
 429         AC_TRY_COMPILE([
 430         #include <sys/types.h>
 431         #ifdef HAVE_SYS_PARAM_H
 432         # include <sys/param.h>
 433         #endif
 434         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 435         # include <sys/mount.h>
 436         #else
 437         # ifdef STATFS_DEFINED_BY_SYS_VFS
 438         #  include <sys/vfs.h>
 439         # else
 440         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 441         #   include <sys/statfs.h>
 442         #  endif
 443         # endif
 444         #endif
 445         ],[
 446                 struct statfs stfs;
 447
 448                 stfs.f_bfree++;
 449         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 450         )
 451     fi ] )
 452 if test "$wine_cv_statfs_bfree" = "yes"
 453 then
 454   AC_DEFINE(STATFS_HAS_BFREE)
 455 fi
 456
 457 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 458   [ if test "x$statfs_bavail" = "xno"
 459     then
 460         wine_cv_statfs_bavail=no
 461     else
 462         AC_TRY_COMPILE([
 463         #include <sys/types.h>
 464         #ifdef HAVE_SYS_PARAM_H
 465         # include <sys/param.h>
 466         #endif
 467         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 468         # include <sys/mount.h>
 469         #else
 470         # ifdef STATFS_DEFINED_BY_SYS_VFS
 471         #  include <sys/vfs.h>
 472         # else
 473         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 474         #   include <sys/statfs.h>
 475         #  endif
 476         # endif
 477         #endif
 478         ],[
 479                 struct statfs stfs;
 480
 481                 stfs.f_bavail++;
 482         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 483         )
 484     fi ] )
 485 if test "$wine_cv_statfs_bavail" = "yes"
 486 then
 487   AC_DEFINE(STATFS_HAS_BAVAIL)
 488 fi
 489
 490 dnl *** check for working sigaltstack
 491 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 492
 493 AC_CACHE_CHECK("for working sigaltstack",
 494         ac_cv_c_working_sigaltstack,
 495         AC_TRY_RUN([
 496         #include <stdio.h>
 497         #include <time.h> /* <sys/time.h> ? bad magic without end */
 498         #include <sys/types.h>
 499         #include <sys/signal.h>
 500         #ifdef HAVE_SYS_PARAM_H
 501         # include <sys/param.h>
 502         #endif
 503         #ifdef HAVE_SYSCALL_H
 504         # include <syscall.h>
 505         #else
 506         # ifdef HAVE_SYS_SYSCALL_H
 507         #  include <sys/syscall.h>
 508         # endif
 509         #endif
 510
 511         unsigned char *xaltstack;
 512
 513         int
 514         main(int argc,char **argv) {
 515             struct sigaltstack  ss;
 516
 517             xaltstack = malloc(16384);
 518             ss.ss_sp    = xaltstack;
 519             ss.ss_size  = 16384;
 520             ss.ss_flags = 0;
 521             if (sigaltstack(&ss, NULL) < 0) {
 522                 /* this catches the glibc case */
 523                 perror("sigaltstack");
 524                 return (1); /* aka exit(1) aka fail */
 525             }
 526             /* assume it works. */
 527             return 0; /* OK */
 528         }
 529         ],
 530         ac_cv_c_working_sigaltstack="yes",
 531         ac_cv_c_working_sigaltstack="no",
 532         ac_cv_c_working_sigaltstack="no"
 533 ))
 534
 535 if test "$ac_cv_c_working_sigaltstack" = "yes"
 536 then
 537     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 538 fi
 539
 540
 541 dnl *** check for file descriptor passing with msg_accrights
 542
 543 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 544  AC_TRY_COMPILE([#include <sys/types.h>
 545 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 546                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 547 if test "$ac_cv_c_msg_accrights" = "yes"
 548 then
 549     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 550 fi
 551
 552 dnl **** Generate output files ****
 553
 554 MAKE_RULES=Make.rules
 555 AC_SUBST_FILE(MAKE_RULES)
 556
 557 AC_OUTPUT([
 558 Make.rules
 559 Makefile
 560 console/Makefile
 561 controls/Makefile
 562 debugger/Makefile
 563 dlls/Makefile
 564 dlls/advapi32/Makefile
 565 dlls/comctl32/Makefile
 566 dlls/imagehlp/Makefile
 567 dlls/msacm/Makefile
 568 dlls/msacm32/Makefile
 569 dlls/ntdll/Makefile
 570 dlls/psapi/Makefile
 571 dlls/rasapi32/Makefile
 572 dlls/shell32/Makefile
 573 dlls/winaspi/Makefile
 574 dlls/wnaspi32/Makefile
 575 documentation/Makefile
 576 files/Makefile
 577 graphics/Makefile
 578 graphics/metafiledrv/Makefile
 579 graphics/psdrv/Makefile
 580 graphics/win16drv/Makefile
 581 graphics/x11drv/Makefile
 582 if1632/Makefile
 583 ipc/Makefile
 584 library/Makefile
 585 libtest/Makefile
 586 loader/Makefile
 587 loader/ne/Makefile
 588 loader/dos/Makefile
 589 memory/Makefile
 590 misc/Makefile
 591 miscemu/Makefile
 592 msdos/Makefile
 593 multimedia/Makefile
 594 objects/Makefile
 595 ole/Makefile
 596 programs/Makefile
 597 programs/clock/Makefile
 598 programs/control/Makefile
 599 programs/notepad/Makefile
 600 programs/progman/Makefile
 601 programs/regtest/Makefile
 602 programs/view/Makefile
 603 programs/winhelp/Makefile
 604 programs/winver/Makefile
 605 rc/Makefile
 606 relay32/Makefile
 607 resources/Makefile
 608 scheduler/Makefile
 609 server/Makefile
 610 tools/Makefile
 611 tools/wrc/Makefile
 612 tsx11/Makefile
 613 win32/Makefile
 614 windows/Makefile
 615 windows/ttydrv/Makefile
 616 windows/x11drv/Makefile ])
 617
 618 if test "$wine_cv_libc_reentrant" = "no"
 619 then
 620   echo
 621   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 622   echo "*** thread support. Consider upgrading libc to a more recent"
 623   echo "*** reentrant version of libc."
 624   echo
 625 fi
 626
 627 echo
 628 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 629 echo
 630
 631 dnl Local Variables:
 632 dnl comment-start: "dnl "
 633 dnl comment-end: ""
 634 dnl comment-start-skip: "\\bdnl\\b\\s *"
 635 dnl compile-command: "autoconf"
 636 dnl End: