release/src-rt-6.x/linux/linux-2.6/arch/mips/kernel/vmlinux.lds.S

   1 #include <asm/asm-offsets.h>
   2 #include <asm-generic/vmlinux.lds.h>
   3
   4 #undef mips
   5 #define mips mips
   6 OUTPUT_ARCH(mips)
   7 ENTRY(kernel_entry)
   8 jiffies = JIFFIES;
   9 SECTIONS
  10 {
  11 #ifdef CONFIG_BOOT_ELF64
  12   /* Read-only sections, merged into text segment: */
  13   /* . = 0xc000000000000000; */
  14
  15   /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
  16   /* . = 0xc00000000001c000; */
  17
  18   /* Set the vaddr for the text segment to a value
  19         >= 0xa800 0000 0001 9000 if no symmon is going to configured
  20         >= 0xa800 0000 0030 0000 otherwise  */
  21
  22   /* . = 0xa800000000300000; */
  23   /* . = 0xa800000000300000; */
  24   . = 0xffffffff80300000;
  25 #endif
  26   . = LOADADDR;
  27   /* read-only */
  28   _text = .;                    /* Text and read-only data */
  29   .text : {
  30     TEXT_TEXT
  31     SCHED_TEXT
  32     LOCK_TEXT
  33     *(.fixup)
  34     *(.gnu.warning)
  35   } =0
  36
  37   . = ALIGN(32);
  38   __fastpath_begin = .;
  39   .text.fastpath : { *(.text.fastpath) }
  40   __fastpath_end = .;
  41
  42   _etext = .;                   /* End of text section */
  43
  44   . = ALIGN(16);                /* Exception table */
  45   __start___ex_table = .;
  46   __ex_table : { *(__ex_table) }
  47   __stop___ex_table = .;
  48
  49   __start___dbe_table = .;      /* Exception table for data bus errors */
  50   __dbe_table : { *(__dbe_table) }
  51   __stop___dbe_table = .;
  52
  53   NOTES
  54
  55   RODATA
  56
  57   /* writeable */
  58   .data : {                     /* Data */
  59     . = . + DATAOFFSET;         /* for CONFIG_MAPPED_KERNEL */
  60     /*
  61      * This ALIGN is needed as a workaround for a bug a gcc bug upto 4.1 which
  62      * limits the maximum alignment to at most 32kB and results in the following
  63      * warning:
  64      *
  65      *  CC      arch/mips/kernel/init_task.o
  66      * arch/mips/kernel/init_task.c:30: warning: alignment of ‘init_thread_union’
  67      * is greater than maximum object file alignment.  Using 32768
  68      */
  69     . = ALIGN(_PAGE_SIZE);
  70     *(.data.init_task)
  71
  72     DATA_DATA
  73
  74     CONSTRUCTORS
  75   }
  76   _gp = . + 0x8000;
  77   .lit8 : { *(.lit8) }
  78   .lit4 : { *(.lit4) }
  79   /* We want the small data sections together, so single-instruction offsets
  80      can access them all, and initialized data all before uninitialized, so
  81      we can shorten the on-disk segment size.  */
  82   .sdata     : { *(.sdata) }
  83
  84   . = ALIGN(_PAGE_SIZE);
  85   __nosave_begin = .;
  86   .data_nosave : { *(.data.nosave) }
  87   . = ALIGN(_PAGE_SIZE);
  88   __nosave_end = .;
  89
  90   . = ALIGN(32);
  91   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  92
  93   _edata =  .;                  /* End of data section */
  94
  95   /* will be freed after init */
  96   . = ALIGN(_PAGE_SIZE);                /* Init code and data */
  97   __init_begin = .;
  98   .init.text : {
  99         _sinittext = .;
 100         *(.init.text)
 101         _einittext = .;
 102   }
 103   .init.data : { *(.init.data) }
 104   . = ALIGN(16);
 105   __setup_start = .;
 106   .init.setup : { *(.init.setup) }
 107   __setup_end = .;
 108
 109   __initcall_start = .;
 110   .initcall.init : {
 111         INITCALLS
 112   }
 113   __initcall_end = .;
 114
 115   __con_initcall_start = .;
 116   .con_initcall.init : { *(.con_initcall.init) }
 117   __con_initcall_end = .;
 118   SECURITY_INIT
 119     /* .exit.text is discarded at runtime, not link time, to deal with
 120      references from .rodata */
 121   .exit.text : { *(.exit.text) }
 122   .exit.data : { *(.exit.data) }
 123 #if defined(CONFIG_BLK_DEV_INITRD)
 124   . = ALIGN(_PAGE_SIZE);
 125   __initramfs_start = .;
 126   .init.ramfs : { *(.init.ramfs) }
 127   __initramfs_end = .;
 128 #endif
 129   . = ALIGN(_PAGE_SIZE);
 130   __per_cpu_start = .;
 131   .data.percpu  : { *(.data.percpu) }
 132   __per_cpu_end = .;
 133   . = ALIGN(_PAGE_SIZE);
 134   __init_end = .;
 135   /* freed after init ends here */
 136
 137   __bss_start = .;              /* BSS */
 138   .sbss      : {
 139     *(.sbss)
 140     *(.scommon)
 141   }
 142   .bss : {
 143     *(.bss)
 144     *(COMMON)
 145   }
 146   __bss_stop = .;
 147
 148   _end = . ;
 149
 150   /* Sections to be discarded */
 151   /DISCARD/ : {
 152         *(.exitcall.exit)
 153
 154         /* ABI crap starts here */
 155         *(.comment)
 156         *(.MIPS.options)
 157         *(.note)
 158         *(.options)
 159         *(.pdr)
 160         *(.reginfo)
 161         *(.mdebug*)
 162   }
 163
 164   /* This is the MIPS specific mdebug section.  */
 165   .mdebug : { *(.mdebug) }
 166
 167   STABS_DEBUG
 168
 169   DWARF_DEBUG
 170
 171   /* These must appear regardless of  .  */
 172   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
 173   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
 174   .note : { *(.note) }
 175 }