plugin/vcssvk.vim

   1 " vim600: set foldmethod=marker:
   2 "
   3 " SVK extension for VCSCommand.
   4 "
   5 " Version:       VCS development
   6 " Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>
   7 " License:
   8 " Copyright (c) 2007 Bob Hiestand
   9 "
  10 " Permission is hereby granted, free of charge, to any person obtaining a copy
  11 " of this software and associated documentation files (the "Software"), to
  12 " deal in the Software without restriction, including without limitation the
  13 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  14 " sell copies of the Software, and to permit persons to whom the Software is
  15 " furnished to do so, subject to the following conditions:
  16 "
  17 " The above copyright notice and this permission notice shall be included in
  18 " all copies or substantial portions of the Software.
  19 "
  20 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  21 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  22 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  23 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  24 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  26 " IN THE SOFTWARE.
  27 "
  28 " Section: Documentation {{{1
  29 "
  30 " Options documentation: {{{2
  31 "
  32 " VCSCommandSVKExec
  33 "   This variable specifies the SVK executable.  If not set, it defaults to
  34 "   'svk' executed from the user's executable path.
  35
  36 " Section: Plugin header {{{1
  37
  38 if exists('VCSCommandDisableAll')
  39         finish
  40 endif
  41
  42 if v:version < 700
  43         echohl WarningMsg|echomsg 'VCSCommand requires at least VIM 7.0'|echohl None
  44         finish
  45 endif
  46
  47 runtime plugin/vcscommand.vim
  48
  49 if !executable(VCSCommandGetOption('VCSCommandSVKExec', 'svk'))
  50         " SVK is not installed
  51         finish
  52 endif
  53
  54 let s:save_cpo=&cpo
  55 set cpo&vim
  56
  57 " Section: Variable initialization {{{1
  58
  59 let s:svkFunctions = {}
  60
  61 " Section: Utility functions {{{1
  62
  63 " Function: s:Executable() {{{2
  64 " Returns the executable used to invoke SVK suitable for use in a shell
  65 " command.
  66 function! s:Executable()
  67         return shellescape(VCSCommandGetOption('VCSCommandSVKExec', 'svk'))
  68 endfunction
  69
  70 " Function: s:DoCommand(cmd, cmdName, statusText, options) {{{2
  71 " Wrapper to VCSCommandDoCommand to add the name of the SVK executable to the
  72 " command argument.
  73 function! s:DoCommand(cmd, cmdName, statusText, options)
  74         if VCSCommandGetVCSType(expand('%')) == 'SVK'
  75                 let fullCmd = s:Executable() . ' ' . a:cmd
  76                 return VCSCommandDoCommand(fullCmd, a:cmdName, a:statusText, a:options)
  77         else
  78                 throw 'SVK VCSCommand plugin called on non-SVK item.'
  79         endif
  80 endfunction
  81
  82 " Section: VCS function implementations {{{1
  83
  84 " Function: s:svkFunctions.Identify(buffer) {{{2
  85 function! s:svkFunctions.Identify(buffer)
  86         let fileName = resolve(bufname(a:buffer))
  87         if isdirectory(fileName)
  88                 let directoryName = fileName
  89         else
  90                 let directoryName = fnamemodify(fileName, ':p:h')
  91         endif
  92         let statusText = s:VCSCommandUtility.system(s:Executable() . ' info -- "' . directoryName . '"', "no")
  93         if(v:shell_error)
  94                 return 0
  95         else
  96                 return 1
  97         endif
  98 endfunction
  99
 100 " Function: s:svkFunctions.Add() {{{2
 101 function! s:svkFunctions.Add(argList)
 102         return s:DoCommand(join(['add'] + a:argList, ' '), 'add', join(a:argList, ' '), {})
 103 endfunction
 104
 105 " Function: s:svkFunctions.Annotate(argList) {{{2
 106 function! s:svkFunctions.Annotate(argList)
 107         if len(a:argList) == 0
 108                 if &filetype == 'SVKannotate'
 109                         " Perform annotation of the version indicated by the current line.
 110                         let caption = matchstr(getline('.'),'\v^\s+\zs\d+')
 111                         let options = ' -r' . caption
 112                 else
 113                         let caption = ''
 114                         let options = ''
 115                 endif
 116         elseif len(a:argList) == 1 && a:argList[0] !~ '^-'
 117                 let caption = a:argList[0]
 118                 let options = ' -r' . caption
 119         else
 120                 let caption = join(a:argList, ' ')
 121                 let options = ' ' . caption
 122         endif
 123
 124         let resultBuffer = s:DoCommand('blame' . options, 'annotate', caption, {})
 125         if resultBuffer > 0
 126                 normal 1G2dd
 127         endif
 128         return resultBuffer
 129 endfunction
 130
 131 " Function: s:svkFunctions.Commit(argList) {{{2
 132 function! s:svkFunctions.Commit(argList)
 133         let resultBuffer = s:DoCommand('commit -F "' . a:argList[0] . '"', 'commit', '', {})
 134         if resultBuffer == 0
 135                 echomsg 'No commit needed.'
 136         endif
 137 endfunction
 138
 139 " Function: s:svkFunctions.Delete() {{{2
 140 function! s:svkFunctions.Delete(argList)
 141         return s:DoCommand(join(['delete'] + a:argList, ' '), 'delete', join(a:argList, ' '), {})
 142 endfunction
 143
 144 " Function: s:svkFunctions.Diff(argList) {{{2
 145 function! s:svkFunctions.Diff(argList)
 146         if len(a:argList) == 0
 147                 let revOptions = []
 148                 let caption = ''
 149         elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 150                 let revOptions = ['-r' . join(a:argList, ':')]
 151                 let caption = '(' . a:argList[0] . ' : ' . get(a:argList, 1, 'current') . ')'
 152         else
 153                 " Pass-through
 154                 let caption = join(a:argList, ' ')
 155                 let revOptions = a:argList
 156         endif
 157
 158         return s:DoCommand(join(['diff'] + revOptions), 'diff', caption, {})
 159 endfunction
 160
 161 " Function: s:svkFunctions.GetBufferInfo() {{{2
 162 " Provides version control details for the current file.  Current version
 163 " number and current repository version number are required to be returned by
 164 " the vcscommand plugin.
 165 " Returns: List of results:  [revision, repository]
 166
 167 function! s:svkFunctions.GetBufferInfo()
 168         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 169         let fileName = resolve(bufname(originalBuffer))
 170         let statusText = s:VCSCommandUtility.system(s:Executable() . ' status -v -- "' . fileName . '"')
 171         if(v:shell_error)
 172                 return []
 173         endif
 174
 175         " File not under SVK control.
 176         if statusText =~ '^?'
 177                 return ['Unknown']
 178         endif
 179
 180         let [flags, revision, repository] = matchlist(statusText, '^\(.\{3}\)\s\+\(\S\+\)\s\+\(\S\+\)\s\+\(\S\+\)\s')[1:3]
 181         if revision == ''
 182                 " Error
 183                 return ['Unknown']
 184         elseif flags =~ '^A'
 185                 return ['New', 'New']
 186         else
 187                 return [revision, repository]
 188         endif
 189 endfunction
 190
 191 " Function: s:svkFunctions.Info(argList) {{{2
 192 function! s:svkFunctions.Info(argList)
 193         return s:DoCommand(join(['info'] + a:argList, ' '), 'info', join(a:argList, ' '), {})
 194 endfunction
 195
 196 " Function: s:svkFunctions.Lock(argList) {{{2
 197 function! s:svkFunctions.Lock(argList)
 198         return s:DoCommand(join(['lock'] + a:argList, ' '), 'lock', join(a:argList, ' '), {})
 199 endfunction
 200
 201 " Function: s:svkFunctions.Log() {{{2
 202 function! s:svkFunctions.Log(argList)
 203         if len(a:argList) == 0
 204                 let options = []
 205                 let caption = ''
 206         elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 207                 let options = ['-r' . join(a:argList, ':')]
 208                 let caption = options[0]
 209         else
 210                 " Pass-through
 211                 let options = a:argList
 212                 let caption = join(a:argList, ' ')
 213         endif
 214
 215         let resultBuffer = s:DoCommand(join(['log', '-v'] + options), 'log', caption, {})
 216         return resultBuffer
 217 endfunction
 218
 219 " Function: s:svkFunctions.Revert(argList) {{{2
 220 function! s:svkFunctions.Revert(argList)
 221         return s:DoCommand('revert', 'revert', '', {})
 222 endfunction
 223
 224 " Function: s:svkFunctions.Review(argList) {{{2
 225 function! s:svkFunctions.Review(argList)
 226         if len(a:argList) == 0
 227                 let versiontag = '(current)'
 228                 let versionOption = ''
 229         else
 230                 let versiontag = a:argList[0]
 231                 let versionOption = ' -r ' . versiontag . ' '
 232         endif
 233
 234         return s:DoCommand('cat' . versionOption, 'review', versiontag, {})
 235 endfunction
 236
 237 " Function: s:svkFunctions.Status(argList) {{{2
 238 function! s:svkFunctions.Status(argList)
 239         let options = ['-v']
 240         if len(a:argList) != 0
 241                 let options = a:argList
 242         endif
 243         return s:DoCommand(join(['status'] + options, ' '), 'status', join(options, ' '), {})
 244 endfunction
 245
 246 " Function: s:svkFunctions.Unlock(argList) {{{2
 247 function! s:svkFunctions.Unlock(argList)
 248         return s:DoCommand(join(['unlock'] + a:argList, ' '), 'unlock', join(a:argList, ' '), {})
 249 endfunction
 250 " Function: s:svkFunctions.Update(argList) {{{2
 251 function! s:svkFunctions.Update(argList)
 252         return s:DoCommand('update', 'update', '', {})
 253 endfunction
 254
 255 " Section: Plugin Registration {{{1
 256 let s:VCSCommandUtility = VCSCommandRegisterModule('SVK', expand('<sfile>'), s:svkFunctions, [])
 257
 258 let &cpo = s:save_cpo