libc/sysdeps/linux/aarch64/__longjmp.S

   1 /* Copyright (C) 1997-2016 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public License as
   7    published by the Free Software Foundation; either version 2.1 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21
  22 /* __longjmp(jmpbuf, val) */
  23
  24 ENTRY (__longjmp)
  25         cfi_def_cfa(x0, 0)
  26         cfi_offset(x19, JB_X19<<3)
  27         cfi_offset(x20, JB_X20<<3)
  28         cfi_offset(x21, JB_X21<<3)
  29         cfi_offset(x22, JB_X22<<3)
  30         cfi_offset(x23, JB_X23<<3)
  31         cfi_offset(x24, JB_X24<<3)
  32         cfi_offset(x25, JB_X25<<3)
  33         cfi_offset(x26, JB_X26<<3)
  34         cfi_offset(x27, JB_X27<<3)
  35         cfi_offset(x28, JB_X28<<3)
  36         cfi_offset(x29, JB_X29<<3)
  37         cfi_offset(x30, JB_LR<<3)
  38
  39         cfi_offset( d8, JB_D8<<3)
  40         cfi_offset( d9, JB_D9<<3)
  41         cfi_offset(d10, JB_D10<<3)
  42         cfi_offset(d11, JB_D11<<3)
  43         cfi_offset(d12, JB_D12<<3)
  44         cfi_offset(d13, JB_D13<<3)
  45         cfi_offset(d14, JB_D14<<3)
  46         cfi_offset(d15, JB_D15<<3)
  47
  48         ldp     x19, x20, [x0, #JB_X19<<3]
  49         ldp     x21, x22, [x0, #JB_X21<<3]
  50         ldp     x23, x24, [x0, #JB_X23<<3]
  51         ldp     x25, x26, [x0, #JB_X25<<3]
  52         ldp     x27, x28, [x0, #JB_X27<<3]
  53         ldp     x29, x30, [x0, #JB_X29<<3]
  54
  55         /* longjmp probe takes 3 arguments, address of jump buffer as
  56            first argument (8@x0), return value as second argument (-4@x1),
  57            and target address (8@x30), respectively.  */
  58         //LIBC_PROBE (longjmp, 3, 8@x0, -4@x1, 8@x30)
  59         ldp      d8,  d9, [x0, #JB_D8<<3]
  60         ldp     d10, d11, [x0, #JB_D10<<3]
  61         ldp     d12, d13, [x0, #JB_D12<<3]
  62         ldp     d14, d15, [x0, #JB_D14<<3]
  63
  64         /* Originally this was implemented with a series of
  65            .cfi_restore() directives.
  66
  67            The theory was that cfi_restore should revert to previous
  68            frame value is the same as the current value.  In practice
  69            this doesn't work, even after cfi_restore() gdb continues
  70            to try to recover a previous frame value offset from x0,
  71            which gets stuffed after a few more instructions.  The
  72            cfi_same_value() mechanism appears to work fine.  */
  73
  74         cfi_same_value(x19)
  75         cfi_same_value(x20)
  76         cfi_same_value(x21)
  77         cfi_same_value(x22)
  78         cfi_same_value(x23)
  79         cfi_same_value(x24)
  80         cfi_same_value(x25)
  81         cfi_same_value(x26)
  82         cfi_same_value(x27)
  83         cfi_same_value(x28)
  84         cfi_same_value(x29)
  85         cfi_same_value(x30)
  86         cfi_same_value(d8)
  87         cfi_same_value(d9)
  88         cfi_same_value(d10)
  89         cfi_same_value(d11)
  90         cfi_same_value(d12)
  91         cfi_same_value(d13)
  92         cfi_same_value(d14)
  93         cfi_same_value(d15)
  94         ldr     x5, [x0, #JB_SP<<3]
  95         mov     sp, x5
  96
  97         /* longjmp_target probe takes 3 arguments, address of jump buffer
  98            as first argument (8@x0), return value as second argument (-4@x1),
  99            and target address (8@x30), respectively.  */
 100         //LIBC_PROBE (longjmp_target, 3, 8@x0, -4@x1, 8@x30)
 101         cmp     x1, #0
 102         mov     x0, #1
 103         csel    x0, x1, x0, ne
 104         /* Use br instead of ret because ret is guaranteed to mispredict */
 105         br      x30
 106 END (__longjmp)
 107 libc_hidden_def(__longjmp)