m4/autotroll.m4

   1 # Build Qt apps with the autotools (Autoconf/Automake).
   2 # M4 macros.
   3 #
   4 # This file is part of AutoTroll.
   5 #
   6 # Copyright (C) 2006  Benoit Sigoure <benoit.sigoure@lrde.epita.fr>
   7 #   modified 2012-2013 by Werner Lemberg <wl@gnu.org>
   8 #
   9 # AutoTroll is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  22 # 02110-1301, USA.
  23 #
  24 # In addition, as a special exception, the copyright holders of
  25 # AutoTroll give you unlimited permission to copy, distribute and
  26 # modify the configure scripts that are the output of Autoconf when
  27 # processing the macros of AutoTroll.  You need not follow the terms
  28 # of the GNU General Public License when using or distributing such
  29 # scripts, even though portions of the text of AutoTroll appear in
  30 # them.  The GNU General Public License (GPL) does govern all other
  31 # use of the material that constitutes AutoTroll.
  32 #
  33 # This special exception to the GPL applies to versions of AutoTroll
  34 # released by the copyright holders of AutoTroll.  Note that people
  35 # who make modified versions of AutoTroll are not obligated to grant
  36 # this special exception for their modified versions; it is their
  37 # choice whether to do so.  The GNU General Public License gives
  38 # permission to release a modified version without this exception;
  39 # this exception also makes it possible to release a modified version
  40 # which carries forward this exception.
  41
  42  # ------------- #
  43  # DOCUMENTATION #
  44  # ------------- #
  45
  46 # Disclaimer: Tested with Qt 4.2 and 4.8 only.  Feedback welcome.
  47 # Simply invoke AT_WITH_QT in your configure.ac.  AT_WITH_QT can take
  48 # arguments which are documented in depth below.  The default
  49 # arguments are equivalent to the default .pro file generated by
  50 # qmake.
  51 #
  52 # Invoking AT_WITH_QT will do the following:
  53 #
  54 #  - Add option `--with-qt[=ARG]' to your configure script.  Possible
  55 #    values for ARG are `yes' (which is the default) and `no' to
  56 #    enable and disable Qt support, respectively, or a path to the
  57 #    directory which contains the Qt binaries in case you have a
  58 #    non-stardard location.
  59 #  - Add option `--without-qt', which is equivalent to `--with-qt=no'.
  60 #  - If Qt support is enabled, define C preprocessor macro HAVE_QT.
  61 #  - Find the programs `qmake', `moc', `uic', and `rcc' and save them
  62 #    in the make variables $(QMAKE), $(MOC), $(UIC), and $(RCC).
  63 #  - Save the path to Qt binaries in $(QT_PATH).
  64 #  - Find the flags necessary to compile and link Qt, that is:
  65 #     * $(QT_DEFINES): -D's defined by qmake.
  66 #     * $(QT_CFLAGS): CFLAGS as defined by qmake (C?!)
  67 #     * $(QT_CXXFLAGS): CXXFLAGS as defined by qmake.
  68 #     * $(QT_INCPATH): -I's defined by qmake.
  69 #     * $(QT_CPPFLAGS): Same as $(QT_DEFINES) + $(QT_INCPATH).
  70 #     * $(QT_LFLAGS): LFLAGS defined by qmake.
  71 #     * $(QT_LDFLAGS): Same thing as $(QT_LFLAGS).
  72 #     * $(QT_LIBS): LIBS defined by qmake.
  73 #
  74 # You *MUST* invoke $(MOC) and/or $(UIC) by yourself where necessary.
  75 # AutoTroll provides you with Makerules to ease this; here is a sample
  76 # Makefile.am to use with AutoTroll which builds the code given in
  77 # chapter 7 of the Qt Tutorial
  78 # (http://doc.trolltech.com/4.2/tutorial-t7.html).
  79 #
  80 # -------------------------------------------------------------------------
  81 # include $(top_srcdir)/build-aux/autotroll.mk
  82 #
  83 # ACLOCAL_AMFLAGS = -I build-aux
  84 #
  85 # bin_PROGRAMS = lcdrange
  86 # lcdrange_SOURCES  = $(BUILT_SOURCES) lcdrange.cpp lcdrange.h main.cpp
  87 # lcdrange_CXXFLAGS = $(QT_CXXFLAGS) $(AM_CXXFLAGS)
  88 # lcdrange_CPPFLAGS = $(QT_CPPFLAGS) $(AM_CPPFLAGS)
  89 # lcdrange_LDFLAGS  = $(QT_LDFLAGS) $(LDFLAGS)
  90 # lcdrange_LDADD    = $(QT_LIBS) $(LDADD)
  91 #
  92 # BUILT_SOURCES = lcdrange.moc.cpp
  93 # -------------------------------------------------------------------------
  94 #
  95 # Note that your MOC, UIC, and RRC files *MUST* be listed explicitly
  96 # in BUILT_SOURCES.  If you name them properly (e.g. `.moc.cc',
  97 # `.qrc.cc', `.ui.cc' -- of course you can use `.cpp' or `.cxx' or
  98 # `.C' rather than `.cc') AutoTroll will build them automagically for
  99 # you, using implicit rules defined in `autotroll.mk'.
 100
 101 m4_define([_AUTOTROLL_SERIAL],
 102   [m4_translit([
 103 # serial 8
 104 ], [#
 105 ], [])])
 106
 107
 108 m4_ifdef([AX_INSTEAD_IF],
 109   [],
 110   [AC_DEFUN([AX_INSTEAD_IF],
 111     [m4_ifval([$1],
 112       [AC_MSG_WARN([$2])
 113        [$1]],
 114       [AC_MSG_ERROR([$2])])])])
 115
 116
 117 # AX_PATH_TOOLS(VARIABLE, PROGS-TO-CHECK-FOR, [VALUE-IF-NOT-FOUND], [PATH])
 118 # -------------------------------------------------------------------------
 119 AC_DEFUN([AX_PATH_TOOLS],
 120   [for ax_tool in $2; do
 121      AC_PATH_TOOL([$1], [$ax_tool], , [$4])
 122      test -n "$$1" && break
 123    done
 124    m4_ifval([$3], [test -n "$$1" || $1="$3"])
 125   ])
 126
 127
 128 m4_pattern_forbid([^AT_])
 129 m4_pattern_forbid([^_AT_])
 130
 131
 132 # AT_WITH_QT([QT_modules], [QT_config], [QT_misc], [RUN-IF-FAILED], [RUN-IF-OK])
 133 # ------------------------------------------------------------------------------
 134 # Enable Qt support and add an option --with-qt to the configure
 135 # script.
 136 #
 137 # The QT_modules argument is optional and defines extra modules to
 138 # enable or disable (it's equivalent to the QT variable in .pro
 139 # files).  Modules can be specified as follows:
 140 #
 141 # AT_WITH_QT   => No argument -> No QT value.
 142 #                                Qmake sets it to "core gui" by
 143 #                                default.
 144 # AT_WITH_QT([xml])   => QT += xml
 145 # AT_WITH_QT([+xml])  => QT += xml
 146 # AT_WITH_QT([-gui])  => QT -= gui
 147 # AT_WITH_QT([xml -gui +sql svg])  => QT += xml sql svg
 148 #                                     QT -= gui
 149 #
 150 # The QT_config argument is also optional and follows the same
 151 # convention as QT_modules.  Instead of changing the QT variable, it
 152 # changes the CONFIG variable, which is used to tweak configuration
 153 # and compiler options.
 154 #
 155 # The last argument, QT_misc (also optional) will be copied as-is the
 156 # .pro file used to guess how to compile Qt apps.  You may use it to
 157 # further tweak the build process of Qt apps if tweaking the QT or
 158 # CONFIG variables isn't enough for you.
 159 #
 160 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or
 161 # if any problem happens.  If this argument is omitted, then
 162 # AC_MSG_ERROR will be called.  RUN-IF-OK is arbitrary code to execute
 163 # if Qt was successfully found.
 164
 165 AC_DEFUN([AT_WITH_QT],
 166   [AC_REQUIRE([AC_CANONICAL_HOST])
 167    AC_REQUIRE([AC_CANONICAL_BUILD])
 168    AC_REQUIRE([AC_PROG_CXX])
 169
 170    echo "$as_me: this is autotroll.m4[]_AUTOTROLL_SERIAL" \
 171      >& AS_MESSAGE_LOG_FD
 172
 173    # This is a hack to get decent flow control with `break'.
 174    for _qt_ignored in once; do
 175
 176      AC_ARG_WITH([qt],
 177        AS_HELP_STRING([--with-qt@<:@=ARG@:>@],
 178          [Qt support.  ARG can be `yes' (the default), `no',
 179           or a path to Qt binaries; if `yes' or empty,
 180           use PATH and some default directories to find Qt binaries]))
 181
 182      if test x"$with_qt" = x"no"; then
 183        break
 184      else
 185        AC_DEFINE([HAVE_QT],[1],
 186          [Define if the Qt framework is available.])
 187      fi
 188
 189      if test x"$with_qt" = x"yes"; then
 190        QT_PATH=
 191      else
 192        QT_PATH=$with_qt
 193      fi
 194
 195      # Find Qt.
 196      AC_ARG_VAR([QT_PATH],
 197        [path to Qt binaries])
 198      if test -d /usr/local/Trolltech; then
 199        # Try to find the latest version.
 200        tmp_qt_paths=`echo /usr/local/Trolltech/*/bin \
 201                      | tr ' ' '\n' \
 202                      | sort -nr \
 203                      | xargs \
 204                      | sed 's/  */:/g'`
 205      fi
 206
 207      # Path to which recent MacPorts (~v1.7) install Qt4.
 208      test -d /opt/local/libexec/qt4-mac/bin \
 209      && tmp_qt_paths="$tmp_qt_paths:/opt/local/libexec/qt4-mac/bin"
 210
 211      # Find qmake.
 212      AC_ARG_VAR([QMAKE],
 213        [Qt Makefile generator command])
 214      AX_PATH_TOOLS([QMAKE],
 215        [qmake qmake-qt4 qmake-qt3],
 216        [missing],
 217        [$QT_DIR:$QT_PATH:$PATH:$tmp_qt_paths])
 218      if test x"$QMAKE" = xmissing; then
 219        AX_INSTEAD_IF([$4],
 220          [Cannot find qmake.  Try --with-qt=PATH.])
 221        break
 222      fi
 223
 224      # Find moc (Meta Object Compiler).
 225      AC_ARG_VAR([MOC],
 226        [Qt Meta Object Compiler command])
 227      AX_PATH_TOOLS([MOC],
 228        [moc moc-qt4 moc-qt3],
 229        [missing],
 230        [$QT_PATH:$PATH:$tmp_qt_paths])
 231      if test x"$MOC" = xmissing; then
 232        AX_INSTEAD_IF([$4],
 233          [Cannot find moc (Meta Object Compiler).  Try --with-qt=PATH.])
 234        break
 235      fi
 236
 237      # Find uic (User Interface Compiler).
 238      AC_ARG_VAR([UIC],
 239        [Qt User Interface Compiler command])
 240      AX_PATH_TOOLS([UIC],
 241        [uic uic-qt4 uic-qt3 uic3],
 242        [missing],
 243        [$QT_PATH:$PATH:$tmp_qt_paths])
 244      if test x"$UIC" = xmissing; then
 245        AX_INSTEAD_IF([$4],
 246          [Cannot find uic (User Interface Compiler).  Try --with-qt=PATH.])
 247        break
 248      fi
 249
 250      # Find rcc (Qt Resource Compiler).
 251      AC_ARG_VAR([RCC],
 252        [Qt Resource Compiler command])
 253      AX_PATH_TOOLS([RCC],
 254        [rcc],
 255        [missing],
 256        [$QT_PATH:$PATH:$tmp_qt_paths])
 257      if test x"$RCC" = xmissing; then
 258        AC_MSG_WARN(
 259          [Cannot find rcc (Qt Resource Compiler).  Try --with-qt=PATH.])
 260      fi
 261
 262      AC_MSG_CHECKING([whether host operating system is Darwin])
 263      at_darwin=no
 264      at_qmake_args=
 265      case $host_os in
 266        darwin*)
 267          at_darwin=yes
 268          at_qmake_args='-spec macx-g++'
 269          ;;
 270      esac
 271      AC_MSG_RESULT([$at_darwin])
 272
 273      # If we don't know the path to Qt, guess it from the path to
 274      # qmake.
 275      if test x"$QT_PATH" = x; then
 276        QT_PATH=`dirname "$QMAKE"`
 277      fi
 278      if test x"$QT_PATH" = x; then
 279        AX_INSTEAD_IF([$4],
 280          [Cannot find your Qt installation.  Try --with-qt=PATH.])
 281        break
 282      fi
 283      AC_SUBST([QT_PATH])
 284
 285      # Get ready to build a test-app with Qt.
 286      if mkdir conftest.dir \
 287         && cd conftest.dir; then
 288        :
 289      else
 290        AX_INSTEAD_IF([$4],
 291          [Cannot mkdir conftest.dir or cd to that directory.])
 292        break
 293      fi
 294
 295      cat >conftest.h <<_ASEOF
 296
 297 #include <QObject>
 298
 299 class Foo: public QObject
 300 {
 301   Q_OBJECT;
 302 public:
 303   Foo();
 304   ~Foo() {}
 305 public Q_SLOTS:
 306   void setValue(int value);
 307 Q_SIGNALS:
 308   void valueChanged(int newValue);
 309 private:
 310   int value_;
 311 };
 312
 313 _ASEOF
 314
 315      cat >conftest.cpp <<_ASEOF
 316
 317 #include "conftest.h"
 318
 319 Foo::Foo()
 320   : value_ (42)
 321 {
 322   connect(this, SIGNAL(valueChanged(int)),
 323           this, SLOT(setValue(int)));
 324 }
 325
 326 void Foo::setValue(int value)
 327 {
 328   value_ = value;
 329 }
 330
 331 int main()
 332 {
 333   Foo f;
 334 }
 335
 336 _ASEOF
 337
 338      if $QMAKE -project; then
 339        :
 340      else
 341        AX_INSTEAD_IF([$4],
 342          [Calling $QMAKE -project failed.])
 343        break
 344      fi
 345
 346      # Find the .pro file generated by qmake.
 347      pro_file=conftest.dir.pro
 348      test -f $pro_file || pro_file=`echo *.pro`
 349      if test -f "$pro_file"; then
 350        :
 351      else
 352        AX_INSTEAD_IF([$4],
 353          [Can't find the .pro file generated by Qmake.])
 354        break
 355      fi
 356
 357      dnl Tweak the value of QT in the .pro if have been the 1st arg.
 358      m4_ifval([$1],
 359        [_AT_TWEAK_PRO_FILE([QT], [$1])])
 360
 361      dnl Tweak the value of CONFIG in the .pro if have been given a
 362      dnl 2nd arg.
 363      m4_ifval([$2],
 364        [_AT_TWEAK_PRO_FILE([CONFIG], [$2])])
 365
 366      m4_ifval([$3],
 367        [ # Add the extra-settings the user wants to set in the .pro.
 368          echo "$3" >>"$pro_file"
 369        ])
 370
 371      echo "$as_me:$LINENO: Invoking $QMAKE on $pro_file" \
 372        >& AS_MESSAGE_LOG_FD
 373      sed 's/^/| /' "$pro_file" >& AS_MESSAGE_LOG_FD
 374
 375      if $QMAKE $at_qmake_args; then
 376        :
 377      else
 378        AX_INSTEAD_IF([$4],
 379          [Calling $QMAKE $at_qmake_args failed.])
 380        break
 381      fi
 382
 383      # QMake has a very annoying misfeature: Sometimes it generates
 384      # Makefiles where all the references to the files from the Qt
 385      # installation are relative.  We can't use them as-is because if
 386      # we take, say, a -I../../usr/include/Qt from that Makefile, the
 387      # flag is invalid as soon as we use it in another (sub)
 388      # directory.  So what this perl pass does is that it rewrites all
 389      # relative paths to absolute paths.  Another problem when
 390      # building on Cygwin is that QMake mixes paths with backslashes
 391      # and forward slashes and paths must be handled with extra care
 392      # because of the stupid Windows drive letters.
 393      echo "$as_me:$LINENO: fixing the Makefiles:" Makefile* \
 394        >& AS_MESSAGE_LOG_FD
 395      cat >fixmk.pl <<\EOF
 396
 397 [
 398  use strict;
 399  use Cwd qw(cwd abs_path);
 400
 401  # This variable is useful on Cygwin for the following reason: Say
 402  # that you are in `/' (that is, in fact you are in C:/cygwin, or
 403  # something like that).  If you `cd ..' then obviously you remain in
 404  # `/' (that is in C:/cygwin).  QMake generates paths that are
 405  # relative to C:/ (or another drive letter, whatever) so the trick to
 406  # get the `..' resolved properly is to prepend the absolute path of
 407  # the current working directory in a Windows-style.  C:/cygwin/../
 408  # will properly become C:/.
 409  my $d = "";
 410  my $r2a = 0;
 411  my $b2f = 0;
 412
 413  my $cygwin = 0;
 414  if ($^O eq "cygwin") {
 415    $cygwin = 1;
 416    $d = cwd();
 417    $d = `cygpath --mixed '$d'`;
 418    chomp($d);
 419    $d .= "/";
 420  }
 421
 422  sub rel2abs($)
 423  {
 424    my $p = $d . shift;
 425    # print "r2a p=$p";
 426    -e $p || return $p;
 427    if ($cygwin) {
 428      $p = `cygpath --mixed '$p'`;
 429      chomp($p);
 430    }
 431    else {
 432     # Do not use abs_path on Cygwin: it incorrectly resolves the paths
 433     # that are relative to C:/ rather than `/'.
 434      $p = abs_path($p);
 435    }
 436    # print " -> $p\n";
 437    ++$r2a;
 438    return $p;
 439  }
 440
 441  # Only useful on Cygwin.
 442  sub back2forward($)
 443  {
 444    my $p = shift;
 445    # print "b2f p=$p";
 446    -e $p || return $p;
 447    $p = `cygpath --mixed '$p'`;
 448    chomp($p);
 449    # print " -> $p\n";
 450    ++$b2f;
 451    return $p;
 452  }
 453
 454  foreach my $mk (@ARGV)
 455  {
 456    next if $mk =~ /~$/;
 457    open(MK, $mk) or die("open $mk: $!");
 458    # print "mk=$mk\n";
 459    my $file = join("", <MK>);
 460    close(MK) or die("close $mk: $!");
 461    rename $mk, $mk . "~" or die("rename $mk: $!");
 462    $file =~ s{(?:\.\.[\\/])+(?:[^"'\s:]+)}{rel2abs($&)}gse;
 463    $file =~ s{(?:[a-zA-Z]:[\\/])?(?:[^"\s]+\\[^"\s:]+)+}
 464              {back2forward($&)}gse if $cygwin;
 465    open(MK, ">", $mk) or die("open >$mk: $!");
 466    print MK $file;
 467    close(MK) or die("close >$mk: $!");
 468    print "$mk: updated $r2a relative paths and $b2f backslash-style paths\n";
 469    $r2a = 0;
 470    $b2f = 0;
 471  }
 472 ]
 473
 474 EOF
 475
 476      perl >& AS_MESSAGE_LOG_FD -w fixmk.pl Makefile* \
 477      || AC_MSG_WARN([failed to fix the Makefiles generated by $QMAKE])
 478      rm -f fixmk.pl
 479
 480      # Try to compile a simple Qt app.
 481      AC_CACHE_CHECK([whether we can build a simple Qt application],
 482        [at_cv_qt_build],
 483        [at_cv_qt_build=ko
 484         : ${MAKE=make}
 485
 486         if $MAKE >& AS_MESSAGE_LOG_FD 2>&1; then
 487           at_cv_qt_build='ok, looks like Qt 4'
 488         else
 489           echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> instead" \
 490             >& AS_MESSAGE_LOG_FD
 491           sed 's/<QObject>/<qobject.h>/' conftest.h > tmp.h \
 492             && mv tmp.h conftest.h
 493           if $MAKE >& AS_MESSAGE_LOG_FD 2>&1; then
 494             at_cv_qt_build='ok, looks like Qt 3'
 495           else
 496             # Sometimes (such as on Debian) build will fail because Qt
 497             # hasn't been installed in debug mode and qmake tries (by
 498             # default) to build apps in debug mode => Try again in
 499             # release mode.
 500             echo "$as_me:$LINENO: Build failed, trying to enforce release mode" \
 501               >& AS_MESSAGE_LOG_FD
 502
 503             _AT_TWEAK_PRO_FILE([CONFIG], [+release])
 504
 505             sed 's/<qobject.h>/<QObject>/' conftest.h > tmp.h \
 506               && mv tmp.h conftest.h
 507             if $MAKE >& AS_MESSAGE_LOG_FD 2>&1; then
 508               at_cv_qt_build='ok, looks like Qt 4, release mode forced'
 509             else
 510               echo "$as_me:$LINENO: Build failed, trying to #include <qobject.h> instead" \
 511                 >& AS_MESSAGE_LOG_FD
 512               sed 's/<QObject>/<qobject.h>/' conftest.h > tmp.h \
 513                 && mv tmp.h conftest.h
 514               if $MAKE >& AS_MESSAGE_LOG_FD 2>&1; then
 515                 at_cv_qt_build='ok, looks like Qt 3, release mode forced'
 516               else
 517                 at_cv_qt_build=ko
 518                 echo "$as_me:$LINENO: failed program was:" \
 519                   >& AS_MESSAGE_LOG_FD
 520                 sed 's/^/| /' conftest.h >& AS_MESSAGE_LOG_FD
 521                 echo "$as_me:$LINENO: failed program was:" \
 522                   >& AS_MESSAGE_LOG_FD
 523                 sed 's/^/| /' conftest.cpp >& AS_MESSAGE_LOG_FD
 524               fi # if make with Qt3-style #include and release mode forced.
 525             fi # if make with Qt4-style #include and release mode forced.
 526           fi # if make with Qt3-style #include.
 527         fi # if make with Qt4-style #include.
 528        ])dnl end: AC_CACHE_CHECK(at_cv_qt_build)
 529
 530      if test x"$at_cv_qt_build" = xko; then
 531        AX_INSTEAD_IF([$4],
 532          [Cannot build a test Qt program])
 533        cd ..
 534        break
 535      fi
 536
 537      QT_VERSION_MAJOR=`echo "$at_cv_qt_build" | sed 's/[[^0-9]]*//g'`
 538      AC_SUBST([QT_VERSION_MAJOR])
 539
 540      # This sed filter is applied after an expression of the form:
 541      # /^FOO.*=/!d; it starts by removing the beginning of the line,
 542      # removing references to SUBLIBS, removing unnecessary
 543      # whitespaces at the beginning, and prefixes all variable uses by
 544      # QT_.
 545      qt_sed_filter='s///;
 546                     s/$(SUBLIBS)//g;
 547                     s/^ *//;
 548                     s/\$(\(@<:@A-Z_@:>@@<:@A-Z_@:>@*\))/$(QT_\1)/g'
 549
 550      # Find the Makefile (qmake happens to generate a fake Makefile
 551      # which invokes a Makefile.Debug or Makefile.Release).  If we
 552      # have both, we'll pick the Makefile.Release.  The reason is that
 553      # that release uses -Os and debug -g.  We can override -Os by
 554      # passing another -O but we usually don't override -g.
 555      if test -f Makefile.Release; then
 556        at_mfile='Makefile.Release'
 557      else
 558        at_mfile='Makefile'
 559      fi
 560      if test -f $at_mfile; then
 561        :
 562      else
 563        AX_INSTEAD_IF([$4],
 564          [Cannot find the Makefile generated by qmake.])
 565        cd ..
 566        break
 567      fi
 568
 569      # Find the DEFINES of Qt (should have been named CPPFLAGS).
 570      AC_CACHE_CHECK([for the DEFINES to use with Qt],
 571        [at_cv_env_QT_DEFINES],
 572        [at_cv_env_QT_DEFINES=`sed "/^DEFINES@<:@^A-Z=@:>@*=/!d;
 573                                    $qt_sed_filter" $at_mfile`])
 574      AC_SUBST([QT_DEFINES],
 575        [$at_cv_env_QT_DEFINES])
 576
 577      # Find the CFLAGS of Qt.  (We can use Qt in C?!)
 578      AC_CACHE_CHECK([for the CFLAGS to use with Qt],
 579        [at_cv_env_QT_CFLAGS],
 580        [at_cv_env_QT_CFLAGS=`sed "/^CFLAGS@<:@^A-Z=@:>@*=/!d;
 581                                   $qt_sed_filter" $at_mfile`])
 582      AC_SUBST([QT_CFLAGS],
 583        [$at_cv_env_QT_CFLAGS])
 584
 585      # Find the CXXFLAGS of Qt.
 586      AC_CACHE_CHECK([for the CXXFLAGS to use with Qt],
 587        [at_cv_env_QT_CXXFLAGS],
 588        [at_cv_env_QT_CXXFLAGS=`sed "/^CXXFLAGS@<:@^A-Z=@:>@*=/!d;
 589                                     $qt_sed_filter" $at_mfile`])
 590      AC_SUBST([QT_CXXFLAGS],
 591        [$at_cv_env_QT_CXXFLAGS])
 592
 593      # Find the INCPATH of Qt.
 594      AC_CACHE_CHECK([for the INCPATH to use with Qt],
 595        [at_cv_env_QT_INCPATH],
 596        [at_cv_env_QT_INCPATH=`sed "/^INCPATH@<:@^A-Z=@:>@*=/!d;
 597                                    $qt_sed_filter" $at_mfile`])
 598      AC_SUBST([QT_INCPATH],
 599        [$at_cv_env_QT_INCPATH])
 600
 601      AC_SUBST([QT_CPPFLAGS],
 602        ["$at_cv_env_QT_DEFINES $at_cv_env_QT_INCPATH"])
 603
 604      # Find the LFLAGS of Qt (Should have been named LDFLAGS).
 605      AC_CACHE_CHECK([for the LDFLAGS to use with Qt],
 606        [at_cv_env_QT_LDFLAGS],
 607        [at_cv_env_QT_LDFLAGS=`sed "/^LFLAGS@<:@^A-Z=@:>@*=/!d;
 608                                    $qt_sed_filter" $at_mfile`])
 609      AC_SUBST([QT_LFLAGS],
 610        [$at_cv_env_QT_LDFLAGS])
 611      AC_SUBST([QT_LDFLAGS],
 612        [$at_cv_env_QT_LDFLAGS])
 613
 614      # Find the LIBS of Qt.
 615      AC_CACHE_CHECK([for the LIBS to use with Qt],
 616       [at_cv_env_QT_LIBS],
 617       [at_cv_env_QT_LIBS=`sed "/^LIBS@<:@^A-Z@:>@*=/!d;
 618                                $qt_sed_filter" $at_mfile`
 619        if test x$at_darwin = xyes; then
 620          # Fix QT_LIBS: as of today Libtool (GNU Libtool 1.5.23a)
 621          # doesn't handle -F properly.  The "bug" has been fixed on 22
 622          # October 2006 by Peter O'Gorman but we provide backward
 623          # compatibility here.
 624          at_cv_env_QT_LIBS=`echo "$at_cv_env_QT_LIBS" \
 625                             | sed 's/^-F/-Wl,-F/;
 626                                    s/ -F/ -Wl,-F/g'`
 627        fi])
 628      AC_SUBST([QT_LIBS],
 629        [$at_cv_env_QT_LIBS])
 630
 631      cd .. && rm -rf conftest.dir
 632
 633      # Run the user code
 634      $5
 635
 636    done  # end hack (useless FOR to be able to use break)
 637   ])
 638
 639
 640 # AT_REQUIRE_QT_VERSION(QT_version, [RUN-IF-FAILED], [RUN-IF-OK])
 641 # ---------------------------------------------------------------
 642 # Check (using qmake) that Qt's version "matches" QT_version.  Must be
 643 # run *after* AT_WITH_QT.  Requires autoconf 2.60.
 644 #
 645 # This macro is ignored if Qt support has been disabled (using
 646 # `--with-qt=no' or `--without-qt').
 647 #
 648 # RUN-IF-FAILED is arbitrary code to execute if Qt cannot be found or
 649 # if any problem happens.  If this argument is omitted, then
 650 # AC_MSG_ERROR will be called.  RUN-IF-OK is arbitrary code to execute
 651 # if Qt was successfully found.
 652
 653 AC_DEFUN([AT_REQUIRE_QT_VERSION],
 654   [AC_PREREQ([2.60])
 655
 656    # this is a hack to get decent flow control with `break'
 657    for _qt_ignored in once; do
 658
 659      if test x"$with_qt" = x"no"; then
 660        break
 661      fi
 662
 663      if test x"$QMAKE" = x; then
 664        AX_INSTEAD_IF([$2],
 665         [\$QMAKE is empty.  Did you invoke AT@&t@_WITH_QT before AT@&t@_REQUIRE_QT_VERSION?])
 666        break
 667      fi
 668
 669      AC_CACHE_CHECK([for Qt's version],
 670        [at_cv_QT_VERSION],
 671        [echo "$as_me:$LINENO: Running $QMAKE --version:" \
 672           >& AS_MESSAGE_LOG_FD
 673         $QMAKE --version >& AS_MESSAGE_LOG_FD 2>&1
 674         qmake_version_sed=['/^.*\([0-9]\.[0-9]\.[0-9]\).*$/!d;s//\1/']
 675         at_cv_QT_VERSION=`$QMAKE --version 2>&1 \
 676                           | sed "$qmake_version_sed"`])
 677      if test x"$at_cv_QT_VERSION" = x; then
 678        AX_INSTEAD_IF([$2],
 679          [Cannot detect Qt's version.])
 680        break
 681      fi
 682      AC_SUBST([QT_VERSION],
 683        [$at_cv_QT_VERSION])
 684      AS_VERSION_COMPARE([$QT_VERSION], [$1],
 685        [AX_INSTEAD_IF([$2],
 686           [This package requires Qt $1 or above.])
 687         break])
 688
 689      # Run the user code
 690      $3
 691
 692    done  # end hack (useless for to be able to use break)
 693   ])
 694
 695
 696 # _AT_TWEAK_PRO_FILE(QT_VAR, VALUE)
 697 # ---------------------------------
 698 # @internal.  Tweak the variable QT_VAR in the .pro file.  VALUE is an
 699 # IFS-separated list of value, and each value is rewritten as follows:
 700 #
 701 #   +value  => QT_VAR += value
 702 #   -value  => QT_VAR -= value
 703 #    value  => QT_VAR += value
 704
 705 AC_DEFUN([_AT_TWEAK_PRO_FILE],
 706   [ # Tweak the value of $1 in the .pro file for $2.
 707    qt_conf=''
 708    for at_mod in $2; do
 709      at_mod=`echo "$at_mod" | sed 's/^-//; tough
 710                                    s/^+//; beef
 711                                    :ough
 712                                    s/^/$1 -= /;n
 713                                    :eef
 714                                    s/^/$1 += /'`
 715      qt_conf="\
 716 $qt_conf
 717 $at_mod"
 718    done
 719     echo "$qt_conf" | sed 1d >>"$pro_file"
 720   ])