| blob | 1d3b5f7739ec7152f0cb73d47675436d33de59ef |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION)
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 dnl Library type .so or .a
16 AC_SUBST(LIBEXT,"so")
18 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
19 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
20 AC_ARG_ENABLE(opengl,AC_HELP_STRING([--enable-opengl],[force usage of OpenGL even if the latter is thread-safe via pthread]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(OPTIONS)
25 if test "x$enable_debug" = "xno"
26 then
27 AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
32 fi
34 dnl **** Check for some programs ****
36 AC_CANONICAL_HOST
37 AC_PROG_MAKE_SET
38 AC_PROG_CC
39 AC_PROG_CPP
41 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
42 [if test -z "$with_wine_tools"; then
43 if test "$cross_compiling" = "yes"; then
44 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
45 else
46 wine_cv_toolsdir="\$(TOPOBJDIR)"
47 fi
48 elif test -d "$with_wine_tools/tools/winebuild"; then
49 case $with_wine_tools in
50 /*) wine_cv_toolsdir="$with_wine_tools" ;;
51 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
52 esac
53 else
54 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
55 fi])
56 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
58 AC_PATH_XTRA
59 AC_PROG_YACC
60 AC_PROG_LEX
62 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
63 dnl **** without one present.
64 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
65 if test "$XYACC" = "none"
66 then
67 AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
68 fi
69 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
70 if test "$XLEX" = "none"
71 then
72 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
73 fi
75 AC_CHECK_TOOL(LD,ld,ld)
76 AC_CHECK_TOOL(AR,ar,ar)
77 AC_PROG_RANLIB
78 AC_CHECK_TOOL(STRIP,strip,strip)
79 AC_CHECK_TOOL(WINDRES,windres,false)
80 AC_PROG_INSTALL
81 AC_PROG_LN_S
82 WINE_PROG_LN
83 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
84 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
86 dnl Check for lint
87 AC_CHECK_PROGS(LINT, lclint lint)
88 if test "$LINT" = "lint"
89 then
90 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
91 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
92 fi
93 AC_SUBST(LINT)
94 AC_SUBST(LINTFLAGS)
96 dnl **** Check for some libraries ****
98 dnl Check for -lm
99 AC_CHECK_LIB(m,sqrt)
100 dnl Check for -li386 for NetBSD and OpenBSD
101 AC_CHECK_LIB(i386,i386_set_ldt)
102 dnl Check for -lossaudio for NetBSD
103 AC_CHECK_LIB(ossaudio,_oss_ioctl)
104 dnl Check for -lw for Solaris
105 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
106 dnl Check for -lnsl for Solaris
107 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
108 dnl Check for -lsocket for Solaris
109 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
110 dnl Check for -lresolv for Solaris
111 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
112 dnl Check for -lxpg4 for FreeBSD
113 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
114 dnl Check for -lmmap for OS/2
115 AC_CHECK_LIB(mmap,mmap)
117 JPEGLIB=""
118 AC_SUBST(JPEGLIB)
119 AC_CHECK_HEADERS(jpeglib.h,
120 AC_CHECK_LIB(jpeg,jpeg_start_decompress,
121 AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
122 JPEGLIB="-ljpeg"
123 )
124 )
127 AC_SUBST(XLIB)
128 AC_SUBST(XFILES)
129 XFILES=""
130 AC_SUBST(OPENGLFILES)
131 OPENGLFILES=""
132 AC_SUBST(GLU32FILES)
133 GLU32FILES=""
134 if test "$have_x" = "yes"
135 then
136 XLIB="-lXext -lX11"
137 ac_save_CPPFLAGS="$CPPFLAGS"
138 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
140 dnl *** All of the following tests require X11/Xlib.h
141 AC_CHECK_HEADERS(X11/Xlib.h,
142 [
143 dnl *** Check for X keyboard extension
144 AC_CHECK_HEADERS(X11/XKBlib.h,
145 [ dnl *** If X11/XKBlib.h exists...
146 AC_CHECK_LIB(X11, XkbQueryExtension,
147 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
148 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
149 ],
150 AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
151 [#include <X11/Xlib.h>])
153 dnl *** Check for X Shm extension
154 AC_CHECK_HEADERS(X11/extensions/XShm.h,
155 [ dnl *** If X11/extensions/XShm.h exists...
156 AC_CHECK_LIB(Xext, XShmQueryExtension,
157 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
158 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
159 ],
160 AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
161 [#include <X11/Xlib.h>])
163 dnl *** Check for Xutil
164 AC_CHECK_HEADERS(X11/Xutil.h,,,
165 [#include <X11/Xlib.h>])
167 dnl *** Check for X shape extension
168 AC_CHECK_HEADERS(X11/extensions/shape.h,
169 [ dnl *** If X11/extensions/shape.h exists...
170 AC_CHECK_LIB(Xext,XShapeQueryExtension,
171 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
172 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
173 ],
174 AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
175 [#include <X11/Xlib.h>
176 #ifdef HAVE_X11_XUTIL_H
177 # include <X11/Xutil.h>
178 #endif])
180 dnl *** Check for XFree86 DGA / DGA 2.0 extension
181 AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
182 [ dnl *** If X11/extensions/xf86dga.h exists, check
183 dnl *** for XDGAQueryExtension()...
184 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
185 [ dnl *** If found...
186 AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
187 [Define if you have the Xxf86dga library version 2])
188 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
189 ],
190 [ dnl *** If not found, look for XF86DGAQueryExtension()
191 dnl *** instead (DGA 2.0 not found)...
192 AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
193 [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
194 [Define if you have the Xxf86dga library version 1])
195 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
196 ],,
197 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
198 )
199 ],
200 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
201 )
202 ],
203 AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
204 [#include <X11/Xlib.h>])
206 dnl *** Check for XFree86 VMODE extension
207 AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
208 [ dnl *** If X11/extensions/xf86vmode.h exists...
209 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
210 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
211 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
212 ],,
213 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
214 )
215 ],
216 AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
217 [#include <X11/Xlib.h>])
219 dnl *** Check for XVideo extension supporting XvImages
220 AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
221 [ dnl *** If X11/extensions/Xvlib.h exists...
222 AC_CHECK_LIB(Xv, XvShmCreateImage,
223 [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
224 X_PRE_LIBS="$X_PRE_LIBS -lXv"
225 ],,
226 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
227 )
228 ],
229 AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
230 [#include <X11/Xlib.h>])
232 dnl *** Check for XRender include file
233 AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
234 ]
235 ) dnl *** End of X11/Xlib.h check
237 dnl Check for the presence of OpenGL
238 if test "x$enable_opengl" != "xno"
239 then
240 if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
241 then
242 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
243 This prevents linking to OpenGL. Delete the file and restart configure.])
244 fi
246 AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
247 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
248 then
249 AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
250 dnl Check for some problems due to old Mesa versions
251 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
252 AC_TRY_COMPILE(
253 [#include <GL/gl.h>],
254 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
255 [wine_cv_opengl_version_OK="yes"],
256 [wine_cv_opengl_version_OK="no"]
257 )
258 )
260 dnl Check for the thread-safety of the OpenGL library
261 AC_CACHE_CHECK([for thread-safe OpenGL version],
262 wine_cv_opengl_version_threadsafe,
263 [saved_libs=$LIBS
264 LIBS="$X_LIBS -lGL"
265 AC_TRY_LINK([],[pthread_getspecific();],
266 [wine_cv_opengl_version_threadsafe="yes"],
267 [wine_cv_opengl_version_threadsafe="no"])
268 LIBS=$saved_libs]
269 )
271 if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o "x$enable_opengl" = "xyes" \)
272 then
273 dnl Check for the presence of the library
274 AC_CHECK_LIB(GL,glXCreateContext,
275 X_PRE_LIBS="$X_PRE_LIBS -lGL"
276 ,,
277 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
279 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
280 then
281 OPENGLFILES='$(OPENGLFILES)'
282 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
284 AC_CHECK_LIB(GL,glXGetProcAddressARB,
285 AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
286 [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
287 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
289 if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
290 then
291 AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
292 [AC_TRY_COMPILE([#include <GL/gl.h>
293 #ifdef HAVE_GL_GLEXT_H
294 # include <GL/glext.h>
295 #endif
296 ],
297 [PFNGLCOLORTABLEEXTPROC test_proc;],
298 [wine_cv_extension_prototypes="yes"],
299 [wine_cv_extension_prototypes="no"]
300 )]
301 )
302 if test "$wine_cv_extension_prototypes" = "yes"
303 then
304 AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
305 [Define if the OpenGL headers define extension typedefs])
306 fi
307 fi
309 fi
310 dnl Check for GLU32 library.
311 AC_CHECK_LIB(GLU,gluLookAt,
312 [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
313 GLU32FILES='$(GLU32FILES)']
314 ,,
315 $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
316 )
317 fi
318 fi
319 fi
321 CPPFLAGS="$ac_save_CPPFLAGS"
322 XFILES='$(XFILES)'
323 else
324 XLIB=""
325 X_CFLAGS=""
326 X_LIBS=""
327 fi
329 dnl **** Check which curses lib to use ***
330 CURSESLIBS=""
331 if test "x$with_curses" != "xno"
332 then
333 AC_CHECK_HEADERS(ncurses.h,
334 [AC_CHECK_LIB(ncurses,waddch,
335 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
336 CURSESLIBS="-lncurses"],
337 [AC_CHECK_HEADERS(curses.h,
338 [AC_CHECK_LIB(curses,waddch,
339 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
340 CURSESLIBS="-lcurses"])])])])
341 saved_libs="$LIBS"
342 LIBS="$CURSESLIBS $LIBS"
343 AC_CHECK_FUNCS(getbkgd resizeterm)
344 LIBS="$saved_libs"
345 fi
346 AC_SUBST(CURSESLIBS)
348 CUPSLIBS=""
349 dnl **** Check for CUPS ****
350 wine_cv_warn_cups_h=no
351 AC_CHECK_LIB(cups,cupsGetPPD,
352 [AC_CHECK_HEADER(cups/cups.h,
353 [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
354 CUPSLIBS="-lcups"],
355 wine_cv_warn_cups_h=yes)]
356 )
357 AC_SUBST(CUPSLIBS)
359 dnl **** Check for SANE ****
360 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
361 if test "$sane_devel" = "no"
362 then
363 SANELIBS=""
364 SANEINCL=""
365 else
366 SANELIBS="`$sane_devel --libs`"
367 SANEINCL="`$sane_devel --cflags`"
368 ac_save_CPPFLAGS="$CPPFLAGS"
369 ac_save_LIBS="$LIBS"
370 CPPFLAGS="$CPPFLAGS $SANEINCL"
371 LIBS="$LIBS $SANELIBS"
372 AC_CHECK_HEADER(sane/sane.h,
373 [AC_CHECK_LIB(sane,sane_open,
374 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
375 [SANELIBS=""
376 SANEINCL=""])],
377 [SANELIBS=""
378 SANEINCL=""])
379 LIBS="$ac_save_LIBS"
380 CPPFLAGS="$ac_save_CPPFLAGS"
381 fi
382 AC_SUBST(SANELIBS)
383 AC_SUBST(SANEINCL)
385 dnl **** Check for FreeType 2 ****
386 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
387 if test "$ft_lib" = "no"
388 then
389 FREETYPEINCL=""
390 wine_cv_msg_freetype=no
391 else
392 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
393 if test "$ft_devel" = "no"
394 then
395 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
396 if test "$ft_devel2" = "freetype2-config"
397 then
398 ft_devel=$ft_devel2
399 fi
400 fi
401 if test "$ft_devel" = "no"
402 then
403 FREETYPEINCL=""
404 wine_cv_msg_freetype=yes
405 else
406 FREETYPEINCL=`$ft_devel --cflags`
407 ac_save_CPPFLAGS="$CPPFLAGS"
408 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
409 AC_CHECK_HEADERS(freetype/freetype.h \
410 freetype/ftglyph.h \
411 freetype/tttables.h \
412 freetype/ftnames.h \
413 freetype/ftsnames.h \
414 freetype/ttnameid.h \
415 freetype/ftoutln.h \
416 freetype/internal/sfnt.h)
417 AC_TRY_CPP([#include <ft2build.h>
418 #include <freetype/fttrigon.h>],
419 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
420 [Define if you have the <freetype/fttrigon.h> header file.])
421 wine_cv_fttrigon=yes],
422 wine_cv_fttrigon=no)
423 CPPFLAGS="$ac_save_CPPFLAGS"
424 dnl Check that we have at least freetype/freetype.h
425 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
426 then
427 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
428 wine_cv_msg_freetype=no
429 else
430 FREETYPEINCL=""
431 wine_cv_msg_freetype=yes
432 fi
433 fi
434 fi
435 AC_SUBST(FREETYPEINCL)
437 dnl **** Check for parport (currently Linux only) ****
438 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
439 AC_TRY_COMPILE(
440 [#include <linux/ppdev.h>],
441 [ioctl (1,PPCLAIM,0)],
442 [ac_cv_c_ppdev="yes"],
443 [ac_cv_c_ppdev="no"])
444 )
445 if test "$ac_cv_c_ppdev" = "yes"
446 then
447 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
448 fi
450 dnl **** Check for va_copy ****
451 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
452 AC_TRY_LINK(
453 [#include <stdarg.h>],
454 [va_list ap1, ap2;
455 va_copy(ap1,ap2);
456 ],
457 [ac_cv_c_va_copy="yes"],
458 [ac_cv_c_va_copy="no"])
459 )
460 if test "$ac_cv_c_va_copy" = "yes"
461 then
462 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
463 fi
464 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
465 AC_TRY_LINK(
466 [#include <stdarg.h>],
467 [va_list ap1, ap2;
468 __va_copy(ap1,ap2);
469 ],
470 [ac_cv_c___va_copy="yes"],
471 [ac_cv_c___va_copy="no"])
472 )
473 if test "$ac_cv_c___va_copy" = "yes"
474 then
475 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
476 fi
478 dnl **** Check for IPX (currently Linux only) ****
479 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
480 AC_TRY_COMPILE(
481 [#include <sys/socket.h>
482 #include <netipx/ipx.h>],
483 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
484 [ac_cv_c_ipx_gnu="yes"],
485 [ac_cv_c_ipx_gnu="no"])
486 )
487 if test "$ac_cv_c_ipx_gnu" = "yes"
488 then
489 AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
490 fi
492 if test "$ac_cv_c_ipx_gnu" = "no"
493 then
494 AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
495 AC_TRY_COMPILE(
496 [#include <sys/socket.h>
497 #include <asm/types.h>
498 #include <linux/ipx.h>],
499 [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
500 [ac_cv_c_ipx_linux="yes"],
501 [ac_cv_c_ipx_linux="no"])
502 )
503 if test "$ac_cv_c_ipx_linux" = "yes"
504 then
505 AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
506 fi
507 fi
509 dnl **** Check for Open Sound System ****
510 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
512 AC_CACHE_CHECK([for Open Sound System],
513 ac_cv_c_opensoundsystem,
514 AC_TRY_COMPILE([
515 #if defined(HAVE_SYS_SOUNDCARD_H)
516 #include <sys/soundcard.h>
517 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
518 #include <machine/soundcard.h>
519 #elif defined(HAVE_SOUNDCARD_H)
520 #include <soundcard.h>
521 #endif
522 ],[
524 /* check for one of the Open Sound System specific SNDCTL_ defines */
525 #if !defined(SNDCTL_DSP_STEREO)
526 #error No open sound system
527 #endif
528 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
530 if test "$ac_cv_c_opensoundsystem" = "yes"
531 then
532 AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
533 fi
535 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
536 ac_cv_c_opensoundsystem_midi,
537 AC_TRY_COMPILE([
538 #if defined(HAVE_SYS_SOUNDCARD_H)
539 #include <sys/soundcard.h>
540 #elif defined(HAVE_MACHINE_SOUNDCARD_H)
541 #include <machine/soundcard.h>
542 #elif defined(HAVE_SOUNDCARD_H)
543 #include <soundcard.h>
544 #endif
545 ],[
547 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
548 #if !defined(SNDCTL_SEQ_SYNC)
549 #error No open sound system MIDI interface
550 #endif
551 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
553 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
554 then
555 AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
556 fi
558 dnl **** Check for aRts Sound Server ****
559 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
560 AC_CACHE_CHECK([for aRts Sound server],
561 ac_cv_c_artsserver,
562 if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
563 then
564 ac_cv_c_artsserver=no
565 else
566 ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
567 ARTSC_LIBS=`$ARTSCCONFIG --libs`
568 ac_cv_c_artsserver=no
569 save_CFLAGS="$CFLAGS"
570 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
571 AC_TRY_COMPILE([
572 #include <artsc.h>
573 ],[
574 arts_stream_t stream;
575 ],[
576 ac_cv_c_artsserver=yes
577 ])
578 CFLAGS="$save_CFLAGS"
579 fi)
581 if test "$ac_cv_c_artsserver" = "yes"
582 then
583 AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
584 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
586 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
587 fi
589 dnl **** Check for ALSA ****
590 AC_SUBST(ALSALIBS,"")
591 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
592 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
593 then
594 AC_CHECK_LIB(asound,snd_pcm_open,
595 AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
596 ALSALIBS="-lasound")
597 fi
599 dnl **** Check for NAS ****
600 AC_SUBST(NASLIBS,"")
601 AC_CHECK_HEADERS(audio/audiolib.h,
602 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
603 AC_CHECK_LIB(audio,AuCreateFlow,
604 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
605 NASLIBS="-laudio -lXt \$(X_LIBS) \$(XLIB)"],,
606 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
608 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
610 AC_SUBST(AUDIOIOLIBS,"")
611 AC_CHECK_HEADERS(libaudioio.h,
612 [AC_CHECK_LIB(audioio,AudioIOGetVersion,
613 [AUDIOIOLIBS="-laudioio"
614 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
616 dnl **** Check for broken glibc mmap64 ****
618 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
619 AC_TRY_RUN([
620 #define _FILE_OFFSET_BITS 64
621 #include <stdio.h>
622 #include <unistd.h>
623 #include <fcntl.h>
624 #include <sys/mman.h>
625 #include <errno.h>
627 int main(int argc,char **argv) {
628 int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
629 if (fd == -1) exit(1);
631 unlink("conftest.map");
633 write(fd,"test",4);
635 if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
636 (errno == EINVAL)
637 ) {
638 exit(1);
639 }
640 close(fd);
641 fprintf(stderr,"success!\n");
642 exit(0);
643 }
645 ],
646 ac_cv_mmap64_works="yes",
647 ac_cv_mmap64_works="no",
648 ac_cv_mmap64_works="no") )
650 if test "$ac_cv_mmap64_works" = "yes"
651 then
652 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
653 fi
655 dnl **** Check for gcc strength-reduce bug ****
657 if test "x${GCC}" = "xyes"
658 then
659 CFLAGS="$CFLAGS -Wall"
660 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
661 AC_TRY_RUN([
662 int L[[4]] = {0,1,2,3};
663 int main(void) {
664 static int Array[[3]];
665 unsigned int B = 3;
666 int i;
667 for(i=0; i<B; i++) Array[[i]] = i - 3;
668 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
669 L[[i]] = 4;
671 exit( Array[[1]] != -2 || L[[2]] != 3);
672 }],
673 ac_cv_c_gcc_strength_bug="no",
674 ac_cv_c_gcc_strength_bug="yes",
675 ac_cv_c_gcc_strength_bug="yes") )
676 if test "$ac_cv_c_gcc_strength_bug" = "yes"
677 then
678 CFLAGS="$CFLAGS -fno-strength-reduce"
679 fi
681 dnl Check for -mpreferred-stack-boundary
682 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
683 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
684 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
685 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
686 then
687 CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
688 fi
689 fi
691 dnl **** Check how to define a function in assembly code ****
693 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
694 WINE_TRY_ASM_LINK(
695 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
696 ac_cv_asm_func_def=".def",
697 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
698 ac_cv_asm_func_def=".type @function",
699 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
700 ac_cv_asm_func_def=".type 2",
701 ac_cv_asm_func_def="unknown")])]))
703 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
704 case "$ac_cv_asm_func_def" in
705 ".def")
706 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
707 ".type @function")
708 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
709 ".type 2")
710 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
711 *)
712 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
713 esac
715 dnl **** Check for underscore on external symbols ****
717 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
718 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
719 [extern int ac_test;],
720 [if (ac_test) return 1],
721 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
723 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
724 if test "$ac_cv_c_extern_prefix" = "yes"
725 then
726 AC_DEFINE([__ASM_NAME(name)], ["_" name])
727 else
728 AC_DEFINE([__ASM_NAME(name)], [name])
729 fi
731 dnl **** Check whether stdcall symbols need to be decorated ****
733 AC_CACHE_CHECK([whether stdcall symbols need to be decorated], ac_cv_c_stdcall_decoration,
734 WINE_TRY_ASM_LINK(["\t.globl _ac_test@0\n_ac_test@0:\n\t.globl ac_test@0\nac_test@0:"],
735 [extern void __attribute__((__stdcall__)) ac_test(void);],
736 [ac_test()],
737 ac_cv_c_stdcall_decoration="yes",ac_cv_c_stdcall_decoration="no"))
738 if test "$ac_cv_c_stdcall_decoration" = "yes"
739 then
740 AC_DEFINE(NEED_STDCALL_DECORATION, 1, [Define if stdcall symbols need to be decorated])
741 fi
743 dnl **** Check for .string in assembler ****
745 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
746 WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
747 ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
748 if test "$ac_cv_c_asm_string" = "yes"
749 then
750 AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
751 fi
753 dnl **** Check for working dll ****
755 AC_SUBST(DLLEXT,"")
756 AC_SUBST(DLLFLAGS,"")
757 AC_SUBST(DLLIBS,"")
758 AC_SUBST(LDDLLFLAGS,"")
759 AC_SUBST(LDSHARED,"")
761 case $host_os in
762 cygwin*|mingw32*)
763 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
764 if test "$DLLWRAP" = "false"; then
765 LIBEXT="a"
766 else
767 dnl FIXME - check whether dllwrap works correctly...
768 LIBEXT="dll"
769 fi
770 ;;
771 *)
772 AC_CHECK_HEADERS(dlfcn.h,
773 [AC_CHECK_FUNCS(dlopen,,
774 [AC_CHECK_LIB(dl,dlopen,
775 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
776 DLLIBS="-ldl"],
777 [LIBEXT="a"])])],
778 [LIBEXT="a"])
780 if test "$LIBEXT" = "so"
781 then
782 DLLFLAGS="-fPIC"
783 DLLEXT=".so"
784 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
785 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
786 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
787 if test "$ac_cv_c_dll_gnuelf" = "yes"
788 then
789 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
790 LDDLLFLAGS="-Wl,-Bsymbolic"
791 else
792 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
793 [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
794 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
795 if test "$ac_cv_c_dll_unixware" = "yes"
796 then
797 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
798 LDDLLFLAGS="-Wl,-B,symbolic"
799 fi
800 fi
801 fi
803 dnl Check for cross compiler to build test programs
804 AC_SUBST(CROSSTEST,"")
805 if test "$cross_compiling" = "no"
806 then
807 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc,false)
808 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool,false)
809 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
810 fi
811 ;;
812 esac
814 if test "$LIBEXT" = "a"; then
815 AC_MSG_ERROR(
816 [could not find a way to build shared libraries.
817 It is currently not possible to build Wine without shared library
818 (.so) support to allow transparent switch between .so and .dll files.
819 If you are using Linux, you will need a newer binutils.]
820 )
821 fi
823 case $build_os in
824 cygwin*|mingw32*)
825 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$PATH\"") ;;
826 *)
827 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/library:\$(TOOLSDIR)/unicode:\$\$LD_LIBRARY_PATH\"") ;;
828 esac
830 dnl Mingw needs explicit msvcrt for linking libwine
831 AC_SUBST(CRTLIBS,"")
832 case $host_os in
833 mingw32*)
834 CRTLIBS="-lmsvcrt" ;;
835 esac
837 dnl **** Get the soname for libraries that we load dynamically ****
839 if test "$LIBEXT" = "so"
840 then
841 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
842 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
843 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
844 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
845 fi
848 dnl **** Check for reentrant libc ****
850 wine_cv_libc_reentrant=no
851 dnl Linux style errno location
852 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
853 dnl FreeBSD style errno location
854 WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
855 dnl Solaris style errno location
856 WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
857 dnl UnixWare style errno location
858 WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
859 dnl NetBSD style errno location
860 WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
861 ))))
863 if test "$wine_cv_libc_reentrant" != "no"
864 then
865 AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
866 [Define to the name of the function returning errno for reentrant libc])
867 fi
869 dnl **** Check for reentrant X libraries ****
870 dnl
871 dnl This may fail to determine whether X libraries are reentrant if
872 dnl AC_PATH_XTRA does not set x_libraries.
874 if test "$have_x" = "yes"
875 then
876 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
877 [libX11_check=none
878 for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
879 if test -r $dir/libX11.so; then
880 libX11_check="-D $dir/libX11.so"
881 break
882 fi
883 if test -r $dir/libX11.a; then
884 libX11_check="$dir/libX11.a"
885 break
886 fi
887 done
888 if test "$libX11_check" != "none"; then
889 if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
890 then
891 wine_cv_x_reentrant=yes
892 else
893 wine_cv_x_reentrant=no
894 fi
895 else
896 wine_cv_x_reentrant=unknown
897 fi])
898 fi
900 dnl **** Check for functions ****
902 AC_FUNC_ALLOCA()
903 AC_CHECK_FUNCS(\
904 __libc_fork \
905 _lwp_create \
906 _pclose \
907 _popen \
908 _snprintf \
909 _stricmp \
910 _strnicmp \
911 chsize \
912 clone \
913 ecvt \
914 finite \
915 fpclass \
916 ftruncate \
917 ftruncate64 \
918 getnetbyaddr \
919 getnetbyname \
920 getpagesize \
921 getprotobyname \
922 getprotobynumber \
923 getpwuid \
924 getservbyport \
925 getsockopt \
926 inet_network \
927 lseek64 \
928 lstat \
929 memmove \
930 mkstemp \
931 mmap \
932 pclose \
933 popen \
934 pread \
935 pwrite \
936 rfork \
937 select \
938 sendmsg \
939 settimeofday \
940 sigaltstack \
941 snprintf \
942 statfs \
943 strcasecmp \
944 strerror \
945 strncasecmp \
946 tcgetattr \
947 timegm \
948 usleep \
949 vfscanf \
950 wait4 \
951 waitpid \
952 )
954 dnl **** Check for header files ****
956 AC_CHECK_HEADERS(\
957 arpa/inet.h \
958 arpa/nameser.h \
959 direct.h \
960 elf.h \
961 float.h \
962 ieeefp.h \
963 io.h \
964 libaudioio.h \
965 libio.h \
966 libutil.h \
967 link.h \
968 linux/cdrom.h \
969 linux/hdreg.h \
970 linux/input.h \
971 linux/joystick.h \
972 linux/major.h \
973 linux/param.h \
974 linux/serial.h \
975 linux/ucdrom.h \
976 netdb.h \
977 netinet/in.h \
978 netinet/in_systm.h \
979 netinet/tcp.h \
980 pty.h \
981 pwd.h \
982 sched.h \
983 scsi/sg.h \
984 socket.h \
985 stdint.h \
986 strings.h \
987 sys/cdio.h \
988 sys/errno.h \
989 sys/file.h \
990 sys/filio.h \
991 sys/inttypes.h \
992 sys/ioctl.h \
993 sys/ipc.h \
994 sys/link.h \
995 sys/lwp.h \
996 sys/mman.h \
997 sys/modem.h \
998 sys/mount.h \
999 sys/msg.h \
1000 sys/param.h \
1001 sys/poll.h \
1002 sys/ptrace.h \
1003 sys/reg.h \
1004 sys/shm.h \
1005 sys/signal.h \
1006 sys/socket.h \
1007 sys/sockio.h \
1008 sys/statfs.h \
1009 sys/strtio.h \
1010 sys/syscall.h \
1011 sys/sysctl.h \
1012 sys/time.h \
1013 sys/times.h \
1014 sys/user.h \
1015 sys/v86.h \
1016 sys/v86intr.h \
1017 sys/vfs.h \
1018 sys/vm86.h \
1019 sys/wait.h \
1020 syscall.h \
1021 termios.h \
1022 ucontext.h \
1023 unistd.h \
1024 utime.h \
1025 )
1026 AC_HEADER_STAT()
1028 dnl *** Check for net/if.h
1029 AC_CHECK_HEADERS(net/if.h,,,
1030 [#if HAVE_SYS_TYPES_H
1031 # include <sys/types.h>
1032 #endif
1033 #if HAVE_SYS_SOCKET_H
1034 # include <sys/socket.h>
1035 #endif])
1037 dnl *** Check for netinet/ip.h
1038 AC_CHECK_HEADERS(netinet/ip.h,,,
1039 [#if HAVE_SYS_SOCKET_H
1040 # include <sys/socket.h>
1041 #endif
1042 #if HAVE_NETINET_IN_SYSTM_H
1043 # include <netinet/in_systm.h>
1044 #endif])
1046 dnl *** Check for resolv.h
1047 AC_CHECK_HEADERS(resolv.h,,,
1048 [#if HAVE_SYS_SOCKET_H
1049 # include <sys/socket.h>
1050 #endif])
1052 dnl **** Check for types ****
1054 AC_C_CONST
1055 AC_C_INLINE
1056 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1057 AC_CHECK_SIZEOF(long long,0)
1059 AC_CACHE_CHECK([whether linux/input.h is for real],
1060 wine_cv_linux_input_h,
1061 AC_TRY_COMPILE([
1062 #include <linux/input.h>
1063 ] , [
1064 int foo = EVIOCGBIT(EV_ABS,42);
1065 int bar = BTN_PINKIE;
1066 int fortytwo = 42;
1067 ],
1068 wine_cv_linux_input_h=yes,
1069 wine_cv_linux_input_h=no,
1070 no
1071 )
1072 )
1073 if test "$wine_cv_linux_input_h" = "yes"
1074 then
1075 AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1076 [Define if we have linux/input.h AND it contains the INPUT event API])
1077 fi
1080 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1081 wine_cv_linux_gethostbyname_r_6,
1082 AC_TRY_COMPILE([
1083 #include <netdb.h>
1084 ], [
1085 char *name=NULL;
1086 struct hostent he;
1087 struct hostent *result;
1088 char *buf=NULL;
1089 int bufsize=0;
1090 int res,errnr;
1091 char *addr=NULL;
1092 int addrlen=0;
1093 int addrtype=0;
1094 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1095 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1096 ],
1097 wine_cv_linux_gethostbyname_r_6=yes,
1098 wine_cv_linux_gethostbyname_r_6=no
1099 )
1100 )
1101 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1102 then
1103 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1104 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1105 fi
1107 if test "$ac_cv_header_linux_joystick_h" = "yes"
1108 then
1109 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1110 wine_cv_linux_joystick_22_api,
1111 AC_TRY_COMPILE([
1112 #include <sys/ioctl.h>
1113 #include <linux/joystick.h>
1115 struct js_event blub;
1116 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1117 #error "no 2.2 header"
1118 #endif
1119 ],/*empty*/,
1120 wine_cv_linux_joystick_22_api=yes,
1121 wine_cv_linux_joystick_22_api=no,
1122 wine_cv_linux_joystick_22_api=no
1123 )
1124 )
1125 if test "$wine_cv_linux_joystick_22_api" = "yes"
1126 then
1127 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1128 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1129 fi
1130 fi
1132 dnl **** statfs checks ****
1134 if test "$ac_cv_header_sys_vfs_h" = "yes"
1135 then
1136 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1137 wine_cv_sys_vfs_has_statfs,
1138 AC_TRY_COMPILE([
1139 #include <sys/types.h>
1140 #ifdef HAVE_SYS_PARAM_H
1141 # include <sys/param.h>
1142 #endif
1143 #include <sys/vfs.h>
1144 ],[
1145 struct statfs stfs;
1147 memset(&stfs,0,sizeof(stfs));
1148 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1149 )
1150 )
1151 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1152 then
1153 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1154 [Define if the struct statfs is defined by <sys/vfs.h>])
1155 fi
1156 fi
1158 if test "$ac_cv_header_sys_statfs_h" = "yes"
1159 then
1160 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1161 wine_cv_sys_statfs_has_statfs,
1162 AC_TRY_COMPILE([
1163 #include <sys/types.h>
1164 #ifdef HAVE_SYS_PARAM_H
1165 # include <sys/param.h>
1166 #endif
1167 #include <sys/statfs.h>
1168 ],[
1169 struct statfs stfs;
1170 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1171 )
1172 )
1173 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1174 then
1175 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1176 [Define if the struct statfs is defined by <sys/statfs.h>])
1177 fi
1178 fi
1180 if test "$ac_cv_header_sys_mount_h" = "yes"
1181 then
1182 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1183 wine_cv_sys_mount_has_statfs,
1184 AC_TRY_COMPILE([
1185 #include <sys/types.h>
1186 #ifdef HAVE_SYS_PARAM_H
1187 # include <sys/param.h>
1188 #endif
1189 #include <sys/mount.h>
1190 ],[
1191 struct statfs stfs;
1192 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1193 )
1194 )
1195 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1196 then
1197 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1198 [Define if the struct statfs is defined by <sys/mount.h>])
1199 fi
1200 fi
1202 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1204 WINE_CHECK_STRUCT_MEMBER(statfs,f_bfree,
1205 [#include <sys/types.h>
1206 #ifdef HAVE_SYS_PARAM_H
1207 # include <sys/param.h>
1208 #endif
1209 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1210 # include <sys/mount.h>
1211 #else
1212 # ifdef STATFS_DEFINED_BY_SYS_VFS
1213 # include <sys/vfs.h>
1214 # else
1215 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1216 # include <sys/statfs.h>
1217 # endif
1218 # endif
1219 #endif],
1220 [AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])])
1222 WINE_CHECK_STRUCT_MEMBER(statfs,f_bavail,
1223 [#include <sys/types.h>
1224 #ifdef HAVE_SYS_PARAM_H
1225 # include <sys/param.h>
1226 #endif
1227 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1228 # include <sys/mount.h>
1229 #else
1230 # ifdef STATFS_DEFINED_BY_SYS_VFS
1231 # include <sys/vfs.h>
1232 # else
1233 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1234 # include <sys/statfs.h>
1235 # endif
1236 # endif
1237 #endif],
1238 [AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])])
1240 dnl Check for file descriptor passing with msg_accrights
1241 WINE_CHECK_STRUCT_MEMBER(msghdr,msg_accrights,
1242 [#include <sys/types.h>
1243 #include <sys/socket.h>],
1244 [AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])])
1246 dnl Check for the sa_len member in struct sockaddr
1247 WINE_CHECK_STRUCT_MEMBER(sockaddr,sa_len,
1248 [#include <sys/types.h>
1249 #include <sys/socket.h>],
1250 [AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])])
1252 dnl Check for the sun_len member in struct sockaddr_un
1253 WINE_CHECK_STRUCT_MEMBER(sockaddr_un,sun_len,
1254 [#include <sys/types.h>
1255 #include <sys/socket.h>
1256 #include <sys/un.h>],
1257 [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])])
1259 dnl *** check for the need to define __i386__
1261 case $host_cpu in
1262 *i[3456789]86* )
1263 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1264 AC_EGREP_CPP(yes,[#ifndef __i386__
1265 yes
1266 #endif],
1267 ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1268 ;;
1269 esac
1270 if test "$ac_cv_cpp_def_i386" = "yes"
1271 then
1272 CFLAGS="$CFLAGS -D__i386__"
1273 LINTFLAGS="$LINTFLAGS -D__i386__"
1274 fi
1276 dnl *** check for the need to define __sparc__
1278 case $host_cpu in
1279 *sparc* )
1280 AC_CACHE_CHECK([whether we need to define __sparc__],ac_cv_cpp_def_sparc,
1281 AC_EGREP_CPP(yes,[#ifndef __sparc__
1282 yes
1283 #endif],
1284 ac_cv_cpp_def_sparc="yes", ac_cv_cpp_def_sparc="no"))
1285 ;;
1286 esac
1287 if test "$ac_cv_cpp_def_sparc" = "yes"
1288 then
1289 CFLAGS="$CFLAGS -D__sparc__"
1290 LINTFLAGS="$LINTFLAGS -D__sparc__"
1291 fi
1293 dnl *** check for the need to define __sun__
1295 case $host_vendor in
1296 *sun* )
1297 AC_CACHE_CHECK([whether we need to define __sun__],ac_cv_cpp_def_sun,
1298 AC_EGREP_CPP(yes,[#ifndef __sun__
1299 yes
1300 #endif],
1301 ac_cv_cpp_def_sun="yes", ac_cv_cpp_def_sun="no"))
1302 ;;
1303 esac
1304 if test "$ac_cv_cpp_def_sun" = "yes"
1305 then
1306 CFLAGS="$CFLAGS -D__sun__"
1307 LINTFLAGS="$LINTFLAGS -D__sun__"
1308 fi
1310 dnl **** Generate output files ****
1312 AH_TOP([#define __WINE_CONFIG_H])
1314 WINE_CONFIG_EXTRA_DIR(controls)
1315 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1316 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1317 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1318 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1319 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1320 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1321 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1322 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1323 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1324 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1325 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1326 WINE_CONFIG_EXTRA_DIR(dlls/gdi/win16drv)
1327 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1328 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1329 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1330 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1331 WINE_CONFIG_EXTRA_DIR(files)
1332 WINE_CONFIG_EXTRA_DIR(graphics)
1333 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1334 WINE_CONFIG_EXTRA_DIR(if1632)
1335 WINE_CONFIG_EXTRA_DIR(include/wine)
1336 WINE_CONFIG_EXTRA_DIR(loader)
1337 WINE_CONFIG_EXTRA_DIR(loader/ne)
1338 WINE_CONFIG_EXTRA_DIR(memory)
1339 WINE_CONFIG_EXTRA_DIR(misc)
1340 WINE_CONFIG_EXTRA_DIR(msdos)
1341 WINE_CONFIG_EXTRA_DIR(objects)
1342 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1343 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1344 WINE_CONFIG_EXTRA_DIR(programs/winetest/tests)
1345 WINE_CONFIG_EXTRA_DIR(relay32)
1346 WINE_CONFIG_EXTRA_DIR(scheduler)
1347 WINE_CONFIG_EXTRA_DIR(win32)
1348 WINE_CONFIG_EXTRA_DIR(windows)
1350 MAKE_RULES=Make.rules
1351 AC_SUBST_FILE(MAKE_RULES)
1353 MAKE_DLL_RULES=dlls/Makedll.rules
1354 AC_SUBST_FILE(MAKE_DLL_RULES)
1356 MAKE_TEST_RULES=dlls/Maketest.rules
1357 AC_SUBST_FILE(MAKE_TEST_RULES)
1359 MAKE_PROG_RULES=programs/Makeprog.rules
1360 AC_SUBST_FILE(MAKE_PROG_RULES)
1362 AC_CONFIG_FILES([
1363 Make.rules
1364 dlls/Makedll.rules
1365 dlls/Maketest.rules
1366 programs/Makeprog.rules
1367 Makefile
1368 dlls/Makefile
1369 dlls/advapi32/Makefile
1370 dlls/advapi32/tests/Makefile
1371 dlls/avicap32/Makefile
1372 dlls/avifil32/Makefile
1373 dlls/comcat/Makefile
1374 dlls/comctl32/Makefile
1375 dlls/commdlg/Makefile
1376 dlls/crtdll/Makefile
1377 dlls/crypt32/Makefile
1378 dlls/d3d8/Makefile
1379 dlls/dciman32/Makefile
1380 dlls/ddraw/Makefile
1381 dlls/devenum/Makefile
1382 dlls/dinput/Makefile
1383 dlls/dinput8/Makefile
1384 dlls/dplay/Makefile
1385 dlls/dplayx/Makefile
1386 dlls/dsound/Makefile
1387 dlls/gdi/Makefile
1388 dlls/glu32/Makefile
1389 dlls/icmp/Makefile
1390 dlls/imagehlp/Makefile
1391 dlls/imm32/Makefile
1392 dlls/kernel/Makefile
1393 dlls/kernel/tests/Makefile
1394 dlls/lzexpand/Makefile
1395 dlls/mapi32/Makefile
1396 dlls/mpr/Makefile
1397 dlls/msacm/Makefile
1398 dlls/msacm/imaadp32/Makefile
1399 dlls/msacm/msadp32/Makefile
1400 dlls/msacm/msg711/Makefile
1401 dlls/msacm/winemp3/Makefile
1402 dlls/msdmo/Makefile
1403 dlls/msimg32/Makefile
1404 dlls/msisys/Makefile
1405 dlls/msnet32/Makefile
1406 dlls/msrle32/Makefile
1407 dlls/msvcrt/Makefile
1408 dlls/msvcrt20/Makefile
1409 dlls/msvideo/Makefile
1410 dlls/netapi32/Makefile
1411 dlls/netapi32/tests/Makefile
1412 dlls/ntdll/Makefile
1413 dlls/ntdll/tests/Makefile
1414 dlls/odbc32/Makefile
1415 dlls/ole32/Makefile
1416 dlls/oleaut32/Makefile
1417 dlls/oleaut32/tests/Makefile
1418 dlls/olecli/Makefile
1419 dlls/oledlg/Makefile
1420 dlls/olepro32/Makefile
1421 dlls/olesvr/Makefile
1422 dlls/opengl32/Makefile
1423 dlls/psapi/Makefile
1424 dlls/qcap/Makefile
1425 dlls/quartz/Makefile
1426 dlls/rasapi32/Makefile
1427 dlls/richedit/Makefile
1428 dlls/rpcrt4/Makefile
1429 dlls/serialui/Makefile
1430 dlls/setupapi/Makefile
1431 dlls/shdocvw/Makefile
1432 dlls/shell32/Makefile
1433 dlls/shell32/tests/Makefile
1434 dlls/shfolder/Makefile
1435 dlls/shlwapi/Makefile
1436 dlls/shlwapi/tests/Makefile
1437 dlls/snmpapi/Makefile
1438 dlls/sti/Makefile
1439 dlls/tapi32/Makefile
1440 dlls/ttydrv/Makefile
1441 dlls/twain/Makefile
1442 dlls/url/Makefile
1443 dlls/urlmon/Makefile
1444 dlls/user/Makefile
1445 dlls/user/tests/Makefile
1446 dlls/version/Makefile
1447 dlls/win32s/Makefile
1448 dlls/winaspi/Makefile
1449 dlls/winedos/Makefile
1450 dlls/wineps/Makefile
1451 dlls/wininet/Makefile
1452 dlls/wininet/tests/Makefile
1453 dlls/winmm/Makefile
1454 dlls/winmm/joystick/Makefile
1455 dlls/winmm/mcianim/Makefile
1456 dlls/winmm/mciavi/Makefile
1457 dlls/winmm/mcicda/Makefile
1458 dlls/winmm/mciseq/Makefile
1459 dlls/winmm/mciwave/Makefile
1460 dlls/winmm/midimap/Makefile
1461 dlls/winmm/wavemap/Makefile
1462 dlls/winmm/winealsa/Makefile
1463 dlls/winmm/winearts/Makefile
1464 dlls/winmm/wineaudioio/Makefile
1465 dlls/winmm/winenas/Makefile
1466 dlls/winmm/wineoss/Makefile
1467 dlls/winnls/Makefile
1468 dlls/winsock/Makefile
1469 dlls/winsock/tests/Makefile
1470 dlls/winspool/Makefile
1471 dlls/wintrust/Makefile
1472 dlls/wow32/Makefile
1473 dlls/wsock32/Makefile
1474 dlls/x11drv/Makefile
1475 documentation/Makefile
1476 include/Makefile
1477 library/Makefile
1478 miscemu/Makefile
1479 ole/Makefile
1480 programs/Makefile
1481 programs/avitools/Makefile
1482 programs/clock/Makefile
1483 programs/cmdlgtst/Makefile
1484 programs/control/Makefile
1485 programs/expand/Makefile
1486 programs/notepad/Makefile
1487 programs/osversioncheck/Makefile
1488 programs/progman/Makefile
1489 programs/regapi/Makefile
1490 programs/regedit/Makefile
1491 programs/regsvr32/Makefile
1492 programs/regtest/Makefile
1493 programs/uninstaller/Makefile
1494 programs/view/Makefile
1495 programs/wcmd/Makefile
1496 programs/wineconsole/Makefile
1497 programs/winedbg/Makefile
1498 programs/winefile/Makefile
1499 programs/winemine/Makefile
1500 programs/winepath/Makefile
1501 programs/winetest/Makefile
1502 programs/winhelp/Makefile
1503 programs/winver/Makefile
1504 server/Makefile
1505 tools/Makefile
1506 tools/widl/Makefile
1507 tools/winapi/Makefile
1508 tools/winebuild/Makefile
1509 tools/winedump/Makefile
1510 tools/wmc/Makefile
1511 tools/wpp/Makefile
1512 tools/wrc/Makefile
1513 tsx11/Makefile
1514 unicode/Makefile])
1516 AC_OUTPUT
1518 if test "$have_x" = "no"
1519 then
1520 echo
1521 echo "*** Warning: X development files not found. Wine will be built without"
1522 echo "*** X support, which currently does not work, and would probably not be"
1523 echo "*** what you want anyway. You will need to install devel packages of"
1524 echo "*** Xlib/Xfree86 at the very least."
1525 fi
1527 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1528 then
1529 echo
1530 echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1531 echo "*** terminal resize support. Consider upgrading ncurses."
1532 fi
1534 if test "$wine_cv_libc_reentrant" = "no"
1535 then
1536 echo
1537 echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1538 echo "*** threading support. Consider upgrading libc to a more recent"
1539 echo "*** reentrant version of libc."
1540 fi
1542 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1543 then
1544 echo
1545 echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1546 echo "*** applications won't work properly. You should upgrade your X11 library."
1547 fi
1549 if test "$wine_cv_opengl_version_OK" = "no"
1550 then
1551 echo
1552 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1553 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1554 fi
1556 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "x"
1557 then
1558 echo
1559 echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1560 echo "*** thread-safety. To prevent crashes, OpenGL support has been disabled."
1561 echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1562 echo "*** start configure with '--enable-opengl' to force OpenGL support."
1563 fi
1565 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a "x$enable_opengl" = "xyes"
1566 then
1567 echo
1568 echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1569 echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1570 echo "*** support before reporting bugs."
1571 fi
1573 if test "$wine_cv_warn_cups_h" = "yes"
1574 then
1575 echo
1576 echo "*** Note: You have cups runtime libraries, but no development"
1577 echo "*** libraries. Install the cups-devel package or whichever package"
1578 echo "*** contains cups.h to enable CUPS support in Wine."
1579 fi
1581 if test "$wine_cv_msg_freetype" = "yes"
1582 then
1583 echo
1584 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1585 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1586 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1587 echo "*** enable Wine to use TrueType fonts."
1588 fi
1590 echo
1591 echo "Configure finished. Do 'make depend && make' to compile Wine."
1592 echo
1594 dnl Local Variables:
1595 dnl comment-start: "dnl "
1596 dnl comment-end: ""
1597 dnl comment-start-skip: "\\bdnl\\b\\s *"
1598 dnl compile-command: "autoconf"
1599 dnl End: