games-engines/qtads/qtads-9999.ebuild

   1 EAPI=4
   2
   3 EGIT_REPO_URI="git://${PN}.git.sourceforge.net/gitroot/${PN}/${PN}"
   4 inherit eutils gnome2-utils fdo-mime qt4-r2 git-2 games
   5
   6 DESCRIPTION="Multimedia interpreter for TADS text adventures"
   7 HOMEPAGE="http://qtads.sourceforge.net"
   8
   9 LICENSE="GPL-2"
  10 SLOT="0"
  11 KEYWORDS=""
  12 IUSE=""
  13
  14 # Note that for sdl-sound, we need the "mp3", not the "mpeg" USE flag. "mpeg"
  15 # uses the SMPEG lib for decoding, which plays some MP3s at double speed. "mp3"
  16 # uses SDL_sound's internal MPGLIB, which doesn't have that problem. It's OK
  17 # if both "mp3" as well as "mpeg" are enabled, because SDL_sound tries MPGLIB
  18 # first, and only if that fails will it use SMPEG.
  19 DEPEND="dev-qt/qtgui:4
  20         media-libs/libsdl[audio]
  21         media-libs/sdl-mixer[midi,vorbis]
  22         media-libs/sdl-sound[mp3]"
  23 RDEPEND="${DEPEND}"
  24
  25 DOCS="AUTHORS HTML_TADS_LICENSE NEWS README"
  26
  27 src_configure() {
  28         eqmake4 qtads.pro -after CONFIG-=silent
  29 }
  30
  31 src_install() {
  32         dogamesbin qtads
  33         doman qtads.6
  34         dodoc ${DOCS}
  35         newicon -s 256 qtads_256x256.png ${PN}.png
  36         insinto /usr/share/icons
  37         doins -r "icons/hicolor"
  38         insinto /usr/share/mime/packages
  39         doins "icons/qtads.xml"
  40         make_desktop_entry qtads QTads ${PN} Game "GenericName=TADS Multimedia Interpreter\nMimeType=application/x-tads;application/x-t3vm-image;"
  41         prepgamesdirs
  42 }
  43
  44 pkg_preinst() {
  45         games_pkg_preinst
  46         gnome2_icon_savelist
  47 }
  48
  49 pkg_postinst() {
  50         games_pkg_postinst
  51         fdo-mime_desktop_database_update
  52         fdo-mime_mime_database_update
  53         gnome2_icon_cache_update
  54 }
  55
  56 pkg_postrm() {
  57         fdo-mime_desktop_database_update
  58         fdo-mime_mime_database_update
  59         gnome2_icon_cache_update
  60 }