lib/libcrypto/perlasm/x86_64-xlate.pl

   1 #!/usr/bin/env perl
   2
   3 # Ascetic x86_64 AT&T to MASM/NASM assembler translator by <appro>.
   4 #
   5 # Why AT&T to MASM and not vice versa? Several reasons. Because AT&T
   6 # format is way easier to parse. Because it's simpler to "gear" from
   7 # Unix ABI to Windows one [see cross-reference "card" at the end of
   8 # file]. Because Linux targets were available first...
   9 #
  10 # In addition the script also "distills" code suitable for GNU
  11 # assembler, so that it can be compiled with more rigid assemblers,
  12 # such as Solaris /usr/bin/as.
  13 #
  14 # This translator is not designed to convert *arbitrary* assembler
  15 # code from AT&T format to MASM one. It's designed to convert just
  16 # enough to provide for dual-ABI OpenSSL modules development...
  17 # There *are* limitations and you might have to modify your assembler
  18 # code or this script to achieve the desired result...
  19 #
  20 # Currently recognized limitations:
  21 #
  22 # - can't use multiple ops per line;
  23 #
  24 # Dual-ABI styling rules.
  25 #
  26 # 1. Adhere to Unix register and stack layout [see cross-reference
  27 #    ABI "card" at the end for explanation].
  28 # 2. Forget about "red zone," stick to more traditional blended
  29 #    stack frame allocation. If volatile storage is actually required
  30 #    that is. If not, just leave the stack as is.
  31 # 3. Functions tagged with ".type name,@function" get crafted with
  32 #    unified Win64 prologue and epilogue automatically. If you want
  33 #    to take care of ABI differences yourself, tag functions as
  34 #    ".type name,@abi-omnipotent" instead.
  35 # 4. To optimize the Win64 prologue you can specify number of input
  36 #    arguments as ".type name,@function,N." Keep in mind that if N is
  37 #    larger than 6, then you *have to* write "abi-omnipotent" code,
  38 #    because >6 cases can't be addressed with unified prologue.
  39 # 5. Name local labels as .L*, do *not* use dynamic labels such as 1:
  40 #    (sorry about latter).
  41 # 6. Don't use [or hand-code with .byte] "rep ret." "ret" mnemonic is
  42 #    required to identify the spots, where to inject Win64 epilogue!
  43 #    But on the pros, it's then prefixed with rep automatically:-)
  44 # 7. Stick to explicit ip-relative addressing. If you have to use
  45 #    GOTPCREL addressing, stick to mov symbol@GOTPCREL(%rip),%r??.
  46 #    Both are recognized and translated to proper Win64 addressing
  47 #    modes. To support legacy code a synthetic directive, .picmeup,
  48 #    is implemented. It puts address of the *next* instruction into
  49 #    target register, e.g.:
  50 #
  51 #               .picmeup        %rax
  52 #               lea             .Label-.(%rax),%rax
  53 #
  54 # 8. In order to provide for structured exception handling unified
  55 #    Win64 prologue copies %rsp value to %rax. For further details
  56 #    see SEH paragraph at the end.
  57 # 9. .init segment is allowed to contain calls to functions only.
  58 # a. If function accepts more than 4 arguments *and* >4th argument
  59 #    is declared as non 64-bit value, do clear its upper part.
  60 \f
  61 my $flavour = shift;
  62 my $output  = shift;
  63 if ($flavour =~ /\./) { $output = $flavour; undef $flavour; }
  64
  65 open STDOUT,">$output" || die "can't open $output: $!"
  66         if (defined($output));
  67
  68 my $gas=1;      $gas=0 if ($output =~ /\.asm$/);
  69 my $elf=1;      $elf=0 if (!$gas);
  70 my $win64=0;
  71 my $prefix="";
  72 my $decor=".L";
  73
  74 my $masmref=8 + 50727*2**-32;   # 8.00.50727 shipped with VS2005
  75 my $masm=0;
  76 my $PTR=" PTR";
  77
  78 my $nasmref=2.03;
  79 my $nasm=0;
  80
  81 if    ($flavour eq "mingw64")   { $gas=1; $elf=0; $win64=1;
  82                                   $prefix=`echo __USER_LABEL_PREFIX__ | $ENV{CC} -E -P -`;
  83                                   chomp($prefix);
  84                                 }
  85 elsif ($flavour eq "macosx")    { $gas=1; $elf=0; $prefix="_"; $decor="L\$"; }
  86 elsif ($flavour eq "masm")      { $gas=0; $elf=0; $masm=$masmref; $win64=1; $decor="\$L\$"; }
  87 elsif ($flavour eq "nasm")      { $gas=0; $elf=0; $nasm=$nasmref; $win64=1; $decor="\$L\$"; $PTR=""; }
  88 elsif (!$gas)
  89 {   if ($ENV{ASM} =~ m/nasm/ && `nasm -v` =~ m/version ([0-9]+)\.([0-9]+)/i)
  90     {   $nasm = $1 + $2*0.01; $PTR="";  }
  91     elsif (`ml64 2>&1` =~ m/Version ([0-9]+)\.([0-9]+)(\.([0-9]+))?/)
  92     {   $masm = $1 + $2*2**-16 + $4*2**-32;   }
  93     die "no assembler found on %PATH" if (!($nasm || $masm));
  94     $win64=1;
  95     $elf=0;
  96     $decor="\$L\$";
  97 }
  98
  99 my $current_segment;
 100 my $current_function;
 101 my %globals;
 102
 103 { package opcode;       # pick up opcodes
 104     sub re {
 105         my      $self = shift;  # single instance in enough...
 106         local   *line = shift;
 107         undef   $ret;
 108
 109         if ($line =~ /^([a-z][a-z0-9]*)/i) {
 110             $self->{op} = $1;
 111             $ret = $self;
 112             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 113
 114             undef $self->{sz};
 115             if ($self->{op} =~ /^(movz)x?([bw]).*/) {   # movz is pain...
 116                 $self->{op} = $1;
 117                 $self->{sz} = $2;
 118             } elsif ($self->{op} =~ /call|jmp/) {
 119                 $self->{sz} = "";
 120             } elsif ($self->{op} =~ /^p/ && $' !~ /^(ush|op|insrw)/) { # SSEn
 121                 $self->{sz} = "";
 122             } elsif ($self->{op} =~ /^v/) { # VEX
 123                 $self->{sz} = "";
 124             } elsif ($self->{op} =~ /mov[dq]/ && $line =~ /%xmm/) {
 125                 $self->{sz} = "";
 126             } elsif ($self->{op} =~ /([a-z]{3,})([qlwb])$/) {
 127                 $self->{op} = $1;
 128                 $self->{sz} = $2;
 129             }
 130         }
 131         $ret;
 132     }
 133     sub size {
 134         my $self = shift;
 135         my $sz   = shift;
 136         $self->{sz} = $sz if (defined($sz) && !defined($self->{sz}));
 137         $self->{sz};
 138     }
 139     sub out {
 140         my $self = shift;
 141         if ($gas) {
 142             if ($self->{op} eq "movz") {        # movz is pain...
 143                 sprintf "%s%s%s",$self->{op},$self->{sz},shift;
 144             } elsif ($self->{op} =~ /^set/) {
 145                 "$self->{op}";
 146             } elsif ($self->{op} eq "ret") {
 147                 my $epilogue = "";
 148                 if ($win64 && $current_function->{abi} eq "svr4") {
 149                     $epilogue = "movq   8(%rsp),%rdi\n\t" .
 150                                 "movq   16(%rsp),%rsi\n\t";
 151                 }
 152                 $epilogue . "retq";
 153             } elsif ($self->{op} eq "call" && !$elf && $current_segment eq ".init") {
 154                 ".p2align\t3\n\t.quad";
 155             } else {
 156                 "$self->{op}$self->{sz}";
 157             }
 158         } else {
 159             $self->{op} =~ s/^movz/movzx/;
 160             if ($self->{op} eq "ret") {
 161                 $self->{op} = "";
 162                 if ($win64 && $current_function->{abi} eq "svr4") {
 163                     $self->{op} = "mov  rdi,QWORD${PTR}[8+rsp]\t;WIN64 epilogue\n\t".
 164                                   "mov  rsi,QWORD${PTR}[16+rsp]\n\t";
 165                 }
 166                 $self->{op} .= "DB\t0F3h,0C3h\t\t;repret";
 167             } elsif ($self->{op} =~ /^(pop|push)f/) {
 168                 $self->{op} .= $self->{sz};
 169             } elsif ($self->{op} eq "call" && $current_segment eq ".CRT\$XCU") {
 170                 $self->{op} = "\tDQ";
 171             }
 172             $self->{op};
 173         }
 174     }
 175     sub mnemonic {
 176         my $self=shift;
 177         my $op=shift;
 178         $self->{op}=$op if (defined($op));
 179         $self->{op};
 180     }
 181 }
 182 { package const;        # pick up constants, which start with $
 183     sub re {
 184         my      $self = shift;  # single instance in enough...
 185         local   *line = shift;
 186         undef   $ret;
 187
 188         if ($line =~ /^\$([^,]+)/) {
 189             $self->{value} = $1;
 190             $ret = $self;
 191             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 192         }
 193         $ret;
 194     }
 195     sub out {
 196         my $self = shift;
 197
 198         if ($gas) {
 199             # Solaris /usr/bin/as can't handle multiplications
 200             # in $self->{value}
 201             $self->{value} =~ s/(?<![\w\$\.])(0x?[0-9a-f]+)/oct($1)/egi;
 202             $self->{value} =~ s/([0-9]+\s*[\*\/\%]\s*[0-9]+)/eval($1)/eg;
 203             sprintf "\$%s",$self->{value};
 204         } else {
 205             $self->{value} =~ s/(0b[0-1]+)/oct($1)/eig;
 206             $self->{value} =~ s/0x([0-9a-f]+)/0$1h/ig if ($masm);
 207             sprintf "%s",$self->{value};
 208         }
 209     }
 210 }
 211 { package ea;           # pick up effective addresses: expr(%reg,%reg,scale)
 212     sub re {
 213         my      $self = shift;  # single instance in enough...
 214         local   *line = shift;
 215         undef   $ret;
 216
 217         # optional * ---vvv--- appears in indirect jmp/call
 218         if ($line =~ /^(\*?)([^\(,]*)\(([%\w,]+)\)/) {
 219             $self->{asterisk} = $1;
 220             $self->{label} = $2;
 221             ($self->{base},$self->{index},$self->{scale})=split(/,/,$3);
 222             $self->{scale} = 1 if (!defined($self->{scale}));
 223             $ret = $self;
 224             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 225
 226             if ($win64 && $self->{label} =~ s/\@GOTPCREL//) {
 227                 die if (opcode->mnemonic() ne "mov");
 228                 opcode->mnemonic("lea");
 229             }
 230             $self->{base}  =~ s/^%//;
 231             $self->{index} =~ s/^%// if (defined($self->{index}));
 232         }
 233         $ret;
 234     }
 235     sub size {}
 236     sub out {
 237         my $self = shift;
 238         my $sz = shift;
 239
 240         $self->{label} =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 241         $self->{label} =~ s/\.L/$decor/g;
 242
 243         # Silently convert all EAs to 64-bit. This is required for
 244         # elder GNU assembler and results in more compact code,
 245         # *but* most importantly AES module depends on this feature!
 246         $self->{index} =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 247         $self->{base}  =~ s/^[er](.?[0-9xpi])[d]?$/r\1/;
 248
 249         # Solaris /usr/bin/as can't handle multiplications
 250         # in $self->{label}, new gas requires sign extension...
 251         use integer;
 252         $self->{label} =~ s/(?<![\w\$\.])(0x?[0-9a-f]+)/oct($1)/egi;
 253         $self->{label} =~ s/([0-9]+\s*[\*\/\%]\s*[0-9]+)/eval($1)/eg;
 254         $self->{label} =~ s/([0-9]+)/$1<<32>>32/eg;
 255
 256         if ($gas) {
 257             $self->{label} =~ s/^___imp_/__imp__/   if ($flavour eq "mingw64");
 258
 259             if (defined($self->{index})) {
 260                 sprintf "%s%s(%s,%%%s,%d)",$self->{asterisk},
 261                                         $self->{label},
 262                                         $self->{base}?"%$self->{base}":"",
 263                                         $self->{index},$self->{scale};
 264             } else {
 265                 sprintf "%s%s(%%%s)",   $self->{asterisk},$self->{label},$self->{base};
 266             }
 267         } else {
 268             %szmap = (  b=>"BYTE$PTR", w=>"WORD$PTR", l=>"DWORD$PTR",
 269                         q=>"QWORD$PTR",o=>"OWORD$PTR",x=>"XMMWORD$PTR" );
 270
 271             $self->{label} =~ s/\./\$/g;
 272             $self->{label} =~ s/(?<![\w\$\.])0x([0-9a-f]+)/0$1h/ig;
 273             $self->{label} = "($self->{label})" if ($self->{label} =~ /[\*\+\-\/]/);
 274             $sz="q" if ($self->{asterisk} || opcode->mnemonic() eq "movq");
 275             $sz="l" if (opcode->mnemonic() eq "movd");
 276
 277             if (defined($self->{index})) {
 278                 sprintf "%s[%s%s*%d%s]",$szmap{$sz},
 279                                         $self->{label}?"$self->{label}+":"",
 280                                         $self->{index},$self->{scale},
 281                                         $self->{base}?"+$self->{base}":"";
 282             } elsif ($self->{base} eq "rip") {
 283                 sprintf "%s[%s]",$szmap{$sz},$self->{label};
 284             } else {
 285                 sprintf "%s[%s%s]",$szmap{$sz},
 286                                         $self->{label}?"$self->{label}+":"",
 287                                         $self->{base};
 288             }
 289         }
 290     }
 291 }
 292 { package register;     # pick up registers, which start with %.
 293     sub re {
 294         my      $class = shift; # muliple instances...
 295         my      $self = {};
 296         local   *line = shift;
 297         undef   $ret;
 298
 299         # optional * ---vvv--- appears in indirect jmp/call
 300         if ($line =~ /^(\*?)%(\w+)/) {
 301             bless $self,$class;
 302             $self->{asterisk} = $1;
 303             $self->{value} = $2;
 304             $ret = $self;
 305             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 306         }
 307         $ret;
 308     }
 309     sub size {
 310         my      $self = shift;
 311         undef   $ret;
 312
 313         if    ($self->{value} =~ /^r[\d]+b$/i)  { $ret="b"; }
 314         elsif ($self->{value} =~ /^r[\d]+w$/i)  { $ret="w"; }
 315         elsif ($self->{value} =~ /^r[\d]+d$/i)  { $ret="l"; }
 316         elsif ($self->{value} =~ /^r[\w]+$/i)   { $ret="q"; }
 317         elsif ($self->{value} =~ /^[a-d][hl]$/i){ $ret="b"; }
 318         elsif ($self->{value} =~ /^[\w]{2}l$/i) { $ret="b"; }
 319         elsif ($self->{value} =~ /^[\w]{2}$/i)  { $ret="w"; }
 320         elsif ($self->{value} =~ /^e[a-z]{2}$/i){ $ret="l"; }
 321
 322         $ret;
 323     }
 324     sub out {
 325         my $self = shift;
 326         if ($gas)       { sprintf "%s%%%s",$self->{asterisk},$self->{value}; }
 327         else            { $self->{value}; }
 328     }
 329 }
 330 { package label;        # pick up labels, which end with :
 331     sub re {
 332         my      $self = shift;  # single instance is enough...
 333         local   *line = shift;
 334         undef   $ret;
 335
 336         if ($line =~ /(^[\.\w]+)\:/) {
 337             $self->{value} = $1;
 338             $ret = $self;
 339             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 340
 341             $self->{value} =~ s/^\.L/$decor/;
 342         }
 343         $ret;
 344     }
 345     sub out {
 346         my $self = shift;
 347
 348         if ($gas) {
 349             my $func = ($globals{$self->{value}} or $self->{value}) . ":";
 350             if ($win64  &&
 351                         $current_function->{name} eq $self->{value} &&
 352                         $current_function->{abi} eq "svr4") {
 353                 $func .= "\n";
 354                 $func .= "      movq    %rdi,8(%rsp)\n";
 355                 $func .= "      movq    %rsi,16(%rsp)\n";
 356                 $func .= "      movq    %rsp,%rax\n";
 357                 $func .= "${decor}SEH_begin_$current_function->{name}:\n";
 358                 my $narg = $current_function->{narg};
 359                 $narg=6 if (!defined($narg));
 360                 $func .= "      movq    %rcx,%rdi\n" if ($narg>0);
 361                 $func .= "      movq    %rdx,%rsi\n" if ($narg>1);
 362                 $func .= "      movq    %r8,%rdx\n"  if ($narg>2);
 363                 $func .= "      movq    %r9,%rcx\n"  if ($narg>3);
 364                 $func .= "      movq    40(%rsp),%r8\n" if ($narg>4);
 365                 $func .= "      movq    48(%rsp),%r9\n" if ($narg>5);
 366             }
 367             $func;
 368         } elsif ($self->{value} ne "$current_function->{name}") {
 369             $self->{value} .= ":" if ($masm && $ret!~m/^\$/);
 370             $self->{value} . ":";
 371         } elsif ($win64 && $current_function->{abi} eq "svr4") {
 372             my $func =  "$current_function->{name}" .
 373                         ($nasm ? ":" : "\tPROC $current_function->{scope}") .
 374                         "\n";
 375             $func .= "  mov     QWORD${PTR}[8+rsp],rdi\t;WIN64 prologue\n";
 376             $func .= "  mov     QWORD${PTR}[16+rsp],rsi\n";
 377             $func .= "  mov     rax,rsp\n";
 378             $func .= "${decor}SEH_begin_$current_function->{name}:";
 379             $func .= ":" if ($masm);
 380             $func .= "\n";
 381             my $narg = $current_function->{narg};
 382             $narg=6 if (!defined($narg));
 383             $func .= "  mov     rdi,rcx\n" if ($narg>0);
 384             $func .= "  mov     rsi,rdx\n" if ($narg>1);
 385             $func .= "  mov     rdx,r8\n"  if ($narg>2);
 386             $func .= "  mov     rcx,r9\n"  if ($narg>3);
 387             $func .= "  mov     r8,QWORD${PTR}[40+rsp]\n" if ($narg>4);
 388             $func .= "  mov     r9,QWORD${PTR}[48+rsp]\n" if ($narg>5);
 389             $func .= "\n";
 390         } else {
 391            "$current_function->{name}".
 392                         ($nasm ? ":" : "\tPROC $current_function->{scope}");
 393         }
 394     }
 395 }
 396 { package expr;         # pick up expressions
 397     sub re {
 398         my      $self = shift;  # single instance is enough...
 399         local   *line = shift;
 400         undef   $ret;
 401
 402         if ($line =~ /(^[^,]+)/) {
 403             $self->{value} = $1;
 404             $ret = $self;
 405             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 406
 407             $self->{value} =~ s/\@PLT// if (!$elf);
 408             $self->{value} =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 409             $self->{value} =~ s/\.L/$decor/g;
 410         }
 411         $ret;
 412     }
 413     sub out {
 414         my $self = shift;
 415         if ($nasm && opcode->mnemonic()=~m/^j/) {
 416             "NEAR ".$self->{value};
 417         } else {
 418             $self->{value};
 419         }
 420     }
 421 }
 422 { package directive;    # pick up directives, which start with .
 423     sub re {
 424         my      $self = shift;  # single instance is enough...
 425         local   *line = shift;
 426         undef   $ret;
 427         my      $dir;
 428         my      %opcode =       # lea 2f-1f(%rip),%dst; 1: nop; 2:
 429                 (       "%rax"=>0x01058d48,     "%rcx"=>0x010d8d48,
 430                         "%rdx"=>0x01158d48,     "%rbx"=>0x011d8d48,
 431                         "%rsp"=>0x01258d48,     "%rbp"=>0x012d8d48,
 432                         "%rsi"=>0x01358d48,     "%rdi"=>0x013d8d48,
 433                         "%r8" =>0x01058d4c,     "%r9" =>0x010d8d4c,
 434                         "%r10"=>0x01158d4c,     "%r11"=>0x011d8d4c,
 435                         "%r12"=>0x01258d4c,     "%r13"=>0x012d8d4c,
 436                         "%r14"=>0x01358d4c,     "%r15"=>0x013d8d4c      );
 437
 438         if ($line =~ /^\s*(\.\w+)/) {
 439             $dir = $1;
 440             $ret = $self;
 441             undef $self->{value};
 442             $line = substr($line,@+[0]); $line =~ s/^\s+//;
 443
 444             SWITCH: for ($dir) {
 445                 /\.picmeup/ && do { if ($line =~ /(%r[\w]+)/i) {
 446                                         $dir="\t.long";
 447                                         $line=sprintf "0x%x,0x90000000",$opcode{$1};
 448                                     }
 449                                     last;
 450                                   };
 451                 /\.global|\.globl|\.extern/
 452                             && do { $globals{$line} = $prefix . $line;
 453                                     $line = $globals{$line} if ($prefix);
 454                                     last;
 455                                   };
 456                 /\.type/    && do { ($sym,$type,$narg) = split(',',$line);
 457                                     if ($type eq "\@function") {
 458                                         undef $current_function;
 459                                         $current_function->{name} = $sym;
 460                                         $current_function->{abi}  = "svr4";
 461                                         $current_function->{narg} = $narg;
 462                                         $current_function->{scope} = defined($globals{$sym})?"PUBLIC":"PRIVATE";
 463                                     } elsif ($type eq "\@abi-omnipotent") {
 464                                         undef $current_function;
 465                                         $current_function->{name} = $sym;
 466                                         $current_function->{scope} = defined($globals{$sym})?"PUBLIC":"PRIVATE";
 467                                     }
 468                                     $line =~ s/\@abi\-omnipotent/\@function/;
 469                                     $line =~ s/\@function.*/\@function/;
 470                                     last;
 471                                   };
 472                 /\.asciz/   && do { if ($line =~ /^"(.*)"$/) {
 473                                         $dir  = ".byte";
 474                                         $line = join(",",unpack("C*",$1),0);
 475                                     }
 476                                     last;
 477                                   };
 478                 /\.rva|\.long|\.quad/
 479                             && do { $line =~ s/([_a-z][_a-z0-9]*)/$globals{$1} or $1/gei;
 480                                     $line =~ s/\.L/$decor/g;
 481                                     last;
 482                                   };
 483             }
 484
 485             if ($gas) {
 486                 $self->{value} = $dir . "\t" . $line;
 487
 488                 if ($dir =~ /\.extern/) {
 489                     $self->{value} = ""; # swallow extern
 490                 } elsif (!$elf && $dir =~ /\.type/) {
 491                     $self->{value} = "";
 492                     $self->{value} = ".def\t" . ($globals{$1} or $1) . ";\t" .
 493                                 (defined($globals{$1})?".scl 2;":".scl 3;") .
 494                                 "\t.type 32;\t.endef"
 495                                 if ($win64 && $line =~ /([^,]+),\@function/);
 496                 } elsif (!$elf && $dir =~ /\.size/) {
 497                     $self->{value} = "";
 498                     if (defined($current_function)) {
 499                         $self->{value} .= "${decor}SEH_end_$current_function->{name}:"
 500                                 if ($win64 && $current_function->{abi} eq "svr4");
 501                         undef $current_function;
 502                     }
 503                 } elsif (!$elf && $dir =~ /\.align/) {
 504                     $self->{value} = ".p2align\t" . (log($line)/log(2));
 505                 } elsif ($dir eq ".section") {
 506                     $current_segment=$line;
 507                     if (!$elf && $current_segment eq ".init") {
 508                         if      ($flavour eq "macosx")  { $self->{value} = ".mod_init_func"; }
 509                         elsif   ($flavour eq "mingw64") { $self->{value} = ".section\t.ctors"; }
 510                     }
 511                 } elsif ($dir =~ /\.(text|data)/) {
 512                     $current_segment=".$1";
 513                 } elsif ($dir =~ /\.hidden/) {
 514                     if    ($flavour eq "macosx")  { $self->{value} = ".private_extern\t$prefix$line"; }
 515                     elsif ($flavour eq "mingw64") { $self->{value} = ""; }
 516                 } elsif ($dir =~ /\.comm/) {
 517                     $self->{value} = "$dir\t$prefix$line";
 518                     $self->{value} =~ s|,([0-9]+),([0-9]+)$|",$1,".log($2)/log(2)|e if ($flavour eq "macosx");
 519                 }
 520                 $line = "";
 521                 return $self;
 522             }
 523
 524             # non-gas case or nasm/masm
 525             SWITCH: for ($dir) {
 526                 /\.text/    && do { my $v=undef;
 527                                     if ($nasm) {
 528                                         $v="section     .text code align=64\n";
 529                                     } else {
 530                                         $v="$current_segment\tENDS\n" if ($current_segment);
 531                                         $current_segment = ".text\$";
 532                                         $v.="$current_segment\tSEGMENT ";
 533                                         $v.=$masm>=$masmref ? "ALIGN(64)" : "PAGE";
 534                                         $v.=" 'CODE'";
 535                                     }
 536                                     $self->{value} = $v;
 537                                     last;
 538                                   };
 539                 /\.data/    && do { my $v=undef;
 540                                     if ($nasm) {
 541                                         $v="section     .data data align=8\n";
 542                                     } else {
 543                                         $v="$current_segment\tENDS\n" if ($current_segment);
 544                                         $current_segment = "_DATA";
 545                                         $v.="$current_segment\tSEGMENT";
 546                                     }
 547                                     $self->{value} = $v;
 548                                     last;
 549                                   };
 550                 /\.section/ && do { my $v=undef;
 551                                     $line =~ s/([^,]*).*/$1/;
 552                                     $line = ".CRT\$XCU" if ($line eq ".init");
 553                                     if ($nasm) {
 554                                         $v="section     $line";
 555                                         if ($line=~/\.([px])data/) {
 556                                             $v.=" rdata align=";
 557                                             $v.=$1 eq "p"? 4 : 8;
 558                                         } elsif ($line=~/\.CRT\$/i) {
 559                                             $v.=" rdata align=8";
 560                                         }
 561                                     } else {
 562                                         $v="$current_segment\tENDS\n" if ($current_segment);
 563                                         $v.="$line\tSEGMENT";
 564                                         if ($line=~/\.([px])data/) {
 565                                             $v.=" READONLY";
 566                                             $v.=" ALIGN(".($1 eq "p" ? 4 : 8).")" if ($masm>=$masmref);
 567                                         } elsif ($line=~/\.CRT\$/i) {
 568                                             $v.=" READONLY ";
 569                                             $v.=$masm>=$masmref ? "ALIGN(8)" : "DWORD";
 570                                         }
 571                                     }
 572                                     $current_segment = $line;
 573                                     $self->{value} = $v;
 574                                     last;
 575                                   };
 576                 /\.extern/  && do { $self->{value}  = "EXTERN\t".$line;
 577                                     $self->{value} .= ":NEAR" if ($masm);
 578                                     last;
 579                                   };
 580                 /\.globl|.global/
 581                             && do { $self->{value}  = $masm?"PUBLIC":"global";
 582                                     $self->{value} .= "\t".$line;
 583                                     last;
 584                                   };
 585                 /\.size/    && do { if (defined($current_function)) {
 586                                         undef $self->{value};
 587                                         if ($current_function->{abi} eq "svr4") {
 588                                             $self->{value}="${decor}SEH_end_$current_function->{name}:";
 589                                             $self->{value}.=":\n" if($masm);
 590                                         }
 591                                         $self->{value}.="$current_function->{name}\tENDP" if($masm && $current_function->{name});
 592                                         undef $current_function;
 593                                     }
 594                                     last;
 595                                   };
 596                 /\.align/   && do { $self->{value} = "ALIGN\t".$line; last; };
 597                 /\.(value|long|rva|quad)/
 598                             && do { my $sz  = substr($1,0,1);
 599                                     my @arr = split(/,\s*/,$line);
 600                                     my $last = pop(@arr);
 601                                     my $conv = sub  {   my $var=shift;
 602                                                         $var=~s/^(0b[0-1]+)/oct($1)/eig;
 603                                                         $var=~s/^0x([0-9a-f]+)/0$1h/ig if ($masm);
 604                                                         if ($sz eq "D" && ($current_segment=~/.[px]data/ || $dir eq ".rva"))
 605                                                         { $var=~s/([_a-z\$\@][_a-z0-9\$\@]*)/$nasm?"$1 wrt ..imagebase":"imagerel $1"/egi; }
 606                                                         $var;
 607                                                     };
 608
 609                                     $sz =~ tr/bvlrq/BWDDQ/;
 610                                     $self->{value} = "\tD$sz\t";
 611                                     for (@arr) { $self->{value} .= &$conv($_).","; }
 612                                     $self->{value} .= &$conv($last);
 613                                     last;
 614                                   };
 615                 /\.byte/    && do { my @str=split(/,\s*/,$line);
 616                                     map(s/(0b[0-1]+)/oct($1)/eig,@str);
 617                                     map(s/0x([0-9a-f]+)/0$1h/ig,@str) if ($masm);
 618                                     while ($#str>15) {
 619                                         $self->{value}.="DB\t"
 620                                                 .join(",",@str[0..15])."\n";
 621                                         foreach (0..15) { shift @str; }
 622                                     }
 623                                     $self->{value}.="DB\t"
 624                                                 .join(",",@str) if (@str);
 625                                     last;
 626                                   };
 627                 /\.comm/    && do { my @str=split(/,\s*/,$line);
 628                                     my $v=undef;
 629                                     if ($nasm) {
 630                                         $v.="common     $prefix@str[0] @str[1]";
 631                                     } else {
 632                                         $v="$current_segment\tENDS\n" if ($current_segment);
 633                                         $current_segment = "_DATA";
 634                                         $v.="$current_segment\tSEGMENT\n";
 635                                         $v.="COMM       @str[0]:DWORD:".@str[1]/4;
 636                                     }
 637                                     $self->{value} = $v;
 638                                     last;
 639                                   };
 640             }
 641             $line = "";
 642         }
 643
 644         $ret;
 645     }
 646     sub out {
 647         my $self = shift;
 648         $self->{value};
 649     }
 650 }
 651
 652 sub rex {
 653  local *opcode=shift;
 654  my ($dst,$src,$rex)=@_;
 655
 656    $rex|=0x04 if($dst>=8);
 657    $rex|=0x01 if($src>=8);
 658    push @opcode,($rex|0x40) if ($rex);
 659 }
 660
 661 # older gas and ml64 don't handle SSE>2 instructions
 662 my %regrm = (   "%eax"=>0, "%ecx"=>1, "%edx"=>2, "%ebx"=>3,
 663                 "%esp"=>4, "%ebp"=>5, "%esi"=>6, "%edi"=>7      );
 664
 665 if ($flavour ne "openbsd") {
 666
 667 $movq = sub {   # elderly gas can't handle inter-register movq
 668   my $arg = shift;
 669   my @opcode=(0x66);
 670     if ($arg =~ /%xmm([0-9]+),\s*%r(\w+)/) {
 671         my ($src,$dst)=($1,$2);
 672         if ($dst !~ /[0-9]+/)   { $dst = $regrm{"%e$dst"}; }
 673         rex(\@opcode,$src,$dst,0x8);
 674         push @opcode,0x0f,0x7e;
 675         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 676         @opcode;
 677     } elsif ($arg =~ /%r(\w+),\s*%xmm([0-9]+)/) {
 678         my ($src,$dst)=($2,$1);
 679         if ($dst !~ /[0-9]+/)   { $dst = $regrm{"%e$dst"}; }
 680         rex(\@opcode,$src,$dst,0x8);
 681         push @opcode,0x0f,0x6e;
 682         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 683         @opcode;
 684     } else {
 685         ();
 686     }
 687 };
 688
 689 }
 690
 691 my $pextrd = sub {
 692     if (shift =~ /\$([0-9]+),\s*%xmm([0-9]+),\s*(%\w+)/) {
 693       my @opcode=(0x66);
 694         $imm=$1;
 695         $src=$2;
 696         $dst=$3;
 697         if ($dst =~ /%r([0-9]+)d/)      { $dst = $1; }
 698         elsif ($dst =~ /%e/)            { $dst = $regrm{$dst}; }
 699         rex(\@opcode,$src,$dst);
 700         push @opcode,0x0f,0x3a,0x16;
 701         push @opcode,0xc0|(($src&7)<<3)|($dst&7);       # ModR/M
 702         push @opcode,$imm;
 703         @opcode;
 704     } else {
 705         ();
 706     }
 707 };
 708
 709 my $pinsrd = sub {
 710     if (shift =~ /\$([0-9]+),\s*(%\w+),\s*%xmm([0-9]+)/) {
 711       my @opcode=(0x66);
 712         $imm=$1;
 713         $src=$2;
 714         $dst=$3;
 715         if ($src =~ /%r([0-9]+)/)       { $src = $1; }
 716         elsif ($src =~ /%e/)            { $src = $regrm{$src}; }
 717         rex(\@opcode,$dst,$src);
 718         push @opcode,0x0f,0x3a,0x22;
 719         push @opcode,0xc0|(($dst&7)<<3)|($src&7);       # ModR/M
 720         push @opcode,$imm;
 721         @opcode;
 722     } else {
 723         ();
 724     }
 725 };
 726
 727 if ($flavour ne "openbsd") {
 728
 729 $pshufb = sub {
 730     if (shift =~ /%xmm([0-9]+),\s*%xmm([0-9]+)/) {
 731       my @opcode=(0x66);
 732         rex(\@opcode,$2,$1);
 733         push @opcode,0x0f,0x38,0x00;
 734         push @opcode,0xc0|($1&7)|(($2&7)<<3);           # ModR/M
 735         @opcode;
 736     } else {
 737         ();
 738     }
 739 };
 740
 741 $palignr = sub {
 742     if (shift =~ /\$([0-9]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
 743       my @opcode=(0x66);
 744         rex(\@opcode,$3,$2);
 745         push @opcode,0x0f,0x3a,0x0f;
 746         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
 747         push @opcode,$1;
 748         @opcode;
 749     } else {
 750         ();
 751     }
 752 };
 753
 754 $pclmulqdq = sub {
 755     if (shift =~ /\$([x0-9a-f]+),\s*%xmm([0-9]+),\s*%xmm([0-9]+)/) {
 756       my @opcode=(0x66);
 757         rex(\@opcode,$3,$2);
 758         push @opcode,0x0f,0x3a,0x44;
 759         push @opcode,0xc0|($2&7)|(($3&7)<<3);           # ModR/M
 760         my $c=$1;
 761         push @opcode,$c=~/^0/?oct($c):$c;
 762         @opcode;
 763     } else {
 764         ();
 765     }
 766 };
 767
 768 }
 769
 770 if ($nasm) {
 771     print <<___;
 772 default rel
 773 %define XMMWORD
 774 ___
 775 } elsif ($masm) {
 776     print <<___;
 777 OPTION  DOTNAME
 778 ___
 779 }
 780 print "#include \"x86_arch.h\"\n";
 781
 782 while($line=<>) {
 783
 784     chomp($line);
 785
 786     $line =~ s|[#!].*$||;       # get rid of asm-style comments...
 787     $line =~ s|/\*.*\*/||;      # ... and C-style comments...
 788     $line =~ s|^\s+||;          # ... and skip white spaces in beginning
 789
 790     undef $label;
 791     undef $opcode;
 792     undef @args;
 793
 794     if ($label=label->re(\$line))       { print $label->out(); }
 795
 796     if (directive->re(\$line)) {
 797         printf "%s",directive->out();
 798     } elsif ($opcode=opcode->re(\$line)) {
 799         my $asm = eval("\$".$opcode->mnemonic());
 800         undef @bytes;
 801
 802         if ((ref($asm) eq 'CODE') && scalar(@bytes=&$asm($line))) {
 803             print $gas?".byte\t":"DB\t",join(',',@bytes),"\n";
 804             next;
 805         }
 806
 807         ARGUMENT: while (1) {
 808         my $arg;
 809
 810         if ($arg=register->re(\$line))  { opcode->size($arg->size()); }
 811         elsif ($arg=const->re(\$line))  { }
 812         elsif ($arg=ea->re(\$line))     { }
 813         elsif ($arg=expr->re(\$line))   { }
 814         else                            { last ARGUMENT; }
 815
 816         push @args,$arg;
 817
 818         last ARGUMENT if ($line !~ /^,/);
 819
 820         $line =~ s/^,\s*//;
 821         } # ARGUMENT:
 822
 823         if ($#args>=0) {
 824             my $insn;
 825             my $sz=opcode->size();
 826
 827             if ($gas) {
 828                 $insn = $opcode->out($#args>=1?$args[$#args]->size():$sz);
 829                 @args = map($_->out($sz),@args);
 830                 printf "\t%s\t%s",$insn,join(",",@args);
 831             } else {
 832                 $insn = $opcode->out();
 833                 foreach (@args) {
 834                     my $arg = $_->out();
 835                     # $insn.=$sz compensates for movq, pinsrw, ...
 836                     if ($arg =~ /^xmm[0-9]+$/) { $insn.=$sz; $sz="x" if(!$sz); last; }
 837                     if ($arg =~ /^mm[0-9]+$/)  { $insn.=$sz; $sz="q" if(!$sz); last; }
 838                 }
 839                 @args = reverse(@args);
 840                 undef $sz if ($nasm && $opcode->mnemonic() eq "lea");
 841                 printf "\t%s\t%s",$insn,join(",",map($_->out($sz),@args));
 842             }
 843         } else {
 844             printf "\t%s",$opcode->out();
 845         }
 846     }
 847
 848     print $line,"\n";
 849 }
 850
 851 print "\n$current_segment\tENDS\n"      if ($current_segment && $masm);
 852 print "END\n"                           if ($masm);
 853
 854 close STDOUT;
 855
 856 \f#################################################
 857 # Cross-reference x86_64 ABI "card"
 858 #
 859 #               Unix            Win64
 860 # %rax          *               *
 861 # %rbx          -               -
 862 # %rcx          #4              #1
 863 # %rdx          #3              #2
 864 # %rsi          #2              -
 865 # %rdi          #1              -
 866 # %rbp          -               -
 867 # %rsp          -               -
 868 # %r8           #5              #3
 869 # %r9           #6              #4
 870 # %r10          *               *
 871 # %r11          *               *
 872 # %r12          -               -
 873 # %r13          -               -
 874 # %r14          -               -
 875 # %r15          -               -
 876 #
 877 # (*)   volatile register
 878 # (-)   preserved by callee
 879 # (#)   Nth argument, volatile
 880 #
 881 # In Unix terms top of stack is argument transfer area for arguments
 882 # which could not be accomodated in registers. Or in other words 7th
 883 # [integer] argument resides at 8(%rsp) upon function entry point.
 884 # 128 bytes above %rsp constitute a "red zone" which is not touched
 885 # by signal handlers and can be used as temporal storage without
 886 # allocating a frame.
 887 #
 888 # In Win64 terms N*8 bytes on top of stack is argument transfer area,
 889 # which belongs to/can be overwritten by callee. N is the number of
 890 # arguments passed to callee, *but* not less than 4! This means that
 891 # upon function entry point 5th argument resides at 40(%rsp), as well
 892 # as that 32 bytes from 8(%rsp) can always be used as temporal
 893 # storage [without allocating a frame]. One can actually argue that
 894 # one can assume a "red zone" above stack pointer under Win64 as well.
 895 # Point is that at apparently no occasion Windows kernel would alter
 896 # the area above user stack pointer in true asynchronous manner...
 897 #
 898 # All the above means that if assembler programmer adheres to Unix
 899 # register and stack layout, but disregards the "red zone" existense,
 900 # it's possible to use following prologue and epilogue to "gear" from
 901 # Unix to Win64 ABI in leaf functions with not more than 6 arguments.
 902 #
 903 # omnipotent_function:
 904 # ifdef WIN64
 905 #       movq    %rdi,8(%rsp)
 906 #       movq    %rsi,16(%rsp)
 907 #       movq    %rcx,%rdi       ; if 1st argument is actually present
 908 #       movq    %rdx,%rsi       ; if 2nd argument is actually ...
 909 #       movq    %r8,%rdx        ; if 3rd argument is ...
 910 #       movq    %r9,%rcx        ; if 4th argument ...
 911 #       movq    40(%rsp),%r8    ; if 5th ...
 912 #       movq    48(%rsp),%r9    ; if 6th ...
 913 # endif
 914 #       ...
 915 # ifdef WIN64
 916 #       movq    8(%rsp),%rdi
 917 #       movq    16(%rsp),%rsi
 918 # endif
 919 #       ret
 920 #
 921 \f#################################################
 922 # Win64 SEH, Structured Exception Handling.
 923 #
 924 # Unlike on Unix systems(*) lack of Win64 stack unwinding information
 925 # has undesired side-effect at run-time: if an exception is raised in
 926 # assembler subroutine such as those in question (basically we're
 927 # referring to segmentation violations caused by malformed input
 928 # parameters), the application is briskly terminated without invoking
 929 # any exception handlers, most notably without generating memory dump
 930 # or any user notification whatsoever. This poses a problem. It's
 931 # possible to address it by registering custom language-specific
 932 # handler that would restore processor context to the state at
 933 # subroutine entry point and return "exception is not handled, keep
 934 # unwinding" code. Writing such handler can be a challenge... But it's
 935 # doable, though requires certain coding convention. Consider following
 936 # snippet:
 937 #
 938 # .type function,@function
 939 # function:
 940 #       movq    %rsp,%rax       # copy rsp to volatile register
 941 #       pushq   %r15            # save non-volatile registers
 942 #       pushq   %rbx
 943 #       pushq   %rbp
 944 #       movq    %rsp,%r11
 945 #       subq    %rdi,%r11       # prepare [variable] stack frame
 946 #       andq    $-64,%r11
 947 #       movq    %rax,0(%r11)    # check for exceptions
 948 #       movq    %r11,%rsp       # allocate [variable] stack frame
 949 #       movq    %rax,0(%rsp)    # save original rsp value
 950 # magic_point:
 951 #       ...
 952 #       movq    0(%rsp),%rcx    # pull original rsp value
 953 #       movq    -24(%rcx),%rbp  # restore non-volatile registers
 954 #       movq    -16(%rcx),%rbx
 955 #       movq    -8(%rcx),%r15
 956 #       movq    %rcx,%rsp       # restore original rsp
 957 #       ret
 958 # .size function,.-function
 959 #
 960 # The key is that up to magic_point copy of original rsp value remains
 961 # in chosen volatile register and no non-volatile register, except for
 962 # rsp, is modified. While past magic_point rsp remains constant till
 963 # the very end of the function. In this case custom language-specific
 964 # exception handler would look like this:
 965 #
 966 # EXCEPTION_DISPOSITION handler (EXCEPTION_RECORD *rec,ULONG64 frame,
 967 #               CONTEXT *context,DISPATCHER_CONTEXT *disp)
 968 # {     ULONG64 *rsp = (ULONG64 *)context->Rax;
 969 #       if (context->Rip >= magic_point)
 970 #       {   rsp = ((ULONG64 **)context->Rsp)[0];
 971 #           context->Rbp = rsp[-3];
 972 #           context->Rbx = rsp[-2];
 973 #           context->R15 = rsp[-1];
 974 #       }
 975 #       context->Rsp = (ULONG64)rsp;
 976 #       context->Rdi = rsp[1];
 977 #       context->Rsi = rsp[2];
 978 #
 979 #       memcpy (disp->ContextRecord,context,sizeof(CONTEXT));
 980 #       RtlVirtualUnwind(UNW_FLAG_NHANDLER,disp->ImageBase,
 981 #               dips->ControlPc,disp->FunctionEntry,disp->ContextRecord,
 982 #               &disp->HandlerData,&disp->EstablisherFrame,NULL);
 983 #       return ExceptionContinueSearch;
 984 # }
 985 #
 986 # It's appropriate to implement this handler in assembler, directly in
 987 # function's module. In order to do that one has to know members'
 988 # offsets in CONTEXT and DISPATCHER_CONTEXT structures and some constant
 989 # values. Here they are:
 990 #
 991 #       CONTEXT.Rax                             120
 992 #       CONTEXT.Rcx                             128
 993 #       CONTEXT.Rdx                             136
 994 #       CONTEXT.Rbx                             144
 995 #       CONTEXT.Rsp                             152
 996 #       CONTEXT.Rbp                             160
 997 #       CONTEXT.Rsi                             168
 998 #       CONTEXT.Rdi                             176
 999 #       CONTEXT.R8                              184
1000 #       CONTEXT.R9                              192
1001 #       CONTEXT.R10                             200
1002 #       CONTEXT.R11                             208
1003 #       CONTEXT.R12                             216
1004 #       CONTEXT.R13                             224
1005 #       CONTEXT.R14                             232
1006 #       CONTEXT.R15                             240
1007 #       CONTEXT.Rip                             248
1008 #       CONTEXT.Xmm6                            512
1009 #       sizeof(CONTEXT)                         1232
1010 #       DISPATCHER_CONTEXT.ControlPc            0
1011 #       DISPATCHER_CONTEXT.ImageBase            8
1012 #       DISPATCHER_CONTEXT.FunctionEntry        16
1013 #       DISPATCHER_CONTEXT.EstablisherFrame     24
1014 #       DISPATCHER_CONTEXT.TargetIp             32
1015 #       DISPATCHER_CONTEXT.ContextRecord        40
1016 #       DISPATCHER_CONTEXT.LanguageHandler      48
1017 #       DISPATCHER_CONTEXT.HandlerData          56
1018 #       UNW_FLAG_NHANDLER                       0
1019 #       ExceptionContinueSearch                 1
1020 #
1021 # In order to tie the handler to the function one has to compose
1022 # couple of structures: one for .xdata segment and one for .pdata.
1023 #
1024 # UNWIND_INFO structure for .xdata segment would be
1025 #
1026 # function_unwind_info:
1027 #       .byte   9,0,0,0
1028 #       .rva    handler
1029 #
1030 # This structure designates exception handler for a function with
1031 # zero-length prologue, no stack frame or frame register.
1032 #
1033 # To facilitate composing of .pdata structures, auto-generated "gear"
1034 # prologue copies rsp value to rax and denotes next instruction with
1035 # .LSEH_begin_{function_name} label. This essentially defines the SEH
1036 # styling rule mentioned in the beginning. Position of this label is
1037 # chosen in such manner that possible exceptions raised in the "gear"
1038 # prologue would be accounted to caller and unwound from latter's frame.
1039 # End of function is marked with respective .LSEH_end_{function_name}
1040 # label. To summarize, .pdata segment would contain
1041 #
1042 #       .rva    .LSEH_begin_function
1043 #       .rva    .LSEH_end_function
1044 #       .rva    function_unwind_info
1045 #
1046 # Reference to functon_unwind_info from .xdata segment is the anchor.
1047 # In case you wonder why references are 32-bit .rvas and not 64-bit
1048 # .quads. References put into these two segments are required to be
1049 # *relative* to the base address of the current binary module, a.k.a.
1050 # image base. No Win64 module, be it .exe or .dll, can be larger than
1051 # 2GB and thus such relative references can be and are accommodated in
1052 # 32 bits.
1053 #
1054 # Having reviewed the example function code, one can argue that "movq
1055 # %rsp,%rax" above is redundant. It is not! Keep in mind that on Unix
1056 # rax would contain an undefined value. If this "offends" you, use
1057 # another register and refrain from modifying rax till magic_point is
1058 # reached, i.e. as if it was a non-volatile register. If more registers
1059 # are required prior [variable] frame setup is completed, note that
1060 # nobody says that you can have only one "magic point." You can
1061 # "liberate" non-volatile registers by denoting last stack off-load
1062 # instruction and reflecting it in finer grade unwind logic in handler.
1063 # After all, isn't it why it's called *language-specific* handler...
1064 #
1065 # Attentive reader can notice that exceptions would be mishandled in
1066 # auto-generated "gear" epilogue. Well, exception effectively can't
1067 # occur there, because if memory area used by it was subject to
1068 # segmentation violation, then it would be raised upon call to the
1069 # function (and as already mentioned be accounted to caller, which is
1070 # not a problem). If you're still not comfortable, then define tail
1071 # "magic point" just prior ret instruction and have handler treat it...
1072 #
1073 # (*)   Note that we're talking about run-time, not debug-time. Lack of
1074 #       unwind information makes debugging hard on both Windows and
1075 #       Unix. "Unlike" referes to the fact that on Unix signal handler
1076 #       will always be invoked, core dumped and appropriate exit code
1077 #       returned to parent (for user notification).