Add ssdiff to examples
[Spreadsheet-Read.git] / examples / xlsgrep
1 #!/pro/bin/perl
2
3 # xlscat:  show XLS/SXC file as Text
4 # xlsgrep: grep pattern
5 #          (m)'13 [24-10-2013] Copyright H.M.Brand 2005-2014
6
7 use strict;
8 use warnings;
9
10 our $VERSION = "2.5";
11
12 my $is_grep = $0 =~ m/grep$/;
13
14 sub usage
15 {
16     my $err = shift and select STDERR;
17     (my $scrpt = $0) =~ s{.*[\/]}{};
18     my $p = $is_grep ? " pattern" : "";
19     print
20         "usage: $scrpt\t[-s <sep>] [-L] [-n] [-A] [-u] [Selection]$p file.xls\n",
21         "             \t[-c | -m]                 [-u] [Selection]$p file.xls\n",
22         "             \t -i                            [-S sheets]$p file.xls\n",
23         "    Generic options:\n",
24         "       -v[#]       Set verbose level (xlscat/xlsgrep)\n",
25         "       -d[#]       Set debug   level (Spreadsheet::Read)\n",
26         "       -u          Use unformatted values\n",
27         "       --noclip    Do not strip empty sheets and\n",
28         "                   trailing empty rows and columns\n",
29         "       -e <enc>    Set encoding for input and output\n",
30         "       -b <enc>    Set encoding for input\n",
31         "       -a <enc>    Set encoding for output\n",
32         "    Input CSV:\n",
33         "       --in-sep=c  Set input sep_char for CSV\n",
34         "    Input XLS:\n",
35         "       --dtfmt=fmt Specify the default date format to replace 'm-d-yy'\n",
36         "                   the default replacement is 'yyyy-mm-dd'\n",
37         "    Output Text (default):\n",
38         "       -s <sep>    Use separator <sep>. Default '|', \\n allowed\n",
39         "       -L          Line up the columns\n",
40         "       -n          Number lines (prefix with column number)\n",
41         "       -A          Show field attributes in ANSI escapes\n",
42         $is_grep ? (
43         "    Grep options:\n",
44         "       -i          Ignore case\n",
45         "       -w          Match whole words only\n",
46         "       -h[#]       Show # header lines\n") : (
47         "    Output Index only:\n",
48         "       -i          Show sheet names and size only\n"),
49         "    Output CSV:\n",
50         "       -c          Output CSV, separator = ','\n",
51         "       -m          Output CSV, separator = ';'\n",
52         "    Output HTML:\n",
53         "       -H          Output HTML\n",
54         "    Selection:\n",
55         "       -S <sheets> Only print sheets <sheets>. 'all' is a valid set\n",
56         "                   Default only prints the first sheet\n",
57         "       -R <rows>   Only print rows    <rows>. Default is 'all'\n",
58         "       -C <cols>   Only print columns <cols>. Default is 'all'\n",
59         "       -F <flds>   Only fields <flds> e.g. -FA3,B16\n";
60     @_ and print join "\n", @_, "";
61     exit $err;
62     } # usage
63
64 use Getopt::Long qw(:config bundling noignorecase);
65 my $opt_c;              # Generate CSV
66 my $opt_s;              # Text separator
67 my $opt_S;              # Sheets to print
68 my $opt_R;              # Rows to print
69 my $opt_C;              # Columns to print
70 my $dtfmt;              # Default date-format for Excel
71 my $opt_F = "";         # Fields to print
72 my $opt_i = 0;          # Index (cat) | ignore_case (grep)
73 my $opt_L = 0;          # Auto-size/align columns
74 my $opt_n = 0;          # Prefix lines with column number
75 my $opt_u = 0;          # Show unformatted values
76 my $opt_v = 0;          # Verbosity for xlscat
77 my $opt_d = 0;          # Debug level for Spreadsheet::Read
78 my $opt_A = 0;          # Show field colors in ANSI escapes
79 my $opt_H = 0;          # Output in HTML
80 my $opt_h = 0;          # Number of header lines for grep
81 my $opt_w = 0;          # Grep words
82 my $clip  = 1;
83 my $enc_i;              # Input  encoding
84 my $enc_o;              # Output encoding
85 my $sep;                # Input field sep for CSV
86 GetOptions (
87     "help|?"            => sub { usage (0); },
88
89     # Input CSV
90     "c|csv"             => sub { $opt_c = "," },
91     "m|ms"              => sub { $opt_c = ";" },
92     "insepchar".
93      "|in-sep".
94      "|in-sep-char=s"   => \$sep,
95
96     # Input XLS
97     "dtfmt".
98      "|date-format=s"   => \$dtfmt,
99
100     # Output
101     "i|index"           => \$opt_i,
102     "s|separator".
103      "|outsepchar".
104      "|out-sep".
105      "|out-sep-char=s"  => \$opt_s,
106     "S|sheets=s"        => \$opt_S,
107     "R|rows=s"          => \$opt_R,
108     "C|columns=s"       => \$opt_C,
109     "F|fields=s"        => \$opt_F,
110     "L|fit|align!"      => \$opt_L,
111     "n|number!"         => \$opt_n,
112     "A|ansi|color!"     => \$opt_A,
113     "u|unformatted!"    => \$opt_u,
114     "v|verbose:1"       => \$opt_v,
115     "d|debug:1"         => \$opt_d,
116     "H|html:1"          => \$opt_H,
117       "noclip"          => sub { $clip = 0 },
118
119     # Encoding
120     "e|encoding=s"      => sub { $enc_i = $enc_o = $_[1] },
121     "b|encoding-in=s"   => \$enc_i,
122     "a|encoding-out=s"  => \$enc_o,
123
124     # Grep
125     "i|ignore-case!"    => \$opt_i,
126     "w|word!"           => \$opt_w,
127     "h|header:1"        => \$opt_h,
128     ) or usage 1, "GetOpt: $@";
129
130 unless ($is_grep) {
131 $opt_i && $opt_L and usage 1, "Options i and L are mutually exclusive";
132 $opt_i && $opt_s and usage 1, "Options i and s are mutually exclusive";
133 $opt_i && $opt_c and usage 1, "Options i and c are mutually exclusive";
134 $opt_i && $opt_u and usage 1, "Options i and u are mutually exclusive";
135 $opt_i && $opt_S and usage 1, "Options i and S are mutually exclusive";
136 $opt_i && $opt_R and usage 1, "Options i and R are mutually exclusive";
137 $opt_i && $opt_C and usage 1, "Options i and C are mutually exclusive";
138 $opt_i && $opt_F and usage 1, "Options i and F are mutually exclusive";
139 $opt_i && $opt_H and usage 1, "Options i and H are mutually exclusive";
140 }
141 $opt_c && $opt_s and usage 1, "Options c and s are mutually exclusive";
142 $opt_c && $opt_H and usage 1, "Options c and H are mutually exclusive";
143 $opt_s && $opt_H and usage 1, "Options s and H are mutually exclusive";
144
145 defined $opt_s or $opt_s = "|"; eval "\$opt_s = qq{$opt_s}";
146 defined $opt_S or $opt_S = $opt_i || $is_grep ? "all" : "1";
147 $opt_i && !$is_grep && $opt_v < 1 and $opt_v = 1;
148
149 if ($opt_c) {
150     $opt_L = 0; # Cannot align CSV
151     $opt_c =~ m/^1?$/ and $opt_c = ",";
152     $opt_c = Text::CSV_XS->new ({
153         binary   => 1,
154         sep_char => $opt_c,
155         eol      => "\r\n",
156         });
157     }
158
159 # Debugging. Prefer Data::Peek over Data::Dumper if available
160 {   use Data::Dumper;
161     my $dp = 0;
162     eval q{
163         use Data::Peek;
164         $dp = 1;
165         };
166     sub ddumper
167     {
168         $dp ? DDumper (@_)
169             : print STDERR Dumper (@_);
170         } # ddumper
171     }
172
173 my $pattern;
174 if ($is_grep) {
175     $pattern = shift or usage 1;
176     $opt_w and $pattern = "\\b$pattern\\b";
177     $opt_i and $pattern = "(?i:$pattern)";
178     $pattern = qr{$pattern};
179     $opt_v > 1 and warn "Matching on $pattern\n";
180     }
181
182 @ARGV or usage 1;
183 my $file = shift;
184 -f $file or usage 1, "the file argument is not a regular file";
185 -s $file or usage 1, "the file is empty";
186
187 use Encode qw( encode decode );
188 use Spreadsheet::Read;
189
190 if ($opt_c) {
191     Spreadsheet::Read::parses ("csv") or die "No CSV module found\n";
192     eval q{use Text::CSV_XS};
193     }
194 if ($opt_H) {
195     $enc_o = "utf-8";
196     $opt_H = sub { $_[0]; };
197     eval q{
198         use HTML::Entities;
199         $opt_H = sub {
200             encode_entities (decode ("utf-8", $_[0]));
201             };
202         };
203     }
204
205 my @RDarg = (debug => $opt_d, clip => $clip);
206 $opt_A         and push @RDarg, "attr"  => 1;
207 defined $sep   and push @RDarg, "sep"   => $sep, parser => "csv";
208 defined $dtfmt and push @RDarg, "dtfmt" => $dtfmt;
209 $opt_v > 4 and warn "ReadData ($file, @RDarg);\n";
210 my $xls = ReadData ($file, @RDarg) or die "cannot read $file\n";
211 $opt_v > 7 and ddumper ($xls);
212 my $sc  = $xls->[0]{sheets}     or die "No sheets in $file\n";
213 $opt_v > 1 and warn "Opened $file with $sc sheets\n";
214
215 $opt_S eq "all" and $opt_S = "1..$sc";  # all
216 $opt_S =~ s/-$/-$sc/;                   # 3,6-
217 $opt_S =~ s/-/../g;
218 my %print;
219 eval "%{\$print{sheet}} = map { \$_ => 1 } $opt_S";
220
221 my $v_fmt = $opt_C || $opt_R || $opt_F ? "" : "%6d x %6d%s";
222
223 # New style xterm (based on ANSI colors):
224 # 30 Black
225 # 31 Red
226 # 32 Green
227 # 33 Yellow
228 # 34 Blue
229 # 35 Magenta
230 # 36 Cyan
231 # 37 White
232 sub color_reduce
233 {
234     my ($rgb, $base) = @_;
235     defined $rgb or return "";
236     my ($r, $g, $b) = map { hex >> 7 }
237         ($rgb =~ m/^\s*#?([\da-f]{2})([\da-f]{2})([\da-f]{2})/);
238     $base + 4 * $b + 2 * $g + $r;
239     } # color_reduce
240
241 sub ansi_color
242 {
243     my ($fg, $bg, $bold, $ul) = @_;
244
245     # warn "$fg on $bg $bold $ul\n";
246     my $attr = join ";", 0, grep { /\S/ }
247         $bold ? 1 : "",
248         $ul   ? 4 : "",
249         color_reduce ($fg, 30),
250         color_reduce ($bg, 40);
251
252     "\e[${attr}m";
253     } # ansi_color
254
255 sub css_color
256 {
257     my ($fg, $bg, $bold, $ul, $ha) = @_;
258
259     my @css;
260     $bold and push @css, "font-weight: bold";
261     $ul   and push @css, "text-decoration: underline";
262     $fg   and push @css, "color: $fg";
263     $bg   and push @css, "background: $bg";
264     $ha   and push @css, "text-align: $ha";
265
266     local $" = "; ";
267     @css ? qq{ style="@css"} : "";
268     } # css_color
269
270             binmode STDERR, ":utf8";
271 $enc_o and  binmode STDOUT, ":encoding($enc_o)";
272
273 if ($opt_H) {
274     print <<EOH;
275 <?xml version="1.0" encoding="utf-8"?>
276 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">
277 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en">
278 <head>
279   <title>$file</title>
280   <meta name="Author" content="xlscat $VERSION" />
281   <style type="text/css">
282     body, h2,
283     td, th { font-family:     "Nimbus Sans L", "DejaVu Sans",
284                               Helvetica, Arial, sans; }
285     table  { border-spacing:  2px;
286              border-collapse: collapse;               }
287     td, th { vertical-align:  top;
288              padding:         4px;                    }
289     table  > tbody > tr > th,
290     table  > tr > th {
291              background:      #e0e0e0;                }
292     table  > tbody > tr > td:not([class]),
293     table  > tr > td:not([class]) {
294              background:      #f0f0f0;                }
295     .odd   { background:      #e0e0e0;                }
296     </style>
297   </head>
298 <body>
299 EOH
300     }
301
302 my $name_len = 30;
303 if ($opt_i) {
304     my $nl = 0;
305     foreach my $sn (keys %{$xls->[0]{sheet}}) {
306         length ($sn) > $nl and $nl = length $sn;
307         }
308     $nl and $name_len = $nl;
309     }
310 my @opt_F = split m/[^A-Z\d]+/ => $opt_F;
311 foreach my $si (1 .. $sc) {
312     my @data;
313     exists $print{sheet}{$si} or next;
314     $opt_v > 1 and warn "Opening sheet $si ...\n";
315     my $s = $xls->[$si] or next;
316     $opt_v > 5 and ddumper ($s);
317     my @r = (1, $s->{maxrow});
318     my @c = (1, $s->{maxcol});
319     my ($sn, $nr, $nc) = ($s->{label}, $r[-1], $c[-1]);
320     $opt_v and printf STDERR "%s - %02d: [ %-*s ] %3d Cols, %5d Rows\n",
321         $file, $si, $name_len, $sn, $nc, $nr;
322     $opt_i && !$is_grep and next;
323
324     if (@opt_F) {
325         foreach my $fld (@opt_F) {
326             $is_grep && defined $s->{$fld} && $s->{$fld} !~ $pattern and next;
327             print "$fld:",$s->{$fld},"\n";
328             }
329         next;
330         }
331
332     if (my $rows = $opt_R) {
333         $rows eq "all" and $rows = "1..$nr";    # all
334         $rows =~ s/-$/-$nr/;                    # 3,6-
335         $rows =~ s/-/../g;
336         eval "%{\$print{row}} = map { \$_ => 1 } $rows";
337         }
338     if (my $cols = $opt_C) {
339         $cols eq "all" and $cols = "1..$nc";    # all
340         if ($cols =~ m/[A-Za-z]/) {             # -C B,D => -C 2,4
341             my %ct = map {
342                 my ($cc, $rr) = cell2cr (uc "$_".1);
343                 ($_ => $cc)
344                 } ($cols =~ m/([a-zA-Z]+)/g);
345             $cols =~ s/([A-Za-z]+)/$ct{$1}/g;
346             }
347         $cols =~ s/-$/-$nc/;                    # 3,6-
348         $cols =~ s/-/../g;
349         eval "\$print{col} = [ map { \$_ - 1  } $cols ]";
350         $nc = @{$print{col}};
351         }
352     $opt_v >= 8 and ddumper (\%print);
353
354     $opt_H and print qq{<h2>$sn</h2>\n\n<table border="1">\n};
355     my $undef = $opt_v > 2 ? "-- undef --" : "";
356     my ($h, @w) = (0, (0) x $nc); # data height, -width, and default column widths
357     my @align = ("") x $nc;
358     foreach my $r ($r[0] .. $r[1]) {
359         exists $print{row} && !exists $print{row}{$r} and next;
360         my @att;
361         my @row = map {
362             my $cell = cr2cell ($_, $r);
363             my ($uval, $fval) = map {
364                 defined $_ ? $enc_i ? decode ($enc_i, $_) : $_ : $undef
365                 } $s->{cell}[$_][$r], $s->{$cell};
366             $opt_v > 2 and warn "$_:$r '$uval' / '$fval'\n";
367             $opt_A and 
368                 push @att, [ @{$s->{attr}[$_][$r]}{qw( fgcolor bgcolor bold uline halign )} ];
369             defined $s->{cell}[$_][$r] ? $opt_u ? $uval : $fval : "";
370             } $c[0] .. $c[1];
371         exists $print{col} and @row = @row[@{$print{col}}];
372         $is_grep && $r > $opt_h &&
373             ! grep { defined $_ && $_ =~ $pattern } @row and next;
374         if ($opt_L) {
375             foreach my $c (0 .. $#row) {
376                 my $l = length $row[$c];
377                 $l > $w[$c] and $w[$c] = $l;
378                 $row[$c] =~ m/\D/ and $align[$c] = "-";
379                 }
380             }
381         if ($enc_o) { $_ = encode ($enc_o, $_) for @row; }
382         if ($opt_H) {   # HTML
383             print "  <tr>";
384             foreach my $c (0 .. $#row) {
385                 my $css = css_color (@{$att[$c]});
386                 $r % 2 and $css .= qq{ class="odd"};
387                 my $td  = $opt_H->($row[$c]);
388                 print "<td$css>$td</td>";
389                 }
390             print "</tr>\n";
391             next;
392             }
393         if ($opt_c) {   # CSV
394             $opt_c->print (*STDOUT, \@row) or die $opt_c->error_diag;
395             next;
396             }
397         if ($opt_n) {
398             unshift @row, $r;
399             unshift @att, [ "#ffffff", "#000000", 0, 0 ];
400             }
401         if ($opt_L) {   # Autofit / Align
402             push @data, [ [ @row ], [ @att ] ];
403             next;
404             }
405         if ($opt_A) {
406             foreach my $c (0 .. $#row) {
407                 $row[$c] =
408                     ansi_color (@{$att[$c]}).
409                     $row[$c] .
410                     "\e[0m";
411                 }
412             }
413         print join ($opt_s => @row), "\n";
414         } continue {
415             ++$h % 100 == 0 && $opt_v and printf STDERR $v_fmt, $nc, $h, "\r";
416             }
417     $opt_H and print "  </table>\n\n";
418     printf STDERR $v_fmt, $nc, $h, "\n";
419     $opt_L or next;
420     if ($opt_n) {
421         unshift @w, length $data[-1][0][0];
422         unshift @align, "";
423         }
424     my $fmt = join ($opt_s =>
425         map { my $f = "%$align[$_]$w[$_]s";
426               $opt_A ? "%s$f%s" : $f } 0 .. $#w)."\n";
427     for (@data) {
428         my ($row, $att) = @$_;
429         my @row = $opt_A
430             ? map { (
431                 ansi_color (@{$att->[$_]}),
432                 $row->[$_],
433                 "\e[0m" ) } 0 .. $#$row
434             : @$row;
435         printf $fmt, @row;
436         }
437     }
438 $opt_H and print "</body>\n</html>\n";