configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 test -z "$LDLIBS" && LDLIBS=-lm AC_SUBST(LDLIBS)
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_WITH(library,
  16 [  --with-library          build Wine as a library instead of an emulator],
  17 [OPTIONS="-DWINELIB" MAIN_TARGET="libwine.a"],
  18 [OPTIONS="" MAIN_TARGET="wine"])
  19
  20 AC_ARG_WITH(dll,
  21 [  --with-dll              build Wine as a DLL instead of an emulator],
  22 [OPTIONS="-DWINELIB" MAIN_TARGET="libwine.so.1.0"])
  23
  24 AC_ARG_WITH(ipc,
  25 [  --with-ipc              use inter-process communication for DDE],
  26 [OPTIONS="$OPTIONS -DCONFIG_IPC"])
  27
  28 AC_SUBST(MAIN_TARGET)
  29 AC_SUBST(OPTIONS)
  30
  31 dnl **** Check for some programs and libraries ****
  32
  33 AC_PROG_MAKE_SET
  34 AC_PROG_CC
  35 AC_PROG_CPP
  36 AC_PATH_XTRA
  37 AC_PROG_YACC
  38 AC_PROG_LEX
  39 AC_PROG_RANLIB
  40 AC_PROG_INSTALL
  41 dnl Check for -li386 for NetBSD
  42 AC_CHECK_LIB(i386,i386_set_ldt,LDLIBS="$LDLIBS -li386")
  43
  44 dnl **** Check for gcc strength-reduce bug ****
  45
  46 if test "x${GCC}" = "xyes"
  47 then
  48   CFLAGS="$CFLAGS -Wall"
  49   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
  50                   AC_TRY_RUN([
  51 int main(void) {
  52   static int Array[[3]];
  53   unsigned int B = 3;
  54   int i;
  55   for(i=0; i<B; i++) Array[[i]] = i - 3;
  56   exit( Array[[1]] != -2 );
  57 }],
  58     ac_cv_c_gcc_strength_bug="no",
  59     ac_cv_c_gcc_strength_bug="yes",
  60     ac_cv_c_gcc_strength_bug="yes") )
  61   if test "$ac_cv_c_gcc_strength_bug" = "yes"
  62   then
  63     CFLAGS="$CFLAGS -fno-strength-reduce"
  64   fi
  65 fi
  66
  67 dnl **** Check for underscore on external symbols ****
  68
  69 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
  70                ac_cv_c_extern_prefix,
  71 [saved_libs=$LIBS
  72 LIBS="conftest_asm.s $LIBS"
  73 cat > conftest_asm.s <<EOF
  74         .globl _ac_test
  75 _ac_test:
  76         .long 0
  77 EOF
  78 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
  79             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
  80 LIBS=$saved_libs])
  81 if test "$ac_cv_c_extern_prefix" = "yes"
  82 then
  83   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
  84 fi
  85
  86 dnl **** Check for working dll ****
  87
  88 if test "$MAIN_TARGET" = "libwine.so.1.0"
  89 then
  90   AC_CACHE_CHECK("whether we can build a dll",
  91                  ac_cv_c_dll,
  92   [saved_cflags=$CFLAGS
  93   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
  94   AC_TRY_LINK(,[return 1],ac_cv_c_dll="yes",ac_cv_c_dll="no")
  95   CFLAGS=$saved_cflags
  96   ])
  97   if test "$ac_cv_c_dll" = "yes"
  98   then
  99     CFLAGS="$CFLAGS -fPIC"
 100   else
 101     MAIN_TARGET="libwine.a"
 102   fi
 103 fi
 104
 105 dnl **** Check for functions and header files ****
 106
 107 AC_CHECK_FUNCS(memmove tcgetattr usleep)
 108 AC_HEADER_STAT()
 109 AC_C_CONST()
 110 AC_TYPE_SIZE_T()
 111
 112 dnl **** Generate output files ****
 113
 114 MAKE_RULES=Make.rules
 115 AC_SUBST_FILE(MAKE_RULES)
 116
 117 AC_OUTPUT([
 118 Make.rules
 119 Makefile
 120 controls/Makefile
 121 debugger/Makefile
 122 files/Makefile
 123 graphics/Makefile
 124 graphics/metafiledrv/Makefile
 125 graphics/win16drv/Makefile
 126 graphics/x11drv/Makefile
 127 if1632/Makefile
 128 ipc/Makefile
 129 library/Makefile
 130 libtest/Makefile
 131 loader/Makefile
 132 memory/Makefile
 133 misc/Makefile
 134 miscemu/Makefile
 135 msdos/Makefile
 136 multimedia/Makefile
 137 objects/Makefile
 138 programs/Makefile
 139 programs/progman/Makefile
 140 programs/winhelp/Makefile
 141 rc/Makefile
 142 resources/Makefile
 143 scheduler/Makefile
 144 tools/Makefile
 145 win32/Makefile
 146 windows/Makefile ])
 147
 148 echo
 149 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 150 echo
 151
 152 dnl Local Variables:
 153 dnl comment-start: "dnl "
 154 dnl comment-end: ""
 155 dnl comment-start-skip: "\\bdnl\\b\\s *"
 156 dnl compile-command: "autoconf"
 157 dnl End: