release/src-rt-6.x.4708/cfe/cfe/arch/mips/board/c3/src/c3_init.S

   1 /*  *********************************************************************
   2     *  SB1250 Board Support Package
   3     *
   4     *  Board-specific initialization            File: C3_INIT.S
   5     *
   6     *  This module contains the assembly-language part of the init
   7     *  code for this board support package.  The routine
   8     *  "board_earlyinit" lives here.
   9     *
  10     *  Author:  Mitch Lichtenberg (mpl@broadcom.com)
  11     *
  12     *********************************************************************
  13     *
  14     *  Copyright 2000,2001,2002,2003
  15     *  Broadcom Corporation. All rights reserved.
  16     *
  17     *  This software is furnished under license and may be used and
  18     *  copied only in accordance with the following terms and
  19     *  conditions.  Subject to these conditions, you may download,
  20     *  copy, install, use, modify and distribute modified or unmodified
  21     *  copies of this software in source and/or binary form.  No title
  22     *  or ownership is transferred hereby.
  23     *
  24     *  1) Any source code used, modified or distributed must reproduce
  25     *     and retain this copyright notice and list of conditions
  26     *     as they appear in the source file.
  27     *
  28     *  2) No right is granted to use any trade name, trademark, or
  29     *     logo of Broadcom Corporation.  The "Broadcom Corporation"
  30     *     name may not be used to endorse or promote products derived
  31     *     from this software without the prior written permission of
  32     *     Broadcom Corporation.
  33     *
  34     *  3) THIS SOFTWARE IS PROVIDED "AS-IS" AND ANY EXPRESS OR
  35     *     IMPLIED WARRANTIES, INCLUDING BUT NOT LIMITED TO, ANY IMPLIED
  36     *     WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
  37     *     PURPOSE, OR NON-INFRINGEMENT ARE DISCLAIMED. IN NO EVENT
  38     *     SHALL BROADCOM BE LIABLE FOR ANY DAMAGES WHATSOEVER, AND IN
  39     *     PARTICULAR, BROADCOM SHALL NOT BE LIABLE FOR DIRECT, INDIRECT,
  40     *     INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  41     *     (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  42     *     GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  43     *     BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  44     *     OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  45     *     TORT (INCLUDING NEGLIGENCE OR OTHERWISE), EVEN IF ADVISED OF
  46     *     THE POSSIBILITY OF SUCH DAMAGE.
  47     ********************************************************************* */
  48
  49
  50 #include "sbmips.h"
  51 #include "sb1250_genbus.h"
  52 #include "sb1250_uart.h"
  53 #include "sb1250_regs.h"
  54 #include "bsp_config.h"
  55 #include "c3.h"
  56 #include "mipsmacros.h"
  57 #include "sb1250_draminit.h"
  58
  59                 .text
  60
  61 /*#define _SERIAL_PORT_LEDS_*/
  62
  63 /*  *********************************************************************
  64     *  Macros
  65     ********************************************************************* */
  66
  67
  68 /*  *********************************************************************
  69     *  BOARD_EARLYINIT()
  70     *
  71     *  Initialize board registers.  This is the earliest
  72     *  time the BSP gets control.  This routine cannot assume that
  73     *  memory is operational, and therefore all code in this routine
  74     *  must run from registers only.  The $ra register must not
  75     *  be modified, as it contains the return address.
  76     *
  77     *  This routine will be called from uncached space, before
  78     *  the caches are initialized.  If you want to make
  79     *  subroutine calls from here, you must use the CALLKSEG1 macro.
  80     *
  81     *  Among other things, this is where the GPIO registers get
  82     *  programmed to make on-board LEDs function, or other startup
  83     *  that has to be done before anything will work.
  84     *
  85     *  Input parameters:
  86     *      nothing
  87     *
  88     *  Return value:
  89     *      nothing
  90     ********************************************************************* */
  91
  92 LEAF(board_earlyinit)
  93
  94        #
  95        # Configure the GPIOs
  96        #
  97
  98                 li      t0,PHYS_TO_K1(A_GPIO_INT_TYPE)
  99                 li      t1,GPIO_INTERRUPT_MASK
 100                 sd      t1,0(t0)
 101
 102        #
 103        # Turn off the diagnostic LED.
 104        #
 105                 li      t0,PHYS_TO_K1(A_GPIO_PIN_CLR)
 106                 li      t1,M_GPIO_DEBUG_LED
 107                 sd      t1,0(t0)
 108
 109       #
 110       # Set the PGM_L pin to '1' to allow programming via JTAG
 111       #
 112
 113                 li      t0,PHYS_TO_K1(A_GPIO_PIN_SET)
 114                 li      t1,M_GPIO_XPROG_X_PGM_L
 115                 sd      t1,0(t0)
 116
 117       #
 118       # Set direction pin
 119       #
 120
 121
 122                 li      t0,PHYS_TO_K1(A_GPIO_DIRECTION)
 123                 li      t1,GPIO_OUTPUT_MASK
 124                 sd      t1,0(t0)
 125
 126
 127
 128        #
 129        # Configure the alternate boot ROM
 130        #
 131
 132                 li      t0,PHYS_TO_K1(A_IO_EXT_CS_BASE(ALT_BOOTROM_CS))
 133
 134                 li      t1,ALT_BOOTROM_PHYS >> S_IO_ADDRBASE
 135                 sd      t1,R_IO_EXT_START_ADDR(t0)
 136
 137                 li      t1,ALT_BOOTROM_SIZE-1
 138                 sd      t1,R_IO_EXT_MULT_SIZE(t0)
 139
 140                 li      t1,ALT_BOOTROM_TIMING0
 141                 sd      t1,R_IO_EXT_TIME_CFG0(t0)
 142
 143                 li      t1,ALT_BOOTROM_TIMING1
 144                 sd      t1,R_IO_EXT_TIME_CFG1(t0)
 145
 146                 li      t1,ALT_BOOTROM_CONFIG
 147                 sd      t1,R_IO_EXT_CFG(t0)
 148
 149        #
 150        # Configure the Xilinx
 151        #
 152
 153                 li      t0,PHYS_TO_K1(A_IO_EXT_CS_BASE(XILINX_CS))
 154
 155                 li      t1,XILINX_PHYS >> S_IO_ADDRBASE
 156                 sd      t1,R_IO_EXT_START_ADDR(t0)
 157
 158                 li      t1,XILINX_SIZE-1
 159                 sd      t1,R_IO_EXT_MULT_SIZE(t0)
 160
 161                 li      t1,XILINX_TIMING0
 162                 sd      t1,R_IO_EXT_TIME_CFG0(t0)
 163
 164                 li      t1,XILINX_TIMING1
 165                 sd      t1,R_IO_EXT_TIME_CFG1(t0)
 166
 167                 li      t1,XILINX_CONFIG
 168                 sd      t1,R_IO_EXT_CFG(t0)
 169
 170         #
 171         # Make sure that the mailbox register is cleared
 172         #
 173
 174                 li      t0,PHYS_TO_K1(A_IMR_REGISTER(0,R_IMR_MAILBOX_CLR_CPU))
 175                 nor     t1, zero, zero
 176                 sd      t1,(t0)
 177
 178 #ifdef _SERIAL_PORT_LEDS_
 179
 180         # Program the mode register for 8 bits/char, no parity
 181
 182                 li      t0,PHYS_TO_K1(A_DUART_MODE_REG_1_A)
 183                 li      t1,V_DUART_BITS_PER_CHAR_8 | V_DUART_PARITY_MODE_NONE
 184                 sd      t1,(t0)
 185
 186         # Program the mode register for 1 stop bit, ignore CTS
 187
 188                 li      t0,PHYS_TO_K1(A_DUART_MODE_REG_2_A)
 189                 li      t1,M_DUART_STOP_BIT_LEN_1
 190                 sd      t1,(t0)
 191
 192         # Program the baud rate to 115200
 193
 194                 li      t0,PHYS_TO_K1(A_DUART_CLK_SEL_A)
 195                 li      t1,V_DUART_BAUD_RATE(115200)
 196                 sd      t1,(t0)
 197
 198         # Dont use any interrupts
 199
 200                 li      t0,PHYS_TO_K1(A_DUART_IMR)
 201                 ld      t1,(t0)
 202                 and     t1,~M_DUART_IMR_ALL_A
 203                 sd      t1,(t0)
 204
 205         # Enable sending and receiving
 206
 207                 li      t0,PHYS_TO_K1(A_DUART_CMD_A)
 208                 li      t1,M_DUART_RX_EN | M_DUART_TX_EN
 209                 sd      t1,(t0)
 210
 211 #endif
 212
 213
 214                 j       ra
 215
 216 END(board_earlyinit)
 217
 218
 219 /*  *********************************************************************
 220     *  BOARD_DRAMINFO
 221     *
 222     *  Return the address of the DRAM information table
 223     *
 224     *  Input parameters:
 225     *      nothing
 226     *
 227     *  Return value:
 228     *      v0 - DRAM info table, return 0 to use default table
 229     ********************************************************************* */
 230
 231
 232 LEAF(board_draminfo)
 233
 234         #
 235         # This board has soldered-down memory.
 236         #
 237
 238                 move    t0,ra
 239
 240                 LOADREL(v0,dramtab)
 241
 242                 move    ra,t0
 243                 j       ra
 244
 245 dramtab:
 246
 247 #if defined(_C3_) || defined(_C3H_) || defined(_SIM_C3_)
 248
 249         /*
 250          * C3: SGRAMs and SDRAMs
 251          *
 252          * This board has soldered-down memory.
 253          */
 254
 255         DRAM_GLOBALS(MC_NOPORTINTLV)            /* no port interleaving */
 256
 257         /*
 258          * 16MB on MC 0 (SGRAM)
 259          * Micron MT46V2M32LG-65
 260          *
 261          * Minimum tMEMCLK: 8.0ns (125Mhz max freq)
 262          *
 263          * CS0 Geometry: 11 rows, 8 columns, 2 bankbits
 264          *
 265          * 128khz refresh, CAS Latency 3.0
 266          * Timing (ns):   tCK=7.50 tRAS=40 tRP=19.50 tRRD=13.0 tRCD=19.50 tRFC=66 tRC=59
 267          *
 268          * Clock Config: Addrskew 0x0F, DQOskew 0x08, DQIskew 0x08, addrdrive 0x07, datadrive 0x07, clockdrive 0x00
 269          */
 270
 271
 272         DRAM_CHAN_CFG(MC_CHAN0, DRT10(8,0), SGRAM, CASCHECK, BLKSIZE32, NOCSINTLV, CFG_DRAM_ECC, 0)
 273         DRAM_CHAN_CLKCFG(0x0F, 0x08, 0x08, 0x07, 0x07, 0x00)
 274
 275         DRAM_CS_GEOM(MC_CS0, 11, 8, 2)
 276         DRAM_CS_TIMING(DRT10(7,5), JEDEC_RFSH_128khz, JEDEC_CASLAT_30, 0,  40,  DRT4(19,50) ,DRT4(13,0),  DRT4(19,50),  66 , 59)
 277
 278         /*
 279          * 512MB on MC 1 (JEDEC SDRAM)
 280          * <<mfr name>>
 281          *
 282          * Minimum tMEMCLK: 8.0ns (125Mhz max freq)
 283          *
 284          * CS0 Geometry : 13 rows, 10 columns, 2 bankbits
 285          * CS1 Geometry : 13 rows, 10 columns, 2 bankbits
 286          *
 287          * 64khz refresh, CAS Latency 2.5
 288          * Timing (ns):   tCK=7.50 tRAS=45 tRP=20.0 tRRD=15.0 tRCD=20.0 tRFC=auto tRC=auto
 289          *
 290          * Clock Config: Default
 291          */
 292
 293
 294         DRAM_CHAN_CFG(MC_CHAN1, DRT10(8,0), JEDEC, CASCHECK, BLKSIZE32, NOCSINTLV, CFG_DRAM_ECC, 0)
 295         DRAM_CHAN_CLKCFG(0x0F, 0x08, 0x08, 0x0F, 0x0F, 0x00)
 296
 297         DRAM_CS_GEOM(MC_CS0, 13, 10, 2)
 298         DRAM_CS_TIMING(DRT10(7,5), JEDEC_RFSH_64khz, JEDEC_CASLAT_25, 0,  45,  DRT4(20,0) ,DRT4(15,0),  DRT4(20,0),  0,  0)
 299
 300         DRAM_CS_GEOM(MC_CS1, 13, 10, 2)
 301         DRAM_CS_TIMING(DRT10(7,5), JEDEC_RFSH_64khz, JEDEC_CASLAT_25, 0,  45,  DRT4(20,0) ,DRT4(15,0),  DRT4(20,0),  0,  0)
 302
 303         DRAM_EOT;
 304
 305
 306 #elif defined(_C3F_)
 307
 308         /*
 309          * C3F: SGRAMs and FCRAMs
 310          *
 311          * This board has soldered-down memory.
 312          */
 313
 314         DRAM_GLOBALS(MC_NOPORTINTLV)                    /* interleave not supported */
 315
 316         /*
 317          * 16MB on MC 0 (SGRAM)
 318          * Micron MT46V2M32LG-65
 319          *
 320          * Minimum tMEMCLK: 8.0ns (125Mhz max freq)
 321          *
 322          * CS0 Geometry: 11 rows, 8 columns, 2 bankbits
 323          *
 324          * 128khz refresh, CAS Latency 3.0
 325          * Timing (ns):   tCK=7.50 tRAS=40 tRP=19.50 tRRD=13.0 tRCD=19.50 tRFC=66 tRC=59
 326          *
 327          * Clock Config: Addrskew 0x0F, DQOskew 0x08, DQIskew 0x08, addrdrive 0x07, datadrive 0x07, clockdrive 0x00
 328          */
 329
 330         DRAM_CHAN_CFG(MC_CHAN0, DRT10(8,0), SGRAM, CASCHECK, BLKSIZE32, NOCSINTLV, CFG_DRAM_ECC, 0)
 331         DRAM_CHAN_CLKCFG(0x0F, 0x08, 0x08, 0x07, 0x07, 0x00)
 332
 333         DRAM_CS_GEOM(MC_CS0, 11, 8, 2)
 334         DRAM_CS_TIMING(DRT10(7,5), JEDEC_RFSH_128khz, JEDEC_CASLAT_30, 0,  40,  DRT4(19,50) ,DRT4(13,0),  DRT4(19,50),  66 , 59)
 335
 336         /*
 337          * 256MB on MC 1 (FCRAM)
 338          * Toshiba TC59LM806BFT-22
 339          *
 340          * Minimum tMEMCLK: 8.0ns (125Mhz max freq)
 341          *
 342          * CS0 Geometry : 15 rows, 8 columns, 2 bankbits
 343          *
 344          * 128khz refresh, CAS Latency 3.0
 345          * Timing (ns):   tCK=6.50 tRAS=26 tRP=6.50 tRRD=13.0 tRCD=6.50 tRFC=97 tRC=auto
 346          *
 347          * Clock Config: Addrskew 0x08, DQOskew 0x08, DQIskew 0x08, addrdrive 0x07, datadrive 0x07, clockdrive 0x07
 348          */
 349
 350         DRAM_CHAN_CFG(MC_CHAN1, DRT10(8,0), FCRAM, CLOSED, BLKSIZE32, NOCSINTLV, CFG_DRAM_ECC, 0)
 351         DRAM_CHAN_CLKCFG(0x08,0x08,0x08,0x07,0x07,0x07)
 352
 353         DRAM_CS_GEOM(MC_CS0, 15, 8, 2)
 354         DRAM_CS_TIMING(DRT10(6,5), JEDEC_RFSH_128khz, JEDEC_CASLAT_30, 0,  26,  DRT4(6,50) ,DRT4(13,0),  DRT4(6,50),  97 , 0)
 355
 356         DRAM_EOT;
 357 #else
 358 #error "Board type not defined"
 359 #endif
 360
 361
 362 END(board_draminfo)
 363
 364
 365
 366 /*  *********************************************************************
 367     *  BOARD_UARTA_TXCHAR
 368     *
 369     *  Transmit a single character via UART A
 370     *
 371     *  Input parameters:
 372     *      a0 - character to transmit (low-order 8 bits)
 373     *
 374     *  Return value:
 375     *      nothing
 376     *
 377     *  Registers used:
 378     *      t0,t1
 379     ********************************************************************* */
 380
 381 #ifdef _SERIAL_PORT_LEDS_
 382 LEAF(board_uarta_txchar)
 383
 384         # Wait until there is space in the transmit buffer
 385
 386 1:              li      t0,PHYS_TO_K1(A_DUART_STATUS_A)
 387                 ld      t1,(t0)                 # Get status bits
 388                 and     t1,M_DUART_TX_RDY       # test for ready
 389                 beq     t1,0,1b                 # keep going till ready
 390
 391         # Okay, now send the character.
 392
 393                 li      t0,PHYS_TO_K1(A_DUART_TX_HOLD_A)
 394                 sd      a0,(t0)
 395
 396         # done!
 397
 398                 j       ra
 399
 400 END(board_uarta_txchar)
 401 #endif
 402
 403 /*  *********************************************************************
 404     *  BOARD_SETLEDS(x)
 405     *
 406     *  Set LEDs for boot-time progress indication.  Not used if
 407     *  the board does not have progress LEDs.  This routine
 408     *  must not call any other routines, since it may be invoked
 409     *  either from KSEG0 or KSEG1 and it may be invoked
 410     *  whether or not the icache is operational.
 411     *
 412     *  Input parameters:
 413     *      a0 - LED value (8 bits per character, 4 characters)
 414     *
 415     *  Return value:
 416     *      nothing
 417     *
 418     *  Registers used:
 419     *      t0,t1,t2,t3
 420     ********************************************************************* */
 421
 422
 423 LEAF(board_setleds)
 424
 425 #ifdef _SERIAL_PORT_LEDS_
 426                 move    t3,ra
 427                 move    t2,a0
 428
 429                 li      a0,'['
 430                 bal     board_uarta_txchar
 431
 432                 move    a0,t2
 433                 rol     a0,8
 434                 bal     board_uarta_txchar
 435                 rol     a0,8
 436                 bal     board_uarta_txchar
 437                 rol     a0,8
 438                 bal     board_uarta_txchar
 439                 rol     a0,8
 440                 bal     board_uarta_txchar
 441
 442                 li      a0,']'
 443                 bal     board_uarta_txchar
 444
 445                 move    ra,t3
 446
 447 #endif
 448
 449                 j       ra
 450
 451 END(board_setleds)