release/src-rt-6.x.4708/toolchains/hndtools-arm-linux-2.6.36-uclibc-4.5.3/share/aclocal-1.11/cond.m4

   1 # AM_CONDITIONAL                                            -*- Autoconf -*-
   2
   3 # Copyright (C) 1997, 2000, 2001, 2003, 2004, 2005, 2006, 2008
   4 # Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 # serial 9
  11
  12 # AM_CONDITIONAL(NAME, SHELL-CONDITION)
  13 # -------------------------------------
  14 # Define a conditional.
  15 AC_DEFUN([AM_CONDITIONAL],
  16 [AC_PREREQ(2.52)dnl
  17  ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
  18         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
  19 AC_SUBST([$1_TRUE])dnl
  20 AC_SUBST([$1_FALSE])dnl
  21 _AM_SUBST_NOTMAKE([$1_TRUE])dnl
  22 _AM_SUBST_NOTMAKE([$1_FALSE])dnl
  23 m4_define([_AM_COND_VALUE_$1], [$2])dnl
  24 if $2; then
  25   $1_TRUE=
  26   $1_FALSE='#'
  27 else
  28   $1_TRUE='#'
  29   $1_FALSE=
  30 fi
  31 AC_CONFIG_COMMANDS_PRE(
  32 [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
  33   AC_MSG_ERROR([[conditional "$1" was never defined.
  34 Usually this means the macro was only invoked conditionally.]])
  35 fi])])