release/src-rt-6.x.4708/cfe/cfe/arch/mips/common/src/cfe_ldscript.template

   1 /*
   2  * This is the "template" linker script.  It gets run through the C preprocessor
   3  * (via cpp) to construct the real linker script.
   4  */
   5
   6 /* our toolchain defines 'mips'.  Undefine it so it doesn't get expanded */
   7 #undef mips
   8
   9 OUTPUT_ARCH(mips)
  10 ENTRY(vec_reset)
  11 SECTIONS
  12 {
  13   . = CFE_TEXT_START;
  14   .text :
  15
  16 /*
  17  * Neither RAMAPP (CFE as app) nor BOOTRAM (ROM area is writeable) implies
  18  * a boot ROM.
  19  */
  20
  21 #if (!CFG_RAMAPP) && !(CFG_BOOTRAM)
  22    AT ( CFE_ROM_START )
  23 #endif
  24    {
  25      _ftext = . ;
  26     *(.init)
  27      eprol  =  .;
  28     *(.text)
  29
  30 /*
  31  * Embedded PIC mode provides an extra segment of goo for relocation tables.
  32  */
  33 #if CFG_EMBEDDED_PIC
  34     PROVIDE (__runtime_reloc_start = .);
  35     *(.rel.sdata)
  36     PROVIDE (__runtime_reloc_stop = .);
  37 #endif
  38 /*
  39  * When using function-sections, each fucntion has its own section with
  40  * a name like .text.myfunction.
  41  */
  42     *(.text.*)
  43     *(.fini)
  44     *(.rodata)
  45     *(.rodata.*)
  46      _etext  =  .;
  47    }
  48
  49 /*
  50  * If ROM, locate a copy of the data segment in the ROM area.  Otherwise,
  51  * we are loading like a regular application so take data segment from
  52  * current value of "dot".
  53  */
  54 #if (CFG_XIP)
  55   .data CFE_DATA_START :
  56     AT ( LOADADDR(.text) + SIZEOF ( .text ) )
  57 #elif ((!CFG_RAMAPP) && (!CFG_BOOTRAM))
  58   .data CFE_DATA_START :
  59     AT ( (LOADADDR(.text) + SIZEOF ( .text ) + 15) & 0xFFFFFFF0)
  60 #else
  61   .data :
  62 #endif
  63   {
  64     _gp = ALIGN(16) + 0x8000;
  65     _fdata = .;
  66     *(.rdata)
  67     *(.data)
  68     CONSTRUCTORS
  69     *(.sdata)
  70   }
  71    . = ALIGN(16);
  72    _edata  =  .;
  73    _fbss = .;
  74   .sbss : {
  75     *(.sbss)
  76     *(.scommon)
  77   }
  78   .bss : {
  79     *(.bss)
  80     *(COMMON)
  81   }
  82   . = ALIGN(16);
  83    _end = .;
  84 }