tools/make_specfiles

   1 #!/usr/bin/perl -w
   2 #
   3 # Update spec files across dlls that share an implementation
   4 #
   5 # Copyright 2011 Alexandre Julliard
   6 #
   7 # This library is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU Lesser General Public
   9 # License as published by the Free Software Foundation; either
  10 # version 2.1 of the License, or (at your option) any later version.
  11 #
  12 # This library is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # Lesser General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public
  18 # License along with this library; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20 #
  21
  22 use strict;
  23
  24 my %funcs;
  25 my $group_head;
  26
  27 my @dll_groups =
  28 (
  29  [
  30   "msvcrt",
  31   "msvcirt",
  32   "msvcrt40",
  33   "msvcrt20",
  34  ],
  35  [
  36   "msvcrt",
  37   "msvcp90",
  38   "msvcp100",
  39   "msvcp110",
  40   "msvcp120",
  41   "msvcp140",
  42   "msvcp71",
  43   "msvcp80",
  44   "msvcp70",
  45   "msvcp60",
  46  ],
  47  [
  48   "msvcr120",
  49   "msvcr120_app",
  50   "concrt140",
  51  ],
  52  [
  53   "ucrtbase",
  54   "vcruntime140",
  55  ],
  56  [
  57   "msvcp120",
  58   "msvcp120_app",
  59  ],
  60  [
  61   "msvcp140",
  62   "msvcp_win",
  63  ],
  64  [
  65   "d3d10",
  66   "d3d10_1",
  67  ],
  68  [
  69   "d3dx10_43",
  70   "d3dx10_42",
  71   "d3dx10_41",
  72   "d3dx10_40",
  73   "d3dx10_39",
  74   "d3dx10_38",
  75   "d3dx10_37",
  76   "d3dx10_36",
  77   "d3dx10_35",
  78   "d3dx10_34",
  79   "d3dx10_33",
  80  ],
  81  [
  82   "xinput1_3",
  83   "xinput1_4",
  84   "xinput1_2",
  85   "xinput1_1",
  86   "xinput9_1_0",
  87  ],
  88  [
  89   "vcomp",
  90   "vcomp140",
  91   "vcomp120",
  92   "vcomp110",
  93   "vcomp100",
  94   "vcomp90",
  95  ],
  96  [
  97   "advapi32",
  98   "sechost",
  99  ],
 100  [
 101   "netapi32",
 102   "srvcli",
 103  ],
 104  [
 105   "ole32",
 106   "iprop",
 107  ],
 108  [
 109   "secur32",
 110   "security",
 111   "sspicli",
 112  ],
 113  [
 114   "gdi32",
 115   "usp10"
 116  ],
 117  [
 118   "bthprops.cpl",
 119   "irprops.cpl",
 120  ],
 121  [
 122   "sfc_os",
 123   "sfc",
 124  ],
 125  [
 126   "bcrypt",
 127   "ncrypt",
 128   "cng.sys",
 129  ],
 130  [
 131   "ntoskrnl.exe",
 132   "hal",
 133  ],
 134  [
 135   "mscoree",
 136   "mscorwks",
 137  ],
 138  [
 139   "sppc",
 140   "slc",
 141  ],
 142 );
 143
 144 my $update_flags = 0;
 145 my $show_duplicates = 0;
 146
 147 foreach my $arg (@ARGV)
 148 {
 149     if ($arg eq "-f") { $update_flags = 1; }
 150     elsif ($arg eq "-d") { $show_duplicates = 1; }
 151 }
 152
 153 # update a file if changed
 154 sub update_file($$)
 155 {
 156     my $file = shift;
 157     my $new = shift;
 158
 159     open FILE, ">$file.new" or die "cannot create $file.new";
 160     print FILE $new;
 161     close FILE;
 162     rename "$file.new", "$file";
 163     print "$file updated\n";
 164 }
 165
 166 # update a file if changed
 167 sub output_file($$)
 168 {
 169     my $file = shift;
 170     my $new = shift;
 171     my $old = "";
 172     if (open FILE, "<$file")
 173     {
 174         local $/ = undef;
 175         $old .= <FILE>;
 176         close FILE;
 177     }
 178     update_file( $file, $new ) if $old ne $new;
 179 }
 180
 181 # parse a spec file line
 182 sub parse_line($$$)
 183 {
 184     my ($name, $line, $str) = @_;
 185
 186     if ($str =~ /^\s*(\@|\d+)\s+(stdcall|cdecl|varargs|thiscall|stub|extern)\s+((?:-\S+\s+)*)([A-Za-z0-9_\@\$?]+)(?:\s*(\([^)]*\)))?(?:\s+([A-Za-z0-9_\@\$?.]+))?(\s*\#.*)?/)
 187     {
 188         return ( "ordinal" => $1, "callconv" => $2, "flags" => $3, "name" => $4, "args" => $5 || "",
 189                  "target" => $6 || $4, "comment" => $7, "spec" => $name );
 190     }
 191     return () if $str =~ /^\s*$/;
 192     return () if $str =~ /^\s*\#/;
 193     printf STDERR "$name.spec:$line: error: Unrecognized line $_\n";
 194 }
 195
 196 sub read_spec_file($)
 197 {
 198     my $name = shift;
 199     my $file = "dlls/$name/$name.spec";
 200     my %stubs;
 201     open SPEC, "<$file" or die "cannot open $file";
 202     while (<SPEC>)
 203     {
 204         chomp;
 205         my %descr = parse_line( $name, $., $_ );
 206         next unless %descr;
 207
 208         my $func = $descr{name};
 209         if (defined $funcs{$func})
 210         {
 211             my %update = %{$funcs{$func}};
 212             next if $update{ordinal} ne $descr{ordinal} or $update{callconv} ne $descr{callconv} or $update{args} ne $descr{args};
 213
 214             my $arch = $1 if $update{flags} =~ /-arch=(\S+)/;
 215             my $new_arch = $1 if $descr{flags} =~ /-arch=(\S+)/;
 216             next if !defined $arch or !defined $new_arch;
 217
 218             if (($arch eq "win32" and $new_arch eq "win64") or ($arch eq "win64" and $new_arch eq "win32"))
 219             {
 220                 $funcs{$func}{flags} =~ s/-arch=\S+\s+//;
 221                 next;
 222             }
 223
 224             $funcs{$func}{flags} =~ s/-arch=$arch/-arch=$arch,$new_arch/;
 225             next;
 226         }
 227         next if $func eq "@";
 228         $funcs{$func} = \%descr;
 229     }
 230     close SPEC;
 231 }
 232
 233 sub update_spec_file($)
 234 {
 235     my $name = shift;
 236     my $file = "dlls/$name/$name.spec";
 237     my %stubs;
 238     my ($old, $new);
 239
 240     open SPEC, "<$file" or die "cannot open $file";
 241     while (<SPEC>)
 242     {
 243         $old .= $_;
 244         chomp;
 245
 246         my $commented_out = 0;
 247         my %descr = parse_line( $name, $., $_ );
 248         if (!%descr)
 249         {
 250             # check for commented out exports
 251             if (/^\s*\#\s*((?:\@|\d+)\s+)?((?:extern|stub|stdcall|cdecl|varargs|thiscall)\s+.*)/)
 252             {
 253                 $commented_out = 1;
 254                 %descr = parse_line( $name, $., ($1 || "\@ ") . $2 );
 255             }
 256         }
 257         goto done unless %descr;
 258
 259         my $func = $descr{name};
 260         if (!defined $funcs{$func})
 261         {
 262             $funcs{$func} = \%descr unless $commented_out || $name =~ /-/;
 263             goto done;
 264         }
 265
 266         my %parent = %{$funcs{$func}};
 267         goto done if $parent{spec} eq $descr{spec};  # the definition is in this spec file
 268         goto done if $descr{comment} && $descr{comment} =~ /don't forward/;
 269         if ($descr{callconv} ne "stub" && $descr{target} !~ /\./ && !$commented_out)
 270         {
 271             printf "%s:%u: note: %s already defined in %s\n", $file, $., $func, $parent{spec} if $show_duplicates;
 272             goto done;
 273         }
 274
 275         my $flags = $descr{flags};
 276         if ($parent{callconv} ne "stub" || $update_flags)
 277         {
 278             $flags = $parent{flags};
 279             $flags =~ s/-ordinal\s*// if $descr{ordinal} eq "@";
 280             $flags =~ s/-noname\s*// if $descr{ordinal} eq "@";
 281             $flags =~ s/-import\s*//;
 282             if ($descr{flags} =~ /-private/)  # preserve -private flag
 283             {
 284                 $flags = "-private " . $flags unless $flags =~ /-private/;
 285             }
 286         }
 287
 288         if ($parent{callconv} ne "stub" || $parent{args})
 289         {
 290             my $callconv = $parent{callconv} ne "stub" ? $parent{callconv} :
 291                            $parent{spec} =~ /(msvc|ucrtbase)/ ? "cdecl" : "stdcall";  # hack
 292             $_ = sprintf "$descr{ordinal} %s %s%s", $callconv, $flags, $func;
 293
 294             if ($parent{target} =~ /$group_head\./)  # use the same forward as parent if possible
 295             {
 296                 $_ .= sprintf "%s %s", $parent{args}, $parent{target};
 297             }
 298             else
 299             {
 300                 $_ .= sprintf "%s %s.%s", $parent{args}, $parent{spec}, $func;
 301             }
 302         }
 303         else
 304         {
 305             $_ = sprintf "$descr{ordinal} stub %s%s", $flags, $func;
 306         }
 307         $_ .= $descr{comment} || "";
 308
 309       done:
 310         $new .= "$_\n";
 311     }
 312     close SPEC;
 313     update_file( $file, $new ) if $old ne $new;
 314 }
 315
 316 sub get_args_size($)
 317 {
 318     my $args = shift;
 319     my $ret32 = 0;
 320     my $ret64 = 0;
 321     if ($args =~ /^\((.*)\)$/)
 322     {
 323         my @args = split /\s+/, $1;
 324         $ret64 += 8 * scalar @args;
 325         map { $ret32 += ($_ eq "int64") ? 8 : 4; } @args;
 326     }
 327     return ($ret32, $ret64);
 328 }
 329
 330 sub get_syscalls_str(@)
 331 {
 332     my @syscalls = sort { $a->[0] cmp $b->[0] } @_;
 333
 334     my $ret = "";
 335     for (my $i = 0; $i < @syscalls; $i++)
 336     {
 337         my ($name, $args) = @{$syscalls[$i]};
 338         $ret .= sprintf " \\\n    SYSCALL_ENTRY( 0x%04x, %s, %u )", $i, $name, $args;
 339     }
 340     return $ret . "\n";
 341 }
 342
 343 sub read_syscalls($)
 344 {
 345     my $spec = shift;
 346     my @syscalls32 = ();
 347     my @syscalls64 = ();
 348
 349     %funcs = ();
 350     read_spec_file( $spec );
 351
 352     foreach my $func (keys %funcs)
 353     {
 354         my $descr = $funcs{$func};
 355         next unless $descr->{flags} =~ /-syscall/;
 356         next if $descr->{target} ne $func && defined $funcs{$descr->{target}};
 357         my ($args32, $args64) = get_args_size( $funcs{$func}->{args} );
 358         push @syscalls32, [ $func, $args32 ] unless $descr->{flags} =~ /-arch=win64/;
 359         push @syscalls64, [ $func, $args64 ] unless $descr->{flags} =~ /-arch=win32/;
 360     }
 361     return (\@syscalls32, \@syscalls64);
 362 }
 363
 364 sub update_syscalls($$)
 365 {
 366     my ($spec, $file) = @_;
 367     my ($syscalls32, $syscalls64) = read_syscalls( $spec );
 368
 369     output_file( $file,
 370                  "/* Automatically generated by tools/make_specfiles */\n" .
 371                  "\n#define ALL_SYSCALLS32" . get_syscalls_str( @{$syscalls32} ) .
 372                  "\n#define ALL_SYSCALLS64" . get_syscalls_str( @{$syscalls64} ));
 373 }
 374
 375 sub sync_spec_files(@)
 376 {
 377     %funcs = ();
 378     $group_head = shift;
 379     read_spec_file( $group_head );
 380     foreach my $spec (@_) { update_spec_file($spec); }
 381 }
 382
 383 foreach my $group (@dll_groups)
 384 {
 385     sync_spec_files( @{$group} );
 386 }
 387
 388 update_syscalls( "ntdll", "dlls/ntdll/ntsyscalls.h" );
 389 update_syscalls( "win32u", "dlls/win32u/win32syscalls.h" );