configure.ac

   1 # configure.ac
   2
   3 # Copyright (C) 2011-2014 by Werner Lemberg.
   4 #
   5 # This file is part of the ttfautohint library, and may only be used,
   6 # modified, and distributed under the terms given in `COPYING'.  By
   7 # continuing to use, modify, or distribute this file you indicate that you
   8 # have read `COPYING' and understand and accept it fully.
   9 #
  10 # The file `COPYING' mentioned in the previous paragraph is distributed
  11 # with the ttfautohint library.
  12
  13 AC_INIT([ttfautohint],
  14         m4_esyscmd([gnulib/git-version-gen VERSION]),
  15         [freetype-devel@nongnu.org])
  16 AC_CONFIG_AUX_DIR([gnulib])
  17
  18 AM_INIT_AUTOMAKE([-Wall -Werror]
  19                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]),
  20                            [-], [gnu],
  21                            [gnits]))
  22
  23 AC_CONFIG_MACRO_DIRS([gnulib/m4
  24                       m4])
  25
  26 AM_SILENT_RULES([yes])
  27
  28 AC_USE_SYSTEM_EXTENSIONS
  29
  30 AC_PROG_CPP
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_C_INLINE
  34
  35 PKG_PROG_PKG_CONFIG([0.24])
  36
  37 # AM_PROG_AR is new in automake 1.11.2;
  38 # however, MinGW doesn't have it yet (May 2012)
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 gl_EARLY
  42 gl_INIT
  43
  44 PKG_CHECK_MODULES([HARFBUZZ], [harfbuzz >= 0.9.19])
  45
  46 AT_WITH_QT
  47 AT_REQUIRE_QT_VERSION([4.6])
  48
  49 if test x"$with_qt" != x"no"; then
  50   AC_MSG_CHECKING([for QLocale::quoteString])
  51   AS_VERSION_COMPARE([$QT_VERSION], [4.8],
  52     [AC_MSG_RESULT(no)],
  53     [AC_MSG_RESULT(no)],
  54     [AC_MSG_RESULT(yes)
  55      AC_DEFINE([HAVE_QT_QUOTESTRING], [1],
  56        [Define if Qt function QLocale::quoteString is available.])])
  57 fi
  58
  59 AM_CONDITIONAL([USE_QT], [test x"$with_qt" != x"no"])
  60
  61 LT_INIT
  62 LT_LTLIZE_LANG([C])
  63
  64
  65 # We use libtool's convenient check for the math library.
  66 LT_LIB_M
  67 AC_SUBST(LIBM)
  68
  69
  70 AC_ARG_WITH([doc],
  71             [AS_HELP_STRING([--with-doc],
  72                             [install documentation @<:@default=yes@:>@])],
  73             [],
  74             [with_doc=yes])
  75
  76 AC_ARG_WITH([freetype-config],
  77             [AS_HELP_STRING([--with-freetype-config=PROG],
  78                             [use FreeType configuration program PROG])],
  79             [freetype_config=$withval],
  80             [freetype_config=yes])
  81
  82 if test "$freetype_config" = "yes"; then
  83   AC_PATH_TOOL(ft_config,
  84                freetype-config,
  85                no)
  86   if test "$ft_config" = "no"; then
  87     AC_MSG_ERROR([FreeType library is missing; see http://www.freetype.org/])
  88   fi
  89 else
  90   ft_config="$freetype_config"
  91 fi
  92
  93 FREETYPE_CPPFLAGS="`$ft_config --cflags`"
  94 FREETYPE_LIBS="`$ft_config --libtool`"
  95
  96 # many platforms no longer install .la files for system libraries
  97 if test ! -f $FREETYPE_LIBS; then
  98   FREETYPE_LIBS="`$ft_config --libs`"
  99 fi
 100
 101 AC_SUBST(FREETYPE_CPPFLAGS)
 102 AC_SUBST(FREETYPE_LIBS)
 103
 104
 105 AC_MSG_CHECKING([whether FreeType header files are version 2.4.5 or higher])
 106 old_CPPFLAGS="$CPPFLAGS"
 107 CPPFLAGS=$FREETYPE_CPPFLAGS
 108 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 109
 110 #include <ft2build.h>
 111 #include FT_FREETYPE_H
 112 #if (FREETYPE_MAJOR*1000 + FREETYPE_MINOR)*1000 + FREETYPE_PATCH < 2004005
 113 #error Freetype version too low.
 114 #endif
 115
 116 ]])],
 117 [AC_MSG_RESULT(yes)
 118  CPPFLAGS="$old_CPPFLAGS"],
 119 [AC_MSG_ERROR([Need FreeType version 2.4.5 or higher])])
 120
 121
 122 AC_MSG_CHECKING([whether FreeType library is version 2.4.5 or higher])
 123 old_CPPFLAGS="$CPPFLAGS"
 124 CPPFLAGS=$FREETYPE_CPPFLAGS
 125 old_LIBS="$LIBS"
 126 LIBS=$FREETYPE_LIBS
 127 AC_LANG_PUSH([LTLIZED C])
 128 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 129
 130 #include <stdlib.h>
 131 #include <ft2build.h>
 132 #include FT_FREETYPE_H
 133
 134 int
 135 main()
 136 {
 137   FT_Error error;
 138   FT_Library library;
 139   FT_Int major, minor, patch;
 140
 141   error = FT_Init_FreeType(&library);
 142   if (error)
 143   {
 144     printf("(test program reports error code %d)... ", error);
 145     exit(EXIT_FAILURE);
 146   }
 147
 148   FT_Library_Version(library, &major, &minor, &patch);
 149
 150   printf("(found %d.%d.%d)... ", major, minor, patch);
 151
 152   if (((major*1000 + minor)*1000 + patch) >= 2004005)
 153     exit(EXIT_SUCCESS);
 154   exit(EXIT_FAILURE);
 155 }
 156
 157 ]])],
 158 [AC_MSG_RESULT(yes)
 159  CPPFLAGS="$old_CPPFLAGS"
 160  LIBS="$old_LIBS"],
 161 [AC_MSG_ERROR([Need FreeType version 2.4.5 or higher])],
 162 [AC_MSG_RESULT([skipped due to cross-compilation])])
 163 AC_LANG_POP
 164
 165
 166 if test $cross_compiling = no; then
 167   AM_MISSING_PROG(HELP2MAN, help2man)
 168 else
 169   HELP2MAN=:
 170 fi
 171
 172 # The documentation is part of the distributed bundle.  In the following,
 173 # tests for the documentation building tools are made fatal in case those
 174 # files are missing (which can happen during bootstrap).
 175
 176 AC_DEFUN([TA_DOC],
 177   [if test -f "$1"; then
 178      AC_MSG_WARN([$2])
 179      with_doc=no
 180    else
 181      AC_MSG_ERROR([$2])
 182    fi])
 183
 184 image_file=$srcdir/doc/img/ttfautohintGUI.png
 185 html_file=$srcdir/doc/ttfautohint.html
 186 pdf_file=$srcdir/doc/ttfautohint.pdf
 187
 188 if test x"$with_doc" != x"no"; then
 189   # snapshot image creation
 190   if test x"$DISPLAY" == x; then
 191     TA_DOC([$image_file],
 192            [Need X11 to create snapshot image of ttfautohintGUI])
 193   else
 194     AC_CHECK_PROG([IMPORT], [import], [import], [no])
 195     if test x"$IMPORT" == x"no"; then
 196       TA_DOC([$image_file],
 197              [Need ImageMagick to create snapshot image of ttfautohintGUI])
 198     fi
 199   fi
 200
 201   # conversion of SVG to PDF
 202   AC_CHECK_PROG([INKSCAPE], [inkscape], [inkscape], [no])
 203   if test x"$INKSCAPE" == x"no"; then
 204     TA_DOC([$pdf_file],
 205            [Need inkscape to convert SVG image files to PDF])
 206   fi
 207
 208   # documentation creation
 209   AC_CHECK_PROG([PANDOC], [pandoc], [pandoc], [no])
 210   if test x"$PANDOC" == x"no"; then
 211     TA_DOC([$html_file],
 212            [Need pandoc to create PDF and HTML documentation files])
 213   fi
 214
 215   # PDF documentation
 216   AC_CHECK_PROGS([LATEX], [lualatex xelatex], [no])
 217   if test x"$PDFLATEX" == x"no"; then
 218     TA_DOC([$pdf_file],
 219            [Need lualatex or xelatex to create documentation in PDF format])
 220   fi
 221 fi
 222
 223 AM_CONDITIONAL([WITH_DOC], [test x"$with_doc" != x"no"])
 224
 225 AC_CONFIG_HEADERS([config.h])
 226 AC_CONFIG_FILES([Makefile
 227                  gnulib/src/Makefile
 228                  lib/Makefile
 229                  frontend/Makefile
 230                  doc/Makefile])
 231 AC_OUTPUT
 232
 233 # end of configure.ac