git-add--interactive.perl

   1 #!/usr/bin/perl
   2
   3 use 5.008;
   4 use strict;
   5 use warnings;
   6 use Git;
   7
   8 binmode(STDOUT, ":raw");
   9
  10 my $repo = Git->repository();
  11
  12 my $menu_use_color = $repo->get_colorbool('color.interactive');
  13 my ($prompt_color, $header_color, $help_color) =
  14         $menu_use_color ? (
  15                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  16                 $repo->get_color('color.interactive.header', 'bold'),
  17                 $repo->get_color('color.interactive.help', 'red bold'),
  18         ) : ();
  19 my $error_color = ();
  20 if ($menu_use_color) {
  21         my $help_color_spec = ($repo->config('color.interactive.help') or
  22                                 'red bold');
  23         $error_color = $repo->get_color('color.interactive.error',
  24                                         $help_color_spec);
  25 }
  26
  27 my $diff_use_color = $repo->get_colorbool('color.diff');
  28 my ($fraginfo_color) =
  29         $diff_use_color ? (
  30                 $repo->get_color('color.diff.frag', 'cyan'),
  31         ) : ();
  32 my ($funcname_color) =
  33         $diff_use_color ? (
  34                 $repo->get_color('color.diff.func', ''),
  35         ) : ();
  36 my ($diff_plain_color) =
  37         $diff_use_color ? (
  38                 $repo->get_color('color.diff.plain', ''),
  39         ) : ();
  40 my ($diff_old_color) =
  41         $diff_use_color ? (
  42                 $repo->get_color('color.diff.old', 'red'),
  43         ) : ();
  44 my ($diff_new_color) =
  45         $diff_use_color ? (
  46                 $repo->get_color('color.diff.new', 'green'),
  47         ) : ();
  48
  49 my $normal_color = $repo->get_color("", "reset");
  50
  51 my $diff_algorithm = $repo->config('diff.algorithm');
  52
  53 my $use_readkey = 0;
  54 my $use_termcap = 0;
  55 my %term_escapes;
  56
  57 sub ReadMode;
  58 sub ReadKey;
  59 if ($repo->config_bool("interactive.singlekey")) {
  60         eval {
  61                 require Term::ReadKey;
  62                 Term::ReadKey->import;
  63                 $use_readkey = 1;
  64         };
  65         if (!$use_readkey) {
  66                 print STDERR "missing Term::ReadKey, disabling interactive.singlekey\n";
  67         }
  68         eval {
  69                 require Term::Cap;
  70                 my $termcap = Term::Cap->Tgetent;
  71                 foreach (values %$termcap) {
  72                         $term_escapes{$_} = 1 if /^\e/;
  73                 }
  74                 $use_termcap = 1;
  75         };
  76 }
  77
  78 sub colored {
  79         my $color = shift;
  80         my $string = join("", @_);
  81
  82         if (defined $color) {
  83                 # Put a color code at the beginning of each line, a reset at the end
  84                 # color after newlines that are not at the end of the string
  85                 $string =~ s/(\n+)(.)/$1$color$2/g;
  86                 # reset before newlines
  87                 $string =~ s/(\n+)/$normal_color$1/g;
  88                 # codes at beginning and end (if necessary):
  89                 $string =~ s/^/$color/;
  90                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  91         }
  92         return $string;
  93 }
  94
  95 # command line options
  96 my $patch_mode;
  97 my $patch_mode_revision;
  98
  99 sub apply_patch;
 100 sub apply_patch_for_checkout_commit;
 101 sub apply_patch_for_stash;
 102
 103 my %patch_modes = (
 104         'stage' => {
 105                 DIFF => 'diff-files -p',
 106                 APPLY => sub { apply_patch 'apply --cached', @_; },
 107                 APPLY_CHECK => 'apply --cached',
 108                 VERB => 'Stage',
 109                 TARGET => '',
 110                 PARTICIPLE => 'staging',
 111                 FILTER => 'file-only',
 112                 IS_REVERSE => 0,
 113         },
 114         'stash' => {
 115                 DIFF => 'diff-index -p HEAD',
 116                 APPLY => sub { apply_patch 'apply --cached', @_; },
 117                 APPLY_CHECK => 'apply --cached',
 118                 VERB => 'Stash',
 119                 TARGET => '',
 120                 PARTICIPLE => 'stashing',
 121                 FILTER => undef,
 122                 IS_REVERSE => 0,
 123         },
 124         'reset_head' => {
 125                 DIFF => 'diff-index -p --cached',
 126                 APPLY => sub { apply_patch 'apply -R --cached', @_; },
 127                 APPLY_CHECK => 'apply -R --cached',
 128                 VERB => 'Unstage',
 129                 TARGET => '',
 130                 PARTICIPLE => 'unstaging',
 131                 FILTER => 'index-only',
 132                 IS_REVERSE => 1,
 133         },
 134         'reset_nothead' => {
 135                 DIFF => 'diff-index -R -p --cached',
 136                 APPLY => sub { apply_patch 'apply --cached', @_; },
 137                 APPLY_CHECK => 'apply --cached',
 138                 VERB => 'Apply',
 139                 TARGET => ' to index',
 140                 PARTICIPLE => 'applying',
 141                 FILTER => 'index-only',
 142                 IS_REVERSE => 0,
 143         },
 144         'checkout_index' => {
 145                 DIFF => 'diff-files -p',
 146                 APPLY => sub { apply_patch 'apply -R', @_; },
 147                 APPLY_CHECK => 'apply -R',
 148                 VERB => 'Discard',
 149                 TARGET => ' from worktree',
 150                 PARTICIPLE => 'discarding',
 151                 FILTER => 'file-only',
 152                 IS_REVERSE => 1,
 153         },
 154         'checkout_head' => {
 155                 DIFF => 'diff-index -p',
 156                 APPLY => sub { apply_patch_for_checkout_commit '-R', @_ },
 157                 APPLY_CHECK => 'apply -R',
 158                 VERB => 'Discard',
 159                 TARGET => ' from index and worktree',
 160                 PARTICIPLE => 'discarding',
 161                 FILTER => undef,
 162                 IS_REVERSE => 1,
 163         },
 164         'checkout_nothead' => {
 165                 DIFF => 'diff-index -R -p',
 166                 APPLY => sub { apply_patch_for_checkout_commit '', @_ },
 167                 APPLY_CHECK => 'apply',
 168                 VERB => 'Apply',
 169                 TARGET => ' to index and worktree',
 170                 PARTICIPLE => 'applying',
 171                 FILTER => undef,
 172                 IS_REVERSE => 0,
 173         },
 174 );
 175
 176 my %patch_mode_flavour = %{$patch_modes{stage}};
 177
 178 sub run_cmd_pipe {
 179         if ($^O eq 'MSWin32') {
 180                 my @invalid = grep {m/[":*]/} @_;
 181                 die "$^O does not support: @invalid\n" if @invalid;
 182                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
 183                 return qx{@args};
 184         } else {
 185                 my $fh = undef;
 186                 open($fh, '-|', @_) or die;
 187                 return <$fh>;
 188         }
 189 }
 190
 191 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
 192
 193 if (!defined $GIT_DIR) {
 194         exit(1); # rev-parse would have already said "not a git repo"
 195 }
 196 chomp($GIT_DIR);
 197
 198 my %cquote_map = (
 199  "b" => chr(8),
 200  "t" => chr(9),
 201  "n" => chr(10),
 202  "v" => chr(11),
 203  "f" => chr(12),
 204  "r" => chr(13),
 205  "\\" => "\\",
 206  "\042" => "\042",
 207 );
 208
 209 sub unquote_path {
 210         local ($_) = @_;
 211         my ($retval, $remainder);
 212         if (!/^\042(.*)\042$/) {
 213                 return $_;
 214         }
 215         ($_, $retval) = ($1, "");
 216         while (/^([^\\]*)\\(.*)$/) {
 217                 $remainder = $2;
 218                 $retval .= $1;
 219                 for ($remainder) {
 220                         if (/^([0-3][0-7][0-7])(.*)$/) {
 221                                 $retval .= chr(oct($1));
 222                                 $_ = $2;
 223                                 last;
 224                         }
 225                         if (/^([\\\042btnvfr])(.*)$/) {
 226                                 $retval .= $cquote_map{$1};
 227                                 $_ = $2;
 228                                 last;
 229                         }
 230                         # This is malformed -- just return it as-is for now.
 231                         return $_[0];
 232                 }
 233                 $_ = $remainder;
 234         }
 235         $retval .= $_;
 236         return $retval;
 237 }
 238
 239 sub refresh {
 240         my $fh;
 241         open $fh, 'git update-index --refresh |'
 242             or die;
 243         while (<$fh>) {
 244                 ;# ignore 'needs update'
 245         }
 246         close $fh;
 247 }
 248
 249 sub list_untracked {
 250         map {
 251                 chomp $_;
 252                 unquote_path($_);
 253         }
 254         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 255 }
 256
 257 my $status_fmt = '%12s %12s %s';
 258 my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
 259
 260 {
 261         my $initial;
 262         sub is_initial_commit {
 263                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 264                         unless defined $initial;
 265                 return $initial;
 266         }
 267 }
 268
 269 sub get_empty_tree {
 270         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 271 }
 272
 273 sub get_diff_reference {
 274         my $ref = shift;
 275         if (defined $ref and $ref ne 'HEAD') {
 276                 return $ref;
 277         } elsif (is_initial_commit()) {
 278                 return get_empty_tree();
 279         } else {
 280                 return 'HEAD';
 281         }
 282 }
 283
 284 # Returns list of hashes, contents of each of which are:
 285 # VALUE:        pathname
 286 # BINARY:       is a binary path
 287 # INDEX:        is index different from HEAD?
 288 # FILE:         is file different from index?
 289 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 290 # FILE_ADDDEL:  is it add/delete between index and file?
 291 # UNMERGED:     is the path unmerged
 292
 293 sub list_modified {
 294         my ($only) = @_;
 295         my (%data, @return);
 296         my ($add, $del, $adddel, $file);
 297         my @tracked = ();
 298
 299         if (@ARGV) {
 300                 @tracked = map {
 301                         chomp $_;
 302                         unquote_path($_);
 303                 } run_cmd_pipe(qw(git ls-files --), @ARGV);
 304                 return if (!@tracked);
 305         }
 306
 307         my $reference = get_diff_reference($patch_mode_revision);
 308         for (run_cmd_pipe(qw(git diff-index --cached
 309                              --numstat --summary), $reference,
 310                              '--', @tracked)) {
 311                 if (($add, $del, $file) =
 312                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 313                         my ($change, $bin);
 314                         $file = unquote_path($file);
 315                         if ($add eq '-' && $del eq '-') {
 316                                 $change = 'binary';
 317                                 $bin = 1;
 318                         }
 319                         else {
 320                                 $change = "+$add/-$del";
 321                         }
 322                         $data{$file} = {
 323                                 INDEX => $change,
 324                                 BINARY => $bin,
 325                                 FILE => 'nothing',
 326                         }
 327                 }
 328                 elsif (($adddel, $file) =
 329                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 330                         $file = unquote_path($file);
 331                         $data{$file}{INDEX_ADDDEL} = $adddel;
 332                 }
 333         }
 334
 335         for (run_cmd_pipe(qw(git diff-files --numstat --summary --raw --), @tracked)) {
 336                 if (($add, $del, $file) =
 337                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 338                         $file = unquote_path($file);
 339                         my ($change, $bin);
 340                         if ($add eq '-' && $del eq '-') {
 341                                 $change = 'binary';
 342                                 $bin = 1;
 343                         }
 344                         else {
 345                                 $change = "+$add/-$del";
 346                         }
 347                         $data{$file}{FILE} = $change;
 348                         if ($bin) {
 349                                 $data{$file}{BINARY} = 1;
 350                         }
 351                 }
 352                 elsif (($adddel, $file) =
 353                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 354                         $file = unquote_path($file);
 355                         $data{$file}{FILE_ADDDEL} = $adddel;
 356                 }
 357                 elsif (/^:[0-7]+ [0-7]+ [0-9a-f]+ [0-9a-f]+ (.) (.*)$/) {
 358                         $file = unquote_path($2);
 359                         if (!exists $data{$file}) {
 360                                 $data{$file} = +{
 361                                         INDEX => 'unchanged',
 362                                         BINARY => 0,
 363                                 };
 364                         }
 365                         if ($1 eq 'U') {
 366                                 $data{$file}{UNMERGED} = 1;
 367                         }
 368                 }
 369         }
 370
 371         for (sort keys %data) {
 372                 my $it = $data{$_};
 373
 374                 if ($only) {
 375                         if ($only eq 'index-only') {
 376                                 next if ($it->{INDEX} eq 'unchanged');
 377                         }
 378                         if ($only eq 'file-only') {
 379                                 next if ($it->{FILE} eq 'nothing');
 380                         }
 381                 }
 382                 push @return, +{
 383                         VALUE => $_,
 384                         %$it,
 385                 };
 386         }
 387         return @return;
 388 }
 389
 390 sub find_unique {
 391         my ($string, @stuff) = @_;
 392         my $found = undef;
 393         for (my $i = 0; $i < @stuff; $i++) {
 394                 my $it = $stuff[$i];
 395                 my $hit = undef;
 396                 if (ref $it) {
 397                         if ((ref $it) eq 'ARRAY') {
 398                                 $it = $it->[0];
 399                         }
 400                         else {
 401                                 $it = $it->{VALUE};
 402                         }
 403                 }
 404                 eval {
 405                         if ($it =~ /^$string/) {
 406                                 $hit = 1;
 407                         };
 408                 };
 409                 if (defined $hit && defined $found) {
 410                         return undef;
 411                 }
 412                 if ($hit) {
 413                         $found = $i + 1;
 414                 }
 415         }
 416         return $found;
 417 }
 418
 419 # inserts string into trie and updates count for each character
 420 sub update_trie {
 421         my ($trie, $string) = @_;
 422         foreach (split //, $string) {
 423                 $trie = $trie->{$_} ||= {COUNT => 0};
 424                 $trie->{COUNT}++;
 425         }
 426 }
 427
 428 # returns an array of tuples (prefix, remainder)
 429 sub find_unique_prefixes {
 430         my @stuff = @_;
 431         my @return = ();
 432
 433         # any single prefix exceeding the soft limit is omitted
 434         # if any prefix exceeds the hard limit all are omitted
 435         # 0 indicates no limit
 436         my $soft_limit = 0;
 437         my $hard_limit = 3;
 438
 439         # build a trie modelling all possible options
 440         my %trie;
 441         foreach my $print (@stuff) {
 442                 if ((ref $print) eq 'ARRAY') {
 443                         $print = $print->[0];
 444                 }
 445                 elsif ((ref $print) eq 'HASH') {
 446                         $print = $print->{VALUE};
 447                 }
 448                 update_trie(\%trie, $print);
 449                 push @return, $print;
 450         }
 451
 452         # use the trie to find the unique prefixes
 453         for (my $i = 0; $i < @return; $i++) {
 454                 my $ret = $return[$i];
 455                 my @letters = split //, $ret;
 456                 my %search = %trie;
 457                 my ($prefix, $remainder);
 458                 my $j;
 459                 for ($j = 0; $j < @letters; $j++) {
 460                         my $letter = $letters[$j];
 461                         if ($search{$letter}{COUNT} == 1) {
 462                                 $prefix = substr $ret, 0, $j + 1;
 463                                 $remainder = substr $ret, $j + 1;
 464                                 last;
 465                         }
 466                         else {
 467                                 my $prefix = substr $ret, 0, $j;
 468                                 return ()
 469                                     if ($hard_limit && $j + 1 > $hard_limit);
 470                         }
 471                         %search = %{$search{$letter}};
 472                 }
 473                 if (ord($letters[0]) > 127 ||
 474                     ($soft_limit && $j + 1 > $soft_limit)) {
 475                         $prefix = undef;
 476                         $remainder = $ret;
 477                 }
 478                 $return[$i] = [$prefix, $remainder];
 479         }
 480         return @return;
 481 }
 482
 483 # filters out prefixes which have special meaning to list_and_choose()
 484 sub is_valid_prefix {
 485         my $prefix = shift;
 486         return (defined $prefix) &&
 487             !($prefix =~ /[\s,]/) && # separators
 488             !($prefix =~ /^-/) &&    # deselection
 489             !($prefix =~ /^\d+/) &&  # selection
 490             ($prefix ne '*') &&      # "all" wildcard
 491             ($prefix ne '?');        # prompt help
 492 }
 493
 494 # given a prefix/remainder tuple return a string with the prefix highlighted
 495 # for now use square brackets; later might use ANSI colors (underline, bold)
 496 sub highlight_prefix {
 497         my $prefix = shift;
 498         my $remainder = shift;
 499
 500         if (!defined $prefix) {
 501                 return $remainder;
 502         }
 503
 504         if (!is_valid_prefix($prefix)) {
 505                 return "$prefix$remainder";
 506         }
 507
 508         if (!$menu_use_color) {
 509                 return "[$prefix]$remainder";
 510         }
 511
 512         return "$prompt_color$prefix$normal_color$remainder";
 513 }
 514
 515 sub error_msg {
 516         print STDERR colored $error_color, @_;
 517 }
 518
 519 sub list_and_choose {
 520         my ($opts, @stuff) = @_;
 521         my (@chosen, @return);
 522         my $i;
 523         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 524
 525       TOPLOOP:
 526         while (1) {
 527                 my $last_lf = 0;
 528
 529                 if ($opts->{HEADER}) {
 530                         if (!$opts->{LIST_FLAT}) {
 531                                 print "     ";
 532                         }
 533                         print colored $header_color, "$opts->{HEADER}\n";
 534                 }
 535                 for ($i = 0; $i < @stuff; $i++) {
 536                         my $chosen = $chosen[$i] ? '*' : ' ';
 537                         my $print = $stuff[$i];
 538                         my $ref = ref $print;
 539                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 540                             if @prefixes;
 541                         if ($ref eq 'ARRAY') {
 542                                 $print = $highlighted || $print->[0];
 543                         }
 544                         elsif ($ref eq 'HASH') {
 545                                 my $value = $highlighted || $print->{VALUE};
 546                                 $print = sprintf($status_fmt,
 547                                     $print->{INDEX},
 548                                     $print->{FILE},
 549                                     $value);
 550                         }
 551                         else {
 552                                 $print = $highlighted || $print;
 553                         }
 554                         printf("%s%2d: %s", $chosen, $i+1, $print);
 555                         if (($opts->{LIST_FLAT}) &&
 556                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 557                                 print "\t";
 558                                 $last_lf = 0;
 559                         }
 560                         else {
 561                                 print "\n";
 562                                 $last_lf = 1;
 563                         }
 564                 }
 565                 if (!$last_lf) {
 566                         print "\n";
 567                 }
 568
 569                 return if ($opts->{LIST_ONLY});
 570
 571                 print colored $prompt_color, $opts->{PROMPT};
 572                 if ($opts->{SINGLETON}) {
 573                         print "> ";
 574                 }
 575                 else {
 576                         print ">> ";
 577                 }
 578                 my $line = <STDIN>;
 579                 if (!$line) {
 580                         print "\n";
 581                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 582                         last;
 583                 }
 584                 chomp $line;
 585                 last if $line eq '';
 586                 if ($line eq '?') {
 587                         $opts->{SINGLETON} ?
 588                             singleton_prompt_help_cmd() :
 589                             prompt_help_cmd();
 590                         next TOPLOOP;
 591                 }
 592                 for my $choice (split(/[\s,]+/, $line)) {
 593                         my $choose = 1;
 594                         my ($bottom, $top);
 595
 596                         # Input that begins with '-'; unchoose
 597                         if ($choice =~ s/^-//) {
 598                                 $choose = 0;
 599                         }
 600                         # A range can be specified like 5-7 or 5-.
 601                         if ($choice =~ /^(\d+)-(\d*)$/) {
 602                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 603                         }
 604                         elsif ($choice =~ /^\d+$/) {
 605                                 $bottom = $top = $choice;
 606                         }
 607                         elsif ($choice eq '*') {
 608                                 $bottom = 1;
 609                                 $top = 1 + @stuff;
 610                         }
 611                         else {
 612                                 $bottom = $top = find_unique($choice, @stuff);
 613                                 if (!defined $bottom) {
 614                                         error_msg "Huh ($choice)?\n";
 615                                         next TOPLOOP;
 616                                 }
 617                         }
 618                         if ($opts->{SINGLETON} && $bottom != $top) {
 619                                 error_msg "Huh ($choice)?\n";
 620                                 next TOPLOOP;
 621                         }
 622                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 623                                 next if (@stuff <= $i || $i < 0);
 624                                 $chosen[$i] = $choose;
 625                         }
 626                 }
 627                 last if ($opts->{IMMEDIATE} || $line eq '*');
 628         }
 629         for ($i = 0; $i < @stuff; $i++) {
 630                 if ($chosen[$i]) {
 631                         push @return, $stuff[$i];
 632                 }
 633         }
 634         return @return;
 635 }
 636
 637 sub singleton_prompt_help_cmd {
 638         print colored $help_color, <<\EOF ;
 639 Prompt help:
 640 1          - select a numbered item
 641 foo        - select item based on unique prefix
 642            - (empty) select nothing
 643 EOF
 644 }
 645
 646 sub prompt_help_cmd {
 647         print colored $help_color, <<\EOF ;
 648 Prompt help:
 649 1          - select a single item
 650 3-5        - select a range of items
 651 2-3,6-9    - select multiple ranges
 652 foo        - select item based on unique prefix
 653 -...       - unselect specified items
 654 *          - choose all items
 655            - (empty) finish selecting
 656 EOF
 657 }
 658
 659 sub status_cmd {
 660         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 661                         list_modified());
 662         print "\n";
 663 }
 664
 665 sub say_n_paths {
 666         my $did = shift @_;
 667         my $cnt = scalar @_;
 668         print "$did ";
 669         if (1 < $cnt) {
 670                 print "$cnt paths\n";
 671         }
 672         else {
 673                 print "one path\n";
 674         }
 675 }
 676
 677 sub update_cmd {
 678         my @mods = list_modified('file-only');
 679         return if (!@mods);
 680
 681         my @update = list_and_choose({ PROMPT => 'Update',
 682                                        HEADER => $status_head, },
 683                                      @mods);
 684         if (@update) {
 685                 system(qw(git update-index --add --remove --),
 686                        map { $_->{VALUE} } @update);
 687                 say_n_paths('updated', @update);
 688         }
 689         print "\n";
 690 }
 691
 692 sub revert_cmd {
 693         my @update = list_and_choose({ PROMPT => 'Revert',
 694                                        HEADER => $status_head, },
 695                                      list_modified());
 696         if (@update) {
 697                 if (is_initial_commit()) {
 698                         system(qw(git rm --cached),
 699                                 map { $_->{VALUE} } @update);
 700                 }
 701                 else {
 702                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 703                                                  map { $_->{VALUE} } @update);
 704                         my $fh;
 705                         open $fh, '| git update-index --index-info'
 706                             or die;
 707                         for (@lines) {
 708                                 print $fh $_;
 709                         }
 710                         close($fh);
 711                         for (@update) {
 712                                 if ($_->{INDEX_ADDDEL} &&
 713                                     $_->{INDEX_ADDDEL} eq 'create') {
 714                                         system(qw(git update-index --force-remove --),
 715                                                $_->{VALUE});
 716                                         print "note: $_->{VALUE} is untracked now.\n";
 717                                 }
 718                         }
 719                 }
 720                 refresh();
 721                 say_n_paths('reverted', @update);
 722         }
 723         print "\n";
 724 }
 725
 726 sub add_untracked_cmd {
 727         my @add = list_and_choose({ PROMPT => 'Add untracked' },
 728                                   list_untracked());
 729         if (@add) {
 730                 system(qw(git update-index --add --), @add);
 731                 say_n_paths('added', @add);
 732         }
 733         print "\n";
 734 }
 735
 736 sub run_git_apply {
 737         my $cmd = shift;
 738         my $fh;
 739         open $fh, '| git ' . $cmd . " --recount --allow-overlap";
 740         print $fh @_;
 741         return close $fh;
 742 }
 743
 744 sub parse_diff {
 745         my ($path) = @_;
 746         my @diff_cmd = split(" ", $patch_mode_flavour{DIFF});
 747         if (defined $diff_algorithm) {
 748                 splice @diff_cmd, 1, 0, "--diff-algorithm=${diff_algorithm}";
 749         }
 750         if (defined $patch_mode_revision) {
 751                 push @diff_cmd, get_diff_reference($patch_mode_revision);
 752         }
 753         my @diff = run_cmd_pipe("git", @diff_cmd, "--", $path);
 754         my @colored = ();
 755         if ($diff_use_color) {
 756                 @colored = run_cmd_pipe("git", @diff_cmd, qw(--color --), $path);
 757         }
 758         my (@hunk) = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 759
 760         for (my $i = 0; $i < @diff; $i++) {
 761                 if ($diff[$i] =~ /^@@ /) {
 762                         push @hunk, { TEXT => [], DISPLAY => [],
 763                                 TYPE => 'hunk' };
 764                 }
 765                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 766                 push @{$hunk[-1]{DISPLAY}},
 767                         ($diff_use_color ? $colored[$i] : $diff[$i]);
 768         }
 769         return @hunk;
 770 }
 771
 772 sub parse_diff_header {
 773         my $src = shift;
 774
 775         my $head = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 776         my $mode = { TEXT => [], DISPLAY => [], TYPE => 'mode' };
 777         my $deletion = { TEXT => [], DISPLAY => [], TYPE => 'deletion' };
 778
 779         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 780                 my $dest =
 781                    $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ? $mode :
 782                    $src->{TEXT}->[$i] =~ /^deleted file/ ? $deletion :
 783                    $head;
 784                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 785                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 786         }
 787         return ($head, $mode, $deletion);
 788 }
 789
 790 sub hunk_splittable {
 791         my ($text) = @_;
 792
 793         my @s = split_hunk($text);
 794         return (1 < @s);
 795 }
 796
 797 sub parse_hunk_header {
 798         my ($line) = @_;
 799         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt, $heading) =
 800             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@(.*)/;
 801         $o_cnt = 1 unless defined $o_cnt;
 802         $n_cnt = 1 unless defined $n_cnt;
 803         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt, $heading);
 804 }
 805
 806 sub split_hunk {
 807         my ($text, $display) = @_;
 808         my @split = ();
 809         if (!defined $display) {
 810                 $display = $text;
 811         }
 812         # If there are context lines in the middle of a hunk,
 813         # it can be split, but we would need to take care of
 814         # overlaps later.
 815         my ($o_ofs, undef, $n_ofs, undef, $heading) = parse_hunk_header($text->[0]);
 816         my $hunk_start = 1;
 817
 818       OUTER:
 819         while (1) {
 820                 my $next_hunk_start = undef;
 821                 my $i = $hunk_start - 1;
 822                 my $this = +{
 823                         TEXT => [],
 824                         DISPLAY => [],
 825                         TYPE => 'hunk',
 826                         OLD => $o_ofs,
 827                         NEW => $n_ofs,
 828                         OCNT => 0,
 829                         NCNT => 0,
 830                         ADDDEL => 0,
 831                         POSTCTX => 0,
 832                         USE => undef,
 833                 };
 834
 835                 while (++$i < @$text) {
 836                         my $line = $text->[$i];
 837                         my $display = $display->[$i];
 838                         if ($line =~ /^ /) {
 839                                 if ($this->{ADDDEL} &&
 840                                     !defined $next_hunk_start) {
 841                                         # We have seen leading context and
 842                                         # adds/dels and then here is another
 843                                         # context, which is trailing for this
 844                                         # split hunk and leading for the next
 845                                         # one.
 846                                         $next_hunk_start = $i;
 847                                 }
 848                                 push @{$this->{TEXT}}, $line;
 849                                 push @{$this->{DISPLAY}}, $display;
 850                                 $this->{OCNT}++;
 851                                 $this->{NCNT}++;
 852                                 if (defined $next_hunk_start) {
 853                                         $this->{POSTCTX}++;
 854                                 }
 855                                 next;
 856                         }
 857
 858                         # add/del
 859                         if (defined $next_hunk_start) {
 860                                 # We are done with the current hunk and
 861                                 # this is the first real change for the
 862                                 # next split one.
 863                                 $hunk_start = $next_hunk_start;
 864                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 865                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 866                                 $o_ofs -= $this->{POSTCTX};
 867                                 $n_ofs -= $this->{POSTCTX};
 868                                 push @split, $this;
 869                                 redo OUTER;
 870                         }
 871                         push @{$this->{TEXT}}, $line;
 872                         push @{$this->{DISPLAY}}, $display;
 873                         $this->{ADDDEL}++;
 874                         if ($line =~ /^-/) {
 875                                 $this->{OCNT}++;
 876                         }
 877                         else {
 878                                 $this->{NCNT}++;
 879                         }
 880                 }
 881
 882                 push @split, $this;
 883                 last;
 884         }
 885
 886         for my $hunk (@split) {
 887                 $o_ofs = $hunk->{OLD};
 888                 $n_ofs = $hunk->{NEW};
 889                 my $o_cnt = $hunk->{OCNT};
 890                 my $n_cnt = $hunk->{NCNT};
 891
 892                 my $fraginfo = join(
 893                         "",
 894                         "@@ -$o_ofs",
 895                         (($o_cnt != 1) ? ",$o_cnt" : ''),
 896                         " +$n_ofs",
 897                         (($n_cnt != 1) ? ",$n_cnt" : ''),
 898                         " @@"
 899                 );
 900                 unshift @{$hunk->{TEXT}}, join(
 901                         "",
 902                         $fraginfo,
 903                         $heading,
 904                         "\n"
 905                 );
 906                 unshift @{$hunk->{DISPLAY}}, join(
 907                         "",
 908                         $diff_use_color ? colored($fraginfo_color, $fraginfo) : $fraginfo,
 909                         $diff_use_color ? colored($funcname_color, $heading) : $heading,
 910                         "\n"
 911                 );
 912         }
 913         return @split;
 914 }
 915
 916 sub find_last_o_ctx {
 917         my ($it) = @_;
 918         my $text = $it->{TEXT};
 919         my ($o_ofs, $o_cnt) = parse_hunk_header($text->[0]);
 920         my $i = @{$text};
 921         my $last_o_ctx = $o_ofs + $o_cnt;
 922         while (0 < --$i) {
 923                 my $line = $text->[$i];
 924                 if ($line =~ /^ /) {
 925                         $last_o_ctx--;
 926                         next;
 927                 }
 928                 last;
 929         }
 930         return $last_o_ctx;
 931 }
 932
 933 sub merge_hunk {
 934         my ($prev, $this) = @_;
 935         my ($o0_ofs, $o0_cnt, $n0_ofs, $n0_cnt) =
 936             parse_hunk_header($prev->{TEXT}[0]);
 937         my ($o1_ofs, $o1_cnt, $n1_ofs, $n1_cnt) =
 938             parse_hunk_header($this->{TEXT}[0]);
 939
 940         my (@line, $i, $ofs, $o_cnt, $n_cnt);
 941         $ofs = $o0_ofs;
 942         $o_cnt = $n_cnt = 0;
 943         for ($i = 1; $i < @{$prev->{TEXT}}; $i++) {
 944                 my $line = $prev->{TEXT}[$i];
 945                 if ($line =~ /^\+/) {
 946                         $n_cnt++;
 947                         push @line, $line;
 948                         next;
 949                 }
 950
 951                 last if ($o1_ofs <= $ofs);
 952
 953                 $o_cnt++;
 954                 $ofs++;
 955                 if ($line =~ /^ /) {
 956                         $n_cnt++;
 957                 }
 958                 push @line, $line;
 959         }
 960
 961         for ($i = 1; $i < @{$this->{TEXT}}; $i++) {
 962                 my $line = $this->{TEXT}[$i];
 963                 if ($line =~ /^\+/) {
 964                         $n_cnt++;
 965                         push @line, $line;
 966                         next;
 967                 }
 968                 $ofs++;
 969                 $o_cnt++;
 970                 if ($line =~ /^ /) {
 971                         $n_cnt++;
 972                 }
 973                 push @line, $line;
 974         }
 975         my $head = ("@@ -$o0_ofs" .
 976                     (($o_cnt != 1) ? ",$o_cnt" : '') .
 977                     " +$n0_ofs" .
 978                     (($n_cnt != 1) ? ",$n_cnt" : '') .
 979                     " @@\n");
 980         @{$prev->{TEXT}} = ($head, @line);
 981 }
 982
 983 sub coalesce_overlapping_hunks {
 984         my (@in) = @_;
 985         my @out = ();
 986
 987         my ($last_o_ctx, $last_was_dirty);
 988
 989         for (grep { $_->{USE} } @in) {
 990                 if ($_->{TYPE} ne 'hunk') {
 991                         push @out, $_;
 992                         next;
 993                 }
 994                 my $text = $_->{TEXT};
 995                 my ($o_ofs) = parse_hunk_header($text->[0]);
 996                 if (defined $last_o_ctx &&
 997                     $o_ofs <= $last_o_ctx &&
 998                     !$_->{DIRTY} &&
 999                     !$last_was_dirty) {
1000                         merge_hunk($out[-1], $_);
1001                 }
1002                 else {
1003                         push @out, $_;
1004                 }
1005                 $last_o_ctx = find_last_o_ctx($out[-1]);
1006                 $last_was_dirty = $_->{DIRTY};
1007         }
1008         return @out;
1009 }
1010
1011 sub reassemble_patch {
1012         my $head = shift;
1013         my @patch;
1014
1015         # Include everything in the header except the beginning of the diff.
1016         push @patch, (grep { !/^[-+]{3}/ } @$head);
1017
1018         # Then include any headers from the hunk lines, which must
1019         # come before any actual hunk.
1020         while (@_ && $_[0] !~ /^@/) {
1021                 push @patch, shift;
1022         }
1023
1024         # Then begin the diff.
1025         push @patch, grep { /^[-+]{3}/ } @$head;
1026
1027         # And then the actual hunks.
1028         push @patch, @_;
1029
1030         return @patch;
1031 }
1032
1033 sub color_diff {
1034         return map {
1035                 colored((/^@/  ? $fraginfo_color :
1036                          /^\+/ ? $diff_new_color :
1037                          /^-/  ? $diff_old_color :
1038                          $diff_plain_color),
1039                         $_);
1040         } @_;
1041 }
1042
1043 sub edit_hunk_manually {
1044         my ($oldtext) = @_;
1045
1046         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
1047         my $fh;
1048         open $fh, '>', $hunkfile
1049                 or die "failed to open hunk edit file for writing: " . $!;
1050         print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
1051         print $fh @$oldtext;
1052         my $participle = $patch_mode_flavour{PARTICIPLE};
1053         my $is_reverse = $patch_mode_flavour{IS_REVERSE};
1054         my ($remove_plus, $remove_minus) = $is_reverse ? ('-', '+') : ('+', '-');
1055         print $fh <<EOF;
1056 # ---
1057 # To remove '$remove_minus' lines, make them ' ' lines (context).
1058 # To remove '$remove_plus' lines, delete them.
1059 # Lines starting with # will be removed.
1060 #
1061 # If the patch applies cleanly, the edited hunk will immediately be
1062 # marked for $participle. If it does not apply cleanly, you will be given
1063 # an opportunity to edit again. If all lines of the hunk are removed,
1064 # then the edit is aborted and the hunk is left unchanged.
1065 EOF
1066         close $fh;
1067
1068         chomp(my $editor = run_cmd_pipe(qw(git var GIT_EDITOR)));
1069         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
1070
1071         if ($? != 0) {
1072                 return undef;
1073         }
1074
1075         open $fh, '<', $hunkfile
1076                 or die "failed to open hunk edit file for reading: " . $!;
1077         my @newtext = grep { !/^#/ } <$fh>;
1078         close $fh;
1079         unlink $hunkfile;
1080
1081         # Abort if nothing remains
1082         if (!grep { /\S/ } @newtext) {
1083                 return undef;
1084         }
1085
1086         # Reinsert the first hunk header if the user accidentally deleted it
1087         if ($newtext[0] !~ /^@/) {
1088                 unshift @newtext, $oldtext->[0];
1089         }
1090         return \@newtext;
1091 }
1092
1093 sub diff_applies {
1094         return run_git_apply($patch_mode_flavour{APPLY_CHECK} . ' --check',
1095                              map { @{$_->{TEXT}} } @_);
1096 }
1097
1098 sub _restore_terminal_and_die {
1099         ReadMode 'restore';
1100         print "\n";
1101         exit 1;
1102 }
1103
1104 sub prompt_single_character {
1105         if ($use_readkey) {
1106                 local $SIG{TERM} = \&_restore_terminal_and_die;
1107                 local $SIG{INT} = \&_restore_terminal_and_die;
1108                 ReadMode 'cbreak';
1109                 my $key = ReadKey 0;
1110                 ReadMode 'restore';
1111                 if ($use_termcap and $key eq "\e") {
1112                         while (!defined $term_escapes{$key}) {
1113                                 my $next = ReadKey 0.5;
1114                                 last if (!defined $next);
1115                                 $key .= $next;
1116                         }
1117                         $key =~ s/\e/^[/;
1118                 }
1119                 print "$key" if defined $key;
1120                 print "\n";
1121                 return $key;
1122         } else {
1123                 return <STDIN>;
1124         }
1125 }
1126
1127 sub prompt_yesno {
1128         my ($prompt) = @_;
1129         while (1) {
1130                 print colored $prompt_color, $prompt;
1131                 my $line = prompt_single_character;
1132                 return 0 if $line =~ /^n/i;
1133                 return 1 if $line =~ /^y/i;
1134         }
1135 }
1136
1137 sub edit_hunk_loop {
1138         my ($head, $hunk, $ix) = @_;
1139         my $text = $hunk->[$ix]->{TEXT};
1140
1141         while (1) {
1142                 $text = edit_hunk_manually($text);
1143                 if (!defined $text) {
1144                         return undef;
1145                 }
1146                 my $newhunk = {
1147                         TEXT => $text,
1148                         TYPE => $hunk->[$ix]->{TYPE},
1149                         USE => 1,
1150                         DIRTY => 1,
1151                 };
1152                 if (diff_applies($head,
1153                                  @{$hunk}[0..$ix-1],
1154                                  $newhunk,
1155                                  @{$hunk}[$ix+1..$#{$hunk}])) {
1156                         $newhunk->{DISPLAY} = [color_diff(@{$text})];
1157                         return $newhunk;
1158                 }
1159                 else {
1160                         prompt_yesno(
1161                                 'Your edited hunk does not apply. Edit again '
1162                                 . '(saying "no" discards!) [y/n]? '
1163                                 ) or return undef;
1164                 }
1165         }
1166 }
1167
1168 sub help_patch_cmd {
1169         my $verb = lc $patch_mode_flavour{VERB};
1170         my $target = $patch_mode_flavour{TARGET};
1171         print colored $help_color, <<EOF ;
1172 y - $verb this hunk$target
1173 n - do not $verb this hunk$target
1174 q - quit; do not $verb this hunk or any of the remaining ones
1175 a - $verb this hunk and all later hunks in the file
1176 d - do not $verb this hunk or any of the later hunks in the file
1177 g - select a hunk to go to
1178 / - search for a hunk matching the given regex
1179 j - leave this hunk undecided, see next undecided hunk
1180 J - leave this hunk undecided, see next hunk
1181 k - leave this hunk undecided, see previous undecided hunk
1182 K - leave this hunk undecided, see previous hunk
1183 s - split the current hunk into smaller hunks
1184 e - manually edit the current hunk
1185 ? - print help
1186 EOF
1187 }
1188
1189 sub apply_patch {
1190         my $cmd = shift;
1191         my $ret = run_git_apply $cmd, @_;
1192         if (!$ret) {
1193                 print STDERR @_;
1194         }
1195         return $ret;
1196 }
1197
1198 sub apply_patch_for_checkout_commit {
1199         my $reverse = shift;
1200         my $applies_index = run_git_apply 'apply '.$reverse.' --cached --check', @_;
1201         my $applies_worktree = run_git_apply 'apply '.$reverse.' --check', @_;
1202
1203         if ($applies_worktree && $applies_index) {
1204                 run_git_apply 'apply '.$reverse.' --cached', @_;
1205                 run_git_apply 'apply '.$reverse, @_;
1206                 return 1;
1207         } elsif (!$applies_index) {
1208                 print colored $error_color, "The selected hunks do not apply to the index!\n";
1209                 if (prompt_yesno "Apply them to the worktree anyway? ") {
1210                         return run_git_apply 'apply '.$reverse, @_;
1211                 } else {
1212                         print colored $error_color, "Nothing was applied.\n";
1213                         return 0;
1214                 }
1215         } else {
1216                 print STDERR @_;
1217                 return 0;
1218         }
1219 }
1220
1221 sub patch_update_cmd {
1222         my @all_mods = list_modified($patch_mode_flavour{FILTER});
1223         error_msg "ignoring unmerged: $_->{VALUE}\n"
1224                 for grep { $_->{UNMERGED} } @all_mods;
1225         @all_mods = grep { !$_->{UNMERGED} } @all_mods;
1226
1227         my @mods = grep { !($_->{BINARY}) } @all_mods;
1228         my @them;
1229
1230         if (!@mods) {
1231                 if (@all_mods) {
1232                         print STDERR "Only binary files changed.\n";
1233                 } else {
1234                         print STDERR "No changes.\n";
1235                 }
1236                 return 0;
1237         }
1238         if ($patch_mode) {
1239                 @them = @mods;
1240         }
1241         else {
1242                 @them = list_and_choose({ PROMPT => 'Patch update',
1243                                           HEADER => $status_head, },
1244                                         @mods);
1245         }
1246         for (@them) {
1247                 return 0 if patch_update_file($_->{VALUE});
1248         }
1249 }
1250
1251 # Generate a one line summary of a hunk.
1252 sub summarize_hunk {
1253         my $rhunk = shift;
1254         my $summary = $rhunk->{TEXT}[0];
1255
1256         # Keep the line numbers, discard extra context.
1257         $summary =~ s/@@(.*?)@@.*/$1 /s;
1258         $summary .= " " x (20 - length $summary);
1259
1260         # Add some user context.
1261         for my $line (@{$rhunk->{TEXT}}) {
1262                 if ($line =~ m/^[+-].*\w/) {
1263                         $summary .= $line;
1264                         last;
1265                 }
1266         }
1267
1268         chomp $summary;
1269         return substr($summary, 0, 80) . "\n";
1270 }
1271
1272
1273 # Print a one-line summary of each hunk in the array ref in
1274 # the first argument, starting with the index in the 2nd.
1275 sub display_hunks {
1276         my ($hunks, $i) = @_;
1277         my $ctr = 0;
1278         $i ||= 0;
1279         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
1280                 my $status = " ";
1281                 if (defined $hunks->[$i]{USE}) {
1282                         $status = $hunks->[$i]{USE} ? "+" : "-";
1283                 }
1284                 printf "%s%2d: %s",
1285                         $status,
1286                         $i + 1,
1287                         summarize_hunk($hunks->[$i]);
1288         }
1289         return $i;
1290 }
1291
1292 sub patch_update_file {
1293         my $quit = 0;
1294         my ($ix, $num);
1295         my $path = shift;
1296         my ($head, @hunk) = parse_diff($path);
1297         ($head, my $mode, my $deletion) = parse_diff_header($head);
1298         for (@{$head->{DISPLAY}}) {
1299                 print;
1300         }
1301
1302         if (@{$mode->{TEXT}}) {
1303                 unshift @hunk, $mode;
1304         }
1305         if (@{$deletion->{TEXT}}) {
1306                 foreach my $hunk (@hunk) {
1307                         push @{$deletion->{TEXT}}, @{$hunk->{TEXT}};
1308                         push @{$deletion->{DISPLAY}}, @{$hunk->{DISPLAY}};
1309                 }
1310                 @hunk = ($deletion);
1311         }
1312
1313         $num = scalar @hunk;
1314         $ix = 0;
1315
1316         while (1) {
1317                 my ($prev, $next, $other, $undecided, $i);
1318                 $other = '';
1319
1320                 if ($num <= $ix) {
1321                         $ix = 0;
1322                 }
1323                 for ($i = 0; $i < $ix; $i++) {
1324                         if (!defined $hunk[$i]{USE}) {
1325                                 $prev = 1;
1326                                 $other .= ',k';
1327                                 last;
1328                         }
1329                 }
1330                 if ($ix) {
1331                         $other .= ',K';
1332                 }
1333                 for ($i = $ix + 1; $i < $num; $i++) {
1334                         if (!defined $hunk[$i]{USE}) {
1335                                 $next = 1;
1336                                 $other .= ',j';
1337                                 last;
1338                         }
1339                 }
1340                 if ($ix < $num - 1) {
1341                         $other .= ',J';
1342                 }
1343                 if ($num > 1) {
1344                         $other .= ',g';
1345                 }
1346                 for ($i = 0; $i < $num; $i++) {
1347                         if (!defined $hunk[$i]{USE}) {
1348                                 $undecided = 1;
1349                                 last;
1350                         }
1351                 }
1352                 last if (!$undecided);
1353
1354                 if ($hunk[$ix]{TYPE} eq 'hunk' &&
1355                     hunk_splittable($hunk[$ix]{TEXT})) {
1356                         $other .= ',s';
1357                 }
1358                 if ($hunk[$ix]{TYPE} eq 'hunk') {
1359                         $other .= ',e';
1360                 }
1361                 for (@{$hunk[$ix]{DISPLAY}}) {
1362                         print;
1363                 }
1364                 print colored $prompt_color, $patch_mode_flavour{VERB},
1365                   ($hunk[$ix]{TYPE} eq 'mode' ? ' mode change' :
1366                    $hunk[$ix]{TYPE} eq 'deletion' ? ' deletion' :
1367                    ' this hunk'),
1368                   $patch_mode_flavour{TARGET},
1369                   " [y,n,q,a,d,/$other,?]? ";
1370                 my $line = prompt_single_character;
1371                 if ($line) {
1372                         if ($line =~ /^y/i) {
1373                                 $hunk[$ix]{USE} = 1;
1374                         }
1375                         elsif ($line =~ /^n/i) {
1376                                 $hunk[$ix]{USE} = 0;
1377                         }
1378                         elsif ($line =~ /^a/i) {
1379                                 while ($ix < $num) {
1380                                         if (!defined $hunk[$ix]{USE}) {
1381                                                 $hunk[$ix]{USE} = 1;
1382                                         }
1383                                         $ix++;
1384                                 }
1385                                 next;
1386                         }
1387                         elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1388                                 my $response = $1;
1389                                 my $no = $ix > 10 ? $ix - 10 : 0;
1390                                 while ($response eq '') {
1391                                         my $extra = "";
1392                                         $no = display_hunks(\@hunk, $no);
1393                                         if ($no < $num) {
1394                                                 $extra = " (<ret> to see more)";
1395                                         }
1396                                         print "go to which hunk$extra? ";
1397                                         $response = <STDIN>;
1398                                         if (!defined $response) {
1399                                                 $response = '';
1400                                         }
1401                                         chomp $response;
1402                                 }
1403                                 if ($response !~ /^\s*\d+\s*$/) {
1404                                         error_msg "Invalid number: '$response'\n";
1405                                 } elsif (0 < $response && $response <= $num) {
1406                                         $ix = $response - 1;
1407                                 } else {
1408                                         error_msg "Sorry, only $num hunks available.\n";
1409                                 }
1410                                 next;
1411                         }
1412                         elsif ($line =~ /^d/i) {
1413                                 while ($ix < $num) {
1414                                         if (!defined $hunk[$ix]{USE}) {
1415                                                 $hunk[$ix]{USE} = 0;
1416                                         }
1417                                         $ix++;
1418                                 }
1419                                 next;
1420                         }
1421                         elsif ($line =~ /^q/i) {
1422                                 for ($i = 0; $i < $num; $i++) {
1423                                         if (!defined $hunk[$i]{USE}) {
1424                                                 $hunk[$i]{USE} = 0;
1425                                         }
1426                                 }
1427                                 $quit = 1;
1428                                 last;
1429                         }
1430                         elsif ($line =~ m|^/(.*)|) {
1431                                 my $regex = $1;
1432                                 if ($1 eq "") {
1433                                         print colored $prompt_color, "search for regex? ";
1434                                         $regex = <STDIN>;
1435                                         if (defined $regex) {
1436                                                 chomp $regex;
1437                                         }
1438                                 }
1439                                 my $search_string;
1440                                 eval {
1441                                         $search_string = qr{$regex}m;
1442                                 };
1443                                 if ($@) {
1444                                         my ($err,$exp) = ($@, $1);
1445                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1446                                         error_msg "Malformed search regexp $exp: $err\n";
1447                                         next;
1448                                 }
1449                                 my $iy = $ix;
1450                                 while (1) {
1451                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1452                                         last if ($text =~ $search_string);
1453                                         $iy++;
1454                                         $iy = 0 if ($iy >= $num);
1455                                         if ($ix == $iy) {
1456                                                 error_msg "No hunk matches the given pattern\n";
1457                                                 last;
1458                                         }
1459                                 }
1460                                 $ix = $iy;
1461                                 next;
1462                         }
1463                         elsif ($line =~ /^K/) {
1464                                 if ($other =~ /K/) {
1465                                         $ix--;
1466                                 }
1467                                 else {
1468                                         error_msg "No previous hunk\n";
1469                                 }
1470                                 next;
1471                         }
1472                         elsif ($line =~ /^J/) {
1473                                 if ($other =~ /J/) {
1474                                         $ix++;
1475                                 }
1476                                 else {
1477                                         error_msg "No next hunk\n";
1478                                 }
1479                                 next;
1480                         }
1481                         elsif ($line =~ /^k/) {
1482                                 if ($other =~ /k/) {
1483                                         while (1) {
1484                                                 $ix--;
1485                                                 last if (!$ix ||
1486                                                          !defined $hunk[$ix]{USE});
1487                                         }
1488                                 }
1489                                 else {
1490                                         error_msg "No previous hunk\n";
1491                                 }
1492                                 next;
1493                         }
1494                         elsif ($line =~ /^j/) {
1495                                 if ($other !~ /j/) {
1496                                         error_msg "No next hunk\n";
1497                                         next;
1498                                 }
1499                         }
1500                         elsif ($other =~ /s/ && $line =~ /^s/) {
1501                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1502                                 if (1 < @split) {
1503                                         print colored $header_color, "Split into ",
1504                                         scalar(@split), " hunks.\n";
1505                                 }
1506                                 splice (@hunk, $ix, 1, @split);
1507                                 $num = scalar @hunk;
1508                                 next;
1509                         }
1510                         elsif ($other =~ /e/ && $line =~ /^e/) {
1511                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1512                                 if (defined $newhunk) {
1513                                         splice @hunk, $ix, 1, $newhunk;
1514                                 }
1515                         }
1516                         else {
1517                                 help_patch_cmd($other);
1518                                 next;
1519                         }
1520                         # soft increment
1521                         while (1) {
1522                                 $ix++;
1523                                 last if ($ix >= $num ||
1524                                          !defined $hunk[$ix]{USE});
1525                         }
1526                 }
1527         }
1528
1529         @hunk = coalesce_overlapping_hunks(@hunk);
1530
1531         my $n_lofs = 0;
1532         my @result = ();
1533         for (@hunk) {
1534                 if ($_->{USE}) {
1535                         push @result, @{$_->{TEXT}};
1536                 }
1537         }
1538
1539         if (@result) {
1540                 my @patch = reassemble_patch($head->{TEXT}, @result);
1541                 my $apply_routine = $patch_mode_flavour{APPLY};
1542                 &$apply_routine(@patch);
1543                 refresh();
1544         }
1545
1546         print "\n";
1547         return $quit;
1548 }
1549
1550 sub diff_cmd {
1551         my @mods = list_modified('index-only');
1552         @mods = grep { !($_->{BINARY}) } @mods;
1553         return if (!@mods);
1554         my (@them) = list_and_choose({ PROMPT => 'Review diff',
1555                                      IMMEDIATE => 1,
1556                                      HEADER => $status_head, },
1557                                    @mods);
1558         return if (!@them);
1559         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1560         system(qw(git diff -p --cached), $reference, '--',
1561                 map { $_->{VALUE} } @them);
1562 }
1563
1564 sub quit_cmd {
1565         print "Bye.\n";
1566         exit(0);
1567 }
1568
1569 sub help_cmd {
1570         print colored $help_color, <<\EOF ;
1571 status        - show paths with changes
1572 update        - add working tree state to the staged set of changes
1573 revert        - revert staged set of changes back to the HEAD version
1574 patch         - pick hunks and update selectively
1575 diff          - view diff between HEAD and index
1576 add untracked - add contents of untracked files to the staged set of changes
1577 EOF
1578 }
1579
1580 sub process_args {
1581         return unless @ARGV;
1582         my $arg = shift @ARGV;
1583         if ($arg =~ /--patch(?:=(.*))?/) {
1584                 if (defined $1) {
1585                         if ($1 eq 'reset') {
1586                                 $patch_mode = 'reset_head';
1587                                 $patch_mode_revision = 'HEAD';
1588                                 $arg = shift @ARGV or die "missing --";
1589                                 if ($arg ne '--') {
1590                                         $patch_mode_revision = $arg;
1591                                         $patch_mode = ($arg eq 'HEAD' ?
1592                                                        'reset_head' : 'reset_nothead');
1593                                         $arg = shift @ARGV or die "missing --";
1594                                 }
1595                         } elsif ($1 eq 'checkout') {
1596                                 $arg = shift @ARGV or die "missing --";
1597                                 if ($arg eq '--') {
1598                                         $patch_mode = 'checkout_index';
1599                                 } else {
1600                                         $patch_mode_revision = $arg;
1601                                         $patch_mode = ($arg eq 'HEAD' ?
1602                                                        'checkout_head' : 'checkout_nothead');
1603                                         $arg = shift @ARGV or die "missing --";
1604                                 }
1605                         } elsif ($1 eq 'stage' or $1 eq 'stash') {
1606                                 $patch_mode = $1;
1607                                 $arg = shift @ARGV or die "missing --";
1608                         } else {
1609                                 die "unknown --patch mode: $1";
1610                         }
1611                 } else {
1612                         $patch_mode = 'stage';
1613                         $arg = shift @ARGV or die "missing --";
1614                 }
1615                 die "invalid argument $arg, expecting --"
1616                     unless $arg eq "--";
1617                 %patch_mode_flavour = %{$patch_modes{$patch_mode}};
1618         }
1619         elsif ($arg ne "--") {
1620                 die "invalid argument $arg, expecting --";
1621         }
1622 }
1623
1624 sub main_loop {
1625         my @cmd = ([ 'status', \&status_cmd, ],
1626                    [ 'update', \&update_cmd, ],
1627                    [ 'revert', \&revert_cmd, ],
1628                    [ 'add untracked', \&add_untracked_cmd, ],
1629                    [ 'patch', \&patch_update_cmd, ],
1630                    [ 'diff', \&diff_cmd, ],
1631                    [ 'quit', \&quit_cmd, ],
1632                    [ 'help', \&help_cmd, ],
1633         );
1634         while (1) {
1635                 my ($it) = list_and_choose({ PROMPT => 'What now',
1636                                              SINGLETON => 1,
1637                                              LIST_FLAT => 4,
1638                                              HEADER => '*** Commands ***',
1639                                              ON_EOF => \&quit_cmd,
1640                                              IMMEDIATE => 1 }, @cmd);
1641                 if ($it) {
1642                         eval {
1643                                 $it->[1]->();
1644                         };
1645                         if ($@) {
1646                                 print "$@";
1647                         }
1648                 }
1649         }
1650 }
1651
1652 process_args();
1653 refresh();
1654 if ($patch_mode) {
1655         patch_update_cmd();
1656 }
1657 else {
1658         status_cmd();
1659         main_loop();
1660 }