release/src-rt-6.x.4708/toolchains/hndtools-arm-linux-2.6.36-uclibc-4.5.3/share/aclocal-1.11/silent.m4

   1 ##                                                          -*- Autoconf -*-
   2 # Copyright (C) 2009  Free Software Foundation, Inc.
   3 #
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # serial 1
   9
  10 # AM_SILENT_RULES([DEFAULT])
  11 # --------------------------
  12 # Enable less verbose build rules; with the default set to DEFAULT
  13 # (`yes' being less verbose, `no' or empty being verbose).
  14 AC_DEFUN([AM_SILENT_RULES],
  15 [AC_ARG_ENABLE([silent-rules],
  16 [  --enable-silent-rules          less verbose build output (undo: `make V=1')
  17   --disable-silent-rules         verbose build output (undo: `make V=0')])
  18 case $enable_silent_rules in
  19 yes) AM_DEFAULT_VERBOSITY=0;;
  20 no)  AM_DEFAULT_VERBOSITY=1;;
  21 *)   AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
  22 esac
  23 AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
  24 AM_BACKSLASH='\'
  25 AC_SUBST([AM_BACKSLASH])dnl
  26 _AM_SUBST_NOTMAKE([AM_BACKSLASH])dnl
  27 ])