configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.25)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(buf-freelists,
  40    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  41 AC_ARG_ENABLE(openbsd-malloc,
  42    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  43 AC_ARG_ENABLE(instrument-downloads,
  44    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  45 AC_ARG_ENABLE(static-openssl,
  46    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  47 AC_ARG_ENABLE(static-libevent,
  48    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  49
  50 if test x$enable_buf_freelists != xno; then
  51   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  52             [Defined if we try to use freelists for buffer RAM chunks])
  53 fi
  54 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  55 if test x$enable_instrument_downloads = xyes; then
  56   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  57             [Defined if we want to keep track of how much of each kind of resource we download.])
  58 fi
  59
  60 AC_ARG_ENABLE(transparent,
  61      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  62      [case "${enableval}" in
  63         yes) transparent=true ;;
  64         no)  transparent=false ;;
  65         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  66       esac], [transparent=true])
  67
  68 AC_ARG_ENABLE(threads,
  69      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  70
  71 if test x$enable_threads = x; then
  72    case $host in
  73     *-*-solaris* )
  74      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  75      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  76 cpu workers lock up here, so I will disable threads.])
  77      enable_threads="no";;
  78     *)
  79      enable_threads="yes";;
  80    esac
  81 fi
  82
  83 if test "$enable_threads" = "yes"; then
  84   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  85 fi
  86
  87 case $host in
  88    *-*-solaris* )
  89      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  90      ;;
  91 esac
  92
  93 AC_ARG_ENABLE(geoip-stats,
  94      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  95
  96 if test "$enable_geoip_stats" = "yes"; then
  97   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
  98 fi
  99
 100 AC_ARG_ENABLE(gcc-warnings,
 101      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 102 AC_ARG_ENABLE(gcc-warnings-advisory,
 103      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 104
 105 AC_ARG_ENABLE(local-appdata,
 106    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 107 if test "$enable_local_appdata" = "yes"; then
 108   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 109             [Defined if we default to host local appdata paths on Windows])
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_PROG_MAKE_SET
 115 AC_PROG_RANLIB
 116
 117 TORUSER=_tor
 118 AC_ARG_WITH(tor-user,
 119         [  --with-tor-user=NAME    Specify username for tor daemon ],
 120         [
 121            TORUSER=$withval
 122         ]
 123 )
 124 AC_SUBST(TORUSER)
 125
 126 TORGROUP=_tor
 127 AC_ARG_WITH(tor-group,
 128         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 129         [
 130            TORGROUP=$withval
 131         ]
 132 )
 133 AC_SUBST(TORGROUP)
 134
 135
 136 dnl If WIN32 is defined and non-zero, we are building for win32
 137 AC_MSG_CHECKING([for win32])
 138 AC_RUN_IFELSE([
 139 int main(int c, char **v) {
 140 #ifdef WIN32
 141 #if WIN32
 142   return 0;
 143 #else
 144   return 1;
 145 #endif
 146 #else
 147   return 2;
 148 #endif
 149 }],
 150 bwin32=true; AC_MSG_RESULT([yes]),
 151 bwin32=false; AC_MSG_RESULT([no]),
 152 bwin32=cross; AC_MSG_RESULT([cross])
 153 )
 154
 155 if test "$bwin32" = cross; then
 156 AC_MSG_CHECKING([for win32 (cross)])
 157 AC_COMPILE_IFELSE([
 158 #ifdef WIN32
 159 int main(int c, char **v) {return 0;}
 160 #else
 161 #error
 162 int main(int c, char **v) {return x(y);}
 163 #endif
 164 ],
 165 bwin32=true; AC_MSG_RESULT([yes]),
 166 bwin32=false; AC_MSG_RESULT([no]))
 167 fi
 168
 169 if test "$bwin32" = true; then
 170 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 171 fi
 172 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 173
 174 dnl Enable C99 when compiling with MIPSpro
 175 AC_MSG_CHECKING([for MIPSpro compiler])
 176 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 177 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 178 #error
 179   return x(y);
 180 #endif
 181 ]),
 182 bmipspro=false; AC_MSG_RESULT(no),
 183 bmipspro=true; AC_MSG_RESULT(yes))
 184
 185 if test "$bmipspro" = true; then
 186   CFLAGS="$CFLAGS -c99"
 187 fi
 188
 189 AC_C_BIGENDIAN
 190
 191 AC_SEARCH_LIBS(socket, [socket])
 192 AC_SEARCH_LIBS(gethostbyname, [nsl])
 193 AC_SEARCH_LIBS(dlopen, [dl])
 194 AC_SEARCH_LIBS(inet_aton, [resolv])
 195
 196 if test "$enable_threads" = "yes"; then
 197   AC_SEARCH_LIBS(pthread_create, [pthread])
 198   AC_SEARCH_LIBS(pthread_detach, [pthread])
 199 fi
 200
 201 dnl -------------------------------------------------------------------
 202 dnl Check for functions before libevent, since libevent-1.2 apparently
 203 dnl exports strlcpy without defining it in a header.
 204
 205 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 206
 207 using_custom_malloc=no
 208 if test x$enable_openbsd_malloc = xyes ; then
 209    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 210    using_custom_malloc=yes
 211 fi
 212 if test x$tcmalloc = xyes ; then
 213    using_custom_malloc=yes
 214 fi
 215 if test $using_custom_malloc = no ; then
 216    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 217 fi
 218
 219 if test "$enable_threads" = "yes"; then
 220   AC_CHECK_HEADERS(pthread.h)
 221   AC_CHECK_FUNCS(pthread_create)
 222 fi
 223
 224 dnl ------------------------------------------------------
 225 dnl Where do you live, libevent?  And how do we call you?
 226
 227 if test "$bwin32" = true; then
 228   TOR_LIB_WS32=-lws2_32
 229   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 230   # think it's actually necessary.
 231   TOR_LIB_GDI=-lgdi32
 232 else
 233   TOR_LIB_WS32=
 234   TOR_LIB_GDI=
 235 fi
 236 AC_SUBST(TOR_LIB_WS32)
 237 AC_SUBST(TOR_LIB_GDI)
 238
 239 dnl We need to do this before we try our disgusting hack below.
 240 AC_CHECK_HEADERS([sys/types.h])
 241
 242 dnl This is a disgusting hack so we safely include older libevent headers.
 243 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 244 AC_CHECK_TYPE(u_int32_t, unsigned long)
 245 AC_CHECK_TYPE(u_int16_t, unsigned short)
 246 AC_CHECK_TYPE(u_int8_t, unsigned char)
 247
 248 tor_libevent_pkg_redhat="libevent"
 249 tor_libevent_pkg_debian="libevent-dev"
 250 tor_libevent_devpkg_redhat="libevent-devel"
 251 tor_libevent_devpkg_debian="libevent-dev"
 252
 253 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 254 #ifdef WIN32
 255 #include <winsock2.h>
 256 #endif
 257 #include <stdlib.h>
 258 #include <sys/time.h>
 259 #include <sys/types.h>
 260 #include <event.h>], [
 261 #ifdef WIN32
 262 #include <winsock2.h>
 263 #endif
 264 void exit(int); void *event_init(void);],
 265     [
 266 #ifdef WIN32
 267 {WSADATA d; WSAStartup(0x101,&d); }
 268 #endif
 269 event_init(); exit(0);
 270 ], [--with-libevent-dir], [/opt/libevent])
 271
 272 dnl Now check for particular libevent functions.
 273 save_LIBS="$LIBS"
 274 save_LDFLAGS="$LDFLAGS"
 275 save_CPPFLAGS="$CPPFLAGS"
 276 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 277 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 278 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 279 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 280 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 281 [#include <event.h>
 282 ])
 283
 284 LIBS="$save_LIBS"
 285 LDFLAGS="$save_LDFLAGS"
 286 CPPFLAGS="$save_CPPFLAGS"
 287
 288 if test "$enable_static_libevent" = "yes"; then
 289    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 290      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 291    else
 292      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a"
 293    fi
 294 else
 295      TOR_LIBEVENT_LIBS="-levent"
 296 fi
 297 AC_SUBST(TOR_LIBEVENT_LIBS)
 298
 299 dnl ------------------------------------------------------
 300 dnl Where do you live, openssl?  And how do we call you?
 301
 302 tor_openssl_pkg_redhat="openssl"
 303 tor_openssl_pkg_debian="libssl"
 304 tor_openssl_devpkg_redhat="openssl-devel"
 305 tor_openssl_devpkg_debian="libssl-dev"
 306
 307 ALT_openssl_WITHVAL=""
 308 AC_ARG_WITH(ssl-dir,
 309   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 310   [
 311       if test "x$withval" != xno && test "x$withval" != "x" ; then
 312          ALT_openssl_WITHVAL="$withval"
 313       fi
 314   ])
 315
 316 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 317     [#include <openssl/rand.h>],
 318     [void RAND_add(const void *buf, int num, double entropy);],
 319     [RAND_add((void*)0,0,0); exit(0);], [],
 320     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 321
 322 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 323
 324 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 325 if test "$enable_static_openssl" = "yes"; then
 326    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 327      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 328    else
 329      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 330    fi
 331 else
 332      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 333 fi
 334 AC_SUBST(TOR_OPENSSL_LIBS)
 335
 336 dnl ------------------------------------------------------
 337 dnl Where do you live, zlib?  And how do we call you?
 338
 339 tor_openssl_pkg_redhat="zlib"
 340 tor_openssl_pkg_debian="zlib1g"
 341 tor_openssl_devpkg_redhat="zlib-devel"
 342 tor_openssl_devpkg_debian="zlib1g-dev"
 343
 344 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 345     [#include <zlib.h>],
 346     [const char * zlibVersion(void);],
 347     [zlibVersion(); exit(0);], [--with-zlib-dir],
 348     [/opt/zlib])
 349
 350 dnl Make sure to enable support for large off_t if available.
 351
 352 AC_SYS_LARGEFILE
 353
 354 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 355
 356 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 357
 358 dnl These headers are not essential
 359
 360 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 361
 362 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 363 [#ifdef HAVE_MALLOC_H
 364 #include <malloc.h>
 365 #endif
 366 #ifdef HAVE_MALLOC_MALLOC_H
 367 #include <malloc/malloc.h>
 368 #endif])
 369
 370 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 371 [#ifdef HAVE_SYS_TYPES_H
 372 #include <sys/types.h>
 373 #endif
 374 #ifdef HAVE_SYS_SOCKET_H
 375 #include <sys/socket.h>
 376 #endif])
 377 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 378 [#ifdef HAVE_SYS_TYPES_H
 379 #include <sys/types.h>
 380 #endif
 381 #ifdef HAVE_SYS_SOCKET_H
 382 #include <sys/socket.h>
 383 #endif
 384 #ifdef HAVE_NET_IF_H
 385 #include <net/if.h>
 386 #endif])
 387 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 388         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 389 [#ifdef HAVE_SYS_TYPES_H
 390 #include <sys/types.h>
 391 #endif
 392 #ifdef HAVE_SYS_SOCKET_H
 393 #include <sys/socket.h>
 394 #endif
 395 #ifdef HAVE_LIMITS_H
 396 #include <limits.h>
 397 #endif
 398 #ifdef HAVE_LINUX_TYPES_H
 399 #include <linux/types.h>
 400 #endif
 401 #ifdef HAVE_NETINET_IN6_H
 402 #include <netinet/in6.h>
 403 #endif
 404 #ifdef HAVE_NETINET_IN_H
 405 #include <netinet/in.h>
 406 #endif])
 407
 408 if test x$transparent = xtrue ; then
 409    transparent_ok=0
 410    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 411      transparent_ok=1
 412    fi
 413    if test x$linux_netfilter_ipv4 = x1 ; then
 414      transparent_ok=1
 415    fi
 416    if test x$transparent_ok = x1 ; then
 417      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 418      case $host in
 419        *-*-openbsd*)
 420          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 421      esac
 422    else
 423      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 424    fi
 425 fi
 426
 427 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 428 [#ifdef HAVE_SYS_TYPES_H
 429 #include <sys/types.h>
 430 #endif
 431 #ifdef HAVE_SYS_TIME_H
 432 #include <sys/time.h>
 433 #endif])
 434
 435 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 436 dnl Watch out.
 437
 438 AC_CHECK_SIZEOF(int8_t)
 439 AC_CHECK_SIZEOF(int16_t)
 440 AC_CHECK_SIZEOF(int32_t)
 441 AC_CHECK_SIZEOF(int64_t)
 442 AC_CHECK_SIZEOF(uint8_t)
 443 AC_CHECK_SIZEOF(uint16_t)
 444 AC_CHECK_SIZEOF(uint32_t)
 445 AC_CHECK_SIZEOF(uint64_t)
 446 AC_CHECK_SIZEOF(intptr_t)
 447 AC_CHECK_SIZEOF(uintptr_t)
 448
 449 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 450
 451 AC_CHECK_SIZEOF(char)
 452 AC_CHECK_SIZEOF(short)
 453 AC_CHECK_SIZEOF(int)
 454 AC_CHECK_SIZEOF(long)
 455 AC_CHECK_SIZEOF(long long)
 456 AC_CHECK_SIZEOF(__int64)
 457 AC_CHECK_SIZEOF(void *)
 458 AC_CHECK_SIZEOF(time_t)
 459 AC_CHECK_SIZEOF(size_t)
 460
 461 AC_CHECK_TYPES([uint, u_char, ssize_t])
 462
 463 dnl used to include sockaddr_storage, but everybody has that.
 464 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 465 [#ifdef HAVE_SYS_TYPES_H
 466 #include <sys/types.h>
 467 #endif
 468 #ifdef HAVE_NETINET_IN_H
 469 #include <netinet/in.h>
 470 #endif
 471 #ifdef HAVE_NETINET_IN6_H
 472 #include <netinet/in6.h>
 473 #endif
 474 #ifdef HAVE_SYS_SOCKET_H
 475 #include <sys/socket.h>
 476 #endif
 477 #ifdef MS_WINDOWS
 478 #define WIN32_WINNT 0x400
 479 #define _WIN32_WINNT 0x400
 480 #define WIN32_LEAN_AND_MEAN
 481 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 482 #include <winsock.h>
 483 #else
 484 #include <winsock2.h>
 485 #include <ws2tcpip.h>
 486 #endif
 487 #endif
 488 ])
 489 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 490 [#ifdef HAVE_SYS_TYPES_H
 491 #include <sys/types.h>
 492 #endif
 493 #ifdef HAVE_NETINET_IN_H
 494 #include <netinet/in.h>
 495 #endif
 496 #ifdef HAVE_NETINET_IN6_H
 497 #include <netinet/in6.h>
 498 #endif
 499 #ifdef HAVE_SYS_SOCKET_H
 500 #include <sys/socket.h>
 501 #endif
 502 #ifdef MS_WINDOWS
 503 #define WIN32_WINNT 0x400
 504 #define _WIN32_WINNT 0x400
 505 #define WIN32_LEAN_AND_MEAN
 506 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 507 #include <winsock.h>
 508 #else
 509 #include <winsock2.h>
 510 #include <ws2tcpip.h>
 511 #endif
 512 #endif
 513 ])
 514
 515 AC_CHECK_TYPES([rlim_t], , ,
 516 [#ifdef HAVE_SYS_TYPES_H
 517 #include <sys/types.h>
 518 #endif
 519 #ifdef HAVE_SYS_TIME_H
 520 #include <sys/time.h>
 521 #endif
 522 #ifdef HAVE_SYS_RESOURCE_H
 523 #include <sys/resource.h>
 524 #endif
 525 ])
 526
 527 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 528 AC_RUN_IFELSE(AC_LANG_SOURCE([
 529 #ifdef HAVE_SYS_TYPES_H
 530 #include <sys/types.h>
 531 #endif
 532 #ifdef HAVE_SYS_TIME_H
 533 #include <sys/time.h>
 534 #endif
 535 #ifdef HAVE_TIME_H
 536 #include <time.h>
 537 #endif
 538 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 539   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 540 ])
 541
 542 if test "$tor_cv_time_t_signed" = cross; then
 543   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 544 fi
 545
 546 if test "$tor_cv_time_t_signed" != no; then
 547   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 548             [Define to 1 iff time_t is signed])
 549 fi
 550
 551 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 552 #ifdef HAVE_SYS_SOCKET_H
 553 #include <sys/socket.h>
 554 #endif
 555 ])
 556
 557 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 558
 559 AC_CHECK_SIZEOF(cell_t)
 560
 561 # Now make sure that NULL can be represented as zero bytes.
 562 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 563 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 564 [[#include <stdlib.h>
 565 #include <string.h>
 566 #include <stdio.h>
 567 #ifdef HAVE_STDDEF_H
 568 #include <stddef.h>
 569 #endif
 570 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 571 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 572        [tor_cv_null_is_zero=yes],
 573        [tor_cv_null_is_zero=no],
 574        [tor_cv_null_is_zero=cross])])
 575
 576 if test "$tor_cv_null_is_zero" = cross ; then
 577   # Cross-compiling; let's hope that the target isn't raving mad.
 578   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 579 fi
 580
 581 if test "$tor_cv_null_is_zero" != no; then
 582   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 583             [Define to 1 iff memset(0) sets pointers to NULL])
 584 fi
 585
 586 # And what happens when we malloc zero?
 587 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 588 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 589 [[#include <stdlib.h>
 590 #include <string.h>
 591 #include <stdio.h>
 592 #ifdef HAVE_STDDEF_H
 593 #include <stddef.h>
 594 #endif
 595 int main () { return malloc(0)?0:1; }]])],
 596        [tor_cv_malloc_zero_works=yes],
 597        [tor_cv_malloc_zero_works=no],
 598        [tor_cv_malloc_zero_works=cross])])
 599
 600 if test "$tor_cv_malloc_zero_works" = cross; then
 601   # Cross-compiling; let's hope that the target isn't raving mad.
 602   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 603 fi
 604
 605 if test "$tor_cv_malloc_zero_works" = yes; then
 606   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 607             [Define to 1 iff malloc(0) returns a pointer])
 608 fi
 609
 610 # whether we seem to be in a 2s-complement world.
 611 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 612 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 613 [[int main () { int problem = ((-99) != (~99)+1);
 614 return problem ? 1 : 0; }]])],
 615        [tor_cv_twos_complement=yes],
 616        [tor_cv_twos_complement=no],
 617        [tor_cv_twos_complement=cross])])
 618
 619 if test "$tor_cv_twos_complement" = cross ; then
 620   # Cross-compiling; let's hope that the target isn't raving mad.
 621   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 622 fi
 623
 624 if test "$tor_cv_twos_complement" != no ; then
 625   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 626             [Define to 1 iff we represent negative integers with two's complement])
 627 fi
 628
 629 # Whether we should use the dmalloc memory allocation debugging library.
 630 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 631 AC_ARG_WITH(dmalloc,
 632 [  --with-dmalloc          Use debug memory allocation library. ],
 633 [if [[ "$withval" = "yes" ]]; then
 634   dmalloc=1
 635   AC_MSG_RESULT(yes)
 636 else
 637   dmalloc=1
 638   AC_MSG_RESULT(no)
 639 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 640 )
 641
 642 if [[ $dmalloc -eq 1 ]]; then
 643   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 644   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 645   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 646   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 647   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 648 fi
 649
 650 AC_ARG_WITH(tcmalloc,
 651 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 652 [ tcmalloc=yes ], [ tcmalloc=no ])
 653
 654 if test x$tcmalloc = xyes ; then
 655    LDFLAGS="-ltcmalloc $LDFLAGS"
 656 fi
 657
 658 # Allow user to specify an alternate syslog facility
 659 AC_ARG_WITH(syslog-facility,
 660 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 661 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 662 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 663 AC_SUBST(LOGFACILITY)
 664
 665 # Check if we have getresuid and getresgid
 666 AC_CHECK_FUNCS(getresuid getresgid)
 667
 668 # Check for gethostbyname_r in all its glorious incompatible versions.
 669 #   (This logic is based on that in Python's configure.in)
 670 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 671   [Define this if you have any gethostbyname_r()])
 672
 673 AC_CHECK_FUNC(gethostbyname_r, [
 674   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 675   OLD_CFLAGS=$CFLAGS
 676   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 677   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 678 #include <netdb.h>
 679   ], [[
 680     char *cp1, *cp2;
 681     struct hostent *h1, *h2;
 682     int i1, i2;
 683     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 684   ]]),[
 685     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 686     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 687      [Define this if gethostbyname_r takes 6 arguments])
 688     AC_MSG_RESULT(6)
 689   ], [
 690     AC_TRY_COMPILE([
 691 #include <netdb.h>
 692     ], [
 693       char *cp1, *cp2;
 694       struct hostent *h1;
 695       int i1, i2;
 696       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 697     ], [
 698       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 699       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 700         [Define this if gethostbyname_r takes 5 arguments])
 701       AC_MSG_RESULT(5)
 702    ], [
 703       AC_TRY_COMPILE([
 704 #include <netdb.h>
 705      ], [
 706        char *cp1;
 707        struct hostent *h1;
 708        struct hostent_data hd;
 709        (void) gethostbyname_r(cp1,h1,&hd);
 710      ], [
 711        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 712        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 713          [Define this if gethostbyname_r takes 3 arguments])
 714        AC_MSG_RESULT(3)
 715      ], [
 716        AC_MSG_RESULT(0)
 717      ])
 718   ])
 719  ])
 720  CFLAGS=$OLD_CFLAGS
 721 ])
 722
 723 AC_CACHE_CHECK([whether the C compiler supports __func__],
 724   tor_cv_have_func_macro,
 725   AC_COMPILE_IFELSE([
 726 #include <stdio.h>
 727 int main(int c, char **v) { puts(__func__); }],
 728   tor_cv_have_func_macro=yes,
 729   tor_cv_have_func_macro=no))
 730
 731 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 732   tor_cv_have_FUNC_macro,
 733   AC_COMPILE_IFELSE([
 734 #include <stdio.h>
 735 int main(int c, char **v) { puts(__FUNC__); }],
 736   tor_cv_have_FUNC_macro=yes,
 737   tor_cv_have_FUNC_macro=no))
 738
 739 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 740   tor_cv_have_FUNCTION_macro,
 741   AC_COMPILE_IFELSE([
 742 #include <stdio.h>
 743 int main(int c, char **v) { puts(__FUNCTION__); }],
 744   tor_cv_have_FUNCTION_macro=yes,
 745   tor_cv_have_FUNCTION_macro=no))
 746
 747 if test "$tor_cv_have_func_macro" = 'yes'; then
 748   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 749 fi
 750
 751 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 752   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 753 fi
 754
 755 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 756   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 757            [Defined if the compiler supports __FUNCTION__])
 758 fi
 759
 760 # $prefix stores the value of the --prefix command line option, or
 761 # NONE if the option wasn't set.  In the case that it wasn't set, make
 762 # it be the default, so that we can use it to expand directories now.
 763 if test "x$prefix" = "xNONE"; then
 764   prefix=$ac_default_prefix
 765 fi
 766
 767 # and similarly for $exec_prefix
 768 if test "x$exec_prefix" = "xNONE"; then
 769   exec_prefix=$prefix
 770 fi
 771
 772 if test "x$CONFDIR" = "x"; then
 773   CONFDIR=`eval echo $sysconfdir/tor`
 774 fi
 775 AC_SUBST(CONFDIR)
 776 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 777 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 778
 779 BINDIR=`eval echo $bindir`
 780 AC_SUBST(BINDIR)
 781 LOCALSTATEDIR=`eval echo $localstatedir`
 782 AC_SUBST(LOCALSTATEDIR)
 783
 784 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 785 # than autoconf's macros like.
 786 if test "$GCC" = yes; then
 787   CFLAGS="$CFLAGS -Wall -g -O2"
 788   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 789   # accident waiting to happen.
 790   CFLAGS="$CFLAGS -fno-strict-aliasing"
 791 else
 792   CFLAGS="$CFLAGS -g -O"
 793   enable_gcc_warnings=no
 794   enable_gcc_warnings_advisory=no
 795 fi
 796
 797 # Add some more warnings which we use in development but not in the
 798 # released versions.  (Some relevant gcc versions can't handle these.)
 799 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 800
 801   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 802 #if !defined(__GNUC__) || (__GNUC__ < 4)
 803 #error
 804 #endif]), have_gcc4=yes, have_gcc4=no)
 805
 806   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 807 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 808 #error
 809 #endif]), have_gcc42=yes, have_gcc42=no)
 810
 811   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 812 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 813 #error
 814 #endif]), have_gcc43=yes, have_gcc43=no)
 815
 816   save_CFLAGS="$CFLAGS"
 817   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 818   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 819                     have_shorten64_flag=no)
 820   CFLAGS="$save_CFLAGS"
 821
 822   case $host in
 823     *-*-openbsd*)
 824       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
 825       # That's fine, except that the headers don't pass -Wredundant-decls.
 826       # Therefore, let's disable -Wsystem-headers when we're building
 827       # with maximal warnings on OpenBSD.
 828       CFLAGS="$CFLAGS -Wno-system-headers" ;;
 829   esac
 830
 831   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 832   if test x$enable_gcc_warnings = xyes; then
 833     CFLAGS="$CFLAGS -Werror"
 834   fi
 835
 836   # Disabled, so we can use mallinfo(): -Waggregate-return
 837
 838   if test x$have_gcc4 = xyes ; then
 839     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 840     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 841   fi
 842
 843   if test x$have_gcc42 = xyes ; then
 844     # These warnings break gcc 4.0.2 and work on gcc 4.2
 845     # XXXX020 Use -fstack-protector.
 846     # XXXX020 See if any of these work with earlier versions.
 847     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 848     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 849   fi
 850
 851   if test x$have_gcc43 = xyes ; then
 852     # These warnings break gcc 4.2 and work on gcc 4.3
 853     # XXXX020 See if any of these work with earlier versions.
 854     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 855   fi
 856
 857   if test x$have_shorten64_flag = xyes ; then
 858     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 859   fi
 860
 861 ##This will break the world on some 64-bit architectures
 862 # CFLAGS="$CFLAGS -Winline"
 863 fi
 864
 865
 866
 867 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 868
 869 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 870 AC_OUTPUT
 871
 872 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 873   ./contrib/updateVersions.pl
 874 fi
 875