configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2017"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl Prevent clang from accepting unknown flags with a mere warning
  98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
 100
 101 dnl
 102 dnl  Check the operating system
 103 dnl
 104 HAVE_WIN64="0"
 105 HAVE_IOS="0"
 106 HAVE_OSX="0"
 107 HAVE_TVOS="0"
 108
 109 case "${host_os}" in
 110   "")
 111     SYS=unknown
 112     ;;
 113   linux*)
 114     SYS=linux
 115     ;;
 116   bsdi*)
 117     SYS=bsdi
 118     CFLAGS="${CFLAGS} -pthread"
 119     ;;
 120   freebsd*)
 121     SYS=freebsd
 122     CFLAGS="${CFLAGS} -pthread"
 123     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 124     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 125     ac_cv_ld_z_defs=no
 126     ;;
 127   openbsd*)
 128     SYS=openbsd
 129     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 130     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 131     ;;
 132   netbsd*)
 133     SYS=netbsd
 134     ;;
 135   dragonfly*)
 136     SYS=dragonfly
 137     ;;
 138   darwin*)
 139
 140     dnl Force gcc "-arch" flag
 141     ARCH_flag=""
 142     case "${host}" in
 143       i?86*)
 144         ARCH_flag="-arch i386"
 145       ;;
 146       ppc64*)
 147         ARCH_flag="-arch ppc64"
 148       ;;
 149       ppc*)
 150         ARCH_flag="-arch ppc"
 151       ;;
 152       x86_64*)
 153         ARCH_flag="-arch x86_64"
 154       ;;
 155       arm*)
 156         ac_cv_c_bigendian="no"
 157         ac_cv_c_attribute_packed="no"
 158       ;;
 159     esac
 160
 161     SYS=darwin
 162     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 163     CXX="${CXX} -stdlib=libc++ -std=c++11"
 164     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 165     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 166     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 167     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 168     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 169     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 170
 171     AC_EGREP_CPP(yes,
 172             [#import <TargetConditionals.h>
 173              #if TARGET_OS_IPHONE
 174              yes
 175              #endif],
 176              [HAVE_IOS="1"],
 177              [HAVE_OSX="1"])
 178
 179     AC_EGREP_CPP(yes,
 180             [#import <TargetConditionals.h>
 181              #if TARGET_OS_TV
 182              yes
 183              #endif],
 184              [HAVE_TVOS="1"
 185              HAVE_IOS="0"
 186              HAVE_OSX="0"
 187              ],)
 188
 189     dnl Allow binaries created on Lion to run on earlier releases
 190     AC_EGREP_CPP(yes,
 191            [#import <Cocoa/Cocoa.h>
 192             #ifdef MAC_OS_X_VERSION_10_7
 193             yes
 194             #endif],
 195             [AC_MSG_RESULT([yes])
 196             AC_LIBOBJ([getdelim])
 197             AC_LIBOBJ([strndup])
 198             AC_LIBOBJ([strnlen])],)
 199
 200     dnl
 201     dnl  Handle Mac OS X SDK flags
 202     dnl
 203     AC_ARG_WITH(macosx-sdk,
 204       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 205         [compile using the SDK in DIR])])
 206     if test "${with_macosx_sdk}" != "" ; then
 207         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 208         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 209         CC="${CC} -isysroot ${with_macosx_sdk}"
 210         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 211         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 212         LD="${LD} -syslibroot ${with_macosx_sdk}"
 213     fi
 214     AC_ARG_WITH(macosx-version-min,
 215       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 216         [compile for Mac OS X VERSION and above])])
 217     if test "${with_macosx_version_min}" != "" ; then
 218         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 219         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 220         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 221         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 222         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 223     fi
 224     ;;
 225   *mingw32* | *cygwin* | *wince* | *mingwce*)
 226     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 227     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 228     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 229     AC_CHECK_TOOL(WINDRES, windres, :)
 230     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 231     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 232     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 233     AH_TOP([#endif])
 234     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 235     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 236     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 237     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 238     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 239     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 240     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 241     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 242     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 243     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 244     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 245
 246     case "${host_os}" in
 247       *mingw32*)
 248         SYS=mingw32
 249         ;;
 250       *cygwin*)
 251         dnl Check if we are using the mno-cygwin mode in which case we are
 252         dnl actually dealing with a mingw32 compiler.
 253         AC_EGREP_CPP(yes,
 254             [#ifdef _WIN32
 255              yes
 256              #endif],
 257             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 258         ;;
 259     esac
 260
 261     if test "${SYS}" = "mingw32"; then
 262         # DEP, ASLR, NO SEH
 263         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 264
 265         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 266         ac_default_prefix="`pwd`/_win32"
 267         DESTDIR="`pwd`/_win32/"
 268
 269         dnl
 270         dnl NSIS/MSI Installer prefix and WIN64
 271         dnl
 272         case "${host}" in
 273             amd64*|x86_64*)
 274                 HAVE_WIN64="1"
 275                 WINDOWS_ARCH="x64"
 276                 PROGRAMFILES="PROGRAMFILES64"
 277                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 278             ;;
 279             *)
 280                 WINDOWS_ARCH="x86"
 281                 PROGRAMFILES="PROGRAMFILES"
 282             ;;
 283         esac
 284         AC_SUBST(WINDOWS_ARCH)
 285         AC_SUBST(PROGRAMFILES)
 286
 287     fi
 288     ;;
 289   *nto*)
 290     SYS=nto
 291     ;;
 292   solaris*)
 293     SYS=solaris
 294     ;;
 295   hpux*)
 296     SYS=hpux
 297     ;;
 298   *os2*)
 299     SYS=os2
 300     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 301     AC_LIBOBJ([freeaddrinfo])
 302     AC_LIBOBJ([gai_strerror])
 303     ;;
 304   *nacl*)
 305     SYS=nacl
 306     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 307     AC_LIBOBJ([sigwait])
 308     AC_LIBOBJ([recvmsg])
 309     AC_LIBOBJ([sendmsg])
 310     ;;
 311   *)
 312     SYS="${host_os}"
 313     ;;
 314 esac
 315
 316 dnl WinRT
 317 AC_ARG_ENABLE(winstore_app,
 318      AS_HELP_STRING([--enable-winstore-app],
 319                     [Build targetted for Windows Store apps (default disabled)]))
 320
 321 vlc_winstore_app=0
 322 AS_IF([test "${SYS}" = "mingw32"],[
 323   LIBCOM="-lole32"
 324   AS_IF([test "${enable_winstore_app}" = "yes"], [
 325     vlc_winstore_app=1
 326     LIBCOM=""
 327      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 328      AC_LIBOBJ([gai_strerror])
 329     ],[])
 330   AC_SUBST(LIBCOM)
 331   ])
 332 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 333
 334 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 335 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 336
 337 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 338 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 339 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 340 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 341
 342 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 343
 344 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 345 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 346 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 347 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 348
 349 dnl
 350 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 351 dnl for program foo on win32
 352 case "${build_os}" in
 353     cygwin|msys|mingw32)
 354         ac_executable_extensions=".exe"
 355         BUILDEXEEXT=".exe"
 356     ;;
 357     os2*)
 358         BUILDEXEEXT=".exe"
 359     ;;
 360     *)
 361     ;;
 362 esac
 363 AC_SUBST(BUILDEXEEXT)
 364
 365 dnl Android is linux, but a bit different
 366 AS_IF([test "$SYS" = linux],[
 367     AC_MSG_CHECKING([for an Android system])
 368     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 369         [[#ifndef __ANDROID__
 370          # error Not Android
 371          #endif
 372         ]],[[;]])
 373     ],[
 374       HAVE_ANDROID="1"
 375       AC_MSG_RESULT([yes])
 376     ],[
 377       AC_MSG_RESULT([no])
 378     ])
 379 ])
 380 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 381
 382 dnl Tizen (minimum SDK version: 2.3)
 383 AS_IF([test "$SYS" = linux],[
 384     AC_MSG_CHECKING([for Tizen])
 385     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 386         [[#include <tizen.h>
 387         ]],[[;]])
 388     ],[
 389       HAVE_TIZEN="1"
 390       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 391       AC_MSG_RESULT([yes])
 392     ],[
 393       AC_MSG_RESULT([no])
 394     ])
 395 ])
 396 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 397
 398 dnl
 399 dnl  Check for the contrib directory
 400 dnl
 401 AC_ARG_WITH(contrib,
 402   [AS_HELP_STRING([--with-contrib[=DIR]],
 403     [search for 3rd party libraries in DIR/include and DIR/lib])
 404 ])
 405 AC_MSG_CHECKING([for 3rd party libraries path])
 406 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 407   CONTRIB_DIR="${srcdir}/contrib/${host}"
 408   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 409     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 410     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 411     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 412       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 413       CONTRIB_DIR=""
 414       AC_MSG_RESULT([not found])
 415     ])
 416   ])
 417 ], [
 418   AS_IF([test "${with_contrib}" != "no"], [
 419     CONTRIB_DIR="${with_contrib}"
 420   ], [
 421     CONTRIB_DIR=""
 422     AC_MSG_RESULT([disabled])
 423   ])
 424 ])
 425 AS_IF([test -n "${CONTRIB_DIR}"], [
 426   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 427     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 428   ], [
 429     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 430     CONTRIB_DIR=""
 431     AC_MSG_RESULT([not usable])
 432   ])
 433
 434 ])
 435 AS_IF([test -n "${CONTRIB_DIR}"], [
 436   AC_MSG_RESULT([${CONTRIB_DIR}])
 437   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 438   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 439   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 440   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 441   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 442   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 443
 444   AS_IF([test -z "$LUAC"], [
 445     dnl Old contribs mixed cross-tools and cross-compiled executables
 446     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 447       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 448     ])
 449
 450     dnl Newer contribs follow usual name space rules
 451     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 452       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 453     ])
 454   ])
 455
 456   AS_IF([test "${SYS}" = "darwin"], [
 457     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 458     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 459   ])
 460 ], [
 461   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 462     AC_MSG_ERROR([Third party libraries not found!])
 463   ])
 464 ])
 465 AC_SUBST(CONTRIB_DIR)
 466
 467 dnl Add extras/tools to the PATH
 468 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 469 AS_IF([test -d "${TOOLS_DIR}"], [
 470     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 471     export PATH="${TOOLS_DIR}":$PATH
 472 ])
 473
 474 dnl
 475 dnl  Libtool
 476 dnl  It's very bad, but our former custom system was worst
 477 dnl  -- Courmisch
 478 dnl
 479
 480 dnl override platform specific check for dependent libraries
 481 dnl otherwise libtool linking of shared libraries will
 482 dnl fail on anything other than pass_all.
 483 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 484     [lt_cv_deplibs_check_method=pass_all])
 485
 486 LT_INIT([dlopen win32-dll shared disable-static])
 487 LT_LANG([C++])
 488 LT_LANG([Windows Resource])
 489
 490 DOLT
 491
 492 lt_cv_deplibs_check_method=pass_all
 493
 494 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 495   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 496 ])
 497
 498 dnl
 499 dnl Gettext stuff
 500 dnl
 501 AM_GNU_GETTEXT_VERSION([0.19.8])
 502 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 503
 504 dnl
 505 dnl Iconv stuff
 506 dnl
 507 AM_ICONV
 508
 509 dnl
 510 dnl checks for mingw
 511 AS_IF([test "${SYS}" = "mingw32"], [
 512
 513 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 514 #if !defined(__MINGW32__)
 515 # error Not compiling with mingw
 516 #endif
 517     ])], [
 518
 519 dnl Check for broken versions of mingw-runtime compatability library
 520     AC_MSG_CHECKING(for broken mingw-runtime)
 521     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 522 #include <_mingw.h>
 523 #if defined(__MINGW64_VERSION_MAJOR)
 524 # if __MINGW64_VERSION_MAJOR < 3
 525 #  error Attempting to use mingw-runtime with broken vsnprintf support
 526 # endif
 527 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 528 # error Attempting to use mingw-runtime with broken vsnprintf support
 529 #endif
 530     ])], [
 531         AC_MSG_RESULT([ok])
 532     ], [
 533         AC_MSG_RESULT([present])
 534         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 535     ])
 536
 537     dnl force use of mingw provided c99 *printf over msvcrt
 538     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 539
 540     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 541     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 542
 543     dnl Check for the need to include the mingwex lib for mingw32
 544     VLC_SAVE_FLAGS
 545     AC_CHECK_LIB(mingwex,opendir,
 546         AC_CHECK_LIB(mingw32,opendir,,
 547             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 548     )
 549     VLC_RESTORE_FLAGS
 550     ], [
 551         AC_MSG_RESULT([Not compiling with mingw])
 552     ])
 553
 554     dnl Check for fnative-struct or mms-bitfields support for mingw32
 555     VLC_SAVE_FLAGS
 556     CFLAGS="${CFLAGS} -mms-bitfields"
 557     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 558     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 559         [ac_cv_c_mms_bitfields],
 560         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 561     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 562         VLC_RESTORE_FLAGS
 563         CFLAGS="${CFLAGS} -fnative-struct"
 564         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 565         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 566             [ac_cv_c_fnative_struct],
 567             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 568         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 569     fi
 570 ])
 571
 572
 573 dnl
 574 dnl Buggy glibc prevention. Purposedly not cached.
 575 dnl See sourceware.org bugs 5058 and 5443.
 576 dnl Ubuntu alone has 20 bug numbers for this...
 577 dnl
 578 AC_MSG_CHECKING(for buggy GNU/libc versions)
 579 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 580 #include <limits.h>
 581 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 582   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 583 # error GNU/libc with dcgettext killer bug!
 584 #endif
 585 ])], [
 586   AC_MSG_RESULT([not present])
 587 ], [
 588   AC_MSG_RESULT([found])
 589   AS_IF([test "x${enable_nls}" != "xno"], [
 590     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 591 work-around for this. Check with your distribution vendor on how to update the
 592 glibc run-time. Alternatively, build with --disable-nls.])
 593   ])
 594 ])
 595
 596 dnl Plugin compilation stuff
 597
 598 VLC_LIBRARY_SUFFIX
 599
 600 dnl Check for system libs needed
 601 need_libc=false
 602
 603 dnl Check for usual libc functions
 604 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 605 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 606 AC_REPLACE_FUNCS([gettimeofday])
 607 AC_CHECK_FUNC(fdatasync,,
 608   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 609 ])
 610
 611 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 612
 613 dnl mingw64 implements those as static inline, not functions with C linkage
 614 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 615 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 616 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 617 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 618
 619 dnl C11 static_assert()
 620 AC_MSG_CHECKING([for static_assert in assert.h])
 621 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 622 static_assert(1, "The impossible happened.");
 623 ])], [
 624   AC_MSG_RESULT([yes])
 625   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 626 ], [
 627   AC_MSG_RESULT([no])
 628 ])
 629
 630 # Windows CE does not have strcoll()
 631 AC_FUNC_STRCOLL
 632
 633 dnl Check for non-standard system calls
 634 case "$SYS" in
 635   "linux")
 636     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
 637     ;;
 638   "mingw32")
 639     AC_CHECK_FUNCS([_lock_file])
 640     ;;
 641 esac
 642
 643 AH_BOTTOM([#include <vlc_fixups.h>])
 644
 645 dnl Check for struct pollfd
 646 AC_CHECK_TYPES([struct pollfd],,,
 647 [#include <sys/types.h>
 648 #if HAVE_POLL
 649 # include <poll.h>
 650 #elif defined (_WIN32)
 651 # include <winsock2.h>
 652 #endif
 653 ])
 654
 655 dnl Check for struct timespec
 656 AC_CHECK_TYPES([struct timespec],,,
 657 [#include <time.h>])
 658
 659 dnl Check for max_align_t
 660 AC_CHECK_TYPES([max_align_t],,,
 661 [#include <stddef.h>])
 662
 663 dnl Checks for socket stuff
 664 VLC_SAVE_FLAGS
 665 SOCKET_LIBS=""
 666 AC_SEARCH_LIBS(connect, [socket], [
 667   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 668     SOCKET_LIBS="$ac_cv_search_connect"
 669   ])
 670 ], [
 671   AS_IF([test "${SYS}" = "mingw32"], [
 672     SOCKET_LIBS="-lws2_32"
 673   ])
 674 ])
 675
 676 AC_SEARCH_LIBS([inet_pton], [nsl], [
 677  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 678     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 679   ])
 680 ],, [${SOCKET_LIBS}])
 681
 682 LIBS="${LIBS} ${SOCKET_LIBS}"
 683 AC_LINK_IFELSE([
 684     AC_LANG_PROGRAM([#ifdef _WIN32
 685         # if _WIN32_WINNT < 0x600
 686         #  error Needs vista+
 687         # endif
 688         #include <ws2tcpip.h>
 689         #else
 690         #include <sys/socket.h>
 691         #include <arpa/inet.h>
 692         #endif], [
 693         char dst[[sizeof(struct in_addr)]];
 694         inet_pton(AF_INET, "127.0.0.1", dst);
 695     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 696 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 697 VLC_RESTORE_FLAGS
 698 AC_SUBST(SOCKET_LIBS)
 699
 700 dnl Check for socklen_t
 701 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 702 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 703 ac_cv_type_socklen_t,
 704 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 705 [#include <sys/types.h>
 706 #ifdef _WIN32
 707 # include <winsock2.h>
 708 # include <ws2tcpip.h>
 709 #else
 710 # include <sys/socket.h>
 711 #endif]], [[socklen_t len; len = 0;]])],
 712 ac_cv_type_socklen_t=yes,
 713 ac_cv_type_socklen_t=no)])
 714 AS_IF([test "$ac_cv_type_socklen_t" = no],
 715  [AC_DEFINE(socklen_t, int)])
 716
 717 dnl Check for struct sockaddr_storage
 718 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 719 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 720 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 721   [AC_TRY_COMPILE(
 722     [#include <sys/types.h>
 723      #if defined( _WIN32 )
 724      # include <winsock2.h>
 725      #else
 726      # include <sys/socket.h>
 727      #endif], [struct sockaddr_storage addr;],
 728      ac_cv_struct_sockaddr_storage=yes,
 729      ac_cv_struct_sockaddr_storage=no)])
 730 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 731   AC_DEFINE(sockaddr_storage, sockaddr)
 732   AC_DEFINE(ss_family, sa_family)
 733 ])
 734
 735 dnl FreeBSD has a gnugetopt library for this:
 736 GNUGETOPT_LIBS=""
 737 AC_CHECK_FUNC(getopt_long,, [
 738   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 739     GNUGETOPT_LIBS="-lgnugetopt"
 740   ])
 741 ])
 742 AC_SUBST(GNUGETOPT_LIBS)
 743
 744 AC_CHECK_LIB(m,cos,[
 745   LIBM="-lm"
 746 ], [
 747   LIBM=""
 748 ])
 749 AC_SUBST(LIBM)
 750
 751 AC_CHECK_LIB(m,lrintf, [
 752   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 753   VLC_ADD_LIBS([skins2],[-lm])
 754 ])
 755 AC_CHECK_LIB(m,nanf,
 756   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 757 )
 758 AC_CHECK_LIB(m,sincos, [
 759   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 760 ], [
 761   AC_LIBOBJ([sincos])
 762 ])
 763
 764 AC_MSG_CHECKING([_Thread_local support])
 765 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 766                    int main() {}])], [
 767     AC_MSG_RESULT([ok])
 768     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 769 ],[ AC_MSG_RESULT([no])])
 770
 771 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 772 dnl check for its availability explicitely
 773 AC_CHECK_HEADERS([threads.h])
 774
 775 dnl Check for dynamic plugins
 776 LIBDL=""
 777 have_dynamic_objects="no"
 778 VLC_SAVE_FLAGS
 779 AC_SEARCH_LIBS(dlsym, [dl svld], [
 780   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 781     LIBDL="$ac_cv_search_dlsym"
 782   ])
 783   have_dynamic_objects="yes"
 784 ])
 785 VLC_RESTORE_FLAGS
 786
 787 # Windows
 788 AS_IF([test "${SYS}" = "mingw32"], [
 789   LIBDL=""
 790   have_dynamic_objects="yes" #assume we can use shared objects
 791 ])
 792
 793 AS_IF([test "${enable_shared}" = "no"], [
 794   have_dynamic_objects=no
 795 ])
 796 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 797
 798 AC_SUBST(LIBDL)
 799
 800 dnl Check for thread library
 801 LIBPTHREAD=""
 802 AS_IF([test "${SYS}" != "mingw32"], [
 803   VLC_SAVE_FLAGS
 804   LIBS=""
 805   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 806     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 807       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 808     ])
 809   ])
 810   VLC_RESTORE_FLAGS
 811 ])
 812 AC_SUBST(LIBPTHREAD)
 813
 814 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 815   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 816     LIBRT="$ac_cv_search_clock_nanosleep"
 817   ])
 818 ], [
 819   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 820     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 821       LIBRT="$ac_cv_search_nanosleep"
 822     ])
 823   ])
 824 ])
 825 AC_SUBST(LIBRT)
 826
 827 dnl
 828 dnl Check for headers
 829 dnl
 830
 831 dnl  POSIX
 832 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 833 AC_CHECK_HEADERS([net/if.h], [], [],
 834 [
 835 #include <sys/types.h>
 836 #include <sys/socket.h>
 837 ])
 838 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 839 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 840
 841 dnl  BSD
 842 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 843
 844 dnl  GNU/Linux
 845 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 846
 847 dnl  MacOS
 848 AC_CHECK_HEADERS([xlocale.h])
 849
 850 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 851 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 852 AC_CHECK_TYPE(ssize_t,, [
 853   AC_DEFINE(ssize_t, int)
 854 ])
 855
 856 dnl It seems that autoconf detects pkg-config only during the first
 857 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 858 dnl it is nested within a conditional block, so it was not working right.
 859 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 860 AC_ARG_VAR(PKG_CONFIG_PATH,
 861        [Paths where to find .pc not at the default location])
 862 PKG_PROG_PKG_CONFIG()
 863
 864 dnl On some OS we need static linking
 865 AS_IF([test -n "${PKG_CONFIG}" ],[
 866     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 867         PKG_CONFIG="${PKG_CONFIG} --static"
 868     ])
 869 ])
 870
 871
 872 dnl
 873 dnl Check for zlib.h and -lz along with system -lminizip if available
 874 dnl
 875 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 876 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 877 if test "${have_zlib}" = "yes"
 878 then
 879   VLC_ADD_LIBS([sap],[-lz])
 880   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 881     AC_CHECK_HEADERS([unzip.h], [
 882       have_minizip=yes
 883       MINIZIP_LIBS="-lminizip -lz"
 884     ], [
 885       have_minizip=no
 886     ])
 887   ])
 888 fi
 889 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 890
 891
 892 dnl
 893 dnl Domain name i18n support via GNU libidn
 894 dnl
 895 PKG_CHECK_MODULES([IDN], [libidn], [
 896   have_libidn="yes"
 897   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 898 ], [
 899   have_libidn="no"
 900 ])
 901
 902
 903 dnl Check for dbus
 904 AC_ARG_ENABLE(dbus,
 905   [AS_HELP_STRING([--enable-dbus],
 906     [compile D-Bus message bus support (default enabled)])])
 907 have_dbus="no"
 908 AS_IF([test "${enable_dbus}" != "no"], [
 909   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 910     have_dbus="yes"
 911   ], [
 912     AS_IF([test -n "${enable_dbus}"], [
 913       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 914     ], [
 915       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 916     ])
 917   ])
 918 ])
 919 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 920
 921
 922 dnl Check for systemd
 923 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 924   have_systemd="yes"
 925 ], [
 926   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 927 ])
 928 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 929
 930
 931 EXTEND_HELP_STRING([Optimization options:])
 932 dnl
 933 dnl  Compiler warnings
 934 dnl
 935
 936 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
 937 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
 938
 939 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local], [CFLAGS])
 940 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 941
 942 dnl
 943 dnl  Debugging mode
 944 dnl
 945 AC_ARG_ENABLE(debug,
 946   [AS_HELP_STRING([--enable-debug],
 947     [build with run-time assertions (default disabled)])],,
 948   [enable_debug="no"])
 949 AH_TEMPLATE(NDEBUG,
 950             [Define to 1 if debug code should NOT be compiled])
 951 AS_IF([test "${enable_debug}" != "no"], [
 952   AC_CHECK_HEADERS([valgrind/valgrind.h])
 953 ], [
 954   AC_DEFINE(NDEBUG)
 955 ])
 956
 957 dnl
 958 dnl  Profiling
 959 dnl
 960 AC_ARG_ENABLE(gprof,
 961   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 962   [enable_gprof="no"])
 963 AS_IF([test "${enable_gprof}" != "no"], [
 964   CFLAGS="${CFLAGS} -pg"
 965   CXXFLAGS="${CXXFLAGS} -pg"
 966   OBJCFLAGS="${OBJCFLAGS} -pg"
 967   LDFLAGS="${LDFLAGS} -pg"
 968 ])
 969
 970 AC_ARG_ENABLE(cprof,
 971   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 972   [enable_cprof="no"])
 973 AS_IF([test "${enable_gprof}" != "no"], [
 974   CFLAGS="${CFLAGS} -finstrument-functions"
 975   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 976   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 977   LDFLAGS="${LDFLAGS} -finstrument-functions"
 978 ])
 979
 980 dnl
 981 dnl  Test coverage
 982 dnl
 983 AC_ARG_ENABLE(coverage,
 984   [AS_HELP_STRING([--enable-coverage],
 985     [build for test coverage (default disabled)])],,
 986   [enable_coverage="no"])
 987 AS_IF([test "${enable_coverage}" != "no"], [
 988   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 989   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 990   LDFLAGS="-lgcov ${LDFLAGS}"
 991 ])
 992
 993 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 994   VLC_SAVE_FLAGS
 995   CFLAGS="${CFLAGS} -fvisibility=hidden"
 996   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 997   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 998   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 999                  [ac_cv_c_visibility_hidden], [
1000     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1001       ac_cv_c_visibility_hidden=yes
1002     ], [
1003       ac_cv_c_visibility_hidden=no
1004     ])
1005   ])
1006   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1007 ])
1008
1009 dnl
1010 dnl Sanitizer flags
1011 dnl
1012 AC_ARG_WITH([sanitizer],
1013     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1014         [build with sanitizer flags (default disabled)])],
1015      [],
1016      [with_sanitizer=no])
1017
1018 AS_VAR_IF(with_sanitizer, no, [], [
1019     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1020         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1021         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1022         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1023     ], [
1024         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1025     ])
1026     AX_APPEND_FLAG([-g])
1027     AX_APPEND_FLAG([-g], [CXXFLAGS])
1028
1029     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1030        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1031        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1032     ])
1033     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1034         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1035         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1036     ])
1037     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1038         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1039         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1040     ])
1041 ])
1042
1043 dnl
1044 dnl  Enable/disable optimizations
1045 dnl
1046 AC_ARG_ENABLE(optimizations,
1047   [AS_HELP_STRING([--disable-optimizations],
1048     [disable compiler optimizations (default enabled)])],,
1049   [enable_optimizations="yes"])
1050
1051 dnl Check for various optimization flags
1052 AS_IF([test "${enable_optimizations}" != "no"], [
1053
1054   dnl -O3 only in production builds
1055   AS_IF([test "${enable_debug}" = "no"], [
1056     VLC_SAVE_FLAGS
1057     CFLAGS="${CFLAGS} -O3"
1058     CXXFLAGS="${CXXFLAGS} -O3"
1059     OBJCFLAGS="${OBJCFLAGS} -O3"
1060     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1061       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1062         ac_cv_c_o3=yes
1063       ], [
1064         ac_cv_c_o3=no
1065       ])
1066     ])
1067     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1068   ])
1069
1070   dnl Check for fast maths
1071   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1072   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1073
1074 AH_BOTTOM([
1075 #if defined(_MSC_VER) && !defined(__clang__)
1076 # pragma fenv_access(off)
1077 # pragma fp_contract(on)
1078 #elif defined(__GNUC__)
1079 /* Not supported so far */
1080 #else
1081 # pragma STDC FENV_ACCESS OFF
1082 # pragma STDC FP_CONTRACT ON
1083 #endif
1084 ])
1085
1086   dnl Check for -funroll-loops
1087   VLC_SAVE_FLAGS
1088   CFLAGS="${CFLAGS} -funroll-loops"
1089   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1090   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1091   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1092     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1093       ac_cv_c_unroll_loops=yes
1094     ], [
1095       ac_cv_c_unroll_loops=no
1096     ])
1097   ])
1098   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1099
1100   AS_IF([test "$enable_debug" = "no"], [
1101     dnl Check for -fomit-frame-pointer
1102     VLC_SAVE_FLAGS
1103     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1104     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1105     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1106     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1107       [ac_cv_c_omit_frame_pointer], [
1108       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1109         ac_cv_c_omit_frame_pointer=yes
1110       ], [
1111         ac_cv_c_omit_frame_pointer=no
1112       ])
1113     ])
1114     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1115   ])
1116 ])
1117
1118 VLC_SAVE_FLAGS
1119 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1120 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1121   AC_TRY_LINK([],, [
1122     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1123   ], [
1124     ac_cv_ld_bsymbolic=""
1125   ])
1126 ])
1127 VLC_RESTORE_FLAGS
1128 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1129 AC_SUBST(SYMBOLIC_LDFLAGS)
1130
1131 VLC_SAVE_FLAGS
1132 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1133 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1134   AC_TRY_LINK([],, [
1135     ac_cv_ld_z_defs="yes"
1136   ], [
1137     ac_cv_ld_z_defs="no"
1138   ])
1139 ])
1140 AS_IF([test "${ac_cv_ld_z_defs}" = "no" -o "x$with_sanitizer" != xno], [VLC_RESTORE_FLAGS])
1141
1142 dnl Check for __attribute__((packed))
1143 AC_CACHE_CHECK([for __attribute__((packed))],
1144   [ac_cv_c_attribute_packed],
1145   [ac_cv_c_attribute_packed=no
1146    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1147                     [ac_cv_c_attribute_packed=yes])])
1148 if test "${ac_cv_c_attribute_packed}" != "no"; then
1149   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1150 fi
1151
1152 dnl
1153 dnl  Check the CPU
1154 dnl
1155 case "${host_cpu}" in
1156   "")
1157     ARCH=unknown
1158     ;;
1159   *)
1160     ARCH="${host_cpu}"
1161     ;;
1162 esac
1163
1164 dnl Check for backtrace() support
1165 AC_CHECK_HEADERS(execinfo.h)
1166 AC_CHECK_FUNCS(backtrace)
1167
1168 dnl
1169 dnl  default modules
1170 dnl
1171 ALIASES="${ALIASES} cvlc rvlc"
1172
1173 dnl
1174 dnl  Accelerated modules
1175 dnl
1176
1177 dnl  Check for fully working MMX intrinsics
1178 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1179 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1180 AC_ARG_ENABLE(mmx,
1181   [AS_HELP_STRING([--disable-mmx],
1182     [disable MMX optimizations (default auto)])],,[
1183   case "${host_cpu}" in
1184     i?86|x86_64)
1185       enable_mmx="yes"
1186       ;;
1187     *)
1188       enable_mmx="no"
1189       ;;
1190   esac
1191 ])
1192 have_mmx="no"
1193 have_mmxext="no"
1194 AS_IF([test "${enable_mmx}" != "no"], [
1195   ARCH="${ARCH} mmx"
1196   VLC_SAVE_FLAGS
1197   CFLAGS="${CFLAGS} -mmmx"
1198   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1199     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1200 [#include <mmintrin.h>
1201 #include <stdint.h>
1202 uint64_t frobzor;]], [
1203 [__m64 a, b, c;
1204 a = b = c = (__m64)frobzor;
1205 a = _mm_slli_pi16(a, 3);
1206 a = _mm_adds_pi16(a, b);
1207 c = _mm_srli_pi16(c, 8);
1208 c = _mm_slli_pi16(c, 3);
1209 b = _mm_adds_pi16(b, c);
1210 a = _mm_unpacklo_pi8(a, b);
1211 frobzor = (uint64_t)a;]])], [
1212       ac_cv_c_mmx_intrinsics=yes
1213     ], [
1214       ac_cv_c_mmx_intrinsics=no
1215     ])
1216   ])
1217   VLC_RESTORE_FLAGS
1218   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1219     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1220   ])
1221
1222   VLC_SAVE_FLAGS
1223   CFLAGS="${CFLAGS} -mmmx"
1224   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1225     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1226 void *p;
1227 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1228 ]])
1229     ], [
1230       ac_cv_mmx_inline=yes
1231     ], [
1232       ac_cv_mmx_inline=no
1233     ])
1234   ])
1235   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1236     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1237     have_mmx="yes"
1238   ])
1239
1240   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1241                  [ac_cv_mmxext_inline], [
1242     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1243 void *p;
1244 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1245 ]])
1246     ], [
1247       ac_cv_mmxext_inline=yes
1248     ], [
1249       ac_cv_mmxext_inline=no
1250     ])
1251   ])
1252   VLC_RESTORE_FLAGS
1253   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1254     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1255     have_mmxext="yes"
1256   ])
1257 ])
1258 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1259 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1260
1261 dnl  Check for fully workin SSE2 intrinsics
1262 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1263 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1264 AC_ARG_ENABLE(sse,
1265   [AS_HELP_STRING([--disable-sse],
1266     [disable SSE (1-4) optimizations (default auto)])],, [
1267   case "${host_cpu}" in
1268     i?86|x86_64)
1269       enable_sse=yes
1270       ;;
1271     *)
1272       enable_sse=no
1273       ;;
1274   esac
1275 ])
1276 have_sse2="no"
1277 AS_IF([test "${enable_sse}" != "no"], [
1278   ARCH="${ARCH} sse sse2"
1279
1280   VLC_SAVE_FLAGS
1281   CFLAGS="${CFLAGS} -msse2"
1282   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1283     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1284 [#include <emmintrin.h>
1285 #include <stdint.h>
1286 uint64_t frobzor;]], [
1287 [__m128i a, b, c;
1288 a = b = c = _mm_set1_epi64((__m64)frobzor);
1289 a = _mm_slli_epi16(a, 3);
1290 a = _mm_adds_epi16(a, b);
1291 c = _mm_srli_epi16(c, 8);
1292 c = _mm_slli_epi16(c, 3);
1293 b = _mm_adds_epi16(b, c);
1294 a = _mm_unpacklo_epi8(a, b);
1295 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1296       ac_cv_c_sse2_intrinsics=yes
1297     ], [
1298       ac_cv_c_sse2_intrinsics=no
1299     ])
1300   ])
1301   VLC_RESTORE_FLAGS
1302   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1303     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1304   ])
1305
1306   VLC_SAVE_FLAGS
1307   CFLAGS="${CFLAGS} -msse"
1308   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1309     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1310 void *p;
1311 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1312 ]])
1313     ], [
1314       ac_cv_sse_inline=yes
1315     ], [
1316       ac_cv_sse_inline=no
1317     ])
1318   ])
1319
1320   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1321     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1322   ])
1323
1324   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1325     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1326 void *p;
1327 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1328 ]])
1329     ], [
1330       ac_cv_sse2_inline=yes
1331     ], [
1332       ac_cv_sse2_inline=no
1333     ])
1334   ])
1335   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1336     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1337     have_sse2="yes"
1338   ])
1339
1340   # SSE3
1341   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1342     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1343 void *p;
1344 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1345 ]])
1346     ], [
1347       ac_cv_sse3_inline=yes
1348     ], [
1349       ac_cv_sse3_inline=no
1350     ])
1351   ])
1352
1353   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1354     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1355   # SSSE3
1356   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1357     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1358 void *p;
1359 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1360 ]])
1361     ], [
1362       ac_cv_ssse3_inline=yes
1363     ], [
1364       ac_cv_ssse3_inline=no
1365     ])
1366   ])
1367
1368   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1369     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1370
1371   # SSE4.1
1372   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1373                  [ac_cv_sse4_1_inline], [
1374     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1375 void *p;
1376 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1377 ]])
1378     ], [
1379       ac_cv_sse4_1_inline=yes
1380     ], [
1381       ac_cv_sse4_1_inline=no
1382     ])
1383   ])
1384
1385   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1386     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1387
1388   # SSE4.2
1389   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1390                  [ac_cv_sse4_2_inline], [
1391     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1392 void *p;
1393 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1394 ]])
1395     ], [
1396       ac_cv_sse4_2_inline=yes
1397     ], [
1398       ac_cv_sse4_2_inline=no
1399     ])
1400   ])
1401
1402   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1403     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1404
1405   # SSE4A
1406   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1407     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1408 void *p;
1409 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1410 ]])
1411     ], [
1412       ac_cv_sse4a_inline=yes
1413     ], [
1414       ac_cv_sse4a_inline=no
1415     ])
1416   ])
1417   VLC_RESTORE_FLAGS
1418   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1419     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1420 ])
1421 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1422
1423 VLC_SAVE_FLAGS
1424 CFLAGS="${CFLAGS} -mmmx"
1425 have_3dnow="no"
1426 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1427   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1428 void *p;
1429 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1430 ]])
1431   ], [
1432     ac_cv_3dnow_inline=yes
1433   ], [
1434     ac_cv_3dnow_inline=no
1435   ])
1436 ])
1437 VLC_RESTORE_FLAGS
1438 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1439   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1440             [Define to 1 if 3D Now! inline assembly is available.])
1441   have_3dnow="yes"
1442 ])
1443 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1444
1445
1446 AC_ARG_ENABLE(neon,
1447   [AS_HELP_STRING([--disable-neon],
1448     [disable NEON optimizations (default auto)])],, [
1449   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1450 ])
1451 AS_IF([test "${enable_neon}" != "no"], [
1452   VLC_SAVE_FLAGS
1453   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1454   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1455     AC_COMPILE_IFELSE([
1456       AC_LANG_PROGRAM(,[[
1457 asm volatile("vqmovun.s64 d0, q1":::"d0");
1458 ]])
1459     ], [
1460       ac_cv_arm_neon="yes"
1461     ], [
1462       ac_cv_arm_neon="no"
1463     ])
1464   ])
1465   VLC_RESTORE_FLAGS
1466 ])
1467 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1468
1469 AC_ARG_ENABLE(arm64,
1470   [AS_HELP_STRING([--disable-arm64],
1471     [disable arm 64-bit optimizations (default auto)])],, [
1472   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1473 ])
1474 AS_IF([test "${enable_arm64}" != "no"], [
1475   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1476     AC_COMPILE_IFELSE([
1477       AC_LANG_PROGRAM(,[[
1478 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1479 ]])
1480     ], [
1481       ac_cv_arm64="yes"
1482     ], [
1483       ac_cv_arm64="no"
1484     ])
1485   ])
1486 ])
1487 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1488
1489
1490 AC_ARG_ENABLE(altivec,
1491   [AS_HELP_STRING([--disable-altivec],
1492     [disable AltiVec optimizations (default auto)])],, [
1493   AS_CASE("${host_cpu}", [powerpc*],
1494         [enable_altivec=yes], [enable_altivec=no])
1495 ])
1496 have_altivec="no"
1497 ALTIVEC_CFLAGS=""
1498 AS_IF([test "${enable_altivec}" = "yes"], [
1499   ARCH="${ARCH} altivec";
1500   VLC_SAVE_FLAGS
1501   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1502     [ac_cv_altivec_inline],
1503     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1504          ac_cv_altivec_inline="yes",
1505          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1506           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1507             [ac_cv_altivec_inline="-Wa,-maltivec"],
1508             ac_cv_altivec_inline=no)
1509          ])])
1510   VLC_RESTORE_FLAGS
1511   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1512     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1513               [Define to 1 if AltiVec inline assembly is available.])
1514     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1515       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1516       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1517     ])
1518     have_altivec="yes"
1519   ])
1520
1521   VLC_SAVE_FLAGS
1522   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1523   [ac_cv_c_altivec], [
1524     CFLAGS="${CFLAGS} -maltivec"
1525     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1526 [#include <altivec.h>]], [
1527 [vec_ld(0, (unsigned char *)0);]])], [
1528       ac_cv_c_altivec="-maltivec"
1529     ], [
1530       ac_cv_c_altivec="no"
1531     ])
1532   ])
1533   VLC_RESTORE_FLAGS
1534   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1535     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1536     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1537     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1538     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1539     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1540     have_altivec="yes"
1541   ])
1542   AC_CHECK_HEADERS(altivec.h)
1543
1544   VLC_SAVE_FLAGS
1545   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1546   AC_CACHE_CHECK([if linker needs -framework vecLib],
1547     [ac_cv_ld_altivec],
1548     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1549   VLC_RESTORE_FLAGS
1550   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1551     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1552   ])
1553 ])
1554 AC_SUBST(ALTIVEC_CFLAGS)
1555 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1556
1557 dnl
1558 dnl  Memory usage
1559 dnl
1560 AC_ARG_ENABLE(optimize-memory,
1561   [AS_HELP_STRING([--enable-optimize-memory],
1562     [optimize memory usage over performance])])
1563 if test "${enable_optimize_memory}" = "yes"; then
1564   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1565 fi
1566
1567 dnl
1568 dnl Allow running as root (useful for people running on embedded platforms)
1569 dnl
1570 AC_ARG_ENABLE(run-as-root,
1571   [AS_HELP_STRING([--enable-run-as-root],
1572     [allow running VLC as root (default disabled)])])
1573 AS_IF([test "${enable_run_as_root}" = "yes"],[
1574     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1575               [Define to 1 to allow running VLC as root (uid 0).])
1576 ])
1577
1578 dnl
1579 dnl Stream output
1580 dnl
1581 AC_ARG_ENABLE(sout,
1582   [AS_HELP_STRING([--disable-sout],
1583     [disable streaming output (default enabled)])])
1584 AS_IF([test "${enable_sout}" != "no"], [
1585   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1586 ])
1587 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1588
1589 dnl Lua modules
1590 AC_ARG_ENABLE(lua,
1591   [AS_HELP_STRING([--disable-lua],
1592     [disable LUA scripting support (default enabled)])])
1593 if test "${enable_lua}" != "no"
1594 then
1595   PKG_CHECK_MODULES(LUA, lua5.2,
1596     [ have_lua=yes ],
1597     [
1598     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1599
1600     PKG_CHECK_MODULES(LUA, lua5.1,
1601       [ have_lua=yes ],
1602       [
1603       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1604       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1605         [ have_lua=yes ],
1606         [
1607           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1608           have_lua=yes
1609           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1610             [],
1611             [ have_lua=no ] )
1612           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1613             [LUA_LIBS="-llua5.2"],
1614           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1615             [LUA_LIBS="-llua5.1"],
1616             AC_CHECK_LIB( lua51 , luaL_newstate,
1617               [LUA_LIBS="-llua51"],
1618               AC_CHECK_LIB( lua , luaL_newstate,
1619                 [LUA_LIBS="-llua"],
1620                 [ have_lua=no
1621                 ], [-lm])
1622             )))
1623         ])
1624       ])
1625     ])
1626   if test "x${have_lua}" != "xyes" ;  then
1627       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1628   fi
1629   AC_ARG_VAR([LUAC], [LUA byte compiler])
1630   AS_IF([test -z "$LUAC"], [
1631      AC_CHECK_TOOL(LUAC, [luac], [false])
1632   ])
1633   AS_IF([test "${LUAC}" = "false"], [
1634     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1635   ])
1636   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1637     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1638   ])
1639 fi
1640 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1641
1642
1643 dnl
1644 dnl VideoLAN manager
1645 dnl
1646 AC_ARG_ENABLE(vlm,
1647   [AS_HELP_STRING([--disable-vlm],
1648     [disable the stream manager (default enabled)])],,
1649   [enable_vlm="${enable_sout}"])
1650 AS_IF([test "${enable_vlm}" != "no"], [
1651   AS_IF([test "${enable_sout}" = "no"], [
1652     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1653   ])
1654   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1655 ])
1656 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1657
1658
1659 dnl
1660 dnl Addons manager storage and repositories modules
1661 dnl
1662 AC_ARG_ENABLE(addonmanagermodules,
1663   [AS_HELP_STRING([--disable-addonmanagermodules],
1664     [disable the addons manager modules (default enabled)])])
1665 if test "${enable_addonmanagermodules}" != "no"
1666 then
1667   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1668 fi
1669 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1670
1671
1672 dnl
1673 dnl  Input plugins
1674 dnl
1675
1676 EXTEND_HELP_STRING([Input plugins:])
1677
1678 dnl
1679 dnl  libarchive access module
1680 dnl
1681 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1682
1683 dnl
1684 dnl  live555 input
1685 dnl
1686 AC_ARG_ENABLE(live555,
1687   [AS_HELP_STRING([--enable-live555],
1688     [enable RTSP input through live555 (default enabled)])])
1689
1690 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1691   PKG_CHECK_MODULES(LIVE555, live555, [
1692     VLC_ADD_PLUGIN([live555])
1693     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1694     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1695   ], [
1696     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1697
1698     AC_LANG_PUSH(C++)
1699     VLC_SAVE_FLAGS
1700
1701     dnl detect include paths
1702     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1703       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1704     ], [
1705       AS_IF([test "${SYS}" != "os2"], [
1706         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1707         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1708       ], [
1709         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1710         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1711         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1712       ])
1713     ])
1714
1715     dnl CPP Flags
1716     AS_IF([test "${SYS}" = "solaris"], [
1717       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1718     ])
1719     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1720     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1721
1722     dnl version check
1723     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1724       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1725 [#include <liveMedia_version.hh>
1726 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1727 # error BOOM
1728 #endif]])
1729       ], [
1730         ac_cv_live555="yes"
1731       ], [
1732         ac_cv_live555="no"
1733       ])
1734     ])
1735
1736     AS_IF([test "$ac_cv_live555" = "no"], [
1737       AC_MSG_WARN([live555 is missing or its installed version is too old:
1738 Version 2011.12.23 or later is required to proceed.
1739 You can get an updated one from http://www.live555.com/liveMedia .])
1740       AS_IF([test -n "${enable_live555}"], [
1741         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1742       ])
1743     ], [
1744       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1745       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1746       AS_IF([test "${SYS}" = "mingw32"], [
1747         # add ws2_32 for closesocket, select, recv
1748         other_libs="$other_libs -lws2_32"
1749       ])
1750
1751       dnl We need to check for pic because live555 don't provide shared libs
1752       dnl and we want to build a plugins so we need -fPIC on some arch.
1753       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1754       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1755       AC_CHECK_LIB(liveMedia_pic, main, [
1756         VLC_ADD_PLUGIN([live555])
1757         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1758       ],[
1759         AC_CHECK_LIB(liveMedia, main, [
1760           VLC_ADD_PLUGIN([live555])
1761           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1762         ],[],[${other_libs}])
1763       ],[${other_libs_pic}])
1764     ])
1765     VLC_RESTORE_FLAGS
1766     AC_LANG_POP(C++)
1767   ])
1768 ])
1769
1770 dnl
1771 dnl IIDC and DV FireWire input modules
1772 dnl
1773 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1774 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1775
1776 dnl
1777 dnl - linsys modules: access module check for libzvbi
1778 dnl
1779 AC_ARG_ENABLE(linsys,
1780   [AS_HELP_STRING([--enable-linsys],
1781     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1782 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1783   VLC_ADD_PLUGIN([linsys_hdsdi])
1784   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1785     VLC_ADD_PLUGIN([linsys_sdi])
1786   ], [
1787     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1788   ])
1789 ])
1790
1791 dnl
1792 dnl dvdread module: check for libdvdread
1793 dnl
1794 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1795
1796 dnl
1797 dnl libdvdnav plugin
1798 dnl
1799 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1800 AS_IF([test "${enable_dvdnav}" != "no"], [
1801   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1802     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1803       AC_MSG_RESULT(yes)
1804       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1805       ],[
1806       AC_MSG_RESULT(no)
1807     ])
1808 ])
1809
1810 dnl
1811 dnl  Blu-ray Disc Support with libbluray
1812 dnl
1813 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1814
1815 dnl
1816 dnl  OpenCV wrapper and example filters
1817 dnl
1818 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1819
1820
1821 dnl
1822 dnl  libsmbclient plugin
1823 dnl
1824 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1825 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1826
1827 dnl
1828 dnl  liBDSM access module
1829 dnl
1830 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1831
1832 dnl
1833 dnl sftp access support
1834 dnl
1835 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1836
1837 dnl
1838 dnl nfs access support
1839 dnl
1840 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1841
1842 dnl
1843 dnl  Video4Linux 2
1844 dnl
1845 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1846   [disable Video4Linux version 2 (default auto)])])
1847 have_v4l2="no"
1848 AS_IF([test "$enable_v4l2" != "no"], [
1849   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1850     have_v4l2="yes"
1851   ])
1852 ])
1853 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1854
1855 dnl
1856 dnl special access module for Blackmagic SDI cards
1857 dnl
1858 AC_ARG_ENABLE(decklink,
1859   [AS_HELP_STRING([--disable-decklink],
1860     [disable Blackmagic DeckLink SDI input (default auto)])])
1861 AC_ARG_WITH(decklink_sdk,
1862   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1863     [                        location of Blackmagic DeckLink SDI SDK])])
1864 have_decklink=no
1865 if test "${enable_decklink}" != "no"
1866 then
1867   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1868   then
1869     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1870   fi
1871   VLC_SAVE_FLAGS
1872   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1873   AC_LANG_PUSH(C++)
1874   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1875       have_decklink=yes
1876   ], [
1877       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1878   ])
1879   AC_LANG_POP(C++)
1880   VLC_RESTORE_FLAGS
1881 fi
1882 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1883
1884
1885 dnl
1886 dnl  Built-in CD-DA and VCD module
1887 dnl
1888 AC_ARG_ENABLE(vcd,
1889   [AS_HELP_STRING([--disable-vcd],
1890     [disable built-in VCD and CD-DA support (default enabled)])])
1891
1892 AC_ARG_ENABLE(libcddb,
1893   [AS_HELP_STRING([--disable-libcddb],
1894     [disable CDDB for Audio CD (default enabled)])])
1895
1896 if test "${enable_vcd}" != "no"
1897 then
1898   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1899   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1900     AC_MSG_RESULT(yes)
1901     VLC_ADD_PLUGIN([vcd cdda])
1902   ],[
1903     AC_MSG_RESULT(no)
1904   ])
1905
1906   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1907   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1908     AC_MSG_RESULT(yes)
1909     VLC_ADD_PLUGIN([vcd cdda])
1910     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1911   ],[
1912     AC_MSG_RESULT(no)
1913   ])
1914
1915   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1916   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1917     AC_MSG_RESULT(yes)
1918     VLC_ADD_PLUGIN([vcd cdda])
1919     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1920   ],[
1921     AC_MSG_RESULT(no)
1922   ])
1923
1924   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1925   then
1926     VLC_ADD_PLUGIN([vcd cdda])
1927   fi
1928
1929   if test "$enable_libcddb" != "no"; then
1930     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1931       HAVE_LIBCDDB=yes
1932       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1933       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1934       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1935       ],:
1936       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1937       HAVE_LIBCDDB=no])
1938   fi
1939 fi
1940
1941 dnl
1942 dnl Linux DVB
1943 dnl
1944 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1945   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1946 [#include <linux/dvb/version.h>
1947 #if (DVB_API_VERSION < 5)
1948 # error Linux DVB API v3.2 and older are not supported.
1949 #endif
1950 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1951 # error Linux DVB API v5.0 is unsupported. Please update.
1952 #endif
1953 ]])], [
1954   ac_cv_linux_dvb_5_1=yes
1955 ], [
1956   ac_cv_linux_dvb_5_1=no
1957 ])])
1958 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1959
1960 dnl
1961 dnl  Screen capture module
1962 dnl
1963 AC_ARG_ENABLE(screen,
1964   [AS_HELP_STRING([--enable-screen],
1965     [disable screen capture (default enabled)])])
1966 if test "${enable_screen}" != "no"; then
1967   if test "${SYS}" = "darwin"; then
1968     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1969       VLC_ADD_PLUGIN([screen])
1970     ])
1971   fi
1972 fi
1973 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1974
1975 dnl
1976 dnl  VNC/RFB access module
1977 dnl
1978 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1979
1980 dnl  RDP/Remote Desktop access module
1981 dnl
1982 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1983
1984 dnl
1985 dnl  Real RTSP plugin
1986 dnl
1987 AC_ARG_ENABLE(realrtsp,
1988   [  --enable-realrtsp       Real RTSP module (default disabled)])
1989 if test "${enable_realrtsp}" = "yes"; then
1990   VLC_ADD_PLUGIN([access_realrtsp])
1991 fi
1992
1993 dnl
1994 dnl QTKit
1995 AC_ARG_ENABLE(macosx-qtkit,
1996   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1997 if test "x${enable_macosx_qtkit}" != "xno" &&
1998   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1999 then
2000   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2001       VLC_ADD_PLUGIN([qtsound])
2002     ])
2003 fi
2004
2005 dnl
2006 dnl AVFoundation
2007 AC_SUBST(have_avfoundation, ["no"])
2008 AC_ARG_ENABLE(macosx-avfoundation,
2009   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2010 if test "x${enable_macosx_avfoundation}" != "xno" &&
2011   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2012 then
2013   SAVED_LIBS="${LIBS}"
2014   LIBS="-framework AVFoundation"
2015   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2016   LIBS="${SAVED_LIBS}"
2017   if test "${have_avfoundation}" != "no"
2018   then
2019     VLC_ADD_PLUGIN([avcapture])
2020   fi
2021 fi
2022 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2023
2024 dnl
2025 dnl  DCP plugin (using asdcplib)
2026 dnl
2027 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2028 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2029
2030 dnl
2031 dnl  Demux plugins
2032 dnl
2033
2034 EXTEND_HELP_STRING([Mux/Demux plugins:])
2035
2036 dnl
2037 dnl  libdvbpsi check for ts mux/demux
2038 dnl
2039 have_dvbpsi="no"
2040 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2041 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2042
2043
2044 dnl
2045 dnl  GME demux plugin
2046 dnl
2047 AC_ARG_ENABLE(gme,
2048   [AS_HELP_STRING([--enable-gme],
2049     [use Game Music Emu (default auto)])])
2050 AS_IF([test "${enable_gme}" != "no"], [
2051   AC_CHECK_HEADER([gme/gme.h], [
2052     VLC_ADD_LIBS([gme], [-lgme])
2053     VLC_ADD_PLUGIN([gme])
2054   ], [
2055     AS_IF([test "x${enable_gme}" != "x"], [
2056       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2057     ])
2058   ])
2059 ])
2060
2061
2062 dnl
2063 dnl  SIDPlay plugin
2064 dnl
2065 AC_ARG_ENABLE(sid,
2066     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2067 AS_IF([test "${enable_sid}" != "no"], [
2068     PKG_CHECK_MODULES(SID, [libsidplay2], [
2069         AC_LANG_PUSH(C++)
2070         oldCPPFLAGS="$CPPFLAGS"
2071         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2072         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2073             VLC_ADD_PLUGIN([sid])
2074             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2075             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2076         ], [
2077             AS_IF([test -n "${enable_sid}"],
2078                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2079                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2080                 )
2081         ])
2082         CPPFLAGS="$oldCPPFLAGS"
2083         AC_LANG_POP(C++)
2084     ], [
2085         AS_IF([test "x${enable_sid}" = "xyes"],
2086             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2087             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2088             )
2089     ])
2090 ])
2091
2092
2093 dnl
2094 dnl  ogg demux plugin
2095 dnl
2096 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2097 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2098     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2099 ],[true])
2100 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2101 if test "${enable_sout}" != "no"; then
2102 dnl Check for libshout
2103     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2104 fi
2105
2106 dnl
2107 dnl  matroska demux plugin
2108 dnl
2109 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2110
2111 dnl
2112 dnl  modplug demux plugin
2113 dnl
2114 AC_ARG_ENABLE(mod,
2115   [AS_HELP_STRING([--disable-mod],
2116     [do not use libmodplug (default auto)])])
2117 if test "${enable_mod}" != "no" ; then
2118     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2119           VLC_ADD_PLUGIN([mod])
2120           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2121           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2122           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2123     ],[
2124        AS_IF([test -n "${enable_mod}"],
2125          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2126          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2127     ])
2128 fi
2129
2130 dnl
2131 dnl  mpc demux plugin
2132 dnl
2133 AC_ARG_ENABLE(mpc,
2134   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2135 if test "${enable_mpc}" != "no"
2136 then
2137   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2138     VLC_ADD_PLUGIN([mpc])
2139     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2140     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2141     VLC_ADD_PLUGIN([mpc])
2142     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2143 fi
2144
2145 dnl
2146 dnl  Codec plugins
2147 dnl
2148
2149 EXTEND_HELP_STRING([Codec plugins:])
2150
2151 dnl
2152 dnl wmafixed plugin
2153 dnl
2154 AC_ARG_ENABLE(wma-fixed,
2155   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2156 if test "${enable_wma_fixed}" = "yes"
2157 then
2158   VLC_ADD_PLUGIN([wma_fixed])
2159 fi
2160
2161 dnl
2162 dnl shine encoder plugin
2163 dnl
2164 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2165
2166
2167 dnl
2168 dnl openmax il codec plugin
2169 dnl
2170 AC_ARG_ENABLE(omxil,
2171   [  --enable-omxil          openmax il codec module (default disabled)])
2172 if test "${enable_omxil}" = "yes"
2173 then
2174   VLC_ADD_PLUGIN([omxil])
2175 fi
2176
2177 dnl
2178 dnl openmax il vout plugin
2179 dnl
2180 AC_ARG_ENABLE(omxil-vout,
2181   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2182 if test "${enable_omxil_vout}" = "yes"
2183 then
2184   VLC_ADD_PLUGIN([omxil_vout])
2185 fi
2186
2187 dnl
2188 dnl raspberry pi openmax il configuration
2189 dnl
2190 AC_ARG_ENABLE(rpi-omxil,
2191   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2192 if test "${enable_rpi_omxil}" = "yes"
2193 then
2194   VLC_ADD_PLUGIN([omxil omxil_vout])
2195   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2196 fi
2197
2198 dnl
2199 dnl CrystalHD codec plugin
2200 dnl
2201 AC_ARG_ENABLE(crystalhd,
2202   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2203 if test "${enable_crystalhd}" != "no"; then
2204     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2205       VLC_ADD_PLUGIN([crystalhd])
2206       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2207     ],[
2208       if test "${SYS}" = "mingw32" ; then
2209         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2210           VLC_ADD_PLUGIN([crystalhd])
2211           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2212             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2213             ])
2214         ],[
2215           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2216                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2217                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2218         ],[#define __LINUX_USER__
2219                #include <libcrystalhd/bc_dts_types.h>
2220         ])
2221       fi
2222     ],[
2223        #include <libcrystalhd/bc_dts_types.h>
2224       ])
2225 fi
2226
2227 dnl
2228 dnl  mad plugin
2229 dnl
2230 have_mad="no"
2231 MAD_CFLAGS=""
2232 MAD_LIBS=""
2233
2234 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2235   enable_mad="yes"
2236 ], [
2237   with_mad="no"
2238 ])
2239 AS_IF([test "${with_mad}" != "no"], [
2240   MAD_CFLAGS="-I${with_mad}/include"
2241   MAD_LIBS="-L${with_mad}/lib"
2242 ])
2243
2244 AC_ARG_ENABLE(mad,
2245   [  --enable-mad            libmad module (default enabled)])
2246 AS_IF([test "${enable_mad}" != "no"], [
2247   VLC_SAVE_FLAGS
2248   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2249   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2250   AC_CHECK_HEADERS(mad.h, [
2251     AC_CHECK_LIB(mad, mad_bit_init, [
2252       have_mad="yes"
2253       MAD_LIBS="${MAD_LIBS} -lmad"
2254     ])
2255   ])
2256   VLC_RESTORE_FLAGS
2257   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2258     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2259   ])
2260 ])
2261 AC_SUBST(MAD_CFLAGS)
2262 AC_SUBST(MAD_LIBS)
2263 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2264
2265 dnl  mpg123 plugin
2266 dnl
2267 dnl
2268 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2269
2270 dnl
2271 dnl gstreamer stuff
2272 dnl
2273 AC_ARG_ENABLE(gst-decode,
2274   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2275
2276 have_gst_decode="no"
2277 AS_IF([test "${enable_gst_decode}" != "no"], [
2278   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2279     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2280       have_gst_decode="yes"
2281     ], [
2282       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2283     ])
2284   ], [
2285     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2286   ])
2287 ])
2288 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2289
2290 dnl
2291 dnl  avcodec decoder/encoder plugin
2292 dnl
2293 AC_ARG_ENABLE(merge-ffmpeg,
2294 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2295   enable_merge_ffmpeg="no"
2296 ])
2297 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2298
2299 AC_MSG_CHECKING([for libavutil variant])
2300 PKG_CHECK_EXISTS([libavutil], [
2301   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2302   libavutil_micro="${libavutil_version##*.}"
2303   AS_IF([test ${libavutil_micro} -le 99], [
2304     avfork="libav"
2305   ], [
2306     avfork="ffmpeg"
2307   ])
2308 ], [
2309   avfork="none"
2310 ])
2311 AC_MSG_RESULT([${avfork}])
2312
2313 AC_ARG_ENABLE(avcodec,
2314 [  --enable-avcodec        libavcodec codec (default enabled)])
2315 AS_IF([test "${enable_avcodec}" != "no"], [
2316   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2317   case "${avfork}" in
2318     libav) av_codec_ver="57.16.0" ;;
2319     ffmpeg) av_codec_ver="57.37.100" ;;
2320     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2321   esac
2322   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2323     VLC_SAVE_FLAGS
2324     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2325     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2326     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2327     AC_CHECK_HEADERS(libavutil/avutil.h)
2328     VLC_RESTORE_FLAGS
2329     have_avcodec="yes"
2330   ],[
2331     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2332   ])
2333 ], [
2334   have_avcodec="no"
2335 ])
2336 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2337
2338 dnl
2339 dnl libva needs avcodec
2340 dnl
2341 AC_ARG_ENABLE(libva,
2342   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2343
2344 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2345   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2346 ])
2347
2348 have_vaapi="no"
2349 have_vaapi_drm="no"
2350 have_vaapi_x11="no"
2351 have_vaapi_wl="no"
2352 AS_IF([test "${enable_libva}" != "no"], [
2353   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2354     have_vaapi="yes"
2355   ], [
2356     AS_IF([test -n "${enable_libva}"], [
2357       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2358     ], [
2359       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2360     ])
2361   ])
2362   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2363     have_vaapi_drm="yes"
2364   ], [
2365     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2366   ])
2367   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2368     have_vaapi_x11="yes"
2369   ], [
2370     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2371   ])
2372   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2373     have_vaapi_wl="yes"
2374   ], [
2375     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2376   ])
2377 ])
2378 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2379 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2380 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2381 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2382
2383 have_avcodec_vaapi="no"
2384 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2385   VLC_SAVE_FLAGS
2386   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2387   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2388   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2389     AC_MSG_NOTICE([VA API acceleration activated])
2390     have_avcodec_vaapi="yes"
2391   ],[
2392     AS_IF([test -n "${enable_libva}"], [
2393       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2394     ], [
2395       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2396     ])
2397   ])
2398   VLC_RESTORE_FLAGS
2399 ])
2400 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2401
2402 dnl
2403 dnl dxva2 needs avcodec
2404 dnl
2405 AC_ARG_ENABLE(dxva2,
2406   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2407
2408 have_avcodec_dxva2="no"
2409 AS_IF([test "${enable_dxva2}" != "no"], [
2410   if test "${SYS}" = "mingw32"; then
2411   AS_IF([test "x${have_avcodec}" = "xyes"], [
2412     AC_CHECK_HEADERS(dxva2api.h,
2413       [
2414         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2415            AC_MSG_NOTICE([DxVA2 acceleration activated])
2416            have_avcodec_dxva2="yes"
2417         ],[
2418     AS_IF([test "${enable_dxva2}" = "yes"],
2419           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2420               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2421         ], [#undef _WIN32_WINNT
2422             /* DXVA2 is only available in Vista and above */
2423             #define _WIN32_WINNT 0x600])
2424       ],[
2425     AS_IF([test "${enable_dxva2}" = "yes"],
2426               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2427               [AC_MSG_WARN([dxva2api.h not found])])
2428       ],[#include <d3d9.h>])
2429   ],[
2430     AS_IF([test "x${enable_dxva2}" != "x"], [
2431       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2432     ])
2433   ])
2434   fi
2435 ])
2436 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2437
2438 dnl
2439 dnl d3d11va needs avcodec
2440 dnl
2441 AC_ARG_ENABLE(d3d11va,
2442   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2443
2444 have_avcodec_d3d11va="no"
2445 AS_IF([test "${enable_d3d11va}" != "no"], [
2446   if test "${SYS}" = "mingw32"; then
2447   AS_IF([test "x${have_avcodec}" = "xyes"], [
2448         AC_CHECK_TYPES([ID3D11VideoDecoder],
2449           [
2450             AC_CHECK_HEADERS(dxva2api.h,
2451               [
2452                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2453                    AC_MSG_NOTICE([D3D11 acceleration activated])
2454                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2455                    have_avcodec_d3d11va="yes"
2456                 ],[
2457                   AS_IF([test "${enable_d3d11va}" = "yes"],
2458                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2459                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2460                   ], [#undef _WIN32_WINNT
2461                       /* D3D11 is only available in Vista and above */
2462                       #define _WIN32_WINNT 0x600])
2463                   ],[
2464                     AS_IF([test "${enable_d3d11va}" = "yes"],
2465                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2466                           [AC_MSG_WARN([dxva2api.h not found])])
2467                   ],[#include <d3d9.h>])
2468           ],[
2469             AS_IF([test "${enable_d3d11va}" = "yes"],
2470                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2471                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2472           ], [#include <d3d11.h>])
2473   ],[
2474     AS_IF([test "x${enable_d3d11va}" != "x"], [
2475       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2476     ])
2477   ])
2478   fi
2479 ])
2480 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2481
2482 dnl
2483 dnl DXGI debug
2484 dnl
2485 AC_CHECK_HEADERS(dxgidebug.h)
2486
2487 dnl
2488 dnl  avformat demuxer/muxer plugin
2489 dnl
2490
2491 AC_ARG_ENABLE(avformat,
2492 [  --enable-avformat       libavformat containers (default enabled)],, [
2493   enable_avformat="${have_avcodec}"
2494 ])
2495 have_avformat="no"
2496 AS_IF([test "${enable_avformat}" != "no"], [
2497   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2498       have_avformat="yes"
2499       VLC_SAVE_FLAGS
2500       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2501       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2502       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2503       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2504       AC_CHECK_HEADERS(libavutil/avutil.h)
2505       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2506         have_avformat="no"
2507       ])
2508       VLC_RESTORE_FLAGS
2509     ],[
2510       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2511   ])
2512 ])
2513 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2514
2515 dnl
2516 dnl  swscale image scaling and conversion plugin
2517 dnl
2518
2519 AC_ARG_ENABLE(swscale,
2520   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2521           (default enabled)]))
2522 if test "${enable_swscale}" != "no"
2523 then
2524   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2525     [
2526       VLC_SAVE_FLAGS
2527       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2528       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2529       AC_CHECK_HEADERS(libswscale/swscale.h)
2530       AC_CHECK_HEADERS(libavutil/avutil.h)
2531       VLC_ADD_PLUGIN([swscale])
2532       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2533       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2534       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2535         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2536       ])
2537       VLC_RESTORE_FLAGS
2538     ],[
2539       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2540   ])
2541 fi
2542
2543 dnl
2544 dnl  postproc plugin
2545 dnl
2546
2547 AC_ARG_ENABLE(postproc,
2548 [  --enable-postproc       libpostproc image post-processing (default auto)])
2549 if test "${enable_postproc}" != "no"
2550 then
2551   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2552     [
2553       VLC_SAVE_FLAGS
2554       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2555       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2556       AC_CHECK_HEADERS(postproc/postprocess.h)
2557       VLC_ADD_PLUGIN([postproc])
2558       VLC_RESTORE_FLAGS
2559     ],[
2560       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2561   ])
2562 fi
2563
2564 dnl
2565 dnl  faad decoder plugin
2566 dnl
2567 AC_ARG_ENABLE(faad,
2568 [  --enable-faad           faad codec (default auto)])
2569 have_faad="no"
2570 AS_IF([test "${enable_faad}" != "no"], [
2571   AC_CHECK_HEADERS([neaacdec.h], [
2572     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2573
2574     AS_IF([test "${have_faad}" = "yes"], [
2575       VLC_ADD_PLUGIN([faad])
2576       VLC_ADD_LIBS([faad],[-lfaad])
2577     ], [
2578       AS_IF([test "${enable_faad}" = "yes"], [
2579         AC_MSG_ERROR([cannot find FAAD library])
2580       ], [
2581         AC_MSG_WARN([cannot find FAAD library])
2582       ])
2583     ])
2584   ])
2585 ])
2586
2587 dnl
2588 dnl  AOM decoder plugin
2589 dnl
2590 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2591
2592 dnl
2593 dnl libvpx decoder plugin
2594 dnl
2595 AC_ARG_ENABLE(vpx,
2596     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2597 AS_IF([test "${enable_vpx}" != "no"],[
2598     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2599         VLC_ADD_PLUGIN([vpx])
2600         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2601         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2602         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2603             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2604         ], [], [${VPX_LIBS}])
2605         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2606             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2607         ], [], [${VPX_LIBS}])
2608         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2609             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2610         ], [], [${VPX_LIBS}])
2611         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2612             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2613         ], [], [${VPX_LIBS}])
2614     ], [
2615     AS_IF([test "${enable_vpx}" = "yes"],[
2616         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2617     ])])
2618 ])
2619
2620 dnl
2621 dnl twolame encoder plugin
2622 dnl
2623 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2624
2625 dnl
2626 dnl fdk-aac encoder plugin
2627 dnl
2628 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2629
2630
2631 dnl
2632 dnl A52/AC3 decoder plugin
2633 dnl
2634 AC_ARG_ENABLE(a52,
2635   [  --enable-a52            A/52 support with liba52 (default enabled)])
2636 if test "${enable_a52}" != "no"
2637 then
2638   AC_ARG_WITH(a52,
2639     [  --with-a52=PATH         a52 headers and libraries])
2640     if test -z "${with_a52}"
2641     then
2642       LDFLAGS_test=""
2643       CPPFLAGS_test=""
2644     else
2645       LDFLAGS_test="-L${with_a52}/lib"
2646       CPPFLAGS_test="-I${with_a52}/include"
2647     fi
2648     VLC_SAVE_FLAGS
2649     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2650     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2651     AC_CHECK_HEADERS(a52dec/a52.h, [
2652       AC_CHECK_LIB(a52, a52_free, [
2653         VLC_ADD_PLUGIN([a52])
2654         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2655         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2656       ],[
2657         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2658         ], [$LIBM])
2659     ],[
2660       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2661     ])
2662     VLC_RESTORE_FLAGS
2663 fi
2664
2665 dnl
2666 dnl DTS Coherent Acoustics decoder plugin
2667 dnl
2668 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2669
2670 dnl
2671 dnl  Flac plugin
2672 dnl
2673 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2674
2675 dnl
2676 dnl  Libmpeg2 plugin
2677 dnl
2678 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2679
2680 dnl
2681 dnl  Vorbis plugin
2682 dnl
2683 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2684
2685 dnl
2686 dnl  Tremor plugin
2687 dnl
2688 AC_ARG_ENABLE(tremor,
2689   [  --enable-tremor         Tremor decoder support (default disabled)])
2690 if test "${enable_tremor}" = "yes"
2691 then
2692   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2693     VLC_ADD_PLUGIN([tremor])
2694    ],[])
2695 fi
2696
2697 dnl
2698 dnl  Speex plugins
2699 dnl
2700 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2701 have_speexdsp="no"
2702 AS_IF([test "${enable_speex}" != "no"], [
2703   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2704     have_speexdsp="yes"
2705   ], [
2706     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2707   ])
2708 ])
2709 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2710
2711 dnl
2712 dnl  Opus plugin
2713 dnl
2714 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2715
2716 dnl
2717 dnl  Ambisonic channel mixer and binauralizer plugin
2718 dnl
2719 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2720
2721 dnl
2722 dnl  theora decoder plugin
2723 dnl
2724 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2725
2726 dnl
2727 dnl  OggSpots decoder plugin
2728 dnl
2729 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2730
2731 dnl
2732 dnl  Daala decoder plugin
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2735
2736 dnl
2737 dnl  schroedinger decoder plugin (for dirac format video)
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2740
2741 dnl
2742 dnl  PNG decoder module
2743 dnl
2744 AC_ARG_ENABLE(png,
2745   [  --enable-png            PNG support (default enabled)])
2746 AS_IF([test "${enable_png}" != "no"], [
2747 AC_CHECK_HEADERS(png.h, [
2748   VLC_SAVE_FLAGS
2749   LDFLAGS="${LDFLAGS} -lz $LIBM"
2750   AC_CHECK_LIB(png, png_set_alpha_mode, [
2751     VLC_ADD_PLUGIN([png])
2752   ], [], [-lz $LIBM])
2753   VLC_RESTORE_FLAGS
2754   ])
2755 ])
2756
2757 dnl
2758 dnl  JPEG decoder module
2759 dnl
2760 AC_ARG_ENABLE(jpeg,
2761   [  --enable-jpeg           JPEG support (default enabled)])
2762 AS_IF([test "${enable_jpeg}" != "no"], [
2763 AC_CHECK_HEADERS(jpeglib.h, [
2764   VLC_ADD_PLUGIN([jpeg])
2765   ])
2766 ])
2767
2768 dnl
2769 dnl  BPG decoder module
2770 dnl
2771 AC_ARG_ENABLE(bpg,
2772   [  --enable-bpg           BPG support (default disabled)])
2773 AS_IF([test "${enable_bpg}" != "no"], [
2774 AC_CHECK_HEADERS(libbpg.h, [
2775   VLC_ADD_PLUGIN([bpg])
2776   ])
2777 ])
2778
2779 dnl
2780 dnl H262 encoder plugin (lib262)
2781 dnl
2782 AC_ARG_ENABLE(x262,
2783   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2784 if test "${enable_x262}" != "no"; then
2785     PKG_CHECK_MODULES(X262, x262, [
2786         VLC_ADD_PLUGIN([x262])
2787         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2788         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2789           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2790         ])
2791         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2792         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2793           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2794         fi
2795     ], [
2796        if test "${enable_x262}" = "yes"; then
2797         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2798        fi
2799     ])
2800 fi
2801
2802 dnl x265 encoder
2803 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2804
2805 dnl
2806 dnl H264 encoder plugin (10-bit lib264)
2807 dnl
2808 AC_ARG_ENABLE(x26410b,
2809   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2810 if test "${enable_x26410b}" != "no"; then
2811     PKG_CHECK_MODULES(X26410B, x26410b, [
2812         VLC_ADD_PLUGIN([x26410b])
2813         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2814         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2815           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2816         ])
2817         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2818         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2819           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2820         fi
2821     ], [
2822        if test "${enable_x26410b}" = "yes"; then
2823         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2824        fi
2825     ])
2826 fi
2827
2828
2829 dnl
2830 dnl H264 encoder plugin (using libx264)
2831 dnl
2832 AC_ARG_ENABLE(x264,
2833   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2834 if test "${enable_x264}" != "no"; then
2835       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2836         VLC_ADD_PLUGIN([x264])
2837         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2838
2839         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2840           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2841         ])
2842
2843         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2844         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2845           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2846         fi
2847       ],[
2848         if test "${enable_x264}" = "yes"; then
2849             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2850           fi
2851       ])
2852 fi
2853
2854 dnl
2855 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2856 dnl
2857 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2858
2859 dnl
2860 dnl libfluidsynth (MIDI synthetizer) plugin
2861 dnl
2862 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2863 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2864 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2865
2866 dnl
2867 dnl Teletext Modules
2868 dnl vbi decoder plugin (using libzbvi)
2869 dnl telx module
2870 dnl uncompatible
2871 dnl
2872 AC_ARG_ENABLE(zvbi,
2873   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2874                   libzvbi (default enabled)]))
2875 AC_ARG_ENABLE(telx,
2876   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2877                   zvbi) (default enabled if zvbi is absent)]))
2878
2879 AS_IF( [test "${enable_zvbi}" != "no"],[
2880     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2881         [
2882           VLC_ADD_PLUGIN([zvbi])
2883           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2884           AS_IF( [test "${enable_telx}" = "yes"],[
2885                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2886                   ])
2887         ],[
2888           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2889         ])
2890     ])
2891 AS_IF( [test "${enable_telx}" != "no" ],[
2892   VLC_ADD_PLUGIN([telx])
2893   ])
2894
2895 dnl
2896 dnl libass subtitle rendering module
2897 dnl
2898 AC_ARG_ENABLE(libass,
2899   [  --enable-libass         Subtitle support using libass (default enabled)])
2900 AS_IF( [test "${enable_libass}" != "no"], [
2901   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2902       [
2903         VLC_ADD_PLUGIN([libass])
2904
2905         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2906           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2907            VLC_ADD_LIBS([libass],[-lfontconfig])
2908        ])
2909       ],[
2910         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2911       ])
2912   ])
2913
2914 dnl
2915 dnl ARIB subtitles rendering module
2916 dnl
2917 AC_ARG_ENABLE(aribsub,
2918   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2919 AS_IF( [test "${enable_aribsub}" != "no" ],[
2920   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2921       have_aribb24="yes"
2922       VLC_ADD_PLUGIN([aribsub])
2923       VLC_ADD_LIBS([aribsub],[-laribb24])
2924       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2925     ],[
2926       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2927       have_aribb24="no"
2928   ])
2929 ])
2930 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2931
2932 dnl
2933 dnl ARIB B25
2934 dnl
2935 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2936
2937 dnl
2938 dnl  kate decoder plugin
2939 dnl
2940 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2941
2942 dnl
2943 dnl  tiger rendering for kate decoder plugin
2944 dnl
2945 AC_ARG_ENABLE(tiger,
2946 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2947 AS_IF([test "${enable_tiger}" != "no"], [
2948   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2949       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2950         AS_IF([test -n "${enable_tiger}"], [
2951           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2952         ])
2953   ])
2954 ])
2955
2956
2957 dnl
2958 dnl  Video plugins
2959 dnl
2960
2961 EXTEND_HELP_STRING([Video plugins:])
2962
2963 dnl
2964 dnl  OpenGL
2965 dnl
2966 PKG_CHECK_MODULES([EGL], [egl], [
2967   have_egl="yes"
2968 ], [
2969   have_egl="no"
2970 ])
2971 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2972
2973 have_gl="no"
2974 PKG_CHECK_MODULES([GL], [gl], [
2975   have_gl="yes"
2976 ], [
2977   AC_MSG_CHECKING([for OpenGL])
2978   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2979 #ifdef _WIN32
2980 # include <GL/glew.h>
2981 #endif
2982 #include <GL/gl.h>
2983 ]], [
2984     [int t0 = GL_TEXTURE0;]])
2985   ], [
2986     GL_CFLAGS=""
2987     have_gl="yes"
2988     AS_IF([test "${SYS}" != "mingw32"], [
2989       GL_LIBS="-lGL"
2990     ], [
2991       GL_LIBS="-lopengl32"
2992     ])
2993   ])
2994   AC_MSG_RESULT([${have_gl}])
2995 ])
2996 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2997
2998 dnl OpenGL ES 2: depends on EGL 1.1
2999 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3000
3001 dnl
3002 dnl  Xlib
3003 dnl
3004
3005 AC_PATH_XTRA()
3006 AC_CHECK_HEADERS(X11/Xlib.h)
3007
3008 dnl
3009 dnl  X C Bindings modules
3010 dnl
3011 AC_ARG_ENABLE(xcb,
3012   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3013   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3014     enable_xcb="yes"
3015   ], [
3016     enable_xcb="no"
3017   ])
3018 ])
3019 AC_ARG_ENABLE(xvideo,
3020   [  --enable-xvideo         XVideo support (default enabled)],, [
3021     enable_xvideo="$enable_xcb"
3022 ])
3023
3024 have_xcb="no"
3025 have_xcb_keysyms="no"
3026 have_xcb_randr="no"
3027 have_xcb_xvideo="no"
3028 AS_IF([test "${enable_xcb}" != "no"], [
3029   dnl libxcb
3030   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3031   have_xcb="yes"
3032   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3033   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3034   PKG_CHECK_MODULES(XPROTO, [xproto])
3035
3036   AS_IF([test "${enable_xvideo}" != "no"], [
3037     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3038   ])
3039
3040   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3041
3042   dnl xcb-utils
3043   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3044     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3045   ])
3046 ])
3047 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3048 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3049 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3050 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3051
3052
3053 dnl
3054 dnl VDPAU needs X11
3055 dnl
3056 AC_ARG_ENABLE(vdpau,
3057   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3058 have_vdpau="no"
3059 AS_IF([test "${enable_vdpau}" != "no"], [
3060   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3061     have_vdpau="yes"
3062     AS_IF([test "${no_x}" = "yes"], [
3063       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3064     ])
3065   ], [
3066     AS_IF([test -n "${enable_vdpau}"], [
3067       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3068     ])
3069   ])
3070 ])
3071 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3072
3073 have_avcodec_vdpau="no"
3074 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3075   case "${avfork}" in
3076     libav) av_vdpau_ver="56.10.0" ;;
3077     ffmpeg) av_vdpau_ver="56.19.100" ;;
3078   esac
3079   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3080     have_avcodec_vdpau="yes"
3081     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3082   ], [
3083     AS_IF([test -n "${enable_vdpau}"], [
3084       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3085     ], [
3086       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3087     ])
3088   ])
3089 ])
3090 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3091
3092
3093 dnl
3094 dnl  Wayland
3095 dnl
3096 AC_ARG_ENABLE(wayland,
3097   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3098 have_wayland="no"
3099 have_wayland_egl="no"
3100
3101 AS_IF([test "${enable_wayland}" != "no"], [
3102   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3103     AC_MSG_CHECKING([for the Wayland protocols])
3104     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3105       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3106       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3107     ], [
3108       AC_MSG_RESULT([not found])
3109       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3110     ])
3111
3112     AC_MSG_CHECKING([for the Wayland scanner])
3113     PKG_CHECK_EXISTS([wayland-scanner], [
3114       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3115       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3116     ], [
3117       AC_MSG_RESULT([not found])
3118       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3119     ])
3120
3121     have_wayland="yes"
3122
3123     AS_IF([test "${have_egl}" = "yes"], [
3124       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3125         have_wayland_egl="yes"
3126       ], [
3127         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3128       ])
3129     ])
3130   ], [
3131     AS_IF([test -n "${enable_wayland}"], [
3132       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3133     ])
3134   ])
3135 ])
3136 AC_SUBST([WAYLAND_PROTOCOLS])
3137 AC_SUBST([WAYLAND_SCANNER])
3138 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3139 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3140
3141
3142 dnl
3143 dnl  SDL image decoder module
3144 dnl
3145 AC_ARG_ENABLE(sdl-image,
3146   [  --enable-sdl-image      SDL image support (default enabled)])
3147 AS_IF([test "${enable_sdl_image}" != "no"],[
3148   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3149     VLC_ADD_PLUGIN([sdl_image])
3150   ], [
3151     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3152   ])
3153 ])
3154
3155 dnl
3156 dnl  freetype module
3157 dnl
3158 AC_ARG_ENABLE(freetype,
3159   [  --enable-freetype       freetype support   (default auto)])
3160 AC_ARG_ENABLE(fribidi,
3161   [  --enable-fribidi        fribidi support    (default auto)])
3162 AC_ARG_ENABLE(harfbuzz,
3163   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3164 AC_ARG_ENABLE(fontconfig,
3165   [  --enable-fontconfig     fontconfig support (default auto)])
3166
3167 AC_ARG_WITH([default-font],
3168     AS_HELP_STRING([--with-default-font=PATH],
3169         [Path to the default font]),
3170         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3171             "$withval", [Default font])])
3172 AC_ARG_WITH([default-monospace-font],
3173     AS_HELP_STRING([--with-default-monospace-font=PATH],
3174         [Path to the default font]),
3175         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3176             "$withval", [Default monospace font])])
3177
3178 AC_ARG_WITH([default-font-family],
3179     AS_HELP_STRING([--with-default-font-family=NAME],
3180         [Path to the default font family]),
3181         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3182             "$withval", [Default font family])])
3183 AC_ARG_WITH([default-monospace-font-family],
3184     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3185         [Path to the default font family]),
3186         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3187             "$withval", [Default monospace font family])])
3188
3189 have_freetype="no"
3190 have_fontconfig="no"
3191 have_fribidi="no"
3192 have_harfbuzz="no"
3193
3194 if test "${enable_freetype}" != "no"; then
3195    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3196       have_freetype="yes"
3197       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3198       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3199
3200     dnl fontconfig support
3201     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3202       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3203         have_fontconfig="yes"
3204       ], [
3205         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3206       ])
3207     ])
3208
3209       dnl fribidi support
3210       if test "${enable_fribidi}" != "no"; then
3211         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3212           have_fribidi="yes"
3213           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3214           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3215         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3216       fi
3217
3218       dnl harfbuzz support
3219       if test "${have_fribidi}" != "no"; then
3220         if test "${enable_harfbuzz}" != "no"; then
3221           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3222             have_harfbuzz="yes"
3223             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3224             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3225           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3226         fi
3227       fi
3228   ],[
3229   AS_IF([test -n "${enable_freetype}"],[
3230     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3231     ])
3232   ])
3233 fi
3234
3235 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3236 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3237 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3238 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3239
3240 dnl
3241 dnl SAPI (text to Speech renderer for Windows)
3242 dnl
3243 AC_LANG_PUSH([C++])
3244 AC_CHECK_TYPES([ISpObjectToken],[
3245               have_sapi="yes"
3246             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3247               [#include <windows.h>
3248                #include <sapi.h>
3249                #include <sphelper.h>])
3250 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3251 AC_LANG_POP([C++])
3252
3253 dnl
3254 dnl  SVG module (text rendering and image decoding)
3255 dnl
3256 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3257 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3258
3259 dnl
3260 dnl  Windows DirectX module
3261 dnl
3262
3263 AC_ARG_ENABLE(directx,
3264   [AS_HELP_STRING([--enable-directx],
3265     [Microsoft DirectX support (default enabled on Windows)])],, [
3266   AS_IF([test "${SYS}" = "mingw32"], [
3267     enable_directx="yes"
3268   ], [
3269     enable_directx="no"
3270   ])
3271 ])
3272 AS_IF([test "${enable_directx}" != "no"], [
3273   dnl DirectDraw
3274   AC_CHECK_HEADERS(ddraw.h, [
3275     VLC_ADD_PLUGIN([directdraw])
3276   ])
3277
3278   dnl OpenGL
3279   AC_CHECK_HEADERS(GL/wglew.h, [
3280     VLC_ADD_PLUGIN([glwin32 wgl])
3281   ],, [
3282     #include <windows.h>
3283     #include <GL/gl.h>
3284   ])
3285
3286   dnl Direct3D11
3287   AC_CHECK_HEADERS(d3d11.h, [
3288     VLC_ADD_PLUGIN([direct3d11 direct3d11_deinterlace direct3d11_adjust])
3289   ])
3290
3291   dnl Direct3D9
3292   AC_CHECK_HEADERS(d3d9.h, [
3293     VLC_ADD_PLUGIN([direct3d9])
3294     AC_CHECK_HEADERS(d3dx9effect.h)
3295
3296     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3297         [[#define COBJMACROS
3298           #include <d3d9.h>
3299           #include <dxva2api.h>
3300           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3301           # error dxva2 too old
3302           #endif
3303         ]],[[;]])
3304       ],[
3305         VLC_ADD_PLUGIN([direct3d9_deinterlace direct3d9_adjust])
3306       ],
3307       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3308
3309   ])
3310 ])
3311
3312 dnl
3313 dnl  Linux framebuffer module
3314 dnl
3315 AC_CHECK_HEADER([linux/fb.h], [
3316   VLC_ADD_PLUGIN([fb])
3317 ])
3318
3319
3320 dnl
3321 dnl  AA plugin
3322 dnl
3323 AC_ARG_ENABLE(aa,
3324   [  --enable-aa             aalib output (default disabled)])
3325 if test "${enable_aa}" = "yes"
3326 then
3327   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3328   if test "${have_aa}" = "true"
3329   then
3330     VLC_ADD_PLUGIN([aa])
3331   fi
3332 fi
3333
3334 dnl
3335 dnl  libcaca plugin
3336 dnl
3337 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3338
3339 dnl
3340 dnl  OS/2 KVA plugin
3341 dnl
3342 AC_ARG_ENABLE(kva,
3343   [AS_HELP_STRING([--enable-kva],
3344     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3345   AS_IF([test "$SYS" = "os2"], [
3346     enable_kva="yes"
3347   ])
3348 ])
3349 have_kva="no"
3350 KVA_LIBS=""
3351 AS_IF([test "$enable_kva" != "no"], [
3352   AC_CHECK_HEADERS([kva.h], [
3353     have_kva="yes"
3354     AC_CHECK_LIB(kva, main, [
3355       KVA_LIBS="-lkva"
3356     ])
3357   ])
3358 ])
3359 AC_SUBST(KVA_LIBS)
3360 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3361
3362 dnl
3363 dnl MMAL plugin
3364 dnl
3365 AC_ARG_ENABLE(mmal,
3366   AS_HELP_STRING([--enable-mmal],
3367     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3368 if test "${enable_mmal}" != "no"; then
3369   VLC_SAVE_FLAGS
3370   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3371   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3372   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3373     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3374         have_mmal="yes"
3375         VLC_ADD_PLUGIN([mmal])
3376         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3377         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3378         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3379           AS_IF([test "${enable_mmal}" = "yes"],
3380             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3381             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3382           ],
3383         [])
3384     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3385       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3386       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3387   VLC_RESTORE_FLAGS
3388 fi
3389 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3390
3391 dnl
3392 dnl evas plugin
3393 dnl
3394 AC_ARG_ENABLE(evas,
3395   [AS_HELP_STRING([--enable-evas],
3396     [use evas output module (default disabled)])])
3397 have_evas="no"
3398 AS_IF([test "${enable_evas}" = "yes"], [
3399   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3400       have_evas="yes"
3401       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3402     ],[
3403     AS_IF([test "x${enable_evas}" != "x"], [
3404       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3405     ])
3406   ])
3407 ])
3408 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3409
3410 dnl
3411 dnl  Audio plugins
3412 dnl
3413
3414 EXTEND_HELP_STRING([Audio plugins:])
3415
3416 dnl
3417 dnl  Pulseaudio module
3418 dnl
3419 AC_ARG_ENABLE(pulse,
3420   [AS_HELP_STRING([--enable-pulse],
3421     [use the PulseAudio client library (default auto)])])
3422 have_pulse="no"
3423 AS_IF([test "${enable_pulse}" != "no"], [
3424   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3425     have_pulse="yes"
3426   ], [
3427     AS_IF([test "x${enable_pulse}" != "x"], [
3428       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3429     ])
3430   ])
3431 ])
3432 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3433
3434 dnl
3435 dnl  ALSA module
3436 dnl
3437 AC_ARG_ENABLE(alsa,
3438   [AS_HELP_STRING([--enable-alsa],
3439     [support the Advanced Linux Sound Architecture (default auto)])],, [
3440   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3441     enable_alsa="yes"
3442   ])
3443 ])
3444 have_alsa="no"
3445 AS_IF([test "${enable_alsa}" != "no"], [
3446   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3447     have_alsa="yes"
3448   ], [
3449     AS_IF([test "x${enable_alsa}" != "x"], [
3450       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3451     ])
3452   ])
3453 ])
3454 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3455
3456 dnl
3457 dnl  Open Sound System module
3458 dnl
3459 AC_ARG_ENABLE(oss,
3460   [AS_HELP_STRING([--enable-oss],
3461     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3462   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3463     enable_oss="no"
3464   ])
3465 ])
3466 have_oss="no"
3467 OSS_LIBS=""
3468 AS_IF([test "$enable_oss" != "no"], [
3469   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3470     have_oss="yes"
3471     AC_CHECK_LIB(ossaudio, main, [
3472       OSS_LIBS="-lossaudio"
3473     ])
3474   ])
3475 ])
3476 AC_SUBST(OSS_LIBS)
3477 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3478
3479 dnl
3480 dnl  OpenBSD sndio module
3481 dnl
3482 AC_ARG_ENABLE([sndio],
3483   [AS_HELP_STRING([--disable-sndio],
3484     [support the OpenBSD sndio (default auto)])],, [
3485   AS_IF([test "$SYS" = "openbsd"], [
3486     enable_sndio="yes"
3487   ])
3488 ])
3489 have_sndio="no"
3490 AS_IF([test "$enable_sndio" != "no"], [
3491   AC_CHECK_HEADER([sndio.h], [
3492     have_sndio="yes"
3493   ])
3494 ])
3495 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3496
3497 dnl
3498 dnl  Windows Audio Session plugin
3499 dnl
3500 AC_ARG_ENABLE([wasapi],
3501   [AS_HELP_STRING([--enable-wasapi],
3502     [use the Windows Audio Session API (default auto)])
3503 ])
3504 have_wasapi="no"
3505 AS_IF([test "$enable_wasapi" != "no"], [
3506   AC_CHECK_HEADER([audioclient.h], [
3507     have_wasapi="yes"
3508   ], [
3509     AS_IF([test "x${enable_wasapi}" != "x"], [
3510       AC_MSG_ERROR([Windows Audio Session API not found.])
3511     ])
3512   ])
3513 ])
3514 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3515
3516 dnl
3517 dnl  JACK modules
3518 dnl
3519 AC_ARG_ENABLE(jack,
3520   [AS_HELP_STRING([--disable-jack],
3521     [do not use jack (default auto)])])
3522 have_jack="no"
3523 AS_IF([test "${enable_jack}" != "no"], [
3524     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3525       [ have_jack=yes ],
3526       [
3527       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3528
3529       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3530       [ have_jack=yes ],
3531       [
3532       AS_IF([test -n "${enable_jack}"],
3533          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3534          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3535       ])
3536     ])
3537 ])
3538 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3539
3540 dnl
3541 dnl  OpenSLES Android
3542 dnl
3543 AC_ARG_ENABLE(opensles,
3544   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3545 if test "${HAVE_ANDROID}" = "1"; then
3546   if test "${enable_opensles}" = "yes"; then
3547       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3548         [ VLC_ADD_PLUGIN([opensles_android]) ],
3549         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3550   fi
3551 fi
3552
3553 dnl
3554 dnl  Tizen audio
3555 dnl
3556 AC_ARG_ENABLE(tizen_audio,
3557   [AS_HELP_STRING([--enable-tizen-audio],
3558     [Tizen audio module (default enabled on Tizen)])],, [
3559   AS_IF([test "$HAVE_TIZEN" = "1"], [
3560     enable_tizen_audio="yes"
3561   ])
3562 ])
3563 if test "${enable_tizen_audio}" = "yes"; then
3564   AC_CHECK_HEADERS(audio_io.h,
3565     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3566     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3567 fi
3568
3569 dnl
3570 dnl libsamplerate plugin
3571 dnl
3572 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3573
3574 dnl
3575 dnl  soxr module
3576 dnl
3577 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3578
3579 dnl
3580 dnl  OS/2 KAI plugin
3581 dnl
3582 AC_ARG_ENABLE(kai,
3583   [AS_HELP_STRING([--enable-kai],
3584     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3585   AS_IF([test "$SYS" = "os2"], [
3586     enable_kai="yes"
3587   ])
3588 ])
3589 have_kai="no"
3590 KAI_LIBS=""
3591 AS_IF([test "$enable_kai" != "no"], [
3592   AC_CHECK_HEADERS([kai.h], [
3593     have_kai="yes"
3594     AC_CHECK_LIB(kai, main, [
3595       KAI_LIBS="-lkai"
3596     ])
3597   ])
3598 ])
3599 AC_SUBST(KAI_LIBS)
3600 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3601
3602 dnl
3603 dnl  chromaprint audio track fingerprinter
3604 dnl
3605 m4_pushdef([libchromaprint_version], 0.6.0)
3606 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3607     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3608     AS_IF([test "${enable_chromaprint}" = "yes"],
3609         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3610         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3611          ),
3612     [(Chromaprint based audio fingerprinter)],[auto])
3613 m4_popdef([libchromaprint_version])
3614
3615 dnl
3616 dnl  Chromecast streaming support
3617 dnl
3618 m4_pushdef([protobuf_lite_version], 2.5.0)
3619 AC_ARG_VAR(PROTOC, [protobuf compiler])
3620 AC_CHECK_PROGS(PROTOC, protoc, no)
3621 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3622     AS_IF([test "x${PROTOC}" != "xno"], [
3623         build_chromecast="yes"
3624     ], [
3625     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3626     ])
3627 ], [
3628     AS_IF([test "${enable_chromecast}" = "yes"],
3629         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3630         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3631     )
3632     enable_chromecast="no"
3633 ], [(Chromecast streaming support)], [auto])
3634 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3635 m4_popdef([protobuf_lite_version])
3636
3637 dnl
3638 dnl  Interface plugins
3639 dnl
3640
3641 EXTEND_HELP_STRING([Interface plugins:])
3642
3643 dnl
3644 dnl QT
3645 dnl
3646 AC_ARG_ENABLE(qt, [
3647   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3648   AS_IF([test "${SYS}" = "darwin"], [
3649     enable_qt="no"
3650   ])
3651 ])
3652 have_qt5_x11="no"
3653 AS_IF([test "${enable_qt}" != "no"], [
3654   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3655       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3656           have_qt5_x11="yes"
3657       ],[
3658           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3659       ])
3660       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3661       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3662       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3663       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3664       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3665       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3666     ], [
3667       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3668         AS_IF([test -n "${enable_qt}"],[
3669           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3670         ],[
3671           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3672         ])
3673         enable_qt="no"
3674       ])
3675       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3676       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3677       AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3678       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3679     ])
3680 ])
3681 AS_IF([test "${enable_qt}" != "no"], [
3682   ALIASES="${ALIASES} qvlc"
3683 ])
3684 AC_SUBST(QT_VERSION)
3685 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3686 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3687
3688 dnl
3689 dnl detect kde4-config patch (used for kde solids).
3690 dnl
3691 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3692 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3693   KDE4_CONFIG="kde4-config"
3694 ])
3695
3696 dnl
3697 dnl Simple test for skins2 dependency
3698 dnl
3699 AS_IF([test "$enable_qt" = "no"], [
3700   AS_IF([test "${enable_skins2}" = "yes"], [
3701     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3702   ], [
3703     enable_skins2="no"
3704     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3705   ])
3706 ])
3707
3708 dnl
3709 dnl Skins2 module
3710 dnl
3711 AC_ARG_ENABLE(skins2,
3712   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3713 AS_IF([test "${enable_skins2}" != "no"], [
3714   have_skins_deps="yes"
3715
3716   dnl Win32
3717   AS_IF([test "${SYS}" = "mingw32"], [
3718     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3719     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3720   dnl OS/2
3721   ], [test "${SYS}" = "os2"], [
3722     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3723   dnl Linux/Unix
3724   ], [
3725     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3726     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3727     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3728     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3729     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3730   ])
3731
3732   dnl we need freetype
3733   AS_IF([test "${have_freetype}" != "yes"], [
3734     have_skins_deps="no"
3735   ])
3736
3737   AS_IF([test "${have_skins_deps}" = "no"], [
3738     AS_IF([test "x${enable_skins2}" = "x"], [
3739       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3740     ], [
3741       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3742     ])
3743     enable_skins2="no"
3744   ], [
3745     ALIASES="${ALIASES} svlc"
3746     enable_skins2="yes"
3747   ])
3748 ])
3749 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3750
3751 AC_ARG_ENABLE(libtar,
3752   [  --enable-libtar         libtar support for skins2 (default auto)])
3753 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3754   AC_CHECK_HEADERS(libtar.h, [
3755     VLC_ADD_LIBS([skins2],[-ltar])
3756   ])
3757 ])
3758
3759 dnl
3760 dnl  MacOS X gui module
3761 dnl
3762 AC_ARG_ENABLE(macosx,
3763   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3764 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3765 then
3766
3767   dnl
3768   dnl If possible, use xcrun to find the right ibtool
3769   dnl
3770
3771   AC_PATH_PROG([XCRUN], [xcrun], [no])
3772   AS_IF([test ! "x${XCRUN}" = "xno"], [
3773     AC_MSG_CHECKING([for ibtool (using xcrun)])
3774     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3775     AC_MSG_RESULT([${XIB}])
3776   ], [
3777     AC_MSG_WARN([Looking for tools without using xcrun])
3778   ])
3779
3780   AS_IF([test "x${XIB}" = "xno"], [
3781     AC_PATH_PROG(XIB, [ibtool], [no])
3782     AS_IF([test "x${XIB}" = "xno"], [
3783       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3784     ])
3785   ])
3786 fi
3787 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3788
3789 dnl
3790 dnl  MacOS X sparkle update support
3791 dnl
3792 AC_ARG_ENABLE(sparkle,
3793   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3794 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3795 then
3796   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3797   then
3798     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3799   fi
3800
3801   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3802 fi
3803 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3804
3805 dnl
3806 dnl  MacOS X breakpad creash reporter support
3807 dnl
3808 AC_ARG_ENABLE(breakpad,
3809   [  --enable-breakpad       Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3810 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3811 then
3812   if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3813   then
3814     AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3815   fi
3816
3817   AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3818 fi
3819 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3820
3821
3822 dnl
3823 dnl  Minimal Mac OS X module
3824 dnl
3825 AC_ARG_ENABLE(minimal-macosx,
3826   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3827 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3828 then
3829   VLC_ADD_PLUGIN([minimal_macosx])
3830 fi
3831
3832 dnl
3833 dnl Mac OS X fancy dmg build tool
3834 dnl
3835 if test "${HAVE_OSX}" = "1"
3836 then
3837   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3838   AS_IF([test "x${DMGBUILD}" = "xno"], [
3839     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3840   ])
3841 fi
3842 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3843
3844 dnl
3845 dnl  VideoToolbox plugins
3846 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3847     VLC_ADD_PLUGIN([videotoolbox])
3848     VLC_ADD_PLUGIN([cvpx])
3849   ])
3850
3851 dnl
3852 dnl  ncurses module
3853 dnl
3854 AC_ARG_ENABLE(ncurses,
3855 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3856 have_ncurses="no"
3857 AS_IF([test "${enable_ncurses}" != "no"] ,[
3858   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3859     have_ncurses="yes"
3860     ALIASES="${ALIASES} nvlc"
3861   ], [
3862     AS_IF([test -n "${enable_ncurses}"], [
3863       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3864     ])
3865   ])
3866 ])
3867 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3868
3869 dnl
3870 dnl  Lirc plugin
3871 dnl
3872 AC_ARG_ENABLE(lirc,
3873   [  --enable-lirc           lirc support (default disabled)])
3874 have_lirc="no"
3875 AS_IF([test "${enable_lirc}" = "yes"], [
3876   AC_CHECK_HEADER(lirc/lirc_client.h, [
3877     AC_CHECK_LIB(lirc_client, lirc_init, [
3878       have_lirc="yes"
3879     ])
3880   ])
3881 ])
3882 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3883
3884 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3885 dnl
3886 dnl  goom visualization plugin
3887 dnl
3888 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3889
3890 dnl
3891 dnl libprojectM visualization plugin
3892 dnl
3893 AC_ARG_ENABLE(projectm,
3894   [  --enable-projectm       projectM visualization plugin (default enabled)])
3895 AS_IF([test "${enable_projectm}" != "no"],
3896   [
3897     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3898     [
3899       VLC_ADD_PLUGIN([projectm])
3900       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3901         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3902         [ AC_MSG_WARN( [Using libprojectM version 1] )
3903       ])
3904     ],[
3905       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3906     ])
3907   ])
3908
3909 dnl
3910 dnl Vovoid VSXu visualization plugin
3911 dnl
3912 AC_ARG_ENABLE(vsxu,
3913   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3914 AS_IF([test "${enable_vsxu}" != "no"],
3915   [
3916     PKG_CHECK_MODULES(VSXU, libvsxu,
3917     [
3918       VLC_ADD_PLUGIN([vsxu])
3919     ],[
3920       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3921     ])
3922   ])
3923
3924 EXTEND_HELP_STRING([Service Discovery plugins:])
3925 dnl
3926 dnl  Avahi-Zeroconf services discovery
3927 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3928
3929 dnl
3930 dnl  libudev services discovery
3931 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3932
3933 dnl
3934 dnl MTP devices services discovery
3935 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3936
3937 dnl
3938 dnl UPnP Plugin (Intel SDK)
3939 dnl
3940 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3941
3942 dnl
3943 dnl mDNS using libmicrodns
3944 dnl
3945 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3946
3947
3948 EXTEND_HELP_STRING([Misc options:])
3949
3950 dnl
3951 dnl  libxml2 module
3952 dnl
3953 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3954
3955
3956 dnl
3957 dnl libgcrypt
3958 dnl
3959 AC_ARG_ENABLE(libgcrypt,
3960   [  --disable-libgcrypt     gcrypt support (default enabled)])
3961 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3962 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3963
3964 # require libgcrypt >= 1.6.0
3965 AS_IF([test "${enable_libgcrypt}" != "no"], [
3966   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3967     VLC_SAVE_FLAGS
3968     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3969     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3970 [#include <gcrypt.h>
3971 #if GCRYPT_VERSION_NUMBER < 0x010600
3972 #error
3973 #endif]])], [
3974       ac_cv_lib_gcrypt=yes
3975     ], [
3976       ac_cv_lib_gcrypt=no
3977     ])
3978     VLC_RESTORE_FLAGS
3979   ])
3980
3981   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3982     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3983   ], [
3984     AS_IF([test "${enable_libgcrypt}" = "yes"], [
3985       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3986     ])
3987   ])
3988 ])
3989
3990 AS_IF([test -z "$GCRYPT_LIBS"], [
3991   GCRYPT_LIBS="-lgcrypt -lgpg-error"
3992 ])
3993
3994 AC_SUBST(GCRYPT_CFLAGS)
3995 AC_SUBST(GCRYPT_LIBS)
3996 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
3997
3998 dnl
3999 dnl TLS/SSL
4000 dnl
4001 AC_ARG_ENABLE(gnutls,
4002   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4003 AS_IF([test "${enable_gnutls}" != "no"], [
4004   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4005     VLC_ADD_PLUGIN([gnutls])
4006   ], [
4007     AS_IF([test -n "${enable_gnutls}"], [
4008       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4009     ])
4010   ])
4011 ])
4012
4013
4014 dnl
4015 dnl Taglib plugin
4016 dnl
4017 AC_ARG_ENABLE(taglib,
4018   [AS_HELP_STRING([--disable-taglib],
4019     [do not use TagLib (default enabled)])])
4020 AS_IF([test "${enable_taglib}" != "no"], [
4021   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4022     VLC_ADD_PLUGIN([taglib])
4023   ], [
4024     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4025 ])
4026
4027 dnl
4028 dnl  libsecret
4029 dnl
4030 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4031
4032 dnl
4033 dnl  kwallet
4034 dnl
4035 AC_ARG_ENABLE(kwallet,
4036   [AS_HELP_STRING([--enable-kwallet],
4037     [use kwallet (via D-Bus) for keystore (default enabled)])])
4038 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4039   VLC_ADD_PLUGIN([kwallet])
4040 ])
4041
4042 dnl
4043 dnl  Developers helper modules (should be hidden from configure help)
4044 dnl
4045 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4046 AS_IF([test "${enable_devtools}" != "no"], [
4047   VLC_ADD_PLUGIN([accesstweaks])
4048 ])
4049
4050 dnl
4051 dnl update checking system
4052 dnl
4053 AC_ARG_ENABLE(update-check,
4054   [  --enable-update-check   update checking system (default disabled)])
4055 if test "${enable_update_check}" = "yes"
4056 then
4057  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4058     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4059 fi
4060 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4061
4062 dnl
4063 dnl OS X notification plugin
4064 dnl
4065 AC_ARG_ENABLE(osx_notifications,
4066   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4067   [enable_osx_notifications=no])
4068 AS_IF([test "${enable_osx_notifications}" != "no"], [
4069   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4070   then
4071       VLC_ADD_PLUGIN([osx_notifications])
4072       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4073       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4074   fi
4075 ])
4076
4077 dnl
4078 dnl Libnotify notification plugin
4079 dnl
4080 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4081
4082 dnl
4083 dnl  Endianness check
4084 dnl
4085 AC_C_BIGENDIAN
4086 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4087   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4088 ], [
4089   DEFS_BIGENDIAN=""
4090 ])
4091 AC_SUBST(DEFS_BIGENDIAN)
4092
4093 dnl
4094 dnl Where to install KDE solid .desktop
4095 dnl
4096 AC_ARG_WITH(kde-solid,
4097   AS_HELP_STRING([--with-kde-solid=PATH],
4098                  [KDE Solid actions directory (auto)]),, [
4099
4100 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4101   with_kde_solid="yes"
4102 fi
4103 ])
4104 soliddatadir=""
4105 AS_IF([test "${with_kde_solid}" != "no"], [
4106   AS_IF([test "${with_kde_solid}" = "yes"], [
4107     kde4datadir="`${KDE4_CONFIG} --install data`"
4108     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4109     soliddatadir="${kde4datadir}/solid/actions"
4110   ], [
4111     soliddatadir="${with_kde_solid}"
4112   ])
4113 ])
4114 AC_SUBST(soliddatadir)
4115 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4116
4117 dnl
4118 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4119 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4120 dnl
4121 if test "${SYS}" = "mingw32"; then
4122     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4123 fi
4124
4125 EXTEND_HELP_STRING([Components:])
4126
4127 dnl
4128 dnl  the VLC binary
4129 dnl
4130 AC_ARG_ENABLE(vlc,
4131   [  --enable-vlc            build the VLC media player (default enabled)])
4132 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4133
4134 dnl
4135 dnl  Stuff used by the program
4136 dnl
4137 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4138 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4139 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4140 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4141 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4142 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4143 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4144 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4145 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4146 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4147 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4148 AC_SUBST(COPYRIGHT_MESSAGE)
4149 AC_SUBST(VERSION_MESSAGE)
4150 AC_SUBST(VERSION_MAJOR)
4151 AC_SUBST(VERSION_MINOR)
4152 AC_SUBST(VERSION_REVISION)
4153 AC_SUBST(VERSION_EXTRA)
4154 AC_SUBST(COPYRIGHT_YEARS)
4155 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4156 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4157 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4158 dnl
4159 dnl  Handle substvars that use $(top_srcdir)
4160 dnl
4161 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4162
4163 dnl
4164 dnl  Configuration is finished
4165 dnl
4166 AC_SUBST(SYS)
4167 AC_SUBST(ARCH)
4168 AC_SUBST(ALIASES)
4169 AC_SUBST(ASM)
4170 AC_SUBST(MOC)
4171 AC_SUBST(RCC)
4172 AC_SUBST(UIC)
4173 AC_SUBST(WINDRES)
4174 AC_SUBST(WINE_SDK_PATH)
4175 AC_SUBST(LIBEXT)
4176 AC_SUBST(AM_CPPFLAGS)
4177 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4178 AC_SUBST(FILE_LIBVLCCORE_DLL)
4179 AC_SUBST(FILE_LIBVLC_DLL)
4180
4181 AC_CONFIG_FILES([
4182   Makefile
4183   doc/Makefile
4184   modules/Makefile
4185   m4/Makefile
4186   po/Makefile.in
4187   share/Makefile
4188   compat/Makefile
4189   src/Makefile
4190   lib/Makefile
4191   bin/Makefile
4192   test/Makefile
4193   modules/hw/mmal/Makefile
4194   share/vlc.appdata.xml.in
4195 ])
4196
4197 AM_COND_IF([HAVE_WIN32], [
4198   AC_CONFIG_FILES([
4199     extras/package/win32/NSIS/spad.nsi
4200     extras/package/win32/NSIS/vlc.win32.nsi
4201     extras/package/win32/msi/config.wxi
4202   ])
4203 ])
4204
4205 AM_COND_IF([HAVE_DARWIN], [
4206   AC_CONFIG_FILES([
4207     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4208     share/macosx/Info.plist:share/Info.plist.in
4209   ])
4210 ])
4211
4212 dnl Generate makefiles
4213 AC_OUTPUT
4214
4215 dnl Do we have to use make or gmake ?
4216 if make --version 2>&1|grep -q GNU
4217 then
4218     # GNU make, all seems good
4219     MAKE=make
4220 else
4221     # Known GNU make alias (on BSD)
4222     MAKE=gmake
4223 fi
4224 dnl Shortcut to nice compile message
4225 if test -n $SHELL; then
4226   SHELL=${CONFIG_SHELL-/bin/sh}
4227 fi
4228 rm -f compile
4229 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4230 echo "#! $SHELL
4231 rm -f .error\$\$
4232 ERROR=0
4233 export PATH=\"$PATH\" LANG=C
4234 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4235 test -f .error\$\$ && ERROR=1
4236 rm -f .error\$\$
4237 exit \$ERROR" >compile
4238 chmod a+x compile
4239
4240 echo "
4241 libvlc configuration
4242 --------------------
4243 version               : ${VERSION}
4244 system                : ${SYS}
4245 architecture          : ${ARCH}
4246 optimizations         : ${enable_optimizations}"
4247 if test "${enable_vlc}" != "no"; then
4248 echo "vlc aliases           :${ALIASES}"
4249 else
4250 echo "build vlc executable  : no"
4251 fi
4252 echo "
4253 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."