games-engines/hugor/hugor-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [ "$PV" != "9999" ]; then
   7         SRC_URI="https://github.com/realnc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
   8         KEYWORDS="~amd64 ~x86"
   9 else
  10         SRC_URI=""
  11         KEYWORDS=""
  12 fi
  13
  14 inherit desktop qmake-utils xdg
  15
  16 if [ "$PV" == "9999" ]; then
  17         EGIT_REPO_URI="https://github.com/realnc/hugor.git"
  18         inherit git-r3
  19 fi
  20
  21 DESCRIPTION="Multimedia interpreter for Hugo text adventures"
  22 HOMEPAGE="http://ifwiki.org/index.php/Hugor"
  23
  24 LICENSE="GPL-3+"
  25 SLOT="0"
  26 IUSE="gstreamer +vlc"
  27
  28 BDEPEND="
  29         virtual/pkgconfig
  30 "
  31 DEPEND="
  32         dev-qt/qtwidgets:5
  33         gstreamer? ( media-libs/gst-plugins-base:1.0 )
  34         media-libs/libadlmidi
  35         media-libs/libmodplug
  36         media-libs/libsdl2[sound]
  37         media-libs/libsndfile
  38         >=media-sound/fluidsynth-2:=
  39         media-sound/mpg123
  40         vlc? ( || ( media-video/vlc[ffmpeg] media-video/vlc[libav] ) )
  41         x11-misc/shared-mime-info
  42 "
  43 RDEPEND="
  44         gstreamer? (
  45                 media-libs/gst-plugins-good:1.0
  46                 media-plugins/gst-plugins-libav
  47         )
  48         ${DEPEND}
  49 "
  50
  51 src_configure() {
  52         local conf
  53         # VLC is slightly better, so we prefer it.
  54         if use vlc; then
  55                 conf="vlc-video"
  56         elif use gstreamer; then
  57                 conf="gstreamer-video"
  58         else
  59                 conf="disable-video"
  60         fi
  61         if use gstreamer && use vlc; then
  62                 elog "Both the gstreamer and the vlc USE flags are set. Hugor "
  63                 elog "will be built with vlc, since it's slightly better."
  64         fi
  65         eqmake5 PREFIX="${EPREFIX}/usr" \
  66                 DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
  67                 CONFIG+="${conf} adlmidi modplug" \
  68                 -after CONFIG-=silent
  69 }
  70
  71 src_install() {
  72         emake INSTALL_ROOT="${D}" install
  73 }