configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  32 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  34 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  35 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  36             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  40 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  41 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  43 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  45 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  47 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  49 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  50 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  52 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  54 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  56 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  57 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  59 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  61 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  63 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  65 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  66 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  68 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  70 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  72 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  74 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  75 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  77
  78 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  79 AC_ARG_ENABLE(tests, AC_HELP_STRING([--disable-tests],[do not build the testsuites]))
  80
  81 AC_CANONICAL_HOST
  82 case $host in
  83   x86_64*linux*)
  84     if test "x$enable_win64" != "xyes"
  85     then
  86       test -n "$CC" || CC="gcc -m32"
  87       test -n "$CXX"|| CXX="g++ -m32"
  88       test -n "$LD" || LD="ld -m elf_i386"
  89       test -n "$AS" || AS="as --32"
  90       host_cpu="i386"
  91     fi
  92     ;;
  93 esac
  94
  95 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  96 case $host_cpu in
  97   *i[[3456789]]86*)
  98     if test "x$enable_win16" != "xno"
  99     then
 100       enable_win16="yes"
 101     fi
 102     ;;
 103 esac
 104
 105 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 106 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 107 if test "x$enable_win16" != "xyes"
 108 then
 109   WIN16_FILES=""
 110   WIN16_INSTALL=""
 111 fi
 112
 113 dnl enable_tests is yes by default, but in some cases it's better to disable the testsuite
 114 if test "x$enable_tests" == "xno"
 115 then
 116   AC_SUBST(TESTSUBDIRS,"")
 117   AC_SUBST(WINETEST,"")
 118 else
 119   AC_SUBST(TESTSUBDIRS,"\$(TESTSUBDIRS)")
 120   AC_SUBST(WINETEST,"winetest")
 121 fi
 122
 123 dnl check for out of tree build with unclean source tree
 124 case "$srcdir" in
 125  .) ;;
 126  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 127       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 128 You need to run 'make distclean' in the source tree first.])
 129     fi ;;
 130 esac
 131
 132 dnl **** Check for some programs ****
 133
 134 AC_PROG_MAKE_SET
 135 AC_PROG_CC
 136 AC_PROG_CXX
 137 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 138 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 139
 140 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 141   [if test -z "$with_wine_tools"; then
 142      if test "$cross_compiling" = "yes"; then
 143        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 144      else
 145        wine_cv_toolsdir="\$(TOPOBJDIR)"
 146      fi
 147    elif test -d "$with_wine_tools/tools/winebuild"; then
 148      case $with_wine_tools in
 149        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 150        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 151      esac
 152    else
 153      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 154    fi])
 155 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 156
 157 AC_PATH_XTRA
 158
 159 dnl Check for flex
 160 AC_CHECK_PROGS(FLEX,flex,none)
 161 if test "$FLEX" = "none"
 162 then
 163   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 164 fi
 165
 166 dnl Check for bison
 167 AC_CHECK_PROGS(BISON,bison,none)
 168 if test "$BISON" = "none"
 169 then
 170   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 171 fi
 172
 173 AC_CHECK_TOOLS(AS,[gas as],as)
 174 AC_CHECK_TOOL(LD,ld,ld)
 175 AC_CHECK_TOOL(AR,ar,ar)
 176 AC_SUBST(ARFLAGS,rc)
 177 AC_PROG_RANLIB
 178 AC_CHECK_TOOL(STRIP,strip,strip)
 179 AC_CHECK_TOOL(WINDRES,windres,false)
 180 AC_PROG_LN_S
 181 WINE_PROG_LN
 182 AC_PROG_EGREP
 183 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 184 AC_PROG_INSTALL
 185 dnl Prepend src dir to install path dir if it's a relative path
 186 case "$INSTALL" in
 187   [[\\/$]]* | ?:[[\\/]]* ) ;;
 188   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 189 esac
 190
 191 dnl Check for lint
 192 AC_CHECK_PROGS(LINT, lclint lint)
 193 if test "$LINT" = "lint"
 194 then
 195   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 196   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 197 fi
 198 AC_SUBST(LINT)
 199 AC_SUBST(LINTFLAGS)
 200
 201 dnl Check for various programs
 202 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 203 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 204 AC_CHECK_PROGS(RSVG, rsvg, false)
 205 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 206
 207 if test "${enable_maintainer_mode+set}" = set
 208 then
 209   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 210   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 211   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 212 fi
 213
 214 case $host_cpu in
 215   *i[[3456789]]86*)
 216     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 217     ;;
 218 esac
 219
 220 dnl **** Check for some libraries ****
 221
 222 dnl Check for -li386 for NetBSD and OpenBSD
 223 AC_CHECK_LIB(i386,i386_set_ldt)
 224 dnl Check for -lossaudio for NetBSD
 225 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 226 dnl Check for -lpthread
 227 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 228
 229 AC_SUBST(XLIB,"")
 230 AC_SUBST(XFILES,"")
 231 AC_SUBST(OPENGLFILES,"")
 232 AC_SUBST(GLU32FILES,"")
 233 AC_SUBST(OPENGL_LIBS,"")
 234 AC_SUBST(QUARTZFILES,"")
 235
 236 dnl **** Check for header files ****
 237
 238 AC_CHECK_HEADERS(\
 239         AudioUnit/AudioUnit.h \
 240         Carbon/Carbon.h \
 241         CoreAudio/CoreAudio.h \
 242         DiskArbitration/DiskArbitration.h \
 243         IOKit/IOKitLib.h \
 244         alsa/asoundlib.h \
 245         arpa/inet.h \
 246         arpa/nameser.h \
 247         asm/types.h \
 248         capi20.h \
 249         cups/cups.h \
 250         curses.h \
 251         direct.h \
 252         dlfcn.h \
 253         elf.h \
 254         float.h \
 255         fontconfig/fontconfig.h \
 256         getopt.h \
 257         ieeefp.h \
 258         io.h \
 259         jack/jack.h \
 260         jpeglib.h \
 261         lber.h \
 262         lcms.h \
 263         lcms/lcms.h \
 264         ldap.h \
 265         libaudioio.h \
 266         link.h \
 267         linux/cdrom.h \
 268         linux/compiler.h \
 269         linux/hdreg.h \
 270         linux/input.h \
 271         linux/ioctl.h \
 272         linux/joystick.h \
 273         linux/major.h \
 274         linux/param.h \
 275         linux/serial.h \
 276         linux/ucdrom.h \
 277         mach/mach.h \
 278         mach/machine.h \
 279         machine/cpu.h \
 280         machine/limits.h \
 281         machine/soundcard.h \
 282         mntent.h \
 283         ncurses.h \
 284         netdb.h \
 285         netinet/in.h \
 286         netinet/in_systm.h \
 287         netinet/tcp.h \
 288         netinet/tcp_fsm.h \
 289         openssl/err.h \
 290         openssl/ssl.h \
 291         png.h \
 292         poll.h \
 293         process.h \
 294         pthread.h \
 295         pwd.h \
 296         regex.h \
 297         sched.h \
 298         scsi/scsi.h \
 299         scsi/scsi_ioctl.h \
 300         scsi/sg.h \
 301         soundcard.h \
 302         stdint.h \
 303         strings.h \
 304         sys/asoundlib.h \
 305         sys/cdio.h \
 306         sys/elf32.h \
 307         sys/epoll.h \
 308         sys/errno.h \
 309         sys/event.h \
 310         sys/exec_elf.h \
 311         sys/filio.h \
 312         sys/ioctl.h \
 313         sys/ipc.h \
 314         sys/limits.h \
 315         sys/link.h \
 316         sys/lwp.h \
 317         sys/mman.h \
 318         sys/modem.h \
 319         sys/msg.h \
 320         sys/mtio.h \
 321         sys/param.h \
 322         sys/poll.h \
 323         sys/prctl.h \
 324         sys/ptrace.h \
 325         sys/reg.h \
 326         sys/resource.h \
 327         sys/scsiio.h \
 328         sys/shm.h \
 329         sys/signal.h \
 330         sys/socket.h \
 331         sys/socketvar.h \
 332         sys/sockio.h \
 333         sys/soundcard.h \
 334         sys/statvfs.h \
 335         sys/strtio.h \
 336         sys/syscall.h \
 337         sys/sysctl.h \
 338         sys/time.h \
 339         sys/times.h \
 340         sys/uio.h \
 341         sys/un.h \
 342         sys/vm86.h \
 343         sys/wait.h \
 344         syscall.h \
 345         termios.h \
 346         unistd.h \
 347         utime.h \
 348         valgrind/memcheck.h
 349 )
 350 AC_HEADER_STAT()
 351
 352 dnl **** Checks for headers that depend on other ones ****
 353
 354 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 355     [#include <sys/types.h>
 356      #ifdef HAVE_SYS_PARAM_H
 357      # include <sys/param.h>
 358      #endif])
 359
 360 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 361     [#include <sys/types.h>
 362      #ifdef HAVE_SYS_SOCKET_H
 363      # include <sys/socket.h>
 364      #endif
 365      #ifdef HAVE_SYS_SOCKETVAR_H
 366      # include <sys/socketvar.h>
 367      #endif
 368      #ifdef HAVE_NETINET_IN_H
 369      # include <netinet/in.h>
 370      #endif])
 371
 372 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 373     [#include <sys/types.h>
 374      #ifdef HAVE_SYS_SOCKET_H
 375      # include <sys/socket.h>
 376      #endif
 377      #ifdef HAVE_SYS_SOCKETVAR_H
 378      # include <sys/socketvar.h>
 379      #endif
 380      #ifdef HAVE_NETINET_IN_H
 381      # include <netinet/in.h>
 382      #endif
 383      #ifdef HAVE_NETINET_TCP_H
 384      # include <netinet/tcp.h>
 385      #endif])
 386
 387 AC_CHECK_HEADERS([linux/ipx.h],,,
 388     [#include <sys/types.h>
 389      #ifdef HAVE_ASM_TYPES_H
 390      # include <asm/types.h>
 391      #endif
 392      #ifdef HAVE_SYS_SOCKET_H
 393      # include <sys/socket.h>
 394      #endif])
 395
 396 AC_CHECK_HEADERS([resolv.h],,,
 397     [#include <sys/types.h>
 398      #ifdef HAVE_SYS_SOCKET_H
 399      # include <sys/socket.h>
 400      #endif
 401      #ifdef HAVE_NETINET_IN_H
 402      # include <netinet/in.h>
 403      #endif
 404      #ifdef HAVE_ARPA_NAMESER_H
 405      # include <arpa/nameser.h>
 406      #endif])
 407
 408 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 409
 410 AC_CHECK_HEADERS([sys/thr.h],,,
 411 [#include <sys/types.h>
 412 #ifdef HAVE_UCONTEXT_H
 413 #include <ucontext.h>
 414 #endif])
 415
 416 AC_CHECK_HEADERS([pthread_np.h],,,
 417 [#ifdef HAVE_PTHREAD_H
 418 #include <pthread.h>
 419 #endif])
 420
 421 AC_CHECK_HEADERS([linux/videodev.h],,,
 422 [#ifdef HAVE_SYS_TIME_H
 423 #include <sys/time.h>
 424 #endif
 425 #include <sys/types.h>
 426 #ifdef HAVE_ASM_TYPES_H
 427 #include <asm/types.h>
 428 #endif])
 429
 430 dnl Check for broken kernel header that doesn't define __user
 431 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 432
 433 dnl **** Check for working dll ****
 434
 435 AC_SUBST(DLLEXT,"")
 436 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 437 AC_SUBST(LDSHARED,"")
 438 AC_SUBST(LDDLLFLAGS,"")
 439 AC_SUBST(LIBEXT,"so")
 440 AC_SUBST(IMPLIBEXT,"def")
 441 AC_SUBST(LDRPATH_INSTALL,"")
 442 AC_SUBST(LDRPATH_LOCAL,"")
 443 WINE_PATH_LDD
 444
 445 case $host_os in
 446   cygwin*|mingw32*)
 447     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 448     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 449     AC_CHECK_TOOL(MINGWAR,ar,false)
 450     if test "$DLLWRAP" = "false"; then
 451       LIBEXT="a"
 452     else
 453       dnl FIXME - check whether dllwrap works correctly...
 454       LIBEXT="dll"
 455     fi
 456     IMPLIBEXT="a"
 457     dnl We can't build 16-bit NE dlls
 458     WIN16_FILES=""
 459     WIN16_INSTALL=""
 460     ;;
 461   darwin*|macosx*)
 462     DLLEXT=".so"
 463     LIBEXT="dylib"
 464     DLLFLAGS="$DLLFLAGS -fPIC"
 465     LDDLLFLAGS="-bundle -multiply_defined suppress"
 466     LIBWINE_LDFLAGS="-multiply_defined suppress"
 467     LDSHARED="\$(CC) -dynamiclib"
 468     STRIP="$STRIP -x"
 469     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 470     dnl declare needed frameworks
 471     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 472     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 473     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 474     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 475     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 476     then
 477         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 478         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 479     fi
 480     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 481     then
 482         dnl CoreServices needed by AudioUnit
 483         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 484     fi
 485     case $host_cpu in
 486       *powerpc*)
 487         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 488         ;;
 489     esac
 490     dnl Enable quartz driver on Mac OS X
 491     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 492     then
 493         AC_SUBST(CARBONLIB,"-framework Carbon")
 494         QUARTZFILES='$(QUARTZFILES)'
 495     fi
 496     ;;
 497   *)
 498     DLLFLAGS="$DLLFLAGS -fPIC"
 499     DLLEXT=".so"
 500     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 501         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 502                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 503     if test "$ac_cv_c_dll_gnuelf" = "yes"
 504     then
 505       LDSHARED="\$(CC) -shared"
 506       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 507       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 508                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 509                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 510                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 511
 512       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 513
 514       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 515                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 516
 517       echo '{ global: *; };' >conftest.map
 518       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 519                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 520       rm -f conftest.map
 521
 522       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 523                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 524
 525       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 526                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 527                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 528           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 529                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 530                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 531
 532       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 533                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 534
 535       case $host_cpu in
 536         *i[[3456789]]86* | x86_64)
 537           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 538                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 539           ;;
 540       esac
 541
 542     else
 543       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 544           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 545                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 546       if test "$ac_cv_c_dll_unixware" = "yes"
 547       then
 548         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 549         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 550
 551       else
 552         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 553           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 554         if test "$ac_cv_c_dll_hpux" = "yes"
 555         then
 556           LIBEXT="sl"
 557           DLLEXT=".sl"
 558           LDDLLFLAGS="-shared -fPIC"
 559           LDSHARED="\$(CC) -shared"
 560         fi
 561       fi
 562     fi
 563
 564     dnl Check for cross compiler to build test programs
 565     AC_SUBST(CROSSTEST,"")
 566     if test "$cross_compiling" = "no"
 567     then
 568       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 569       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 570       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 571       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 572       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 573     fi
 574     ;;
 575 esac
 576
 577 if test "$LIBEXT" = "a"; then
 578   AC_MSG_ERROR(
 579 [could not find a way to build shared libraries.
 580 It is currently not possible to build Wine without shared library
 581 (.so) support to allow transparent switch between .so and .dll files.
 582 If you are using Linux, you will need a newer binutils.]
 583 )
 584 fi
 585
 586 dnl **** Check for X11 ****
 587
 588 if test "$have_x" = "yes"
 589 then
 590     XLIB="-lXext -lX11"
 591     ac_save_CPPFLAGS="$CPPFLAGS"
 592     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 593
 594     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 595     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 596
 597     dnl *** All of the following tests require X11/Xlib.h
 598     AC_CHECK_HEADERS([X11/Xlib.h \
 599                       X11/XKBlib.h \
 600                       X11/Xutil.h \
 601                       X11/Xcursor/Xcursor.h \
 602                       X11/extensions/shape.h \
 603                       X11/extensions/XInput.h \
 604                       X11/extensions/XShm.h \
 605                       X11/extensions/Xcomposite.h \
 606                       X11/extensions/Xinerama.h \
 607                       X11/extensions/Xrandr.h \
 608                       X11/extensions/Xrender.h \
 609                       X11/extensions/xf86vmode.h],,,
 610 [#ifdef HAVE_X11_XLIB_H
 611 # include <X11/Xlib.h>
 612 #endif
 613 #ifdef HAVE_X11_XUTIL_H
 614 # include <X11/Xutil.h>
 615 #endif])
 616
 617         dnl *** Check for X keyboard extension
 618         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 619         then
 620               AC_CHECK_LIB(X11, XkbQueryExtension,
 621               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 622               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 623         fi
 624
 625         dnl *** Check for X cursor
 626         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 627         then
 628             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 629         fi
 630         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 631                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 632
 633         dnl *** Check for X input extension
 634         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 635         then
 636             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 637         fi
 638         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 639                          [libxi development files not found, the Xinput extension won't be supported.])
 640
 641         dnl *** Check for X Shm extension
 642         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 643         then
 644               AC_CHECK_LIB(Xext, XShmQueryExtension,
 645               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 646               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 647         fi
 648         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 649                          [XShm development files not found, X Shared Memory won't be supported.])
 650
 651         dnl *** Check for X shape extension
 652         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 653         then
 654               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 655               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 656               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 657         fi
 658         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 659                          [XShape development files not found, XShape won't be supported.])
 660
 661         dnl *** Check for XFree86 VMODE extension
 662         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 663         then
 664                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 665                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 666                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 667                   ],,
 668                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 669         fi
 670         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 671                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 672
 673         dnl *** Check for Transform functions in Xrender
 674         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 675         then
 676             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 677               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 678                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 679                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 680                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 681
 682         fi
 683         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 684                          [libxrender development files not found, XRender won't be supported.])
 685
 686         dnl *** Check for X RandR extension
 687         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 688         then
 689                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 690 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 691                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 692         fi
 693         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 694                          [libxrandr development files not found, XRandr won't be supported.])
 695
 696         dnl *** Check for Xinerama extension
 697         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 698         then
 699                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 700 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 701                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 702         fi
 703         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 704                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 705
 706         dnl *** Check for X Composite extension
 707         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 708         then
 709             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 710         fi
 711         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 712                          [libxcomposite development files not found, Xcomposite won't be supported.])
 713
 714         dnl *** Check for XICCallback struct
 715         AC_CHECK_MEMBERS([XICCallback.callback],,,
 716 [#ifdef HAVE_X11_XLIB_H
 717 #include <X11/Xlib.h>
 718 #endif])
 719
 720     dnl *** End of X11/Xlib.h check
 721
 722     dnl Check for the presence of OpenGL
 723     opengl_msg=""
 724     if test "x$with_opengl" != "xno"
 725     then
 726         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 727 [#ifdef HAVE_GL_GLX_H
 728 # include <GL/glx.h>
 729 #endif])
 730         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 731         then
 732             dnl Check for some problems due to old Mesa versions
 733             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 734               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 735                 [wine_cv_opengl_header_version_OK="yes"],
 736                 [wine_cv_opengl_header_version_OK="no"]))
 737
 738             if test "$wine_cv_opengl_header_version_OK" = "yes"
 739             then
 740                 dnl Check for the presence of the library
 741                 WINE_CHECK_SONAME(GL,glXCreateContext,
 742                              [OPENGL_LIBS="-lGL"
 743                              OPENGLFILES='$(OPENGLFILES)'
 744                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 745                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 746                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 747                                     OPENGLFILES='$(OPENGLFILES)'
 748                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 749                                     [if test -f /usr/X11R6/lib/libGL.a
 750                                     then
 751                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 752 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 753                                     else
 754                                         opengl_msg="No OpenGL library found on this system."
 755                                     fi],
 756                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 757                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 758                  if test "$ac_cv_header_GL_glu_h" = "yes"
 759                  then
 760                     WINE_CHECK_SONAME(GLU,gluLookAt,[GLU32FILES='$(GLU32FILES)'],,
 761                                       [$OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS])
 762                  fi
 763                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
 764                                  [libGLU development files not found, GLU won't be supported.])
 765              else
 766                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 767              fi
 768          else
 769              opengl_msg="OpenGL development headers not found."
 770          fi
 771     fi
 772     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 773 OpenGL and Direct3D won't be supported.])
 774
 775     dnl **** Check for NAS ****
 776     AC_SUBST(NASLIBS,"")
 777     AC_CHECK_HEADERS(audio/audiolib.h,
 778          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 779           AC_CHECK_LIB(audio,AuCreateFlow,
 780                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 781                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 782                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 783                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 784                           [$X_LIBS])
 785                        ],,
 786                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 787
 788     CPPFLAGS="$ac_save_CPPFLAGS"
 789     XFILES='$(XFILES)'
 790 else
 791     XLIB=""
 792     X_CFLAGS=""
 793     X_LIBS=""
 794 fi
 795 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 796 without X support, which probably isn't what you want. You will need to install
 797 development packages of Xlib/Xfree86 at the very least.])
 798
 799 dnl **** Check for libxml2 ****
 800
 801 AC_SUBST(XML2LIBS,"")
 802 AC_SUBST(XML2INCL,"")
 803 AC_SUBST(XSLTLIBS,"")
 804 AC_SUBST(XSLTINCL,"")
 805 if test "x$with_xml" != "xno"
 806 then
 807     ac_save_CPPFLAGS="$CPPFLAGS"
 808     if test "$PKG_CONFIG" != "false"
 809     then
 810         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 811         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 812     else
 813         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 814         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 815     fi
 816     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 817     AC_CHECK_HEADERS(libxml/parser.h,
 818             [AC_CHECK_LIB(xml2, xmlParseMemory,
 819                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 820                  XML2LIBS="$ac_xml_libs"
 821                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 822              AC_CHECK_LIB(xml2, xmlReadMemory,
 823                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 824              AC_CHECK_LIB(xml2, xmlNewDocPI,
 825                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 826         ])
 827     CPPFLAGS="$ac_save_CPPFLAGS"
 828 fi
 829 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 830                  [libxml2 development files not found, XML won't be supported.])
 831
 832 if test "x$with_xslt" != "xno"
 833 then
 834     if test "$PKG_CONFIG" != "false"
 835     then
 836         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 837         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 838     else
 839         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 840         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 841     fi
 842     ac_save_CPPFLAGS="$CPPFLAGS"
 843     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 844     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
 845     [#ifdef HAVE_LIBXSLT_PATTERN_H
 846 # include <libxslt/pattern.h>
 847 #endif])
 848     CPPFLAGS="$ac_save_CPPFLAGS"
 849     if test "$ac_cv_header_libxslt_transform_h" = "yes"
 850     then
 851         AC_CHECK_LIB(xslt, xsltCompilePattern,
 852             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 853              XSLTLIBS="$ac_xslt_libs"
 854              XSLTINCL="$ac_xslt_cflags"
 855              ac_save_LIBS="$LIBS"
 856              LIBS="$LIBS $ac_xslt_libs"
 857              AC_CHECK_FUNCS(xsltInit)
 858              LIBS="$ac_save_LIBS"],,$ac_xslt_libs)
 859     fi
 860 fi
 861 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 862                  [libxslt development files not found, xslt won't be supported.])
 863
 864 dnl **** Check for libhal ****
 865 AC_SUBST(HALINCL,"")
 866 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 867 then
 868     ac_save_CPPFLAGS="$CPPFLAGS"
 869     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 870     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 871     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 872     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 873     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 874     then
 875         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 876           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 877             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 878     fi
 879     CPPFLAGS="$ac_save_CPPFLAGS"
 880 fi
 881 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 882                  [libhal development files not found, no dynamic device support.])
 883
 884 dnl **** Check which curses lib to use ***
 885 CURSESLIBS=""
 886 if test "$ac_cv_header_ncurses_h" = "yes"
 887 then
 888     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 889 elif test "$ac_cv_header_curses_h" = "yes"
 890 then
 891     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 892 fi
 893 ac_save_LIBS="$LIBS"
 894 LIBS="$LIBS $CURSESLIBS"
 895 AC_CHECK_FUNCS(mousemask)
 896 LIBS="$ac_save_LIBS"
 897 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 898                  [lib(n)curses development files not found, curses won't be supported.])
 899
 900 dnl **** Check for SANE ****
 901 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 902 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 903 then
 904     ac_sane_incl="`$sane_devel --cflags`"
 905     ac_save_CPPFLAGS="$CPPFLAGS"
 906     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 907     AC_CHECK_HEADER(sane/sane.h,
 908         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 909     CPPFLAGS="$ac_save_CPPFLAGS"
 910 fi
 911 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 912                  [libsane development files not found, scanners won't be supported.])
 913
 914 dnl **** Check for libgphoto2 ****
 915 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 916 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 917 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 918 then
 919     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 920     ac_gphoto2_libs=""
 921     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 922     do
 923       case "$i" in
 924         -L/usr/lib|-L/usr/lib64) ;;
 925         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 926       esac
 927     done
 928     ac_save_CPPFLAGS="$CPPFLAGS"
 929     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 930     AC_CHECK_HEADER(gphoto2-camera.h,
 931                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 932                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 933                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 934                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 935                                   [$GPHOTO2LIBS])])
 936     CPPFLAGS="$ac_save_CPPFLAGS"
 937 fi
 938 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 939                  [libgphoto2 development files not found, digital cameras won't be supported.])
 940
 941
 942 dnl **** Check for resolver library ***
 943 AC_SUBST(RESOLVLIBS,"")
 944 if test "$ac_cv_header_resolv_h" = "yes"
 945 then
 946     AC_CHECK_LIB(resolv, res_query,
 947         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 948          RESOLVLIBS="-lresolv"])
 949 fi
 950
 951 dnl **** Check for LittleCMS ***
 952 AC_SUBST(LCMSLIBS,"")
 953 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 954 then
 955     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 956         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 957          LCMSLIBS="-llcms"])
 958 fi
 959 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 960                  [liblcms development files not found, Color Management won't be supported.])
 961
 962 dnl **** Check for OpenLDAP ***
 963 AC_SUBST(LDAPLIBS,"")
 964 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 965 then
 966     AC_CHECK_LIB(ldap_r, ldap_initialize,
 967         [AC_CHECK_LIB(lber, ber_init,
 968             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 969              LDAPLIBS="-lldap_r -llber"],,
 970              [$LIBPTHREAD])],,
 971              [$LIBPTHREAD])
 972     WINE_CHECK_LIB_FUNCS(\
 973         ldap_count_references \
 974         ldap_first_reference \
 975         ldap_next_reference \
 976         ldap_parse_reference \
 977         ldap_parse_sort_control \
 978         ldap_parse_sortresponse_control \
 979         ldap_parse_vlv_control \
 980         ldap_parse_vlvresponse_control,
 981         [$LDAPLIBS $LIBPTHREAD])
 982 fi
 983 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 984                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 985
 986 dnl **** Check for FreeType 2 ****
 987 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 988 if test "$ft_devel" != "false"
 989 then
 990     ac_freetype_libs=`$ft_devel --libs`
 991     ac_freetype_incl=`$ft_devel --cflags`
 992     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 993     if test "$ft_lib" = "yes"
 994     then
 995         ac_save_CPPFLAGS="$CPPFLAGS"
 996         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 997         AC_CHECK_HEADERS(ft2build.h \
 998                          freetype/freetype.h \
 999                          freetype/ftglyph.h \
1000                          freetype/fttypes.h \
1001                          freetype/tttables.h \
1002                          freetype/ftnames.h \
1003                          freetype/ftsnames.h \
1004                          freetype/ttnameid.h \
1005                          freetype/ftoutln.h \
1006                          freetype/ftwinfnt.h \
1007                          freetype/ftmodapi.h \
1008                          freetype/internal/sfnt.h,,,
1009                          [#ifdef HAVE_FT2BUILD_H
1010                           # include <ft2build.h>
1011                           #endif])
1012         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1013                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1014           [Define if you have the <freetype/fttrigon.h> header file.])
1015                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1016         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1017         ac_save_CFLAGS="$CFLAGS"
1018         CFLAGS="$CFLAGS $ac_freetype_libs"
1019         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1020         CFLAGS="$ac_save_CFLAGS"
1021         CPPFLAGS="$ac_save_CPPFLAGS"
1022         dnl Check that we have at least freetype/freetype.h
1023         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1024         then
1025             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1026             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1027             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1028         fi
1029     fi
1030 fi
1031
1032 dnl Only build the fonts dir if we have freetype
1033 if test "x$FREETYPELIBS" = "x"
1034 then
1035     WINE_WARNING([FreeType development files not found.
1036 Fonts will not be built. Dialog text may be invisible or unaligned.])
1037 else
1038   AC_SUBST(FONTSSUBDIRS,"fonts")
1039 fi
1040
1041 dnl **** Check for parport (currently Linux only) ****
1042 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1043  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1044     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1045 if test "$ac_cv_c_ppdev" = "yes"
1046 then
1047     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1048 fi
1049
1050 dnl **** Check for va_copy ****
1051 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1052  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1053     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1054  )
1055 if test "$ac_cv_c_va_copy" = "yes"
1056 then
1057     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1058 fi
1059 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1060  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1061     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1062  )
1063 if test "$ac_cv_c___va_copy" = "yes"
1064 then
1065     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1066 fi
1067
1068 dnl **** Check for sigsetjmp ****
1069 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1070  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1071     sigsetjmp( buf, 1 );
1072     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1073  )
1074 if test "$ac_cv_c_sigsetjmp" = "yes"
1075 then
1076     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1077 fi
1078
1079 dnl **** Check for pthread_rwlock_t ****
1080 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1081 #include <pthread.h>])
1082
1083 dnl **** Check for pthread functions ****
1084 WINE_CHECK_LIB_FUNCS(\
1085         pthread_attr_get_np \
1086         pthread_getattr_np \
1087         pthread_get_stackaddr_np \
1088         pthread_get_stacksize_np,
1089         [$LIBPTHREAD])
1090
1091 dnl **** Check for EsounD ****
1092 AC_PATH_PROG(ESDCONFIG, esd-config)
1093 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1094 then
1095     ESD_CFLAGS=""
1096     for i in `$ESDCONFIG --cflags`
1097     do
1098       case "$i" in
1099         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1100       esac
1101     done
1102     ESD_LIBS=`$ESDCONFIG --libs`
1103     save_CFLAGS="$CFLAGS"
1104     CFLAGS="$CFLAGS $ESD_CFLAGS"
1105     AC_CHECK_LIB(esd,esd_open_sound,
1106         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1107          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1108          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1109     CFLAGS="$save_CFLAGS"
1110 fi
1111
1112 dnl **** Check for ALSA 1.x ****
1113 AC_SUBST(ALSALIBS,"")
1114 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1115 then
1116     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1117         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1118 #include <alsa/asoundlib.h>
1119 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1120 #include <sys/asoundlib.h>
1121 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1122                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1123                          ALSALIBS="-lasound"],[])])
1124 fi
1125
1126 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1127 AC_SUBST(AUDIOIOLIBS,"")
1128 if test "$ac_cv_header_libaudioio_h" = "yes"
1129 then
1130     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1131                   [AUDIOIOLIBS="-laudioio"
1132                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1133 fi
1134
1135 dnl **** Check for capi4linux ****
1136
1137 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1138 then
1139     WINE_CHECK_SONAME(capi20,capi20_register)
1140 fi
1141 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1142                  [libcapi20 development files not found, ISDN won't be supported.])
1143
1144 dnl **** Check for cups ****
1145 if test "$ac_cv_header_cups_cups_h" = "yes"
1146 then
1147     WINE_CHECK_SONAME(cups,cupsGetDefault)
1148 fi
1149 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1150                  [libcups development files not found, CUPS won't be supported.])
1151
1152 dnl **** Check for jack ****
1153 if test "$ac_cv_header_jack_jack_h" = "yes"
1154 then
1155     WINE_CHECK_SONAME(jack,jack_client_new)
1156 fi
1157
1158 dnl **** Check for fontconfig ****
1159 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1160 then
1161     WINE_CHECK_SONAME(fontconfig,FcInit)
1162 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1163 then
1164     dnl fontconfig is in the X directory on Mac OS X
1165     ac_save_CPPFLAGS="$CPPFLAGS"
1166     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1167     $as_unset ac_cv_header_fontconfig_fontconfig_h
1168     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1169     CPPFLAGS="$ac_save_CPPFLAGS"
1170     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1171     then
1172         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1173         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1174     fi
1175 fi
1176 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1177                  [fontconfig development files not found, fontconfig won't be supported.])
1178
1179 dnl **** Check for SSL ****
1180 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1181 then
1182     WINE_CHECK_SONAME(ssl,SSL_library_init)
1183     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1184 fi
1185 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1186                  [OpenSSL development files not found, SSL won't be supported.])
1187
1188 dnl **** Check for libjpeg ****
1189 if test "$ac_cv_header_jpeglib_h" = "yes"
1190 then
1191     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1192 fi
1193 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1194                  [libjpeg development files not found, JPEG won't be supported.])
1195
1196 dnl **** Check for libpng ****
1197 if test "$ac_cv_header_png_h" = "yes"
1198 then
1199     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1200 fi
1201 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1202                  [libpng development files not found, PNG won't be supported.])
1203
1204 dnl **** Check for libodbc ****
1205 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1206
1207 dnl **** Check for any sound system ****
1208 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1209         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1210         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1211         "$ac_cv_header_soundcard_h" != "yes" -a \
1212         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1213 then
1214     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1215 fi
1216
1217 dnl **** Check for gcc specific options ****
1218
1219 AC_SUBST(EXTRACFLAGS,"")
1220 if test "x${GCC}" = "xyes"
1221 then
1222   EXTRACFLAGS="-Wall -pipe"
1223
1224   dnl Check for strength-reduce bug
1225   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1226                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1227 [[static int Array[[3]];
1228   unsigned int B = 3;
1229   int i;
1230   for(i=0; i<B; i++) Array[[i]] = i - 3;
1231   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1232   L[[i]] = 4;
1233   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1234     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1235   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1236   then
1237     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1238   fi
1239
1240   dnl Check for some compiler flags
1241
1242   WINE_TRY_CFLAGS([-fshort-wchar],
1243                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1244                              [Specifies the compiler flag that forces a short wchar_t])])
1245   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1246   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1247   WINE_TRY_CFLAGS([-Wwrite-strings])
1248   WINE_TRY_CFLAGS([-Wtype-limits])
1249
1250   dnl Check for noisy string.h
1251   saved_CFLAGS="$CFLAGS"
1252   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1253   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1254       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1255   CFLAGS="$saved_CFLAGS"
1256   if test "$ac_cv_c_string_h_warnings" = "no"
1257   then
1258     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1259   fi
1260
1261   AC_SUBST(BUILTINFLAG,"")
1262   saved_CFLAGS="$CFLAGS"
1263   CFLAGS="$CFLAGS -Werror"
1264   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1265       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1266   CFLAGS="$saved_CFLAGS"
1267   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1268   then
1269     BUILTINFLAG="-fno-builtin"
1270   fi
1271 fi
1272
1273 dnl **** Check how to define a function in assembly code ****
1274
1275 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1276   WINE_TRY_ASM_LINK(
1277       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1278       ac_cv_asm_func_def=".def",
1279     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1280       ac_cv_asm_func_def=".type @function",
1281     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1282       ac_cv_asm_func_def=".type 2",
1283       ac_cv_asm_func_def="unknown")])]))
1284
1285 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1286 case "$ac_cv_asm_func_def" in
1287   ".def")
1288      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1289   ".type @function")
1290      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1291   ".type 2")
1292      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1293   *)
1294      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1295 esac
1296
1297 dnl **** Check for underscore on external symbols ****
1298
1299 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1300     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1301                       [extern int ac_test;],
1302                       [if (ac_test) return 1],
1303                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1304
1305 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1306 if test "$ac_cv_c_extern_prefix" = "yes"
1307 then
1308   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1309 else
1310   AC_DEFINE([__ASM_NAME(name)], [name])
1311 fi
1312
1313 dnl **** Platform-specific checks ****
1314
1315 AC_SUBST(LDPATH,"")
1316 case $build_os in
1317   cygwin*|mingw32*)
1318     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1319     ;;
1320   darwin*|macosx*)
1321     ;;
1322   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1323     if test -z "$LDRPATH_LOCAL"
1324     then
1325       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1326     fi
1327     ;;
1328   *)
1329     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1330     ;;
1331 esac
1332
1333 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1334 case $host_os in
1335   mingw32*)
1336     AC_SUBST(CRTLIBS,"-lmsvcrt")
1337     AC_SUBST(SOCKETLIBS,"-lws2_32")
1338     ;;
1339 esac
1340
1341 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1342 case $host_cpu in
1343   *i[[3456789]]86*)
1344     case $host_os in
1345       linux* | k*bsd*-gnu)
1346         AC_SUBST(MAIN_BINARY,"wine-glibc")
1347         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1348       freebsd*)
1349         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1350         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1351     esac
1352     ;;
1353 esac
1354
1355 dnl **** Check for functions ****
1356
1357 AC_CHECK_FUNCS(\
1358         _pclose \
1359         _popen \
1360         _snprintf \
1361         _spawnvp \
1362         _strdup \
1363         _stricmp \
1364         _strnicmp \
1365         _strtoi64 \
1366         _strtoui64 \
1367         _vsnprintf \
1368         asctime_r \
1369         chsize \
1370         clone \
1371         dlopen \
1372         epoll_create \
1373         ffs \
1374         finite \
1375         fork \
1376         fpclass \
1377         fstatfs \
1378         fstatvfs \
1379         ftruncate \
1380         futimes \
1381         futimesat \
1382         getdirentries \
1383         getopt_long \
1384         getpagesize \
1385         getpwuid \
1386         gettid \
1387         gettimeofday \
1388         getuid \
1389         inet_pton \
1390         kqueue \
1391         lstat \
1392         memmove \
1393         mmap \
1394         pclose \
1395         poll \
1396         popen \
1397         prctl \
1398         pread \
1399         pwrite \
1400         readlink \
1401         rfork \
1402         sched_yield \
1403         select \
1404         setproctitle \
1405         setrlimit \
1406         settimeofday \
1407         sigaltstack \
1408         sigprocmask \
1409         snprintf \
1410         spawnvp \
1411         statfs \
1412         statvfs \
1413         strcasecmp \
1414         strdup \
1415         strerror \
1416         strncasecmp \
1417         strtold \
1418         strtoll \
1419         strtoull \
1420         tcgetattr \
1421         thr_kill2 \
1422         timegm \
1423         usleep \
1424         vsnprintf \
1425         wait4 \
1426         waitpid \
1427 )
1428
1429 dnl Check for -ldl
1430 if test "$ac_cv_func_dlopen" = no
1431 then
1432     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1433 fi
1434 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1435
1436 dnl Check for -lpoll for Mac OS X/Darwin
1437 if test "$ac_cv_func_poll" = no
1438 then
1439     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1440 fi
1441
1442 dnl Check for -lnsl for Solaris
1443 AC_SEARCH_LIBS(gethostbyname, nsl)
1444
1445 dnl Check for -lsocket for Solaris
1446 AC_SEARCH_LIBS(connect, socket)
1447
1448 dnl Check for -lresolv for Solaris
1449 AC_SEARCH_LIBS(inet_aton, resolv)
1450
1451 dnl **** Check for functions which may rely on -lsocket on Solaris.
1452 AC_CHECK_FUNCS(\
1453         getaddrinfo \
1454         getnameinfo \
1455         getnetbyname \
1456         getprotobyname \
1457         getprotobynumber \
1458         getservbyport \
1459         inet_network \
1460         sendmsg \
1461 )
1462
1463 dnl **** Check for types ****
1464
1465 AC_C_CONST
1466 AC_C_INLINE
1467 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1468 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1469 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1470
1471 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1472 [#ifdef HAVE_LINUX_INPUT_H
1473 #include <linux/input.h>
1474 #endif])
1475
1476 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1477                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1478 if test "$wine_cv_have_sigaddset" = "yes"
1479 then
1480   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1481 fi
1482
1483
1484 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1485         wine_cv_linux_gethostbyname_r_6,
1486         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1487     char *name=0;
1488     struct hostent he;
1489     struct hostent *result;
1490     char *buf=0;
1491     int bufsize=0;
1492     int res,errnr;
1493     char *addr=0;
1494     int addrlen=0;
1495     int addrtype=0;
1496     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1497     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1498     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1499         ])
1500    )
1501    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1502    then
1503       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1504                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1505    fi
1506
1507 if test "$ac_cv_header_linux_joystick_h" = "yes"
1508 then
1509    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1510         wine_cv_linux_joystick_22_api,
1511         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1512         #include <sys/ioctl.h>
1513         #include <sys/types.h>
1514         #include <linux/joystick.h>
1515
1516         struct js_event blub;
1517         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1518         #error "no 2.2 header"
1519         #endif
1520         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1521    )
1522    if test "$wine_cv_linux_joystick_22_api" = "yes"
1523    then
1524       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1525                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1526    fi
1527 fi
1528
1529 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1530
1531 dnl Check for statfs members
1532 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1533 [#include <sys/types.h>
1534 #ifdef HAVE_SYS_PARAM_H
1535 # include <sys/param.h>
1536 #endif
1537 #ifdef HAVE_SYS_MOUNT_H
1538 # include <sys/mount.h>
1539 #endif
1540 #ifdef HAVE_SYS_VFS_H
1541 # include <sys/vfs.h>
1542 #endif
1543 #ifdef HAVE_SYS_STATFS_H
1544 # include <sys/statfs.h>
1545 #endif])
1546
1547 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1548 [#ifdef HAVE_SYS_STATVFS_H
1549 #include <sys/statvfs.h>
1550 #endif])
1551
1552 dnl Check for socket structure members
1553 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1554 [#include <sys/types.h>
1555 #ifdef HAVE_SYS_SOCKET_H
1556 # include <sys/socket.h>
1557 #endif
1558 #ifdef HAVE_SYS_UN_H
1559 # include <sys/un.h>
1560 #endif])
1561
1562 dnl Check for scsireq_t and sg_io_hdr_t members
1563 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1564 [#include <sys/types.h>
1565 #ifdef HAVE_SCSI_SG_H
1566 #include <scsi/sg.h>
1567 #endif])
1568
1569 dnl Check for siginfo_t members
1570 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1571
1572 dnl Check for struct mtget members
1573 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1574 [#include <sys/types.h>
1575 #ifdef HAVE_SYS_MTIO_H
1576 #include <sys/mtio.h>
1577 #endif])
1578
1579 dnl Check for struct option
1580 AC_CHECK_MEMBERS([struct option.name],,,
1581 [#ifdef HAVE_GETOPT_H
1582 #include <getopt.h>
1583 #endif])
1584
1585 dnl Check for stat.st_blocks
1586 AC_CHECK_MEMBERS([struct stat.st_blocks])
1587
1588 dnl Check for sin6_scope_id
1589 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1590 [#ifdef HAVE_SYS_TYPES_H
1591 #include <sys/types.h>
1592 #endif
1593 #ifdef HAVE_NETINET_IN_H
1594 #include <netinet/in.h>
1595 #endif])
1596
1597 dnl Check for ns_msg ptr member
1598 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1599 [#ifdef HAVE_SYS_TYPES_H
1600 #include <sys/types.h>
1601 #endif
1602 #ifdef HAVE_NETINET_IN_H
1603 # include <netinet/in.h>
1604 #endif
1605 #ifdef HAVE_ARPA_NAMESER_H
1606 # include <arpa/nameser.h>
1607 #endif])
1608
1609 dnl Check for the external timezone variables timezone and daylight
1610 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1611                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1612 if test "$ac_cv_have_timezone" = "yes"
1613 then
1614     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1615 fi
1616 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1617                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1618 if test "$ac_cv_have_daylight" = "yes"
1619 then
1620     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1621 fi
1622
1623 dnl Check for isinf
1624 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
1625                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
1626 if test "$ac_cv_have_isinf" = "yes"
1627 then
1628     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
1629 fi
1630
1631 dnl *** check for the need to define platform-specific symbols
1632
1633 case $host_cpu in
1634   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1635   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1636   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1637   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1638   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1639 esac
1640
1641 case $host_vendor in
1642   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1643 esac
1644
1645 dnl **** Generate output files ****
1646
1647 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1648 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1649 ["### Dependencies:\\
1650 \\
1651 .INIT: Makefile\\
1652 .BEGIN: Makefile\\
1653 Makefile: dummy\\
1654         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1655 \\
1656 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1657 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1658 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)\\
1659 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1660 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1661 ["### Dependencies:
1662
1663 .INIT: Makefile
1664 .BEGIN: Makefile
1665 Makefile: dummy
1666         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1667
1668 \$(OBJS): \$(IDL_GEN_HEADERS)
1669 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1670 \$(RC_SRCS:.rc=.res): \$(IDL_TLB_SRCS:.idl=.tlb)
1671 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1672 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1673
1674 AH_TOP([#define __WINE_CONFIG_H])
1675
1676 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1677
1678 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1679 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1680 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1681 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1682 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1683 WINE_CONFIG_EXTRA_DIR(include/wine)
1684
1685 MAKE_RULES=Make.rules
1686 AC_SUBST_FILE(MAKE_RULES)
1687
1688 MAKE_DLL_RULES=dlls/Makedll.rules
1689 AC_SUBST_FILE(MAKE_DLL_RULES)
1690
1691 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1692 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1693
1694 MAKE_TEST_RULES=dlls/Maketest.rules
1695 AC_SUBST_FILE(MAKE_TEST_RULES)
1696
1697 MAKE_PROG_RULES=programs/Makeprog.rules
1698 AC_SUBST_FILE(MAKE_PROG_RULES)
1699
1700 AC_CONFIG_FILES([Make.rules])
1701 AC_CONFIG_FILES([dlls/Makedll.rules])
1702 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1703 AC_CONFIG_FILES([dlls/Maketest.rules])
1704 AC_CONFIG_FILES([programs/Makeprog.rules])
1705 AC_CONFIG_FILES([Makefile])
1706 AC_CONFIG_FILES([dlls/Makefile])
1707 AC_CONFIG_FILES([dlls/acledit/Makefile])
1708 AC_CONFIG_FILES([dlls/activeds/Makefile])
1709 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1710 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1711 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1712 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1713 AC_CONFIG_FILES([dlls/advpack/Makefile])
1714 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1715 AC_CONFIG_FILES([dlls/amstream/Makefile])
1716 AC_CONFIG_FILES([dlls/atl/Makefile])
1717 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1718 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1719 AC_CONFIG_FILES([dlls/browseui/Makefile])
1720 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1721 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1722 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1723 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1724 AC_CONFIG_FILES([dlls/cards/Makefile])
1725 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1726 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1727 AC_CONFIG_FILES([dlls/comcat/Makefile])
1728 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1729 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1730 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1731 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1732 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1733 AC_CONFIG_FILES([dlls/compstui/Makefile])
1734 AC_CONFIG_FILES([dlls/credui/Makefile])
1735 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1736 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1737 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1738 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1740 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1741 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1742 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/cryptui/Makefile])
1744 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1745 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1746 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1747 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1748 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1749 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1750 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1751 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1752 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1753 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1754 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1755 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1756 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1757 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1758 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1759 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1760 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1761 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1762 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1763 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1764 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1765 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1766 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1767 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1768 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1769 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1771 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1772 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1773 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1774 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1775 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1776 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1777 AC_CONFIG_FILES([dlls/devenum/Makefile])
1778 AC_CONFIG_FILES([dlls/dinput/Makefile])
1779 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1780 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1781 AC_CONFIG_FILES([dlls/dmband/Makefile])
1782 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1783 AC_CONFIG_FILES([dlls/dmime/Makefile])
1784 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1785 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1786 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1787 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1788 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1789 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1790 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1791 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1792 AC_CONFIG_FILES([dlls/dplay/Makefile])
1793 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1794 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1796 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1797 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1798 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1799 AC_CONFIG_FILES([dlls/dsound/Makefile])
1800 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1801 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1802 AC_CONFIG_FILES([dlls/dswave/Makefile])
1803 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1804 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1805 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1806 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1807 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1808 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1809 AC_CONFIG_FILES([dlls/fusion/Makefile])
1810 AC_CONFIG_FILES([dlls/fusion/tests/Makefile])
1811 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1812 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1813 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1814 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1815 AC_CONFIG_FILES([dlls/glu32/Makefile])
1816 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1817 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1818 AC_CONFIG_FILES([dlls/hal/Makefile])
1819 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1820 AC_CONFIG_FILES([dlls/hid/Makefile])
1821 AC_CONFIG_FILES([dlls/hlink/Makefile])
1822 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1823 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1824 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1825 AC_CONFIG_FILES([dlls/icmp/Makefile])
1826 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1827 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1828 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1829 AC_CONFIG_FILES([dlls/imm32/Makefile])
1830 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1831 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1832 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1833 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1834 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1835 AC_CONFIG_FILES([dlls/initpki/Makefile])
1836 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1837 AC_CONFIG_FILES([dlls/inseng/Makefile])
1838 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1839 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1840 AC_CONFIG_FILES([dlls/itircl/Makefile])
1841 AC_CONFIG_FILES([dlls/itss/Makefile])
1842 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1843 AC_CONFIG_FILES([dlls/jscript/Makefile])
1844 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1845 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1846 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1847 AC_CONFIG_FILES([dlls/localspl/Makefile])
1848 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1849 AC_CONFIG_FILES([dlls/localui/Makefile])
1850 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1851 AC_CONFIG_FILES([dlls/lz32/Makefile])
1852 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1853 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1854 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1855 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1856 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1857 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1858 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1859 AC_CONFIG_FILES([dlls/midimap/Makefile])
1860 AC_CONFIG_FILES([dlls/mlang/Makefile])
1861 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1862 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1863 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1864 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1865 AC_CONFIG_FILES([dlls/mpr/Makefile])
1866 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1867 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1868 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1869 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1870 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1871 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1872 AC_CONFIG_FILES([dlls/mscms/Makefile])
1873 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1874 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1875 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1876 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1877 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1878 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1879 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1880 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1881 AC_CONFIG_FILES([dlls/msi/Makefile])
1882 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1883 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1884 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1885 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1886 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1887 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1888 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1889 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1890 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1891 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1892 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1893 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1894 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1895 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1896 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1897 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1898 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1899 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1900 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1901 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1902 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1903 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1904 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1905 AC_CONFIG_FILES([dlls/newdev/Makefile])
1906 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1907 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1908 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1909 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1910 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1911 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1912 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1913 AC_CONFIG_FILES([dlls/objsel/Makefile])
1914 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1915 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1916 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1917 AC_CONFIG_FILES([dlls/ole32/Makefile])
1918 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1919 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1920 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1921 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1922 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1923 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1924 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1925 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1926 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1927 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1928 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1929 AC_CONFIG_FILES([dlls/pdh/Makefile])
1930 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1931 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1932 AC_CONFIG_FILES([dlls/printui/Makefile])
1933 AC_CONFIG_FILES([dlls/propsys/Makefile])
1934 AC_CONFIG_FILES([dlls/psapi/Makefile])
1935 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1936 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1937 AC_CONFIG_FILES([dlls/qcap/Makefile])
1938 AC_CONFIG_FILES([dlls/qedit/Makefile])
1939 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1940 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1941 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1942 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1943 AC_CONFIG_FILES([dlls/quartz/Makefile])
1944 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1945 AC_CONFIG_FILES([dlls/query/Makefile])
1946 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1947 AC_CONFIG_FILES([dlls/resutils/Makefile])
1948 AC_CONFIG_FILES([dlls/riched20/Makefile])
1949 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1950 AC_CONFIG_FILES([dlls/riched32/Makefile])
1951 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1952 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1953 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1954 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1955 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1956 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1957 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1958 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1959 AC_CONFIG_FILES([dlls/schannel/Makefile])
1960 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1961 AC_CONFIG_FILES([dlls/secur32/Makefile])
1962 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1963 AC_CONFIG_FILES([dlls/security/Makefile])
1964 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1965 AC_CONFIG_FILES([dlls/serialui/Makefile])
1966 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1967 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1968 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1969 AC_CONFIG_FILES([dlls/sfc/Makefile])
1970 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1971 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1972 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1973 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1974 AC_CONFIG_FILES([dlls/shell32/Makefile])
1975 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1976 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1977 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1978 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1979 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1980 AC_CONFIG_FILES([dlls/slc/Makefile])
1981 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1982 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1983 AC_CONFIG_FILES([dlls/softpub/Makefile])
1984 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1985 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1986 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1987 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1988 AC_CONFIG_FILES([dlls/sti/Makefile])
1989 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1990 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1991 AC_CONFIG_FILES([dlls/sxs/Makefile])
1992 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1993 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1994 AC_CONFIG_FILES([dlls/unicows/Makefile])
1995 AC_CONFIG_FILES([dlls/url/Makefile])
1996 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1997 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1998 AC_CONFIG_FILES([dlls/user32/Makefile])
1999 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
2000 AC_CONFIG_FILES([dlls/userenv/Makefile])
2001 AC_CONFIG_FILES([dlls/userenv/tests/Makefile])
2002 AC_CONFIG_FILES([dlls/usp10/Makefile])
2003 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
2004 AC_CONFIG_FILES([dlls/uuid/Makefile])
2005 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
2006 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
2007 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
2008 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
2009 AC_CONFIG_FILES([dlls/version/Makefile])
2010 AC_CONFIG_FILES([dlls/version/tests/Makefile])
2011 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
2012 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
2013 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
2014 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
2015 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
2016 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
2017 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
2018 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
2019 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
2020 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
2021 AC_CONFIG_FILES([dlls/wined3d/Makefile])
2022 AC_CONFIG_FILES([dlls/winedos/Makefile])
2023 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
2024 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
2025 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
2026 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
2027 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
2028 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
2029 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
2030 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
2031 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
2032 AC_CONFIG_FILES([dlls/wing32/Makefile])
2033 AC_CONFIG_FILES([dlls/winhttp/Makefile])
2034 AC_CONFIG_FILES([dlls/wininet/Makefile])
2035 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
2036 AC_CONFIG_FILES([dlls/winmm/Makefile])
2037 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2038 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2039 AC_CONFIG_FILES([dlls/winscard/Makefile])
2040 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2041 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2042 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2043 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2044 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2045 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2046 AC_CONFIG_FILES([dlls/wmi/Makefile])
2047 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2048 AC_CONFIG_FILES([dlls/wow32/Makefile])
2049 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2050 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2051 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2052 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2053 AC_CONFIG_FILES([documentation/Makefile])
2054 AC_CONFIG_FILES([fonts/Makefile])
2055 AC_CONFIG_FILES([include/Makefile])
2056 AC_CONFIG_FILES([libs/Makefile])
2057 AC_CONFIG_FILES([libs/port/Makefile])
2058 AC_CONFIG_FILES([libs/wine/Makefile])
2059 AC_CONFIG_FILES([libs/wpp/Makefile])
2060 AC_CONFIG_FILES([loader/Makefile])
2061 AC_CONFIG_FILES([programs/Makefile])
2062 AC_CONFIG_FILES([programs/clock/Makefile])
2063 AC_CONFIG_FILES([programs/cmd/Makefile])
2064 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2065 AC_CONFIG_FILES([programs/control/Makefile])
2066 AC_CONFIG_FILES([programs/eject/Makefile])
2067 AC_CONFIG_FILES([programs/expand/Makefile])
2068 AC_CONFIG_FILES([programs/explorer/Makefile])
2069 AC_CONFIG_FILES([programs/hh/Makefile])
2070 AC_CONFIG_FILES([programs/icinfo/Makefile])
2071 AC_CONFIG_FILES([programs/iexplore/Makefile])
2072 AC_CONFIG_FILES([programs/msiexec/Makefile])
2073 AC_CONFIG_FILES([programs/net/Makefile])
2074 AC_CONFIG_FILES([programs/notepad/Makefile])
2075 AC_CONFIG_FILES([programs/oleview/Makefile])
2076 AC_CONFIG_FILES([programs/progman/Makefile])
2077 AC_CONFIG_FILES([programs/reg/Makefile])
2078 AC_CONFIG_FILES([programs/regedit/Makefile])
2079 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2080 AC_CONFIG_FILES([programs/rpcss/Makefile])
2081 AC_CONFIG_FILES([programs/rundll32/Makefile])
2082 AC_CONFIG_FILES([programs/secedit/Makefile])
2083 AC_CONFIG_FILES([programs/services/Makefile])
2084 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2085 AC_CONFIG_FILES([programs/start/Makefile])
2086 AC_CONFIG_FILES([programs/svchost/Makefile])
2087 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2088 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2089 AC_CONFIG_FILES([programs/view/Makefile])
2090 AC_CONFIG_FILES([programs/wineboot/Makefile])
2091 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2092 AC_CONFIG_FILES([programs/winecfg/Makefile])
2093 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2094 AC_CONFIG_FILES([programs/winedbg/Makefile])
2095 AC_CONFIG_FILES([programs/winedevice/Makefile])
2096 AC_CONFIG_FILES([programs/winefile/Makefile])
2097 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2098 AC_CONFIG_FILES([programs/winemine/Makefile])
2099 AC_CONFIG_FILES([programs/winepath/Makefile])
2100 AC_CONFIG_FILES([programs/winetest/Makefile])
2101 AC_CONFIG_FILES([programs/winevdm/Makefile])
2102 AC_CONFIG_FILES([programs/winhlp32/Makefile])
2103 AC_CONFIG_FILES([programs/winver/Makefile])
2104 AC_CONFIG_FILES([programs/wordpad/Makefile])
2105 AC_CONFIG_FILES([programs/write/Makefile])
2106 AC_CONFIG_FILES([programs/xcopy/Makefile])
2107 AC_CONFIG_FILES([server/Makefile])
2108 AC_CONFIG_FILES([tools/Makefile])
2109 AC_CONFIG_FILES([tools/widl/Makefile])
2110 AC_CONFIG_FILES([tools/winebuild/Makefile])
2111 AC_CONFIG_FILES([tools/winedump/Makefile])
2112 AC_CONFIG_FILES([tools/winegcc/Makefile])
2113 AC_CONFIG_FILES([tools/wmc/Makefile])
2114 AC_CONFIG_FILES([tools/wrc/Makefile])
2115
2116 AC_OUTPUT
2117
2118 if test "$no_create" = "yes"
2119 then
2120   exit 0
2121 fi
2122
2123 WINE_PRINT_MESSAGES
2124
2125 echo "
2126 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2127 " >&AS_MESSAGE_FD
2128
2129 dnl Local Variables:
2130 dnl comment-start: "dnl "
2131 dnl comment-end: ""
2132 dnl comment-start-skip: "\\bdnl\\b\\s *"
2133 dnl compile-command: "autoreconf --warnings=all"
2134 dnl End: