| blob | ce9e6fd2a2003d39d6ff17ea70038148c4accb4d |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
5 AC_INIT(vlc, 4.0.0-dev)
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2018"
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
60 AC_PROG_CXX
61 AC_PROG_CPP
62 AC_PROG_OBJC
63 AC_PROG_EGREP
64 AC_PROG_MAKE_SET
65 AC_PROG_INSTALL
66 AM_PROG_AS
67 AC_PROG_LEX
68 AC_PROG_YACC
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90 AS_HELP_STRING([--with-binary-version=STRING],
91 [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94 [Binary specific version])
95 ])
97 dnl Prevent clang from accepting unknown flags with a mere warning
98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
101 dnl
102 dnl Check the operating system
103 dnl
104 HAVE_WIN64="0"
105 HAVE_IOS="0"
106 HAVE_OSX="0"
107 HAVE_TVOS="0"
109 case "${host_os}" in
110 "")
111 SYS=unknown
112 ;;
113 linux*)
114 SYS=linux
115 ;;
116 bsdi*)
117 SYS=bsdi
118 CFLAGS="${CFLAGS} -pthread"
119 ;;
120 freebsd*)
121 SYS=freebsd
122 CFLAGS="${CFLAGS} -pthread"
123 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
124 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
125 ac_cv_ld_z_defs=no
126 ;;
127 openbsd*)
128 SYS=openbsd
129 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
130 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
131 ;;
132 netbsd*)
133 SYS=netbsd
134 ;;
135 dragonfly*)
136 SYS=dragonfly
137 ;;
138 darwin*)
140 dnl Force gcc "-arch" flag
141 ARCH_flag=""
142 case "${host}" in
143 i?86*)
144 ARCH_flag="-arch i386"
145 ;;
146 ppc64*)
147 ARCH_flag="-arch ppc64"
148 ;;
149 ppc*)
150 ARCH_flag="-arch ppc"
151 ;;
152 x86_64*)
153 ARCH_flag="-arch x86_64"
154 ;;
155 arm*)
156 ac_cv_c_bigendian="no"
157 ac_cv_c_attribute_packed="no"
158 ;;
159 esac
161 SYS=darwin
162 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
163 CXX="${CXX} -stdlib=libc++ -std=c++11"
164 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
165 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
166 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
167 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
168 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
169 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
171 AC_EGREP_CPP(yes,
172 [#import <TargetConditionals.h>
173 #if TARGET_OS_IPHONE
174 yes
175 #endif],
176 [HAVE_IOS="1"],
177 [HAVE_OSX="1"])
179 AC_EGREP_CPP(yes,
180 [#import <TargetConditionals.h>
181 #if TARGET_OS_TV
182 yes
183 #endif],
184 [HAVE_TVOS="1"
185 HAVE_IOS="0"
186 HAVE_OSX="0"
187 ],)
189 dnl
190 dnl Handle Mac OS X SDK flags
191 dnl
192 AC_ARG_WITH(macosx-sdk,
193 [AS_HELP_STRING([--with-macosx-sdk=DIR],
194 [compile using the SDK in DIR])])
195 if test "${with_macosx_sdk}" != "" ; then
196 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
197 CPP="${CPP} -isysroot ${with_macosx_sdk}"
198 CC="${CC} -isysroot ${with_macosx_sdk}"
199 CXX="${CXX} -isysroot ${with_macosx_sdk}"
200 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
201 LD="${LD} -syslibroot ${with_macosx_sdk}"
202 fi
203 AC_ARG_WITH(macosx-version-min,
204 [AS_HELP_STRING([--with-macosx-version-min=VERSION],
205 [compile for Mac OS X VERSION and above])])
206 if test "${with_macosx_version_min}" != "" ; then
207 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
208 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
209 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
210 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
211 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
212 fi
213 ;;
214 *mingw32* | *cygwin* | *wince* | *mingwce*)
215 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
216 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
217 CXXFLAGS="${CXXFLAGS} -static-libgcc"
218 AC_CHECK_TOOL(WINDRES, windres, :)
219 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
220 AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
221 AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
222 AH_TOP([#endif])
223 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
224 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
225 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
226 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
227 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
228 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
229 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
230 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
231 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
232 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
233 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
234 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
236 case "${host_os}" in
237 *mingw32*)
238 SYS=mingw32
239 ;;
240 *cygwin*)
241 dnl Check if we are using the mno-cygwin mode in which case we are
242 dnl actually dealing with a mingw32 compiler.
243 AC_EGREP_CPP(yes,
244 [#ifdef _WIN32
245 yes
246 #endif],
247 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
248 ;;
249 esac
251 if test "${SYS}" = "mingw32"; then
252 # DEP, ASLR, NO SEH
253 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
255 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
256 ac_default_prefix="`pwd`/_win32"
257 DESTDIR="`pwd`/_win32/"
259 dnl
260 dnl NSIS/MSI Installer prefix and WIN64
261 dnl
262 case "${host}" in
263 amd64*|x86_64*)
264 HAVE_WIN64="1"
265 WINDOWS_ARCH="x64"
266 PROGRAMFILES="PROGRAMFILES64"
267 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
268 ;;
269 *)
270 WINDOWS_ARCH="x86"
271 PROGRAMFILES="PROGRAMFILES"
272 ;;
273 esac
274 AC_SUBST(WINDOWS_ARCH)
275 AC_SUBST(PROGRAMFILES)
277 fi
278 ;;
279 *nto*)
280 SYS=nto
281 ;;
282 solaris*)
283 SYS=solaris
284 ;;
285 hpux*)
286 SYS=hpux
287 ;;
288 *os2*)
289 SYS=os2
290 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
291 AC_LIBOBJ([freeaddrinfo])
292 AC_LIBOBJ([gai_strerror])
293 AC_CHECK_FUNCS([if_nametoindex])
294 ;;
295 *nacl*)
296 SYS=nacl
297 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
298 AC_LIBOBJ([sigwait])
299 AC_LIBOBJ([recvmsg])
300 AC_LIBOBJ([sendmsg])
301 ;;
302 *)
303 SYS="${host_os}"
304 ;;
305 esac
307 dnl WinRT
308 AC_ARG_ENABLE(winstore_app,
309 AS_HELP_STRING([--enable-winstore-app],
310 [Build targetted for Windows Store apps (default disabled)]))
312 vlc_winstore_app=0
313 AS_IF([test "${SYS}" = "mingw32"],[
314 LIBCOM="-lole32"
315 AS_IF([test "${enable_winstore_app}" = "yes"], [
316 vlc_winstore_app=1
317 LIBCOM=""
318 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
319 AC_LIBOBJ([gai_strerror])
320 ],[])
321 AC_SUBST(LIBCOM)
322 ])
323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
325 AM_CONDITIONAL(HAVE_LINUX, test "${SYS}" = "linux")
326 AM_CONDITIONAL(HAVE_OS2, test "${SYS}" = "os2")
328 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
329 AM_CONDITIONAL(HAVE_IOS, test "${HAVE_IOS}" = "1")
330 AM_CONDITIONAL(HAVE_OSX, test "${HAVE_OSX}" = "1")
331 AM_CONDITIONAL(HAVE_TVOS, test "${HAVE_TVOS}" = "1")
333 AM_CONDITIONAL(HAVE_NACL, test "${SYS}" = "nacl")
334 AM_CONDITIONAL(HAVE_LIBANL, test "${HAVE_LIBANL}" = "1")
336 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
337 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
338 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
339 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
341 dnl
342 dnl Sadly autoconf does not think about testing foo.exe when ask to test
343 dnl for program foo on win32
344 case "${build_os}" in
345 cygwin|msys|mingw32)
346 ac_executable_extensions=".exe"
347 BUILDEXEEXT=".exe"
348 ;;
349 os2*)
350 BUILDEXEEXT=".exe"
351 ;;
352 *)
353 ;;
354 esac
355 AC_SUBST(BUILDEXEEXT)
357 dnl Android is linux, but a bit different
358 AS_IF([test "$SYS" = linux],[
359 AC_MSG_CHECKING([for an Android system])
360 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
361 [[#ifndef __ANDROID__
362 # error Not Android
363 #endif
364 ]],[[;]])
365 ],[
366 HAVE_ANDROID="1"
367 AC_MSG_RESULT([yes])
368 ],[
369 AC_MSG_RESULT([no])
370 ])
371 ])
372 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
374 dnl Tizen (minimum SDK version: 2.3)
375 AS_IF([test "$SYS" = linux],[
376 AC_MSG_CHECKING([for Tizen])
377 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
378 [[#include <tizen.h>
379 ]],[[;]])
380 ],[
381 HAVE_TIZEN="1"
382 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
383 AC_MSG_RESULT([yes])
384 ],[
385 AC_MSG_RESULT([no])
386 ])
387 ])
388 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
390 dnl
391 dnl Check for the contrib directory
392 dnl
393 AC_ARG_WITH(contrib,
394 [AS_HELP_STRING([--with-contrib[=DIR]],
395 [search for 3rd party libraries in DIR/include and DIR/lib])
396 ])
397 AC_MSG_CHECKING([for 3rd party libraries path])
398 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
399 CONTRIB_DIR="${srcdir}/contrib/${host}"
400 AS_IF([test ! -d "${CONTRIB_DIR}"], [
401 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
402 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
403 AS_IF([test ! -d "${CONTRIB_DIR}"], [
404 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
405 CONTRIB_DIR=""
406 AC_MSG_RESULT([not found])
407 ])
408 ])
409 ], [
410 AS_IF([test "${with_contrib}" != "no"], [
411 CONTRIB_DIR="${with_contrib}"
412 ], [
413 CONTRIB_DIR=""
414 AC_MSG_RESULT([disabled])
415 ])
416 ])
417 AS_IF([test -n "${CONTRIB_DIR}"], [
418 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
419 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
420 ], [
421 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
422 CONTRIB_DIR=""
423 AC_MSG_RESULT([not usable])
424 ])
426 ])
427 AS_IF([test -n "${CONTRIB_DIR}"], [
428 AC_MSG_RESULT([${CONTRIB_DIR}])
429 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
430 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
431 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
432 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
433 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
434 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
436 AS_IF([test -z "$LUAC"], [
437 dnl Old contribs mixed cross-tools and cross-compiled executables
438 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
439 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
440 ])
442 dnl Newer contribs follow usual name space rules
443 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
444 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
445 ])
446 ])
448 AS_IF([test "${SYS}" = "darwin"], [
449 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
450 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
451 ])
452 ], [
453 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
454 AC_MSG_ERROR([Third party libraries not found!])
455 ])
456 ])
457 AC_SUBST(CONTRIB_DIR)
459 dnl Add extras/tools to the PATH
460 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
461 AS_IF([test -d "${TOOLS_DIR}"], [
462 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
463 export PATH="${TOOLS_DIR}":$PATH
464 ])
466 dnl
467 dnl Libtool
468 dnl It's very bad, but our former custom system was worst
469 dnl -- Courmisch
470 dnl
472 dnl override platform specific check for dependent libraries
473 dnl otherwise libtool linking of shared libraries will
474 dnl fail on anything other than pass_all.
475 AC_CACHE_VAL(lt_cv_deplibs_check_method,
476 [lt_cv_deplibs_check_method=pass_all])
478 LT_INIT([dlopen win32-dll shared disable-static])
479 LT_LANG([C++])
480 LT_LANG([Windows Resource])
482 DOLT
484 lt_cv_deplibs_check_method=pass_all
486 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
487 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
488 ])
490 dnl
491 dnl Gettext stuff
492 dnl
493 AM_GNU_GETTEXT_VERSION([0.19.8])
494 AM_GNU_GETTEXT([external], [need-formatstring-macros])
496 dnl
497 dnl Iconv stuff
498 dnl
499 AM_ICONV
501 dnl
502 dnl checks for mingw
503 AS_IF([test "${SYS}" = "mingw32"], [
505 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
506 #if !defined(__MINGW32__)
507 # error Not compiling with mingw
508 #endif
509 ])], [
511 dnl Check for broken versions of mingw-runtime compatability library
512 AC_MSG_CHECKING(for broken mingw-runtime)
513 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
514 #include <_mingw.h>
515 #if defined(__MINGW64_VERSION_MAJOR)
516 # if __MINGW64_VERSION_MAJOR < 5
517 # error Update your mingw-w64! This one is too old.
518 # endif
519 #else
520 # error You cannot compile with Mingw. Use Mingw-w64!
521 #endif
522 ])], [
523 AC_MSG_RESULT([ok])
524 ], [
525 AC_MSG_RESULT([present])
526 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
527 ])
529 dnl force use of mingw provided c99 *printf over msvcrt
530 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
532 dnl Check for the need to include the mingwex lib for mingw32
533 VLC_SAVE_FLAGS
534 AC_CHECK_LIB(mingwex,opendir,
535 AC_CHECK_LIB(mingw32,opendir,,
536 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
537 )
538 VLC_RESTORE_FLAGS
539 ], [
540 AC_MSG_RESULT([Not compiling with mingw])
541 ])
543 dnl Check for fnative-struct or mms-bitfields support for mingw32
544 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
545 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
546 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
547 # Check for the warning flag without "-Wno-", GCC accepts
548 # -Wno-<anything> for unsupported warnings, which can trigger
549 # other warnings instead.
550 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
551 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
552 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
553 ])
554 ], [
555 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
556 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
557 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
558 ])
559 ])
560 ])
563 dnl
564 dnl Buggy glibc prevention. Purposedly not cached.
565 dnl See sourceware.org bugs 5058 and 5443.
566 dnl Ubuntu alone has 20 bug numbers for this...
567 dnl
568 AC_MSG_CHECKING(for buggy GNU/libc versions)
569 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
570 #include <limits.h>
571 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
572 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
573 # error GNU/libc with dcgettext killer bug!
574 #endif
575 ])], [
576 AC_MSG_RESULT([not present])
577 ], [
578 AC_MSG_RESULT([found])
579 AS_IF([test "x${enable_nls}" != "xno"], [
580 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
581 work-around for this. Check with your distribution vendor on how to update the
582 glibc run-time. Alternatively, build with --disable-nls.])
583 ])
584 ])
586 dnl Plugin compilation stuff
588 VLC_LIBRARY_SUFFIX
590 dnl Check for system libs needed
591 need_libc=false
593 dnl Check for usual libc functions
594 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
595 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
596 AC_REPLACE_FUNCS([gettimeofday])
597 AC_CHECK_FUNC(fdatasync,,
598 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
599 ])
601 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
603 dnl mingw64 implements those as static inline, not functions with C linkage
604 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
605 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
606 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
607 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
609 dnl C11 static_assert()
610 AC_MSG_CHECKING([for static_assert in assert.h])
611 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
612 static_assert(1, "The impossible happened.");
613 ])], [
614 AC_MSG_RESULT([yes])
615 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
616 ], [
617 AC_MSG_RESULT([no])
618 ])
620 # Windows CE does not have strcoll()
621 AC_FUNC_STRCOLL
623 dnl Check for non-standard system calls
624 case "$SYS" in
625 "linux")
626 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
627 ;;
628 "mingw32")
629 AC_CHECK_FUNCS([_lock_file])
630 ;;
631 esac
633 AH_BOTTOM([#include <vlc_fixups.h>])
635 dnl Check for struct pollfd
636 AC_CHECK_TYPES([struct pollfd],,,
637 [#include <sys/types.h>
638 #if HAVE_POLL
639 # include <poll.h>
640 #elif defined (_WIN32)
641 # include <winsock2.h>
642 #endif
643 ])
645 dnl Check for struct timespec
646 AC_CHECK_TYPES([struct timespec],,,
647 [#include <time.h>])
649 dnl Check for max_align_t
650 AC_CHECK_TYPES([max_align_t],,,
651 [#include <stddef.h>])
653 dnl Checks for socket stuff
654 VLC_SAVE_FLAGS
655 SOCKET_LIBS=""
656 AC_SEARCH_LIBS(connect, [socket], [
657 AS_IF([test "$ac_cv_search_connect" != "none required"], [
658 SOCKET_LIBS="$ac_cv_search_connect"
659 ])
660 ], [
661 AS_IF([test "${SYS}" = "mingw32"], [
662 SOCKET_LIBS="-lws2_32 -liphlpapi"
663 ])
664 ])
666 AC_SEARCH_LIBS([inet_pton], [nsl], [
667 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
668 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
669 ])
670 ],, [${SOCKET_LIBS}])
672 LIBS="${LIBS} ${SOCKET_LIBS}"
673 AC_LINK_IFELSE([
674 AC_LANG_PROGRAM([#ifdef _WIN32
675 #include <ws2tcpip.h>
676 #include <windows.h>
677 # if _WIN32_WINNT < 0x600
678 # error Needs vista+
679 # endif
680 #else
681 #include <sys/socket.h>
682 #include <arpa/inet.h>
683 #endif], [
684 char dst[[sizeof(struct in_addr)]];
685 inet_pton(AF_INET, "127.0.0.1", dst);
686 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
687 AC_CHECK_FUNCS([if_nameindex])
688 VLC_RESTORE_FLAGS
689 AC_SUBST(SOCKET_LIBS)
691 dnl Check for socklen_t
692 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
693 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
694 ac_cv_type_socklen_t,
695 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
696 [#include <sys/types.h>
697 #ifdef _WIN32
698 # include <winsock2.h>
699 # include <ws2tcpip.h>
700 #else
701 # include <sys/socket.h>
702 #endif]], [[socklen_t len; len = 0;]])],
703 ac_cv_type_socklen_t=yes,
704 ac_cv_type_socklen_t=no)])
705 AS_IF([test "$ac_cv_type_socklen_t" = no],
706 [AC_DEFINE(socklen_t, int)])
708 dnl Check for struct sockaddr_storage
709 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
710 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
711 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
712 [AC_TRY_COMPILE(
713 [#include <sys/types.h>
714 #if defined( _WIN32 )
715 # include <winsock2.h>
716 #else
717 # include <sys/socket.h>
718 #endif], [struct sockaddr_storage addr;],
719 ac_cv_struct_sockaddr_storage=yes,
720 ac_cv_struct_sockaddr_storage=no)])
721 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
722 AC_DEFINE(sockaddr_storage, sockaddr)
723 AC_DEFINE(ss_family, sa_family)
724 ])
726 dnl FreeBSD has a gnugetopt library for this:
727 GNUGETOPT_LIBS=""
728 AC_CHECK_FUNC(getopt_long,, [
729 AC_CHECK_LIB([gnugetopt],[getopt_long], [
730 GNUGETOPT_LIBS="-lgnugetopt"
731 ])
732 ])
733 AC_SUBST(GNUGETOPT_LIBS)
735 AC_CHECK_LIB(m,cos,[
736 LIBM="-lm"
737 ], [
738 LIBM=""
739 ])
740 AC_SUBST(LIBM)
742 AC_CHECK_LIB(m,lrintf, [
743 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
744 VLC_ADD_LIBS([skins2],[-lm])
745 ])
746 AC_CHECK_LIB(m,nanf,
747 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
748 )
749 AC_CHECK_LIB(m,sincos, [
750 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
751 ], [
752 AC_LIBOBJ([sincos])
753 ])
755 AC_MSG_CHECKING([_Thread_local support])
756 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
757 int main() {}])], [
758 AC_MSG_RESULT([ok])
759 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
760 ],[ AC_MSG_RESULT([no])])
762 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
763 dnl check for its availability explicitely
764 AC_CHECK_HEADERS([threads.h])
766 AC_CHECK_LIB([anl],[getaddrinfo_a],[
767 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
768 ])
770 dnl Check for dynamic plugins
771 LIBDL=""
772 have_dynamic_objects="no"
773 VLC_SAVE_FLAGS
774 AC_SEARCH_LIBS(dlsym, [dl svld], [
775 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
776 LIBDL="$ac_cv_search_dlsym"
777 ])
778 have_dynamic_objects="yes"
779 ])
780 VLC_RESTORE_FLAGS
782 # Windows
783 AS_IF([test "${SYS}" = "mingw32"], [
784 LIBDL=""
785 have_dynamic_objects="yes" #assume we can use shared objects
786 ])
788 AC_ARG_WITH([libfuzzer],
789 [AS_HELP_STRING([--with-libfuzzer=DIR],
790 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
791 [],
792 [with_libfuzzer=no])
793 AS_VAR_IF(with_libfuzzer, no, [], [
794 enable_shared=no
795 enable_static=yes
796 enable_vlc=no
797 ])
798 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
800 AS_IF([test "${enable_shared}" = "no"], [
801 have_dynamic_objects=no
802 ])
803 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
805 AC_SUBST(LIBDL)
807 dnl Check for thread library
808 LIBPTHREAD=""
809 AS_IF([test "${SYS}" != "mingw32"], [
810 VLC_SAVE_FLAGS
811 LIBS=""
812 AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
813 AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
814 LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
815 ])
816 ])
817 VLC_RESTORE_FLAGS
818 ])
819 AC_SUBST(LIBPTHREAD)
821 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
822 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
823 LIBRT="$ac_cv_search_clock_nanosleep"
824 ])
825 ], [
826 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
827 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
828 LIBRT="$ac_cv_search_nanosleep"
829 ])
830 ])
831 ])
832 AC_SUBST(LIBRT)
834 dnl
835 dnl Check for headers
836 dnl
838 dnl POSIX
839 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
840 AC_CHECK_HEADERS([net/if.h], [], [],
841 [
842 #include <sys/types.h>
843 #include <sys/socket.h>
844 ])
845 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
846 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
848 dnl BSD
849 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
851 dnl GNU/Linux
852 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
854 dnl MacOS
855 AC_CHECK_HEADERS([xlocale.h])
857 dnl Check if C++ headers define locale_t
858 AC_LANG_PUSH(C++)
859 AC_CACHE_CHECK([if C++ headers define locale_t],
860 [ac_cv_cxx_locale_t],
861 [ac_cv_cxx_locale_t=no
862 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
863 [ac_cv_cxx_locale_t=yes])])
864 if test "${ac_cv_cxx_locale_t}" != "no"; then
865 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
866 fi
867 AC_LANG_POP(C++)
869 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
870 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
871 AC_CHECK_TYPE(ssize_t,, [
872 AC_DEFINE(ssize_t, int)
873 ])
875 dnl It seems that autoconf detects pkg-config only during the first
876 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
877 dnl it is nested within a conditional block, so it was not working right.
878 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
879 AC_ARG_VAR(PKG_CONFIG_PATH,
880 [Paths where to find .pc not at the default location])
881 PKG_PROG_PKG_CONFIG()
883 dnl On some OS we need static linking
884 AS_IF([test -n "${PKG_CONFIG}" ],[
885 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
886 PKG_CONFIG="${PKG_CONFIG} --static"
887 ])
888 ])
891 dnl
892 dnl Check for zlib.h and -lz along with system -lminizip if available
893 dnl
894 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
895 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
896 if test "${have_zlib}" = "yes"
897 then
898 VLC_ADD_LIBS([sap],[-lz])
899 PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
900 AC_CHECK_HEADERS([unzip.h], [
901 have_minizip=yes
902 MINIZIP_LIBS="-lminizip -lz"
903 ], [
904 have_minizip=no
905 ])
906 ])
907 fi
908 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
911 dnl
912 dnl Domain name i18n support via GNU libidn
913 dnl
914 PKG_CHECK_MODULES([IDN], [libidn], [
915 have_libidn="yes"
916 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
917 ], [
918 have_libidn="no"
919 ])
922 dnl Check for dbus
923 AC_ARG_ENABLE(dbus,
924 [AS_HELP_STRING([--enable-dbus],
925 [compile D-Bus message bus support (default enabled)])])
926 have_dbus="no"
927 AS_IF([test "${enable_dbus}" != "no"], [
928 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
929 have_dbus="yes"
930 ], [
931 AS_IF([test -n "${enable_dbus}"], [
932 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
933 ], [
934 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
935 ])
936 ])
937 ])
938 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
941 dnl Check for systemd
942 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
943 have_systemd="yes"
944 ], [
945 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
946 ])
947 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
950 EXTEND_HELP_STRING([Optimization options:])
951 dnl
952 dnl Compiler warnings
953 dnl
955 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
956 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
958 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
959 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
961 dnl
962 dnl Debugging mode
963 dnl
964 AC_ARG_ENABLE(debug,
965 [AS_HELP_STRING([--enable-debug],
966 [build with run-time assertions (default disabled)])],,
967 [enable_debug="no"])
968 AH_TEMPLATE(NDEBUG,
969 [Define to 1 if debug code should NOT be compiled])
970 AS_IF([test "${enable_debug}" != "no"], [
971 AC_CHECK_HEADERS([valgrind/valgrind.h])
972 ], [
973 AC_DEFINE(NDEBUG)
974 ])
976 dnl
977 dnl Profiling
978 dnl
979 AC_ARG_ENABLE(gprof,
980 [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
981 [enable_gprof="no"])
982 AS_IF([test "${enable_gprof}" != "no"], [
983 CFLAGS="${CFLAGS} -pg"
984 CXXFLAGS="${CXXFLAGS} -pg"
985 OBJCFLAGS="${OBJCFLAGS} -pg"
986 LDFLAGS="${LDFLAGS} -pg"
987 ])
989 AC_ARG_ENABLE(cprof,
990 [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
991 [enable_cprof="no"])
992 AS_IF([test "${enable_gprof}" != "no"], [
993 CFLAGS="${CFLAGS} -finstrument-functions"
994 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
995 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
996 LDFLAGS="${LDFLAGS} -finstrument-functions"
997 ])
999 dnl
1000 dnl Test coverage
1001 dnl
1002 AC_ARG_ENABLE(coverage,
1003 [AS_HELP_STRING([--enable-coverage],
1004 [build for test coverage (default disabled)])],,
1005 [enable_coverage="no"])
1006 AS_IF([test "${enable_coverage}" != "no"], [
1007 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1008 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1009 LDFLAGS="-lgcov ${LDFLAGS}"
1010 ])
1012 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1013 VLC_SAVE_FLAGS
1014 CFLAGS="${CFLAGS} -fvisibility=hidden"
1015 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1016 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1017 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1018 [ac_cv_c_visibility_hidden], [
1019 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1020 ac_cv_c_visibility_hidden=yes
1021 ], [
1022 ac_cv_c_visibility_hidden=no
1023 ])
1024 ])
1025 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1026 ])
1028 dnl
1029 dnl Sanitizer flags
1030 dnl
1031 AC_ARG_WITH([sanitizer],
1032 [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1033 [build with sanitizer flags (default disabled)])],
1034 [],
1035 [with_sanitizer=no])
1037 AS_VAR_IF(with_sanitizer, no, [], [
1038 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1039 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1040 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1041 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1042 ], [
1043 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1044 ])
1045 AX_APPEND_FLAG([-g])
1046 AX_APPEND_FLAG([-g], [CXXFLAGS])
1048 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1049 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1050 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1051 ])
1052 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1053 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1054 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1055 ])
1056 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1057 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1058 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1059 ])
1060 ])
1062 dnl
1063 dnl Enable/disable optimizations
1064 dnl
1065 AC_ARG_ENABLE(optimizations,
1066 [AS_HELP_STRING([--disable-optimizations],
1067 [disable compiler optimizations (default enabled)])],,
1068 [enable_optimizations="yes"])
1070 dnl Check for various optimization flags
1071 AS_IF([test "${enable_optimizations}" != "no"], [
1073 dnl -O3 only in production builds
1074 AS_IF([test "${enable_debug}" = "no"], [
1075 VLC_SAVE_FLAGS
1076 CFLAGS="${CFLAGS} -O3"
1077 CXXFLAGS="${CXXFLAGS} -O3"
1078 OBJCFLAGS="${OBJCFLAGS} -O3"
1079 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1080 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1081 ac_cv_c_o3=yes
1082 ], [
1083 ac_cv_c_o3=no
1084 ])
1085 ])
1086 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1087 ])
1089 dnl Check for fast maths
1090 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1091 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1093 AH_BOTTOM([
1094 #if defined(_MSC_VER) && !defined(__clang__)
1095 # pragma fenv_access(off)
1096 # pragma fp_contract(on)
1097 #elif defined(__GNUC__)
1098 /* Not supported so far */
1099 #else
1100 # pragma STDC FENV_ACCESS OFF
1101 # pragma STDC FP_CONTRACT ON
1102 #endif
1103 ])
1105 dnl Check for -funroll-loops
1106 VLC_SAVE_FLAGS
1107 CFLAGS="${CFLAGS} -funroll-loops"
1108 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1109 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1110 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1111 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1112 ac_cv_c_unroll_loops=yes
1113 ], [
1114 ac_cv_c_unroll_loops=no
1115 ])
1116 ])
1117 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1119 AS_IF([test "$enable_debug" = "no"], [
1120 dnl Check for -fomit-frame-pointer
1121 VLC_SAVE_FLAGS
1122 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1123 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1124 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1125 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1126 [ac_cv_c_omit_frame_pointer], [
1127 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1128 ac_cv_c_omit_frame_pointer=yes
1129 ], [
1130 ac_cv_c_omit_frame_pointer=no
1131 ])
1132 ])
1133 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1134 ])
1136 VLC_SAVE_FLAGS
1137 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1138 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1139 dnl Win32 requires linking to ssp for stack-protection
1140 AS_IF([test "${SYS}" = "mingw32"], [
1141 LDFLAGS="${LDFLAGS} -lssp"
1142 AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1143 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1144 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1145 ac_cv_ld_ssp="yes"
1146 ], [
1147 ac_cv_ld_ssp="no"
1148 ])
1149 ])
1150 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1151 ])
1152 ])
1154 VLC_SAVE_FLAGS
1155 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1156 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1157 AC_TRY_LINK([],, [
1158 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1159 ], [
1160 ac_cv_ld_bsymbolic=""
1161 ])
1162 ])
1163 VLC_RESTORE_FLAGS
1164 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1165 AC_SUBST(SYMBOLIC_LDFLAGS)
1167 VLC_SAVE_FLAGS
1168 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1169 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1170 AC_TRY_LINK([],, [
1171 ac_cv_ld_z_defs="yes"
1172 ], [
1173 ac_cv_ld_z_defs="no"
1174 ])
1175 ])
1176 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1178 dnl Check for __attribute__((packed))
1179 AC_CACHE_CHECK([for __attribute__((packed))],
1180 [ac_cv_c_attribute_packed],
1181 [ac_cv_c_attribute_packed=no
1182 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1183 [ac_cv_c_attribute_packed=yes])])
1184 if test "${ac_cv_c_attribute_packed}" != "no"; then
1185 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1186 fi
1188 dnl
1189 dnl Check the CPU
1190 dnl
1191 case "${host_cpu}" in
1192 "")
1193 ARCH=unknown
1194 ;;
1195 armv*)
1196 ARCH="arm"
1197 host_cpu="arm"
1198 ;;
1199 *)
1200 ARCH="${host_cpu}"
1201 ;;
1202 esac
1204 dnl Check for backtrace() support
1205 AC_CHECK_HEADERS(execinfo.h)
1206 AC_CHECK_FUNCS(backtrace)
1208 dnl
1209 dnl default modules
1210 dnl
1211 ALIASES="${ALIASES} cvlc rvlc"
1213 dnl
1214 dnl Accelerated modules
1215 dnl
1217 dnl Check for fully working MMX intrinsics
1218 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1219 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1220 AC_ARG_ENABLE(mmx,
1221 [AS_HELP_STRING([--disable-mmx],
1222 [disable MMX optimizations (default auto)])],,[
1223 case "${host_cpu}" in
1224 i?86|x86_64)
1225 enable_mmx="yes"
1226 ;;
1227 *)
1228 enable_mmx="no"
1229 ;;
1230 esac
1231 ])
1232 have_mmx="no"
1233 have_mmxext="no"
1234 AS_IF([test "${enable_mmx}" != "no"], [
1235 ARCH="${ARCH} mmx"
1236 VLC_SAVE_FLAGS
1237 CFLAGS="${CFLAGS} -mmmx"
1238 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1240 [#include <mmintrin.h>
1241 #include <stdint.h>
1242 uint64_t frobzor;]], [
1243 [__m64 a, b, c;
1244 a = b = c = (__m64)frobzor;
1245 a = _mm_slli_pi16(a, 3);
1246 a = _mm_adds_pi16(a, b);
1247 c = _mm_srli_pi16(c, 8);
1248 c = _mm_slli_pi16(c, 3);
1249 b = _mm_adds_pi16(b, c);
1250 a = _mm_unpacklo_pi8(a, b);
1251 frobzor = (uint64_t)a;]])], [
1252 ac_cv_c_mmx_intrinsics=yes
1253 ], [
1254 ac_cv_c_mmx_intrinsics=no
1255 ])
1256 ])
1257 VLC_RESTORE_FLAGS
1258 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1259 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1260 ])
1262 VLC_SAVE_FLAGS
1263 CFLAGS="${CFLAGS} -mmmx"
1264 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1266 void *p;
1267 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1268 ]])
1269 ], [
1270 ac_cv_mmx_inline=yes
1271 ], [
1272 ac_cv_mmx_inline=no
1273 ])
1274 ])
1275 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1276 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1277 have_mmx="yes"
1278 ])
1280 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1281 [ac_cv_mmxext_inline], [
1282 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1283 void *p;
1284 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1285 ]])
1286 ], [
1287 ac_cv_mmxext_inline=yes
1288 ], [
1289 ac_cv_mmxext_inline=no
1290 ])
1291 ])
1292 VLC_RESTORE_FLAGS
1293 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1294 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1295 have_mmxext="yes"
1296 ])
1297 ])
1298 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1299 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1301 dnl Check for fully workin SSE2 intrinsics
1302 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1303 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1304 AC_ARG_ENABLE(sse,
1305 [AS_HELP_STRING([--disable-sse],
1306 [disable SSE (1-4) optimizations (default auto)])],, [
1307 case "${host_cpu}" in
1308 i?86|x86_64)
1309 enable_sse=yes
1310 ;;
1311 *)
1312 enable_sse=no
1313 ;;
1314 esac
1315 ])
1316 have_sse2="no"
1317 AS_IF([test "${enable_sse}" != "no"], [
1318 ARCH="${ARCH} sse sse2"
1320 VLC_SAVE_FLAGS
1321 CFLAGS="${CFLAGS} -msse2"
1322 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1323 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1324 [#include <emmintrin.h>
1325 #include <stdint.h>
1326 uint64_t frobzor;]], [
1327 [__m128i a, b, c;
1328 a = b = c = _mm_set1_epi64((__m64)frobzor);
1329 a = _mm_slli_epi16(a, 3);
1330 a = _mm_adds_epi16(a, b);
1331 c = _mm_srli_epi16(c, 8);
1332 c = _mm_slli_epi16(c, 3);
1333 b = _mm_adds_epi16(b, c);
1334 a = _mm_unpacklo_epi8(a, b);
1335 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1336 ac_cv_c_sse2_intrinsics=yes
1337 ], [
1338 ac_cv_c_sse2_intrinsics=no
1339 ])
1340 ])
1341 VLC_RESTORE_FLAGS
1342 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1343 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1344 ])
1346 VLC_SAVE_FLAGS
1347 CFLAGS="${CFLAGS} -msse"
1348 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1349 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1350 void *p;
1351 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1352 ]])
1353 ], [
1354 ac_cv_sse_inline=yes
1355 ], [
1356 ac_cv_sse_inline=no
1357 ])
1358 ])
1360 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1361 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1362 ])
1364 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1366 void *p;
1367 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1368 ]])
1369 ], [
1370 ac_cv_sse2_inline=yes
1371 ], [
1372 ac_cv_sse2_inline=no
1373 ])
1374 ])
1375 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1376 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1377 have_sse2="yes"
1378 ])
1380 # SSE3
1381 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1382 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1383 void *p;
1384 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1385 ]])
1386 ], [
1387 ac_cv_sse3_inline=yes
1388 ], [
1389 ac_cv_sse3_inline=no
1390 ])
1391 ])
1393 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1394 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1395 # SSSE3
1396 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1397 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1398 void *p;
1399 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1400 ]])
1401 ], [
1402 ac_cv_ssse3_inline=yes
1403 ], [
1404 ac_cv_ssse3_inline=no
1405 ])
1406 ])
1408 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1409 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1411 # SSE4.1
1412 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1413 [ac_cv_sse4_1_inline], [
1414 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1415 void *p;
1416 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1417 ]])
1418 ], [
1419 ac_cv_sse4_1_inline=yes
1420 ], [
1421 ac_cv_sse4_1_inline=no
1422 ])
1423 ])
1425 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1426 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1428 # SSE4.2
1429 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1430 [ac_cv_sse4_2_inline], [
1431 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1432 void *p;
1433 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1434 ]])
1435 ], [
1436 ac_cv_sse4_2_inline=yes
1437 ], [
1438 ac_cv_sse4_2_inline=no
1439 ])
1440 ])
1442 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1443 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1445 # SSE4A
1446 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1447 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1448 void *p;
1449 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1450 ]])
1451 ], [
1452 ac_cv_sse4a_inline=yes
1453 ], [
1454 ac_cv_sse4a_inline=no
1455 ])
1456 ])
1457 VLC_RESTORE_FLAGS
1458 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1459 AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1460 ])
1461 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1463 VLC_SAVE_FLAGS
1464 CFLAGS="${CFLAGS} -mmmx"
1465 have_3dnow="no"
1466 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1467 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1468 void *p;
1469 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1470 ]])
1471 ], [
1472 ac_cv_3dnow_inline=yes
1473 ], [
1474 ac_cv_3dnow_inline=no
1475 ])
1476 ])
1477 VLC_RESTORE_FLAGS
1478 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1479 AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1480 [Define to 1 if 3D Now! inline assembly is available.])
1481 have_3dnow="yes"
1482 ])
1483 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1486 AC_ARG_ENABLE(neon,
1487 [AS_HELP_STRING([--disable-neon],
1488 [disable NEON optimizations (default auto)])],, [
1489 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1490 ])
1491 AS_IF([test "${enable_neon}" != "no"], [
1492 VLC_SAVE_FLAGS
1493 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1494 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1495 AC_COMPILE_IFELSE([
1496 AC_LANG_PROGRAM(,[[
1497 asm volatile("vqmovun.s64 d0, q1":::"d0");
1498 ]])
1499 ], [
1500 ac_cv_arm_neon="yes"
1501 ], [
1502 ac_cv_arm_neon="no"
1503 ])
1504 ])
1505 VLC_RESTORE_FLAGS
1506 ])
1507 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1509 AC_ARG_ENABLE(arm64,
1510 [AS_HELP_STRING([--disable-arm64],
1511 [disable arm 64-bit optimizations (default auto)])],, [
1512 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1513 ])
1514 AS_IF([test "${enable_arm64}" != "no"], [
1515 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1516 AC_COMPILE_IFELSE([
1517 AC_LANG_PROGRAM(,[[
1518 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1519 ]])
1520 ], [
1521 ac_cv_arm64="yes"
1522 ], [
1523 ac_cv_arm64="no"
1524 ])
1525 ])
1526 ])
1527 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1530 AC_ARG_ENABLE(altivec,
1531 [AS_HELP_STRING([--disable-altivec],
1532 [disable AltiVec optimizations (default auto)])],, [
1533 AS_CASE("${host_cpu}", [powerpc*],
1534 [enable_altivec=yes], [enable_altivec=no])
1535 ])
1536 have_altivec="no"
1537 ALTIVEC_CFLAGS=""
1538 AS_IF([test "${enable_altivec}" = "yes"], [
1539 ARCH="${ARCH} altivec";
1540 VLC_SAVE_FLAGS
1541 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1542 [ac_cv_altivec_inline],
1543 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1544 ac_cv_altivec_inline="yes",
1545 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1546 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1547 [ac_cv_altivec_inline="-Wa,-maltivec"],
1548 ac_cv_altivec_inline=no)
1549 ])])
1550 VLC_RESTORE_FLAGS
1551 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1552 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1553 [Define to 1 if AltiVec inline assembly is available.])
1554 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1555 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1556 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1557 ])
1558 have_altivec="yes"
1559 ])
1561 VLC_SAVE_FLAGS
1562 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1563 [ac_cv_c_altivec], [
1564 CFLAGS="${CFLAGS} -maltivec"
1565 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1566 [#include <altivec.h>]], [
1567 [vec_ld(0, (unsigned char *)0);]])], [
1568 ac_cv_c_altivec="-maltivec"
1569 ], [
1570 ac_cv_c_altivec="no"
1571 ])
1572 ])
1573 VLC_RESTORE_FLAGS
1574 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1575 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1576 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1577 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1578 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1579 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1580 have_altivec="yes"
1581 ])
1582 AC_CHECK_HEADERS(altivec.h)
1584 VLC_SAVE_FLAGS
1585 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1586 AC_CACHE_CHECK([if linker needs -framework vecLib],
1587 [ac_cv_ld_altivec],
1588 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1589 VLC_RESTORE_FLAGS
1590 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1591 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1592 ])
1593 ])
1594 AC_SUBST(ALTIVEC_CFLAGS)
1595 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1597 dnl
1598 dnl Memory usage
1599 dnl
1600 AC_ARG_ENABLE(optimize-memory,
1601 [AS_HELP_STRING([--enable-optimize-memory],
1602 [optimize memory usage over performance])])
1603 if test "${enable_optimize_memory}" = "yes"; then
1604 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1605 fi
1607 dnl
1608 dnl Allow running as root (useful for people running on embedded platforms)
1609 dnl
1610 AC_ARG_ENABLE(run-as-root,
1611 [AS_HELP_STRING([--enable-run-as-root],
1612 [allow running VLC as root (default disabled)])])
1613 AS_IF([test "${enable_run_as_root}" = "yes"],[
1614 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1615 [Define to 1 to allow running VLC as root (uid 0).])
1616 ])
1618 dnl
1619 dnl Stream output
1620 dnl
1621 AC_ARG_ENABLE(sout,
1622 [AS_HELP_STRING([--disable-sout],
1623 [disable streaming output (default enabled)])])
1624 AS_IF([test "${enable_sout}" != "no"], [
1625 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1626 ])
1627 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1629 dnl Lua modules
1630 AC_ARG_ENABLE(lua,
1631 [AS_HELP_STRING([--disable-lua],
1632 [disable LUA scripting support (default enabled)])])
1633 if test "${enable_lua}" != "no"
1634 then
1635 PKG_CHECK_MODULES(LUA, lua5.2,
1636 [ have_lua=yes ],
1637 [
1638 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1640 PKG_CHECK_MODULES(LUA, lua5.1,
1641 [ have_lua=yes ],
1642 [
1643 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1644 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1645 [ have_lua=yes ],
1646 [
1647 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1648 have_lua=yes
1649 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1650 [],
1651 [ have_lua=no ] )
1652 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1653 [LUA_LIBS="-llua5.2"],
1654 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1655 [LUA_LIBS="-llua5.1"],
1656 AC_CHECK_LIB( lua51 , luaL_newstate,
1657 [LUA_LIBS="-llua51"],
1658 AC_CHECK_LIB( lua , luaL_newstate,
1659 [LUA_LIBS="-llua"],
1660 [ have_lua=no
1661 ], [-lm])
1662 )))
1663 ])
1664 ])
1665 ])
1666 if test "x${have_lua}" != "xyes" ; then
1667 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1668 fi
1669 AC_ARG_VAR([LUAC], [LUA byte compiler])
1670 AS_IF([test -z "$LUAC"], [
1671 AC_CHECK_TOOL(LUAC, [luac], [false])
1672 ])
1673 AS_IF([test "${LUAC}" = "false"], [
1674 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1675 ])
1676 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1677 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1678 ])
1679 fi
1680 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1683 dnl
1684 dnl VideoLAN manager
1685 dnl
1686 AC_ARG_ENABLE(vlm,
1687 [AS_HELP_STRING([--disable-vlm],
1688 [disable the stream manager (default enabled)])],,
1689 [enable_vlm="${enable_sout}"])
1690 AS_IF([test "${enable_vlm}" != "no"], [
1691 AS_IF([test "${enable_sout}" = "no"], [
1692 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1693 ])
1694 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1695 ])
1696 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1699 dnl
1700 dnl Addons manager storage and repositories modules
1701 dnl
1702 AC_ARG_ENABLE(addonmanagermodules,
1703 [AS_HELP_STRING([--disable-addonmanagermodules],
1704 [disable the addons manager modules (default enabled)])])
1705 if test "${enable_addonmanagermodules}" != "no"
1706 then
1707 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1708 fi
1709 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1712 dnl
1713 dnl Input plugins
1714 dnl
1716 EXTEND_HELP_STRING([Input plugins:])
1718 dnl
1719 dnl libarchive access module
1720 dnl
1721 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1723 dnl
1724 dnl live555 input
1725 dnl
1726 AC_ARG_ENABLE(live555,
1727 [AS_HELP_STRING([--enable-live555],
1728 [enable RTSP input through live555 (default enabled)])])
1730 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1731 PKG_CHECK_MODULES(LIVE555, live555, [
1732 VLC_ADD_PLUGIN([live555])
1733 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1734 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1735 ], [
1736 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1738 AC_LANG_PUSH(C++)
1739 VLC_SAVE_FLAGS
1741 dnl detect include paths
1742 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1743 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1744 ], [
1745 AS_IF([test "${SYS}" != "os2"], [
1746 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1747 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1748 ], [
1749 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1750 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1751 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1752 ])
1753 ])
1755 dnl CPP Flags
1756 AS_IF([test "${SYS}" = "solaris"], [
1757 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1758 ])
1759 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1760 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1762 dnl version check
1763 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1764 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1765 [#include <liveMedia_version.hh>
1766 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1767 # error BOOM
1768 #endif]])
1769 ], [
1770 ac_cv_live555="yes"
1771 ], [
1772 ac_cv_live555="no"
1773 ])
1774 ])
1776 AS_IF([test "$ac_cv_live555" = "no"], [
1777 AC_MSG_WARN([live555 is missing or its installed version is too old:
1778 Version 2011.12.23 or later is required to proceed.
1779 You can get an updated one from http://www.live555.com/liveMedia .])
1780 AS_IF([test -n "${enable_live555}"], [
1781 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1782 ])
1783 ], [
1784 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1785 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1786 AS_IF([test "${SYS}" = "mingw32"], [
1787 # add ws2_32 for closesocket, select, recv
1788 other_libs="$other_libs -lws2_32"
1789 ])
1791 dnl We need to check for pic because live555 don't provide shared libs
1792 dnl and we want to build a plugins so we need -fPIC on some arch.
1793 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1794 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1795 AC_CHECK_LIB(liveMedia_pic, main, [
1796 VLC_ADD_PLUGIN([live555])
1797 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1798 ],[
1799 AC_CHECK_LIB(liveMedia, main, [
1800 VLC_ADD_PLUGIN([live555])
1801 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1802 ],[],[${other_libs}])
1803 ],[${other_libs_pic}])
1804 ])
1805 VLC_RESTORE_FLAGS
1806 AC_LANG_POP(C++)
1807 ])
1808 ])
1810 dnl
1811 dnl IIDC and DV FireWire input modules
1812 dnl
1813 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1814 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1816 dnl
1817 dnl - linsys modules: access module check for libzvbi
1818 dnl
1819 AC_ARG_ENABLE(linsys,
1820 [AS_HELP_STRING([--enable-linsys],
1821 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1822 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1823 VLC_ADD_PLUGIN([linsys_hdsdi])
1824 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1825 VLC_ADD_PLUGIN([linsys_sdi])
1826 ], [
1827 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1828 ])
1829 ])
1831 dnl
1832 dnl dvdread module: check for libdvdread
1833 dnl
1834 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1836 dnl
1837 dnl libdvdnav plugin
1838 dnl
1839 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1840 AS_IF([test "${enable_dvdnav}" != "no"], [
1841 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1842 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1843 AC_MSG_RESULT(yes)
1844 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1845 ],[
1846 AC_MSG_RESULT(no)
1847 ])
1848 ])
1850 dnl
1851 dnl Blu-ray Disc Support with libbluray
1852 dnl
1853 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1855 dnl
1856 dnl OpenCV wrapper and example filters
1857 dnl
1858 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1861 dnl
1862 dnl libsmbclient plugin
1863 dnl
1864 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1865 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1867 dnl
1868 dnl liBDSM access module
1869 dnl
1870 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1872 dnl
1873 dnl sftp access support
1874 dnl
1875 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1877 dnl
1878 dnl nfs access support
1879 dnl
1880 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1882 dnl
1883 dnl Video4Linux 2
1884 dnl
1885 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1886 [disable Video4Linux version 2 (default auto)])])
1887 have_v4l2="no"
1888 AS_IF([test "$enable_v4l2" != "no"], [
1889 AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1890 have_v4l2="yes"
1891 ])
1892 ])
1893 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1895 dnl
1896 dnl special access module for Blackmagic SDI cards
1897 dnl
1898 AC_ARG_ENABLE(decklink,
1899 [AS_HELP_STRING([--disable-decklink],
1900 [disable Blackmagic DeckLink SDI input (default auto)])])
1901 AC_ARG_WITH(decklink_sdk,
1902 [AS_HELP_STRING[--with-decklink-sdk=DIR],
1903 [ location of Blackmagic DeckLink SDI SDK])])
1904 have_decklink=no
1905 if test "${enable_decklink}" != "no"
1906 then
1907 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1908 then
1909 VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1910 fi
1911 VLC_SAVE_FLAGS
1912 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1913 AC_LANG_PUSH(C++)
1914 AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1915 have_decklink=yes
1916 ], [
1917 AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1918 ])
1919 AC_LANG_POP(C++)
1920 VLC_RESTORE_FLAGS
1921 fi
1922 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1925 dnl
1926 dnl Built-in CD-DA and VCD module
1927 dnl
1928 AC_ARG_ENABLE(vcd,
1929 [AS_HELP_STRING([--disable-vcd],
1930 [disable built-in VCD and CD-DA support (default enabled)])])
1932 AC_ARG_ENABLE(libcddb,
1933 [AS_HELP_STRING([--disable-libcddb],
1934 [disable CDDB for Audio CD (default enabled)])])
1936 if test "${enable_vcd}" != "no"
1937 then
1938 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1939 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1940 AC_MSG_RESULT(yes)
1941 VLC_ADD_PLUGIN([vcd cdda])
1942 ],[
1943 AC_MSG_RESULT(no)
1944 ])
1946 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1947 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1948 AC_MSG_RESULT(yes)
1949 VLC_ADD_PLUGIN([vcd cdda])
1950 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1951 ],[
1952 AC_MSG_RESULT(no)
1953 ])
1955 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1956 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1957 AC_MSG_RESULT(yes)
1958 VLC_ADD_PLUGIN([vcd cdda])
1959 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1960 ],[
1961 AC_MSG_RESULT(no)
1962 ])
1964 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1965 then
1966 VLC_ADD_PLUGIN([vcd cdda])
1967 fi
1969 if test "$enable_libcddb" != "no"; then
1970 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1971 HAVE_LIBCDDB=yes
1972 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1973 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1974 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1975 ],:
1976 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1977 HAVE_LIBCDDB=no])
1978 fi
1979 fi
1981 dnl
1982 dnl Linux DVB
1983 dnl
1984 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1985 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1986 [#include <linux/dvb/version.h>
1987 #if (DVB_API_VERSION < 5)
1988 # error Linux DVB API v3.2 and older are not supported.
1989 #endif
1990 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1991 # error Linux DVB API v5.0 is unsupported. Please update.
1992 #endif
1993 ]])], [
1994 ac_cv_linux_dvb_5_1=yes
1995 ], [
1996 ac_cv_linux_dvb_5_1=no
1997 ])])
1998 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
2000 dnl
2001 dnl Screen capture module
2002 dnl
2003 AC_ARG_ENABLE(screen,
2004 [AS_HELP_STRING([--enable-screen],
2005 [disable screen capture (default enabled)])])
2006 if test "${enable_screen}" != "no"; then
2007 if test "${SYS}" = "darwin"; then
2008 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2009 VLC_ADD_PLUGIN([screen])
2010 ])
2011 fi
2012 fi
2013 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2015 dnl
2016 dnl VNC/RFB access module
2017 dnl
2018 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2020 dnl RDP/Remote Desktop access module
2021 dnl
2022 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2024 dnl
2025 dnl Real RTSP plugin
2026 dnl
2027 AC_ARG_ENABLE(realrtsp,
2028 [ --enable-realrtsp Real RTSP module (default disabled)])
2029 if test "${enable_realrtsp}" = "yes"; then
2030 VLC_ADD_PLUGIN([access_realrtsp])
2031 fi
2033 dnl
2034 dnl QTKit
2035 AC_ARG_ENABLE(macosx-qtkit,
2036 [ --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2037 if test "x${enable_macosx_qtkit}" != "xno" &&
2038 (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2039 then
2040 AC_CHECK_HEADERS(QTKit/QTKit.h, [
2041 VLC_ADD_PLUGIN([qtsound])
2042 ])
2043 fi
2045 dnl
2046 dnl AVFoundation
2047 AC_SUBST(have_avfoundation, ["no"])
2048 AC_ARG_ENABLE(macosx-avfoundation,
2049 [ --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2050 if test "x${enable_macosx_avfoundation}" != "xno" &&
2051 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2052 then
2053 SAVED_LIBS="${LIBS}"
2054 LIBS="-framework AVFoundation"
2055 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2056 LIBS="${SAVED_LIBS}"
2057 if test "${have_avfoundation}" != "no"
2058 then
2059 VLC_ADD_PLUGIN([avcapture])
2060 fi
2061 fi
2062 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2064 dnl
2065 dnl DCP plugin (using asdcplib)
2066 dnl
2067 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2068 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2070 dnl
2071 dnl Demux plugins
2072 dnl
2074 EXTEND_HELP_STRING([Mux/Demux plugins:])
2076 dnl
2077 dnl libdvbpsi check for ts mux/demux
2078 dnl
2079 have_dvbpsi="no"
2080 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2081 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2084 dnl
2085 dnl GME demux plugin
2086 dnl
2087 AC_ARG_ENABLE(gme,
2088 [AS_HELP_STRING([--enable-gme],
2089 [use Game Music Emu (default auto)])])
2090 AS_IF([test "${enable_gme}" != "no"], [
2091 AC_CHECK_HEADER([gme/gme.h], [
2092 AC_CHECK_LIB([gme], [gme_identify_header], [
2093 VLC_ADD_PLUGIN([gme])
2094 ], [
2095 AC_CHECK_LIB([gme], [gme_identify_extension], [
2096 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2097 VLC_ADD_PLUGIN([gme])
2098 ],, [-lstdc++ $LIBM])
2099 ])
2100 VLC_ADD_LIBS([gme], [-lgme])
2101 ], [
2102 AS_IF([test "x${enable_gme}" != "x"], [
2103 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2104 ])
2105 ])
2106 ])
2109 dnl
2110 dnl SIDPlay plugin
2111 dnl
2112 AC_ARG_ENABLE(sid,
2113 [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2114 AS_IF([test "${enable_sid}" != "no"], [
2115 PKG_CHECK_MODULES(SID, [libsidplay2], [
2116 AC_LANG_PUSH(C++)
2117 oldCPPFLAGS="$CPPFLAGS"
2118 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2119 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2120 VLC_ADD_PLUGIN([sid])
2121 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2122 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2123 ], [
2124 AS_IF([test -n "${enable_sid}"],
2125 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2126 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2127 )
2128 ])
2129 CPPFLAGS="$oldCPPFLAGS"
2130 AC_LANG_POP(C++)
2131 ], [
2132 AS_IF([test "x${enable_sid}" = "xyes"],
2133 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2134 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2135 )
2136 ])
2137 ])
2140 dnl
2141 dnl ogg demux plugin
2142 dnl
2143 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2144 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2145 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2146 ],[true])
2147 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2148 if test "${enable_sout}" != "no"; then
2149 dnl Check for libshout
2150 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2151 fi
2153 dnl
2154 dnl matroska demux plugin
2155 dnl
2156 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2157 VLC_ADD_PLUGIN([mkv])
2158 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2159 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2160 have_matroska="yes"
2161 ],,[MKV format support], [auto])
2162 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2164 dnl
2165 dnl modplug demux plugin
2166 dnl
2167 AC_ARG_ENABLE(mod,
2168 [AS_HELP_STRING([--disable-mod],
2169 [do not use libmodplug (default auto)])])
2170 if test "${enable_mod}" != "no" ; then
2171 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2172 VLC_ADD_PLUGIN([mod])
2173 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2174 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2175 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2176 ],[
2177 AS_IF([test -n "${enable_mod}"],
2178 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2179 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2180 ])
2181 fi
2183 dnl
2184 dnl mpc demux plugin
2185 dnl
2186 AC_ARG_ENABLE(mpc,
2187 [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2188 if test "${enable_mpc}" != "no"
2189 then
2190 AC_CHECK_HEADERS([mpc/mpcdec.h], [
2191 VLC_ADD_PLUGIN([mpc])
2192 VLC_ADD_LIBS([mpc],[-lmpcdec])],
2193 [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2194 VLC_ADD_PLUGIN([mpc])
2195 VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2196 fi
2198 dnl
2199 dnl Codec plugins
2200 dnl
2202 EXTEND_HELP_STRING([Codec plugins:])
2204 dnl
2205 dnl wmafixed plugin
2206 dnl
2207 AC_ARG_ENABLE(wma-fixed,
2208 [ --enable-wma-fixed libwma-fixed module (default disabled)])
2209 if test "${enable_wma_fixed}" = "yes"
2210 then
2211 VLC_ADD_PLUGIN([wma_fixed])
2212 fi
2214 dnl
2215 dnl shine encoder plugin
2216 dnl
2217 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2220 dnl
2221 dnl openmax il codec plugin
2222 dnl
2223 AC_ARG_ENABLE(omxil,
2224 [ --enable-omxil openmax il codec module (default disabled)])
2225 if test "${enable_omxil}" = "yes"
2226 then
2227 VLC_ADD_PLUGIN([omxil])
2228 fi
2230 dnl
2231 dnl raspberry pi openmax il configuration
2232 dnl
2233 AC_ARG_ENABLE(rpi-omxil,
2234 [ --enable-rpi-omxil openmax il configured for raspberry pi (default disabled)])
2235 if test "${enable_rpi_omxil}" = "yes"
2236 then
2237 VLC_ADD_PLUGIN([omxil])
2238 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2239 fi
2241 dnl
2242 dnl CrystalHD codec plugin
2243 dnl
2244 AC_ARG_ENABLE(crystalhd,
2245 [ --enable-crystalhd crystalhd codec plugin (default auto)])
2246 if test "${enable_crystalhd}" != "no"; then
2247 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2248 VLC_ADD_PLUGIN([crystalhd])
2249 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2250 ],[
2251 if test "${SYS}" = "mingw32" ; then
2252 AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2253 VLC_ADD_PLUGIN([crystalhd])
2254 AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2255 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2256 ])
2257 ],[
2258 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2259 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2260 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2261 ],[#define __LINUX_USER__
2262 #include <libcrystalhd/bc_dts_types.h>
2263 ])
2264 fi
2265 ],[
2266 #include <libcrystalhd/bc_dts_types.h>
2267 ])
2268 fi
2270 dnl
2271 dnl mad plugin
2272 dnl
2273 have_mad="no"
2274 MAD_CFLAGS=""
2275 MAD_LIBS=""
2277 AC_ARG_WITH(mad, [ --with-mad=PATH path to libmad], [
2278 enable_mad="yes"
2279 ], [
2280 with_mad="no"
2281 ])
2282 AS_IF([test "${with_mad}" != "no"], [
2283 MAD_CFLAGS="-I${with_mad}/include"
2284 MAD_LIBS="-L${with_mad}/lib"
2285 ])
2287 AC_ARG_ENABLE(mad,
2288 [ --enable-mad libmad module (default enabled)])
2289 AS_IF([test "${enable_mad}" != "no"], [
2290 VLC_SAVE_FLAGS
2291 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2292 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2293 AC_CHECK_HEADERS(mad.h, [
2294 AC_CHECK_LIB(mad, mad_bit_init, [
2295 have_mad="yes"
2296 MAD_LIBS="${MAD_LIBS} -lmad"
2297 ])
2298 ])
2299 VLC_RESTORE_FLAGS
2300 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2301 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2302 ])
2303 ])
2304 AC_SUBST(MAD_CFLAGS)
2305 AC_SUBST(MAD_LIBS)
2306 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2308 dnl mpg123 plugin
2309 dnl
2310 dnl
2311 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2313 dnl
2314 dnl gstreamer stuff
2315 dnl
2316 AC_ARG_ENABLE(gst-decode,
2317 [ --enable-gst-decode GStreamer based decoding support (currently supports only video decoding) (default auto)])
2319 have_gst_decode="no"
2320 AS_IF([test "${enable_gst_decode}" != "no"], [
2321 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2322 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2323 have_gst_decode="yes"
2324 ], [
2325 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2326 ])
2327 ], [
2328 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2329 ])
2330 ])
2331 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2333 dnl
2334 dnl avcodec decoder/encoder plugin
2335 dnl
2336 AC_ARG_ENABLE(merge-ffmpeg,
2337 [ --enable-merge-ffmpeg merge FFmpeg-based plugins (default disabled)],, [
2338 enable_merge_ffmpeg="no"
2339 ])
2340 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2342 AC_MSG_CHECKING([for libavutil variant])
2343 PKG_CHECK_EXISTS([libavutil], [
2344 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2345 libavutil_micro="${libavutil_version##*.}"
2346 AS_IF([test ${libavutil_micro} -le 99], [
2347 avfork="libav"
2348 ], [
2349 avfork="ffmpeg"
2350 ])
2351 ], [
2352 avfork="none"
2353 ])
2354 AC_MSG_RESULT([${avfork}])
2356 AC_ARG_ENABLE(avcodec,
2357 [ --enable-avcodec libavcodec codec (default enabled)])
2358 AS_IF([test "${enable_avcodec}" != "no"], [
2359 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2360 case "${avfork}" in
2361 libav) av_codec_ver="57.16.0" ;;
2362 ffmpeg) av_codec_ver="57.37.100" ;;
2363 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2364 esac
2365 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2366 VLC_SAVE_FLAGS
2367 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2368 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2369 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2370 AC_CHECK_HEADERS(libavutil/avutil.h)
2371 VLC_RESTORE_FLAGS
2372 have_avcodec="yes"
2373 ],[
2374 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2375 ])
2376 ], [
2377 have_avcodec="no"
2378 ])
2379 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2381 dnl
2382 dnl libva needs avcodec
2383 dnl
2384 AC_ARG_ENABLE(libva,
2385 [ --enable-libva VAAPI GPU decoding support (libVA) (default auto)])
2387 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2388 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2389 ])
2391 have_vaapi="no"
2392 have_vaapi_drm="no"
2393 have_vaapi_x11="no"
2394 have_vaapi_wl="no"
2395 AS_IF([test "${enable_libva}" != "no"], [
2396 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2397 have_vaapi="yes"
2398 ], [
2399 AS_IF([test -n "${enable_libva}"], [
2400 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2401 ], [
2402 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2403 ])
2404 ])
2405 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2406 have_vaapi_drm="yes"
2407 ], [
2408 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2409 ])
2410 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2411 have_vaapi_x11="yes"
2412 ], [
2413 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2414 ])
2415 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2416 have_vaapi_wl="yes"
2417 ], [
2418 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2419 ])
2420 ])
2421 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2422 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2423 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2424 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2426 have_avcodec_vaapi="no"
2427 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2428 VLC_SAVE_FLAGS
2429 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2430 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2431 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2432 AC_MSG_NOTICE([VA API acceleration activated])
2433 have_avcodec_vaapi="yes"
2434 ],[
2435 AS_IF([test -n "${enable_libva}"], [
2436 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2437 ], [
2438 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2439 ])
2440 ])
2441 VLC_RESTORE_FLAGS
2442 ])
2443 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2445 dnl
2446 dnl dxva2 needs avcodec
2447 dnl
2448 AC_ARG_ENABLE(dxva2,
2449 [ --enable-dxva2 DxVA2 GPU decoding support (default auto)])
2451 have_avcodec_dxva2="no"
2452 AS_IF([test "${enable_dxva2}" != "no"], [
2453 if test "${SYS}" = "mingw32"; then
2454 AS_IF([test "x${have_avcodec}" = "xyes"], [
2455 AC_CHECK_HEADERS(dxva2api.h,
2456 [
2457 AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2458 AC_MSG_NOTICE([DxVA2 acceleration activated])
2459 have_avcodec_dxva2="yes"
2460 ],[
2461 AS_IF([test "${enable_dxva2}" = "yes"],
2462 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2463 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2464 ], [#undef _WIN32_WINNT
2465 /* DXVA2 is only available in Vista and above */
2466 #define _WIN32_WINNT 0x600])
2467 ],[
2468 AS_IF([test "${enable_dxva2}" = "yes"],
2469 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2470 [AC_MSG_WARN([dxva2api.h not found])])
2471 ],[#include <d3d9.h>])
2472 ],[
2473 AS_IF([test "x${enable_dxva2}" != "x"], [
2474 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2475 ])
2476 ])
2477 fi
2478 ])
2479 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2481 dnl
2482 dnl d3d11va needs avcodec
2483 dnl
2484 AC_ARG_ENABLE(d3d11va,
2485 [ --enable-d3d11va D3D11 GPU decoding support (default auto)])
2487 have_avcodec_d3d11va="no"
2488 AS_IF([test "${enable_d3d11va}" != "no"], [
2489 if test "${SYS}" = "mingw32"; then
2490 AS_IF([test "x${have_avcodec}" = "xyes"], [
2491 AC_CHECK_TYPES([ID3D11VideoDecoder],
2492 [
2493 AC_CHECK_HEADERS(dxva2api.h,
2494 [
2495 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2496 AC_MSG_NOTICE([D3D11 acceleration activated])
2497 AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2498 have_avcodec_d3d11va="yes"
2499 ],[
2500 AS_IF([test "${enable_d3d11va}" = "yes"],
2501 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2502 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2503 ], [#undef _WIN32_WINNT
2504 /* D3D11 is only available in Vista and above */
2505 #define _WIN32_WINNT 0x600])
2506 ],[
2507 AS_IF([test "${enable_d3d11va}" = "yes"],
2508 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2509 [AC_MSG_WARN([dxva2api.h not found])])
2510 ],[#include <d3d9.h>])
2511 ],[
2512 AS_IF([test "${enable_d3d11va}" = "yes"],
2513 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2514 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2515 ], [#include <d3d11.h>])
2516 ],[
2517 AS_IF([test "x${enable_d3d11va}" != "x"], [
2518 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2519 ])
2520 ])
2521 fi
2522 ])
2523 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2525 dnl
2526 dnl DXGI debug
2527 dnl
2528 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2530 dnl
2531 dnl avformat demuxer/muxer plugin
2532 dnl
2534 AC_ARG_ENABLE(avformat,
2535 [ --enable-avformat libavformat containers (default enabled)],, [
2536 enable_avformat="${have_avcodec}"
2537 ])
2538 have_avformat="no"
2539 AS_IF([test "${enable_avformat}" != "no"], [
2540 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2541 have_avformat="yes"
2542 VLC_SAVE_FLAGS
2543 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2544 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2545 AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2546 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2547 AC_CHECK_HEADERS(libavutil/avutil.h)
2548 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2549 have_avformat="no"
2550 ])
2551 VLC_RESTORE_FLAGS
2552 ],[
2553 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2554 ])
2555 ])
2556 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2558 dnl
2559 dnl swscale image scaling and conversion plugin
2560 dnl
2562 AC_ARG_ENABLE(swscale,
2563 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2564 (default enabled)]))
2565 if test "${enable_swscale}" != "no"
2566 then
2567 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2568 [
2569 VLC_SAVE_FLAGS
2570 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2571 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2572 AC_CHECK_HEADERS(libswscale/swscale.h)
2573 AC_CHECK_HEADERS(libavutil/avutil.h)
2574 VLC_ADD_PLUGIN([swscale])
2575 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2576 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2577 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2578 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2579 ])
2580 VLC_RESTORE_FLAGS
2581 ],[
2582 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2583 ])
2584 fi
2586 dnl
2587 dnl postproc plugin
2588 dnl
2590 AC_ARG_ENABLE(postproc,
2591 [ --enable-postproc libpostproc image post-processing (default auto)])
2592 if test "${enable_postproc}" != "no"
2593 then
2594 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2595 [
2596 VLC_SAVE_FLAGS
2597 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2598 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2599 AC_CHECK_HEADERS(postproc/postprocess.h)
2600 VLC_ADD_PLUGIN([postproc])
2601 VLC_RESTORE_FLAGS
2602 ],[
2603 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2604 ])
2605 fi
2607 dnl
2608 dnl faad decoder plugin
2609 dnl
2610 AC_ARG_ENABLE(faad,
2611 [ --enable-faad faad codec (default auto)])
2612 have_faad="no"
2613 AS_IF([test "${enable_faad}" != "no"], [
2614 AC_CHECK_HEADERS([neaacdec.h], [
2615 AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2617 AS_IF([test "${have_faad}" = "yes"], [
2618 VLC_ADD_PLUGIN([faad])
2619 VLC_ADD_LIBS([faad],[-lfaad])
2620 ], [
2621 AS_IF([test "${enable_faad}" = "yes"], [
2622 AC_MSG_ERROR([cannot find FAAD library])
2623 ], [
2624 AC_MSG_WARN([cannot find FAAD library])
2625 ])
2626 ])
2627 ])
2628 ])
2630 dnl
2631 dnl AOM decoder plugin
2632 dnl
2633 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2635 dnl
2636 dnl libvpx decoder plugin
2637 dnl
2638 AC_ARG_ENABLE(vpx,
2639 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2640 AS_IF([test "${enable_vpx}" != "no"],[
2641 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2642 VLC_ADD_PLUGIN([vpx])
2643 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2644 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2645 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2646 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2647 ], [], [${VPX_LIBS}])
2648 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2649 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2650 ], [], [${VPX_LIBS}])
2651 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2652 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2653 ], [], [${VPX_LIBS}])
2654 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2655 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2656 ], [], [${VPX_LIBS}])
2657 ], [
2658 AS_IF([test "${enable_vpx}" = "yes"],[
2659 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2660 ])])
2661 ])
2663 dnl
2664 dnl twolame encoder plugin
2665 dnl
2666 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2668 dnl
2669 dnl fdk-aac encoder plugin
2670 dnl
2671 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2674 dnl
2675 dnl A52/AC3 decoder plugin
2676 dnl
2677 AC_ARG_ENABLE(a52,
2678 [ --enable-a52 A/52 support with liba52 (default enabled)])
2679 if test "${enable_a52}" != "no"
2680 then
2681 AC_ARG_WITH(a52,
2682 [ --with-a52=PATH a52 headers and libraries])
2683 if test -z "${with_a52}"
2684 then
2685 LDFLAGS_test=""
2686 CPPFLAGS_test=""
2687 else
2688 LDFLAGS_test="-L${with_a52}/lib"
2689 CPPFLAGS_test="-I${with_a52}/include"
2690 fi
2691 VLC_SAVE_FLAGS
2692 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2693 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2694 AC_CHECK_HEADERS(a52dec/a52.h, [
2695 AC_CHECK_LIB(a52, a52_free, [
2696 VLC_ADD_PLUGIN([a52])
2697 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2698 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2699 ],[
2700 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2701 ], [$LIBM])
2702 ],[
2703 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2704 ])
2705 VLC_RESTORE_FLAGS
2706 fi
2708 dnl
2709 dnl DTS Coherent Acoustics decoder plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2713 dnl
2714 dnl Flac plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2718 dnl
2719 dnl Libmpeg2 plugin
2720 dnl
2721 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2723 dnl
2724 dnl Vorbis plugin
2725 dnl
2726 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2728 dnl
2729 dnl Tremor plugin
2730 dnl
2731 AC_ARG_ENABLE(tremor,
2732 [ --enable-tremor Tremor decoder support (default disabled)])
2733 if test "${enable_tremor}" = "yes"
2734 then
2735 AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2736 VLC_ADD_PLUGIN([tremor])
2737 ],[])
2738 fi
2740 dnl
2741 dnl Speex plugins
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2744 have_speexdsp="no"
2745 AS_IF([test "${enable_speex}" != "no"], [
2746 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2747 have_speexdsp="yes"
2748 ], [
2749 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2750 ])
2751 ])
2752 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2754 dnl
2755 dnl Opus plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2759 dnl
2760 dnl Ambisonic channel mixer and binauralizer plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2764 dnl
2765 dnl theora decoder plugin
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2769 dnl
2770 dnl OggSpots decoder plugin
2771 dnl
2772 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2774 dnl
2775 dnl Daala decoder plugin
2776 dnl
2777 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2779 dnl
2780 dnl schroedinger decoder plugin (for dirac format video)
2781 dnl
2782 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2784 dnl
2785 dnl PNG decoder module
2786 dnl
2787 AC_ARG_ENABLE(png,
2788 [ --enable-png PNG support (default enabled)])
2789 AS_IF([test "${enable_png}" != "no"], [
2790 AC_CHECK_HEADERS(png.h, [
2791 VLC_SAVE_FLAGS
2792 LDFLAGS="${LDFLAGS} -lz $LIBM"
2793 AC_CHECK_LIB(png, png_set_alpha_mode, [
2794 VLC_ADD_PLUGIN([png])
2795 ], [], [-lz $LIBM])
2796 VLC_RESTORE_FLAGS
2797 ])
2798 ])
2800 dnl
2801 dnl JPEG decoder module
2802 dnl
2803 AC_ARG_ENABLE(jpeg,
2804 [ --enable-jpeg JPEG support (default enabled)])
2805 AS_IF([test "${enable_jpeg}" != "no"], [
2806 AC_CHECK_HEADERS(jpeglib.h, [
2807 VLC_ADD_PLUGIN([jpeg])
2808 ])
2809 ])
2811 dnl
2812 dnl BPG decoder module
2813 dnl
2814 AC_ARG_ENABLE(bpg,
2815 [ --enable-bpg BPG support (default disabled)])
2816 AS_IF([test "${enable_bpg}" != "no"], [
2817 AC_CHECK_HEADERS(libbpg.h, [
2818 VLC_ADD_PLUGIN([bpg])
2819 ])
2820 ])
2822 dnl
2823 dnl H262 encoder plugin (lib262)
2824 dnl
2825 AC_ARG_ENABLE(x262,
2826 [ --enable-x262 H262 encoding support with static libx262 (default disabled)])
2827 if test "${enable_x262}" != "no"; then
2828 PKG_CHECK_MODULES(X262, x262, [
2829 VLC_ADD_PLUGIN([x262])
2830 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2831 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2832 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2833 ])
2834 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2835 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2836 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2837 fi
2838 ], [
2839 if test "${enable_x262}" = "yes"; then
2840 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2841 fi
2842 ])
2843 fi
2845 dnl x265 encoder
2846 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2848 dnl
2849 dnl H264 encoder plugin (10-bit lib264)
2850 dnl
2851 AC_ARG_ENABLE(x26410b,
2852 [ --enable-x26410b H264 10-bit encoding support with static libx264 (default disabled)])
2853 if test "${enable_x26410b}" != "no"; then
2854 PKG_CHECK_MODULES(X26410B, x26410b, [
2855 VLC_ADD_PLUGIN([x26410b])
2856 VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2857 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2858 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2859 ])
2860 VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2861 if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2862 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2863 fi
2864 ], [
2865 if test "${enable_x26410b}" = "yes"; then
2866 AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2867 fi
2868 ])
2869 fi
2872 dnl
2873 dnl H264 encoder plugin (using libx264)
2874 dnl
2875 AC_ARG_ENABLE(x264,
2876 [ --enable-x264 H264 encoding support with libx264 (default enabled)])
2877 if test "${enable_x264}" != "no"; then
2878 PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2879 VLC_ADD_PLUGIN([x264])
2880 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2882 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2883 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2884 ])
2886 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2887 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2888 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2889 fi
2890 ],[
2891 if test "${enable_x264}" = "yes"; then
2892 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2893 fi
2894 ])
2895 fi
2897 dnl
2898 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2899 dnl
2900 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2902 dnl
2903 dnl libfluidsynth (MIDI synthetizer) plugin
2904 dnl
2905 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2906 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2907 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2909 dnl
2910 dnl Teletext Modules
2911 dnl vbi decoder plugin (using libzbvi)
2912 dnl telx module
2913 dnl uncompatible
2914 dnl
2915 AC_ARG_ENABLE(zvbi,
2916 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2917 libzvbi (default enabled)]))
2918 AC_ARG_ENABLE(telx,
2919 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2920 zvbi) (default enabled if zvbi is absent)]))
2922 AS_IF( [test "${enable_zvbi}" != "no"],[
2923 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2924 [
2925 VLC_ADD_PLUGIN([zvbi])
2926 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2927 AS_IF( [test "${enable_telx}" = "yes"],[
2928 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2929 ])
2930 ],[
2931 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2932 ])
2933 ])
2934 AS_IF( [test "${enable_telx}" != "no" ],[
2935 VLC_ADD_PLUGIN([telx])
2936 ])
2938 dnl
2939 dnl libass subtitle rendering module
2940 dnl
2941 AC_ARG_ENABLE(libass,
2942 [ --enable-libass Subtitle support using libass (default enabled)])
2943 AS_IF( [test "${enable_libass}" != "no"], [
2944 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2945 [
2946 VLC_ADD_PLUGIN([libass])
2948 AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2949 [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2950 VLC_ADD_LIBS([libass],[-lfontconfig])
2951 ])
2952 ],[
2953 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2954 ])
2955 ])
2957 dnl
2958 dnl ARIB subtitles rendering module
2959 dnl
2960 AC_ARG_ENABLE(aribsub,
2961 [ --enable-aribsub ARIB Subtitles support (default enabled)])
2962 AS_IF( [test "${enable_aribsub}" != "no" ],[
2963 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2964 have_aribb24="yes"
2965 VLC_ADD_PLUGIN([aribsub])
2966 VLC_ADD_LIBS([aribsub],[-laribb24])
2967 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2968 ],[
2969 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2970 have_aribb24="no"
2971 ])
2972 ])
2973 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2975 dnl
2976 dnl ARIB B25
2977 dnl
2978 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2980 dnl
2981 dnl kate decoder plugin
2982 dnl
2983 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2985 dnl
2986 dnl tiger rendering for kate decoder plugin
2987 dnl
2988 AC_ARG_ENABLE(tiger,
2989 [ --enable-tiger Tiger rendering library for Kate streams (default auto)])
2990 AS_IF([test "${enable_tiger}" != "no"], [
2991 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2992 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2993 AS_IF([test -n "${enable_tiger}"], [
2994 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2995 ])
2996 ])
2997 ])
2999 dnl
3000 dnl check if we can build the css selector engine
3001 dnl
3002 AC_ARG_ENABLE(css,
3003 [ --enable-css CSS selector engine (default auto)])
3004 AS_IF([test "${enable_css}" != "no"], [
3005 with_css="yes"
3006 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3007 ])
3008 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3011 dnl
3012 dnl Video plugins
3013 dnl
3015 EXTEND_HELP_STRING([Video plugins:])
3017 dnl
3018 dnl OpenGL
3019 dnl
3020 PKG_CHECK_MODULES([EGL], [egl], [
3021 have_egl="yes"
3022 ], [
3023 have_egl="no"
3024 ])
3025 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3027 have_gl="no"
3028 PKG_CHECK_MODULES([GL], [gl], [
3029 have_gl="yes"
3030 ], [
3031 AC_MSG_CHECKING([for OpenGL])
3032 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3033 #ifdef _WIN32
3034 # include <GL/glew.h>
3035 #endif
3036 #include <GL/gl.h>
3037 ]], [
3038 [int t0 = GL_TEXTURE0;]])
3039 ], [
3040 GL_CFLAGS=""
3041 have_gl="yes"
3042 AS_IF([test "${SYS}" != "mingw32"], [
3043 GL_LIBS="-lGL"
3044 ], [
3045 GL_LIBS="-lopengl32"
3046 ])
3047 ])
3048 AC_MSG_RESULT([${have_gl}])
3049 ])
3050 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3052 dnl OpenGL ES 2: depends on EGL 1.1
3053 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3055 dnl
3056 dnl Xlib
3057 dnl
3059 AC_PATH_XTRA()
3060 AC_CHECK_HEADERS(X11/Xlib.h)
3062 dnl
3063 dnl X C Bindings modules
3064 dnl
3065 AC_ARG_ENABLE(xcb,
3066 [ --enable-xcb X11 support with XCB (default enabled)],, [
3067 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3068 enable_xcb="yes"
3069 ], [
3070 enable_xcb="no"
3071 ])
3072 ])
3073 AC_ARG_ENABLE(xvideo,
3074 [ --enable-xvideo XVideo support (default enabled)],, [
3075 enable_xvideo="$enable_xcb"
3076 ])
3078 have_xcb="no"
3079 have_xcb_keysyms="no"
3080 have_xcb_randr="no"
3081 have_xcb_xvideo="no"
3082 AS_IF([test "${enable_xcb}" != "no"], [
3083 dnl libxcb
3084 PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3085 have_xcb="yes"
3086 PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3087 PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3088 PKG_CHECK_MODULES(XPROTO, [xproto])
3090 AS_IF([test "${enable_xvideo}" != "no"], [
3091 PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3092 ])
3094 PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3096 dnl xcb-utils
3097 PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3098 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3099 ])
3100 ])
3101 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3102 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3103 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3104 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3107 dnl
3108 dnl VDPAU needs X11
3109 dnl
3110 AC_ARG_ENABLE(vdpau,
3111 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3112 have_vdpau="no"
3113 AS_IF([test "${enable_vdpau}" != "no"], [
3114 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3115 have_vdpau="yes"
3116 AS_IF([test "${no_x}" = "yes"], [
3117 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3118 ])
3119 ], [
3120 AS_IF([test -n "${enable_vdpau}"], [
3121 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3122 ])
3123 ])
3124 ])
3125 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3127 have_avcodec_vdpau="no"
3128 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3129 case "${avfork}" in
3130 libav) av_vdpau_ver="56.10.0" ;;
3131 ffmpeg) av_vdpau_ver="56.19.100" ;;
3132 esac
3133 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3134 have_avcodec_vdpau="yes"
3135 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3136 ], [
3137 AS_IF([test -n "${enable_vdpau}"], [
3138 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3139 ], [
3140 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3141 ])
3142 ])
3143 ])
3144 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3147 dnl
3148 dnl Wayland
3149 dnl
3150 AC_ARG_ENABLE(wayland,
3151 [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3152 have_wayland="no"
3153 have_wayland_egl="no"
3155 AS_IF([test "${enable_wayland}" != "no"], [
3156 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3157 AC_MSG_CHECKING([for the Wayland protocols])
3158 PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3159 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3160 AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3161 ], [
3162 AC_MSG_RESULT([not found])
3163 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3164 ])
3166 AC_MSG_CHECKING([for the Wayland scanner])
3167 PKG_CHECK_EXISTS([wayland-scanner], [
3168 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3169 AC_MSG_RESULT([${WAYLAND_SCANNER}])
3170 ], [
3171 AC_MSG_RESULT([not found])
3172 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3173 ])
3175 have_wayland="yes"
3177 AS_IF([test "${have_egl}" = "yes"], [
3178 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3179 have_wayland_egl="yes"
3180 ], [
3181 AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3182 ])
3183 ])
3184 ], [
3185 AS_IF([test -n "${enable_wayland}"], [
3186 AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3187 ])
3188 ])
3189 ])
3190 AC_SUBST([WAYLAND_PROTOCOLS])
3191 AC_SUBST([WAYLAND_SCANNER])
3192 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3193 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3196 dnl
3197 dnl SDL image decoder module
3198 dnl
3199 AC_ARG_ENABLE(sdl-image,
3200 [ --enable-sdl-image SDL image support (default enabled)])
3201 AS_IF([test "${enable_sdl_image}" != "no"],[
3202 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3203 VLC_ADD_PLUGIN([sdl_image])
3204 ], [
3205 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3206 ])
3207 ])
3209 dnl
3210 dnl freetype module
3211 dnl
3212 AC_ARG_ENABLE(freetype,
3213 [ --enable-freetype freetype support (default auto)])
3214 AC_ARG_ENABLE(fribidi,
3215 [ --enable-fribidi fribidi support (default auto)])
3216 AC_ARG_ENABLE(harfbuzz,
3217 [ --enable-harfbuzz harfbuzz support (default auto)])
3218 AC_ARG_ENABLE(fontconfig,
3219 [ --enable-fontconfig fontconfig support (default auto)])
3221 AC_ARG_WITH([default-font],
3222 AS_HELP_STRING([--with-default-font=PATH],
3223 [Path to the default font]),
3224 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3225 "$withval", [Default font])])
3226 AC_ARG_WITH([default-monospace-font],
3227 AS_HELP_STRING([--with-default-monospace-font=PATH],
3228 [Path to the default font]),
3229 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3230 "$withval", [Default monospace font])])
3232 AC_ARG_WITH([default-font-family],
3233 AS_HELP_STRING([--with-default-font-family=NAME],
3234 [Path to the default font family]),
3235 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3236 "$withval", [Default font family])])
3237 AC_ARG_WITH([default-monospace-font-family],
3238 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3239 [Path to the default font family]),
3240 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3241 "$withval", [Default monospace font family])])
3243 have_freetype="no"
3244 have_fontconfig="no"
3245 have_fribidi="no"
3246 have_harfbuzz="no"
3248 if test "${enable_freetype}" != "no"; then
3249 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3250 have_freetype="yes"
3251 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3252 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3254 dnl fontconfig support
3255 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3256 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3257 have_fontconfig="yes"
3258 ], [
3259 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3260 ])
3261 ])
3263 dnl fribidi support
3264 if test "${enable_fribidi}" != "no"; then
3265 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3266 have_fribidi="yes"
3267 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3268 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3269 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3270 fi
3272 dnl harfbuzz support
3273 if test "${have_fribidi}" != "no"; then
3274 if test "${enable_harfbuzz}" != "no"; then
3275 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3276 have_harfbuzz="yes"
3277 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3278 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3279 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3280 fi
3281 fi
3282 ],[
3283 AS_IF([test -n "${enable_freetype}"],[
3284 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3285 ])
3286 ])
3287 fi
3289 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3290 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3291 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3292 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3294 dnl
3295 dnl SAPI (text to Speech renderer for Windows)
3296 dnl
3297 AC_LANG_PUSH([C++])
3298 AC_CHECK_TYPES([ISpObjectToken],[
3299 have_sapi="yes"
3300 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3301 [#include <windows.h>
3302 #include <sapi.h>
3303 #include <sphelper.h>])
3304 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3305 AC_LANG_POP([C++])
3307 dnl
3308 dnl SVG module (text rendering and image decoding)
3309 dnl
3310 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3311 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3313 dnl
3314 dnl Windows DirectX module
3315 dnl
3317 AC_ARG_ENABLE(directx,
3318 [AS_HELP_STRING([--enable-directx],
3319 [Microsoft DirectX support (default enabled on Windows)])],, [
3320 AS_IF([test "${SYS}" = "mingw32"], [
3321 enable_directx="yes"
3322 ], [
3323 enable_directx="no"
3324 ])
3325 ])
3326 AS_IF([test "${enable_directx}" != "no"], [
3327 dnl DirectDraw
3328 AC_CHECK_HEADERS(ddraw.h, [
3329 VLC_ADD_PLUGIN([directdraw])
3330 ])
3332 dnl OpenGL
3333 AC_CHECK_HEADERS(GL/wglew.h, [
3334 VLC_ADD_PLUGIN([glwin32 wgl])
3335 ],, [
3336 #include <windows.h>
3337 #include <GL/gl.h>
3338 ])
3340 dnl Direct3D11
3341 AC_CHECK_HEADERS(d3d11.h, [
3342 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3343 ])
3345 dnl Direct3D9
3346 AC_CHECK_HEADERS(d3d9.h, [
3347 VLC_ADD_PLUGIN([direct3d9])
3348 AC_CHECK_HEADERS(d3dx9effect.h)
3350 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3351 [[#define COBJMACROS
3352 #include <d3d9.h>
3353 #include <dxva2api.h>
3354 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3355 # error dxva2 too old
3356 #endif
3357 ]],[[;]])
3358 ],[
3359 VLC_ADD_PLUGIN([direct3d9_filters])
3360 ],
3361 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3363 ])
3364 ])
3366 dnl
3367 dnl Linux framebuffer module
3368 dnl
3369 AC_CHECK_HEADER([linux/fb.h], [
3370 VLC_ADD_PLUGIN([fb])
3371 ])
3373 dnl
3374 dnl libcaca plugin
3375 dnl
3376 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3378 dnl
3379 dnl OS/2 KVA plugin
3380 dnl
3381 AC_ARG_ENABLE(kva,
3382 [AS_HELP_STRING([--enable-kva],
3383 [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3384 AS_IF([test "$SYS" = "os2"], [
3385 enable_kva="yes"
3386 ])
3387 ])
3388 have_kva="no"
3389 KVA_LIBS=""
3390 AS_IF([test "$enable_kva" != "no"], [
3391 AC_CHECK_HEADERS([kva.h], [
3392 have_kva="yes"
3393 AC_CHECK_LIB(kva, main, [
3394 KVA_LIBS="-lkva"
3395 ])
3396 ])
3397 ])
3398 AC_SUBST(KVA_LIBS)
3399 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3401 dnl
3402 dnl MMAL plugin
3403 dnl
3404 AC_ARG_ENABLE(mmal,
3405 AS_HELP_STRING([--enable-mmal],
3406 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3407 if test "${enable_mmal}" != "no"; then
3408 VLC_SAVE_FLAGS
3409 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3410 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3411 AC_CHECK_HEADERS(interface/mmal/mmal.h,
3412 [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3413 have_mmal="yes"
3414 VLC_ADD_PLUGIN([mmal])
3415 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3416 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3417 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3418 AS_IF([test "${enable_mmal}" = "yes"],
3419 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3420 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3421 ],
3422 [])
3423 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3424 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3425 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3426 VLC_RESTORE_FLAGS
3427 fi
3428 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3430 dnl
3431 dnl Audio plugins
3432 dnl
3434 EXTEND_HELP_STRING([Audio plugins:])
3436 dnl
3437 dnl Pulseaudio module
3438 dnl
3439 AC_ARG_ENABLE(pulse,
3440 [AS_HELP_STRING([--enable-pulse],
3441 [use the PulseAudio client library (default auto)])])
3442 have_pulse="no"
3443 AS_IF([test "${enable_pulse}" != "no"], [
3444 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3445 have_pulse="yes"
3446 ], [
3447 AS_IF([test "x${enable_pulse}" != "x"], [
3448 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3449 ])
3450 ])
3451 ])
3452 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3454 dnl
3455 dnl ALSA module
3456 dnl
3457 AC_ARG_ENABLE(alsa,
3458 [AS_HELP_STRING([--enable-alsa],
3459 [support the Advanced Linux Sound Architecture (default auto)])],, [
3460 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3461 enable_alsa="yes"
3462 ])
3463 ])
3464 have_alsa="no"
3465 AS_IF([test "${enable_alsa}" != "no"], [
3466 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3467 have_alsa="yes"
3468 ], [
3469 AS_IF([test "x${enable_alsa}" != "x"], [
3470 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3471 ])
3472 ])
3473 ])
3474 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3476 dnl
3477 dnl Open Sound System module
3478 dnl
3479 AC_ARG_ENABLE(oss,
3480 [AS_HELP_STRING([--enable-oss],
3481 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3482 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3483 enable_oss="no"
3484 ])
3485 ])
3486 have_oss="no"
3487 OSS_LIBS=""
3488 AS_IF([test "$enable_oss" != "no"], [
3489 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3490 have_oss="yes"
3491 AC_CHECK_LIB(ossaudio, main, [
3492 OSS_LIBS="-lossaudio"
3493 ])
3494 ])
3495 ])
3496 AC_SUBST(OSS_LIBS)
3497 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3499 dnl
3500 dnl OpenBSD sndio module
3501 dnl
3502 AC_ARG_ENABLE([sndio],
3503 [AS_HELP_STRING([--disable-sndio],
3504 [support the OpenBSD sndio (default auto)])],, [
3505 AS_IF([test "$SYS" = "openbsd"], [
3506 enable_sndio="yes"
3507 ])
3508 ])
3509 have_sndio="no"
3510 AS_IF([test "$enable_sndio" != "no"], [
3511 AC_CHECK_HEADER([sndio.h], [
3512 have_sndio="yes"
3513 ])
3514 ])
3515 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3517 dnl
3518 dnl Windows Audio Session plugin
3519 dnl
3520 AC_ARG_ENABLE([wasapi],
3521 [AS_HELP_STRING([--enable-wasapi],
3522 [use the Windows Audio Session API (default auto)])
3523 ])
3524 have_wasapi="no"
3525 AS_IF([test "$enable_wasapi" != "no"], [
3526 AC_CHECK_HEADER([audioclient.h], [
3527 have_wasapi="yes"
3528 ], [
3529 AS_IF([test "x${enable_wasapi}" != "x"], [
3530 AC_MSG_ERROR([Windows Audio Session API not found.])
3531 ])
3532 ])
3533 ])
3534 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3536 dnl
3537 dnl JACK modules
3538 dnl
3539 AC_ARG_ENABLE(jack,
3540 [AS_HELP_STRING([--disable-jack],
3541 [do not use jack (default auto)])])
3542 have_jack="no"
3543 AS_IF([test "${enable_jack}" != "no"], [
3544 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3545 [ have_jack=yes ],
3546 [
3547 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3549 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3550 [ have_jack=yes ],
3551 [
3552 AS_IF([test -n "${enable_jack}"],
3553 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3554 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3555 ])
3556 ])
3557 ])
3558 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3560 dnl
3561 dnl OpenSLES Android
3562 dnl
3563 AC_ARG_ENABLE(opensles,
3564 [ --enable-opensles Android OpenSL ES audio module (default disabled)])
3565 if test "${HAVE_ANDROID}" = "1"; then
3566 if test "${enable_opensles}" = "yes"; then
3567 AC_CHECK_HEADERS(SLES/OpenSLES.h,
3568 [ VLC_ADD_PLUGIN([opensles_android]) ],
3569 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3570 fi
3571 fi
3573 dnl
3574 dnl Tizen audio
3575 dnl
3576 AC_ARG_ENABLE(tizen_audio,
3577 [AS_HELP_STRING([--enable-tizen-audio],
3578 [Tizen audio module (default enabled on Tizen)])],, [
3579 AS_IF([test "$HAVE_TIZEN" = "1"], [
3580 enable_tizen_audio="yes"
3581 ])
3582 ])
3583 if test "${enable_tizen_audio}" = "yes"; then
3584 AC_CHECK_HEADERS(audio_io.h,
3585 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3586 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3587 fi
3589 dnl
3590 dnl libsamplerate plugin
3591 dnl
3592 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3594 dnl
3595 dnl soxr module
3596 dnl
3597 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3599 dnl
3600 dnl OS/2 KAI plugin
3601 dnl
3602 AC_ARG_ENABLE(kai,
3603 [AS_HELP_STRING([--enable-kai],
3604 [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3605 AS_IF([test "$SYS" = "os2"], [
3606 enable_kai="yes"
3607 ])
3608 ])
3609 have_kai="no"
3610 KAI_LIBS=""
3611 AS_IF([test "$enable_kai" != "no"], [
3612 AC_CHECK_HEADERS([kai.h], [
3613 have_kai="yes"
3614 AC_CHECK_LIB(kai, main, [
3615 KAI_LIBS="-lkai"
3616 ])
3617 ])
3618 ])
3619 AC_SUBST(KAI_LIBS)
3620 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3622 dnl
3623 dnl chromaprint audio track fingerprinter
3624 dnl
3625 m4_pushdef([libchromaprint_version], 0.6.0)
3626 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3627 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3628 AS_IF([test "${enable_chromaprint}" = "yes"],
3629 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3630 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3631 ),
3632 [(Chromaprint based audio fingerprinter)],[auto])
3633 m4_popdef([libchromaprint_version])
3635 dnl
3636 dnl Chromecast streaming support
3637 dnl
3638 m4_pushdef([protobuf_lite_version], 2.5.0)
3639 AC_ARG_VAR(PROTOC, [protobuf compiler])
3640 AC_CHECK_PROGS(PROTOC, protoc, no)
3641 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3642 AS_IF([test "x${PROTOC}" != "xno"], [
3643 build_chromecast="yes"
3644 ], [
3645 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3646 ])
3647 ], [
3648 AS_IF([test "${enable_chromecast}" = "yes"],
3649 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3650 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3651 )
3652 enable_chromecast="no"
3653 ], [(Chromecast streaming support)], [auto])
3654 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3655 m4_popdef([protobuf_lite_version])
3657 dnl
3658 dnl Interface plugins
3659 dnl
3661 EXTEND_HELP_STRING([Interface plugins:])
3663 dnl
3664 dnl QT
3665 dnl
3666 AC_ARG_ENABLE(qt, [
3667 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3668 AS_IF([test "${SYS}" = "darwin"], [
3669 enable_qt="no"
3670 ])
3671 ])
3672 have_qt5_x11="no"
3673 AS_IF([test "${enable_qt}" != "no"], [
3674 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3675 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3676 have_qt5_x11="yes"
3677 ],[
3678 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3679 ])
3680 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3681 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3682 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3683 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3684 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3685 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3686 ], [
3687 AS_IF([test -n "${enable_qt}"],[
3688 AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3689 ],[
3690 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3691 ])
3692 enable_qt="no"
3693 ])
3694 ])
3696 AS_IF([test "${enable_qt}" != "no"], [
3697 ALIASES="${ALIASES} qvlc"
3698 ])
3699 AC_SUBST(QT_VERSION)
3700 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3701 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3703 dnl
3704 dnl detect kde4-config patch (used for kde solids).
3705 dnl
3706 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3707 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3708 KDE4_CONFIG="kde4-config"
3709 ])
3711 dnl
3712 dnl Simple test for skins2 dependency
3713 dnl
3714 AS_IF([test "$enable_qt" = "no"], [
3715 AS_IF([test "${enable_skins2}" = "yes"], [
3716 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3717 ], [
3718 enable_skins2="no"
3719 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3720 ])
3721 ])
3723 dnl
3724 dnl Skins2 module
3725 dnl
3726 AC_ARG_ENABLE(skins2,
3727 [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3728 AS_IF([test "${enable_skins2}" != "no"], [
3729 have_skins_deps="yes"
3731 dnl Win32
3732 AS_IF([test "${SYS}" = "mingw32"], [
3733 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3734 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3735 dnl OS/2
3736 ], [test "${SYS}" = "os2"], [
3737 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3738 dnl Linux/Unix
3739 ], [
3740 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3741 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3742 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3743 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3744 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3745 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3746 ])
3748 dnl we need freetype
3749 AS_IF([test "${have_freetype}" != "yes"], [
3750 have_skins_deps="no"
3751 ])
3753 AS_IF([test "${have_skins_deps}" = "no"], [
3754 AS_IF([test "x${enable_skins2}" = "x"], [
3755 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3756 ], [
3757 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3758 ])
3759 enable_skins2="no"
3760 ], [
3761 ALIASES="${ALIASES} svlc"
3762 enable_skins2="yes"
3763 ])
3764 ])
3765 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3767 AC_ARG_ENABLE(libtar,
3768 [ --enable-libtar libtar support for skins2 (default auto)])
3769 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3770 AC_CHECK_HEADERS(libtar.h, [
3771 VLC_ADD_LIBS([skins2],[-ltar])
3772 ])
3773 ])
3775 dnl
3776 dnl MacOS X gui module
3777 dnl
3778 AC_ARG_ENABLE(macosx,
3779 [ --enable-macosx Mac OS X gui support (default enabled on Mac OS X)])
3780 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3781 then
3783 dnl
3784 dnl If possible, use xcrun to find the right ibtool
3785 dnl
3787 AC_PATH_PROG([XCRUN], [xcrun], [no])
3788 AS_IF([test ! "x${XCRUN}" = "xno"], [
3789 AC_MSG_CHECKING([for ibtool (using xcrun)])
3790 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3791 AC_MSG_RESULT([${XIB}])
3792 ], [
3793 AC_MSG_WARN([Looking for tools without using xcrun])
3794 ])
3796 AS_IF([test "x${XIB}" = "xno"], [
3797 AC_PATH_PROG(XIB, [ibtool], [no])
3798 AS_IF([test "x${XIB}" = "xno"], [
3799 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3800 ])
3801 ])
3802 fi
3803 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3805 dnl
3806 dnl MacOS X sparkle update support
3807 dnl
3808 AC_ARG_ENABLE(sparkle,
3809 [ --enable-sparkle Sparkle update support for OS X (default enabled on Mac OS X)])
3810 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3811 then
3812 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3813 then
3814 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3815 fi
3817 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3818 fi
3819 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3821 dnl
3822 dnl MacOS X breakpad creash reporter support
3823 dnl
3824 AC_ARG_WITH([breakpad],
3825 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3827 AS_IF([test "$with_breakpad" != "no"], [
3829 AS_IF([test "$with_breakpad" = "yes"], [
3830 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3831 ])
3833 AS_IF([test "$HAVE_OSX" = "1"], [
3834 AC_MSG_CHECKING([for Breakpad framework])
3835 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3836 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3837 AC_MSG_RESULT([no])
3838 with_breakpad="no"
3839 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3840 ], [
3841 AC_MSG_RESULT([yes])
3842 ])
3843 ],[
3844 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3845 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3846 ], [
3847 AC_MSG_ERROR(["breakpad not found"])
3848 ])
3849 ])
3850 ])
3852 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3853 AS_IF([test "$with_breakpad" != "no"], [
3854 AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3855 ])
3857 dnl
3858 dnl Minimal Mac OS X module
3859 dnl
3860 AC_ARG_ENABLE(minimal-macosx,
3861 [ --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3862 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3863 then
3864 VLC_ADD_PLUGIN([minimal_macosx])
3865 fi
3867 dnl
3868 dnl Mac OS X fancy dmg build tool
3869 dnl
3870 if test "${HAVE_OSX}" = "1"
3871 then
3872 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3873 AS_IF([test "x${DMGBUILD}" = "xno"], [
3874 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3875 ])
3876 fi
3877 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3879 dnl
3880 dnl VideoToolbox plugins
3881 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3882 VLC_ADD_PLUGIN([videotoolbox])
3883 VLC_ADD_PLUGIN([cvpx])
3884 ])
3886 dnl
3887 dnl AudioToolbox MIDI plugin
3888 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3889 VLC_ADD_PLUGIN([audiotoolboxmidi])
3890 ])
3892 dnl
3893 dnl ncurses module
3894 dnl
3895 AC_ARG_ENABLE(ncurses,
3896 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3897 have_ncurses="no"
3898 AS_IF([test "${enable_ncurses}" != "no"] ,[
3899 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3900 have_ncurses="yes"
3901 ALIASES="${ALIASES} nvlc"
3902 ], [
3903 AS_IF([test -n "${enable_ncurses}"], [
3904 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3905 ])
3906 ])
3907 ])
3908 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3910 dnl
3911 dnl Lirc plugin
3912 dnl
3913 AC_ARG_ENABLE(lirc,
3914 [ --enable-lirc lirc support (default disabled)])
3915 have_lirc="no"
3916 AS_IF([test "${enable_lirc}" = "yes"], [
3917 AC_CHECK_HEADER(lirc/lirc_client.h, [
3918 AC_CHECK_LIB(lirc_client, lirc_init, [
3919 have_lirc="yes"
3920 ])
3921 ])
3922 ])
3923 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3925 dnl
3926 dnl SRT plugin
3927 dnl
3928 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3930 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3931 dnl
3932 dnl goom visualization plugin
3933 dnl
3934 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3936 dnl
3937 dnl libprojectM visualization plugin
3938 dnl
3939 AC_ARG_ENABLE(projectm,
3940 [ --enable-projectm projectM visualization plugin (default enabled)])
3941 AS_IF([test "${enable_projectm}" != "no"],
3942 [
3943 PKG_CHECK_MODULES(PROJECTM, libprojectM,
3944 [
3945 VLC_ADD_PLUGIN([projectm])
3946 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3947 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3948 [ AC_MSG_WARN( [Using libprojectM version 1] )
3949 ])
3950 ],[
3951 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3952 ])
3953 ])
3955 dnl
3956 dnl Vovoid VSXu visualization plugin
3957 dnl
3958 AC_ARG_ENABLE(vsxu,
3959 [ --enable-vsxu Vovoid VSXu visualization plugin (default auto)])
3960 AS_IF([test "${enable_vsxu}" != "no"],
3961 [
3962 PKG_CHECK_MODULES(VSXU, libvsxu,
3963 [
3964 VLC_ADD_PLUGIN([vsxu])
3965 ],[
3966 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3967 ])
3968 ])
3970 EXTEND_HELP_STRING([Service Discovery plugins:])
3971 dnl
3972 dnl Avahi-Zeroconf services discovery
3973 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3975 dnl
3976 dnl libudev services discovery
3977 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3979 dnl
3980 dnl MTP devices services discovery
3981 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3983 dnl
3984 dnl UPnP Plugin (Intel SDK)
3985 dnl
3986 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3988 dnl
3989 dnl mDNS using libmicrodns
3990 dnl
3991 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3994 EXTEND_HELP_STRING([Misc options:])
3996 dnl
3997 dnl libxml2 module
3998 dnl
3999 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4002 dnl
4003 dnl libgcrypt
4004 dnl
4005 AC_ARG_ENABLE(libgcrypt,
4006 [ --disable-libgcrypt gcrypt support (default enabled)])
4007 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4008 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4010 # require libgcrypt >= 1.6.0
4011 AS_IF([test "${enable_libgcrypt}" != "no"], [
4012 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4013 VLC_SAVE_FLAGS
4014 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4015 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4016 [#include <gcrypt.h>
4017 #if GCRYPT_VERSION_NUMBER < 0x010600
4018 #error
4019 #endif]])], [
4020 ac_cv_lib_gcrypt=yes
4021 ], [
4022 ac_cv_lib_gcrypt=no
4023 ])
4024 VLC_RESTORE_FLAGS
4025 ])
4027 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4028 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4029 ], [
4030 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4031 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4032 ])
4033 ])
4034 ])
4036 AS_IF([test -z "$GCRYPT_LIBS"], [
4037 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4038 ])
4040 AC_SUBST(GCRYPT_CFLAGS)
4041 AC_SUBST(GCRYPT_LIBS)
4042 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4044 dnl
4045 dnl TLS/SSL
4046 dnl
4047 AC_ARG_ENABLE(gnutls,
4048 [ --enable-gnutls GNU TLS TLS/SSL support (default enabled)])
4049 AS_IF([test "${enable_gnutls}" != "no"], [
4050 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4051 VLC_ADD_PLUGIN([gnutls])
4052 ], [
4053 AS_IF([test -n "${enable_gnutls}"], [
4054 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4055 ])
4056 ])
4057 ])
4060 dnl
4061 dnl Taglib plugin
4062 dnl
4063 AC_ARG_ENABLE(taglib,
4064 [AS_HELP_STRING([--disable-taglib],
4065 [do not use TagLib (default enabled)])])
4066 AS_IF([test "${enable_taglib}" != "no"], [
4067 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4068 VLC_ADD_PLUGIN([taglib])
4069 ], [
4070 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4071 ])
4073 dnl
4074 dnl libsecret
4075 dnl
4076 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4078 dnl
4079 dnl kwallet
4080 dnl
4081 AC_ARG_ENABLE(kwallet,
4082 [AS_HELP_STRING([--enable-kwallet],
4083 [use kwallet (via D-Bus) for keystore (default enabled)])])
4084 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4085 VLC_ADD_PLUGIN([kwallet])
4086 ])
4088 dnl
4089 dnl update checking system
4090 dnl
4091 AC_ARG_ENABLE(update-check,
4092 [ --enable-update-check update checking system (default disabled)])
4093 if test "${enable_update_check}" = "yes"
4094 then
4095 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4096 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4097 fi
4098 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4100 dnl
4101 dnl OS X notification plugin
4102 dnl
4103 AC_ARG_ENABLE(osx_notifications,
4104 [ --enable-osx-notifications osx notification plugin (default disabled)],,
4105 [enable_osx_notifications=no])
4106 AS_IF([test "${enable_osx_notifications}" != "no"], [
4107 if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4108 then
4109 VLC_ADD_PLUGIN([osx_notifications])
4110 VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4111 VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4112 fi
4113 ])
4115 dnl
4116 dnl Libnotify notification plugin
4117 dnl
4118 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4120 dnl
4121 dnl libplacebo support
4122 dnl
4123 AC_ARG_ENABLE(libplacebo,
4124 [AS_HELP_STRING([--disable-libplacebo],
4125 [disable libplacebo support (default auto)])])
4127 AS_IF([test "$enable_libplacebo" != "no"], [
4128 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4129 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4130 ], [
4131 AS_IF([test -n "${enable_libplacebo}"], [
4132 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4133 ])
4134 enable_libplacebo="no"
4135 ])
4136 ])
4137 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4140 dnl
4141 dnl Endianness check
4142 dnl
4143 AC_C_BIGENDIAN
4144 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4145 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4146 ], [
4147 DEFS_BIGENDIAN=""
4148 ])
4149 AC_SUBST(DEFS_BIGENDIAN)
4151 dnl
4152 dnl Where to install KDE solid .desktop
4153 dnl
4154 AC_ARG_WITH(kde-solid,
4155 AS_HELP_STRING([--with-kde-solid=PATH],
4156 [KDE Solid actions directory (auto)]),, [
4158 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4159 with_kde_solid="yes"
4160 fi
4161 ])
4162 soliddatadir=""
4163 AS_IF([test "${with_kde_solid}" != "no"], [
4164 AS_IF([test "${with_kde_solid}" = "yes"], [
4165 kde4datadir="`${KDE4_CONFIG} --install data`"
4166 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4167 soliddatadir="${kde4datadir}/solid/actions"
4168 ], [
4169 soliddatadir="${with_kde_solid}"
4170 ])
4171 ])
4172 AC_SUBST(soliddatadir)
4173 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4175 dnl
4176 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4177 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4178 dnl
4179 if test "${SYS}" = "mingw32"; then
4180 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4181 fi
4183 EXTEND_HELP_STRING([Components:])
4185 dnl
4186 dnl the VLC binary
4187 dnl
4188 AC_ARG_ENABLE(vlc,
4189 [ --enable-vlc build the VLC media player (default enabled)])
4190 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4192 dnl
4193 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4194 dnl
4195 AS_VAR_IF(with_libfuzzer, no, [], [
4196 LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4197 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4198 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4199 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4200 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4201 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4202 ], [
4203 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4204 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4205 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4206 ], [
4207 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4208 ])
4209 ])
4210 ])
4212 dnl
4213 dnl Stuff used by the program
4214 dnl
4215 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4216 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4217 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4218 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4219 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4220 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4221 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4222 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4223 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4224 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4225 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4226 AC_SUBST(COPYRIGHT_MESSAGE)
4227 AC_SUBST(VERSION_MESSAGE)
4228 AC_SUBST(VERSION_MAJOR)
4229 AC_SUBST(VERSION_MINOR)
4230 AC_SUBST(VERSION_REVISION)
4231 AC_SUBST(VERSION_EXTRA)
4232 AC_SUBST(COPYRIGHT_YEARS)
4233 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4234 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4235 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4236 dnl
4237 dnl Handle substvars that use $(top_srcdir)
4238 dnl
4239 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4241 dnl
4242 dnl Configuration is finished
4243 dnl
4244 AC_SUBST(SYS)
4245 AC_SUBST(ARCH)
4246 AC_SUBST(ALIASES)
4247 AC_SUBST(ASM)
4248 AC_SUBST(MOC)
4249 AC_SUBST(RCC)
4250 AC_SUBST(UIC)
4251 AC_SUBST(WINDRES)
4252 AC_SUBST(WINE_SDK_PATH)
4253 AC_SUBST(LIBEXT)
4254 AC_SUBST(AM_CPPFLAGS)
4255 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4256 AC_SUBST(FILE_LIBVLCCORE_DLL)
4257 AC_SUBST(FILE_LIBVLC_DLL)
4259 AC_CONFIG_FILES([
4260 Makefile
4261 doc/Makefile
4262 modules/Makefile
4263 m4/Makefile
4264 po/Makefile.in
4265 share/Makefile
4266 compat/Makefile
4267 src/Makefile
4268 lib/Makefile
4269 bin/Makefile
4270 test/Makefile
4271 modules/hw/mmal/Makefile
4272 share/vlc.appdata.xml.in
4273 ])
4275 AM_COND_IF([HAVE_WIN32], [
4276 AC_CONFIG_FILES([
4277 extras/package/win32/NSIS/spad.nsi
4278 extras/package/win32/NSIS/vlc.win32.nsi
4279 extras/package/win32/msi/config.wxi
4280 ])
4281 ])
4283 AM_COND_IF([HAVE_DARWIN], [
4284 AC_CONFIG_FILES([
4285 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4286 share/macosx/Info.plist:share/Info.plist.in
4287 ])
4288 ])
4290 dnl Generate makefiles
4291 AC_OUTPUT
4293 dnl Do we have to use make or gmake ?
4294 if make --version 2>&1|grep -q GNU
4295 then
4296 # GNU make, all seems good
4297 MAKE=make
4298 else
4299 # Known GNU make alias (on BSD)
4300 MAKE=gmake
4301 fi
4302 dnl Shortcut to nice compile message
4303 if test -n $SHELL; then
4304 SHELL=${CONFIG_SHELL-/bin/sh}
4305 fi
4306 rm -f compile
4307 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4308 echo "#! $SHELL
4309 rm -f .error\$\$
4310 ERROR=0
4311 export PATH=\"$PATH\" LANG=C
4312 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4313 test -f .error\$\$ && ERROR=1
4314 rm -f .error\$\$
4315 exit \$ERROR" >compile
4316 chmod a+x compile
4318 echo "
4319 libvlc configuration
4320 --------------------
4321 version : ${VERSION}
4322 system : ${SYS}
4323 architecture : ${ARCH}
4324 optimizations : ${enable_optimizations}"
4325 if test "${enable_vlc}" != "no"; then
4326 echo "vlc aliases :${ALIASES}"
4327 else
4328 echo "build vlc executable : no"
4329 fi
4330 echo "
4331 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."