release/src-rt-6.x.4708/toolchains/hndtools-arm-linux-2.6.36-uclibc-4.5.3/share/automake-1.11/Automake/ChannelDefs.pm

   1 # Copyright (C) 2002, 2003, 2006, 2008, 2009 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2, or (at your option)
   6 # any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 package Automake::ChannelDefs;
  17
  18 use Automake::Config;
  19 BEGIN
  20 {
  21   if ($perl_threads)
  22     {
  23       require threads;
  24       import threads;
  25     }
  26 }
  27 use Automake::Channels;
  28
  29 =head1 NAME
  30
  31 Automake::ChannelDefs - channel definitions for Automake and helper functions
  32
  33 =head1 SYNOPSIS
  34
  35   use Automake::ChannelDefs;
  36
  37   Automake::ChannelDefs::usage ();
  38   prog_error ($MESSAGE, [%OPTIONS]);
  39   error ($WHERE, $MESSAGE, [%OPTIONS]);
  40   error ($MESSAGE);
  41   fatal ($WHERE, $MESSAGE, [%OPTIONS]);
  42   fatal ($MESSAGE);
  43   verb ($MESSAGE, [%OPTIONS]);
  44   switch_warning ($CATEGORY);
  45   parse_WARNINGS ();
  46   parse_warning ($OPTION, $ARGUMENT);
  47   Automake::ChannelDefs::set_strictness ($STRICTNESS_NAME);
  48
  49 =head1 DESCRIPTION
  50
  51 This packages defines channels that can be used in Automake to
  52 output diagnostics and other messages (via C<msg()>).  It also defines
  53 some helper function to enable or disable these channels, and some
  54 shorthand function to output on specific channels.
  55
  56 =cut
  57
  58 use 5.005;
  59 use strict;
  60 use Exporter;
  61
  62 use vars qw (@ISA @EXPORT);
  63
  64 @ISA = qw (Exporter);
  65 @EXPORT = qw (&prog_error &error &fatal &verb
  66               &switch_warning &parse_WARNINGS &parse_warnings);
  67
  68 =head2 CHANNELS
  69
  70 The following channels can be used as the first argument of
  71 C<Automake::Channel::msg>.  For some of them we list a shorthand
  72 function that makes the code more readable.
  73
  74 =over 4
  75
  76 =item C<fatal>
  77
  78 Fatal errors.  Use C<&fatal> to send messages over this channel.
  79
  80 =item C<error>
  81
  82 Common errors.   Use C<&error> to send messages over this channel.
  83
  84 =item C<error-gnu>
  85
  86 Errors related to GNU Standards.
  87
  88 =item C<error-gnu/warn>
  89
  90 Errors related to GNU Standards that should be warnings in `foreign' mode.
  91
  92 =item C<error-gnits>
  93
  94 Errors related to GNITS Standards (silent by default).
  95
  96 =item C<automake>
  97
  98 Internal errors.  Use C<&prog_error> to send messages over this channel.
  99
 100 =item C<gnu>
 101
 102 Warnings related to GNU Coding Standards.
 103
 104 =item C<obsolete>
 105
 106 Warnings about obsolete features (silent by default).
 107
 108 =item C<override>
 109
 110 Warnings about user redefinitions of Automake rules or
 111 variables (silent by default).
 112
 113 =item C<portability>
 114
 115 Warnings about non-portable constructs.
 116
 117 =item C<syntax>
 118
 119 Warnings about weird syntax, unused variables, typos...
 120
 121 =item C<unsupported>
 122
 123 Warnings about unsupported (or mis-supported) features.
 124
 125 =item C<verb>
 126
 127 Messages output in C<--verbose> mode.  Use C<&verb> to send such messages.
 128
 129 =item C<note>
 130
 131 Informative messages.
 132
 133 =back
 134
 135 =cut
 136
 137 # Initialize our list of error/warning channels.
 138 # Do not forget to update &usage and the manual
 139 # if you add or change a warning channel.
 140
 141 register_channel 'fatal', type => 'fatal', uniq_part => UP_NONE, ordered => 0;
 142 register_channel 'error', type => 'error';
 143 register_channel 'error-gnu', type => 'error';
 144 register_channel 'error-gnu/warn', type => 'error';
 145 register_channel 'error-gnits', type => 'error', silent => 1;
 146 register_channel 'automake', type => 'fatal', backtrace => 1,
 147   header => ("####################\n" .
 148              "## Internal Error ##\n" .
 149              "####################\n"),
 150   footer => "\nPlease contact <bug-automake\@gnu.org>.",
 151   uniq_part => UP_NONE, ordered => 0;
 152
 153 register_channel 'gnu', type => 'warning';
 154 register_channel 'obsolete', type => 'warning', silent => 1;
 155 register_channel 'override', type => 'warning', silent => 1;
 156 register_channel 'portability', type => 'warning', silent => 1;
 157 register_channel 'portability-recursive', type => 'warning', silent => 1;
 158 register_channel 'syntax', type => 'warning';
 159 register_channel 'unsupported', type => 'warning';
 160
 161 register_channel 'verb', type => 'debug', silent => 1, uniq_part => UP_NONE,
 162   ordered => 0;
 163 register_channel 'note', type => 'debug', silent => 0;
 164
 165 =head2 FUNCTIONS
 166
 167 =over 4
 168
 169 =item C<usage ()>
 170
 171 Display warning categories.
 172
 173 =cut
 174
 175 sub usage ()
 176 {
 177   print "Warning categories include:
 178   `gnu'           GNU coding standards (default in gnu and gnits modes)
 179   `obsolete'      obsolete features or constructions
 180   `override'      user redefinitions of Automake rules or variables
 181   `portability'   portability issues (default in gnu and gnits modes)
 182   `syntax'        dubious syntactic constructs (default)
 183   `unsupported'   unsupported or incomplete features (default)
 184   `all'           all the warnings
 185   `no-CATEGORY'   turn off warnings in CATEGORY
 186   `none'          turn off all the warnings
 187   `error'         treat warnings as errors
 188 ";
 189 }
 190
 191 =item C<prog_error ($MESSAGE, [%OPTIONS])>
 192
 193 Signal a programming error (on channel C<automake>),
 194 display C<$MESSAGE>, and exit 1.
 195
 196 =cut
 197
 198 sub prog_error ($;%)
 199 {
 200   my ($msg, %opts) = @_;
 201   msg 'automake', '', $msg, %opts;
 202 }
 203
 204 =item C<error ($WHERE, $MESSAGE, [%OPTIONS])>
 205
 206 =item C<error ($MESSAGE)>
 207
 208 Uncategorized errors.
 209
 210 =cut
 211
 212 sub error ($;$%)
 213 {
 214   my ($where, $msg, %opts) = @_;
 215   msg ('error', $where, $msg, %opts);
 216 }
 217
 218 =item C<fatal ($WHERE, $MESSAGE, [%OPTIONS])>
 219
 220 =item C<fatal ($MESSAGE)>
 221
 222 Fatal errors.
 223
 224 =cut
 225
 226 sub fatal ($;$%)
 227 {
 228   my ($where, $msg, %opts) = @_;
 229   msg ('fatal', $where, $msg, %opts);
 230 }
 231
 232 =item C<verb ($MESSAGE, [%OPTIONS])>
 233
 234 C<--verbose> messages.
 235
 236 =cut
 237
 238 sub verb ($;%)
 239 {
 240   my ($msg, %opts) = @_;
 241   $msg = "thread " . threads->tid . ": " . $msg
 242     if $perl_threads;
 243   msg 'verb', '', $msg, %opts;
 244 }
 245
 246 =item C<switch_warning ($CATEGORY)>
 247
 248 If C<$CATEGORY> is C<mumble>, turn on channel C<mumble>.
 249 If it's C<no-mumble>, turn C<mumble> off.
 250 Else handle C<all> and C<none> for completeness.
 251
 252 =cut
 253
 254 sub switch_warning ($)
 255 {
 256   my ($cat) = @_;
 257   my $has_no = 0;
 258
 259   if ($cat =~ /^no-(.*)$/)
 260     {
 261       $cat = $1;
 262       $has_no = 1;
 263     }
 264
 265   if ($cat eq 'all')
 266     {
 267       setup_channel_type 'warning', silent => $has_no;
 268     }
 269   elsif ($cat eq 'none')
 270     {
 271       setup_channel_type 'warning', silent => ! $has_no;
 272     }
 273   elsif ($cat eq 'error')
 274     {
 275       $warnings_are_errors = ! $has_no;
 276       # Set exit code if Perl warns about something
 277       # (like uninitialized variables).
 278       $SIG{"__WARN__"} =
 279         $has_no ? 'DEFAULT' : sub { print STDERR @_; $exit_code = 1; };
 280     }
 281   elsif (channel_type ($cat) eq 'warning')
 282     {
 283       setup_channel $cat, silent => $has_no;
 284       setup_channel 'portability-recursive', silent => $has_no
 285         if $cat eq 'portability';
 286     }
 287   else
 288     {
 289       return 1;
 290     }
 291   return 0;
 292 }
 293
 294 =item C<parse_WARNINGS ()>
 295
 296 Parse the WARNINGS environment variable.
 297
 298 =cut
 299
 300 sub parse_WARNINGS ()
 301 {
 302   if (exists $ENV{'WARNINGS'})
 303     {
 304       # Ignore unknown categories.  This is required because WARNINGS
 305       # should be honored by many tools.
 306       switch_warning $_ foreach (split (',', $ENV{'WARNINGS'}));
 307     }
 308 }
 309
 310 =item C<parse_warning ($OPTION, $ARGUMENT)>
 311
 312 Parse the argument of C<--warning=CATEGORY> or C<-WCATEGORY>.
 313
 314 C<$OPTIONS> is C<"--warning"> or C<"-W">, C<$ARGUMENT> is C<CATEGORY>.
 315
 316 This is meant to be used as an argument to C<Getopt>.
 317
 318 =cut
 319
 320 sub parse_warnings ($$)
 321 {
 322   my ($opt, $categories) = @_;
 323
 324   foreach my $cat (split (',', $categories))
 325     {
 326       msg 'unsupported', "unknown warning category `$cat'"
 327         if switch_warning $cat;
 328     }
 329 }
 330
 331 =item C<set_strictness ($STRICTNESS_NAME)>
 332
 333 Configure channels for strictness C<$STRICTNESS_NAME>.
 334
 335 =cut
 336
 337 sub set_strictness ($)
 338 {
 339   my ($name) = @_;
 340
 341   if ($name eq 'gnu')
 342     {
 343       setup_channel 'error-gnu', silent => 0;
 344       setup_channel 'error-gnu/warn', silent => 0, type => 'error';
 345       setup_channel 'error-gnits', silent => 1;
 346       setup_channel 'portability', silent => 0;
 347       setup_channel 'gnu', silent => 0;
 348     }
 349   elsif ($name eq 'gnits')
 350     {
 351       setup_channel 'error-gnu', silent => 0;
 352       setup_channel 'error-gnu/warn', silent => 0, type => 'error';
 353       setup_channel 'error-gnits', silent => 0;
 354       setup_channel 'portability', silent => 0;
 355       setup_channel 'gnu', silent => 0;
 356     }
 357   elsif ($name eq 'foreign')
 358     {
 359       setup_channel 'error-gnu', silent => 1;
 360       setup_channel 'error-gnu/warn', silent => 0, type => 'warning';
 361       setup_channel 'error-gnits', silent => 1;
 362       setup_channel 'portability', silent => 1;
 363       setup_channel 'gnu', silent => 1;
 364     }
 365   else
 366     {
 367       prog_error "level `$name' not recognized\n";
 368     }
 369 }
 370
 371 =back
 372
 373 =head1 SEE ALSO
 374
 375 L<Automake::Channels>
 376
 377 =head1 HISTORY
 378
 379 Written by Alexandre Duret-Lutz E<lt>F<adl@gnu.org>E<gt>.
 380
 381 =cut
 382
 383 ### Setup "GNU" style for perl-mode and cperl-mode.
 384 ## Local Variables:
 385 ## perl-indent-level: 2
 386 ## perl-continued-statement-offset: 2
 387 ## perl-continued-brace-offset: 0
 388 ## perl-brace-offset: 0
 389 ## perl-brace-imaginary-offset: 0
 390 ## perl-label-offset: -2
 391 ## cperl-indent-level: 2
 392 ## cperl-brace-offset: 0
 393 ## cperl-continued-brace-offset: 0
 394 ## cperl-label-offset: -2
 395 ## cperl-extra-newline-before-brace: t
 396 ## cperl-merge-trailing-else: nil
 397 ## cperl-continued-statement-offset: 2
 398 ## End: