configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   5 # Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 AC_INIT([GNU tar], [1.26.90], [bug-tar@gnu.org])
  23 AC_CONFIG_SRCDIR([src/tar.c])
  24 AC_CONFIG_AUX_DIR([build-aux])
  25 AC_CONFIG_HEADERS([config.h])
  26 AC_PREREQ([2.63])
  27 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-xz dist-shar std-options silent-rules])
  28
  29 # Enable silent rules by default:
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_CC
  33 AC_EXEEXT
  34 AC_PROG_RANLIB
  35 AC_PROG_YACC
  36 gl_EARLY
  37
  38 AC_SYS_LARGEFILE
  39 AC_ISC_POSIX
  40 AC_C_INLINE
  41
  42 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  43   sgtty.h string.h \
  44   sys/param.h sys/device.h sys/gentape.h \
  45   sys/inet.h sys/io/trioctl.h \
  46   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  47   unistd.h locale.h)
  48
  49 AC_CHECK_HEADERS([sys/buf.h], [], [],
  50 [#if HAVE_SYS_PARAM_H
  51 #include <sys/param.h>
  52 #endif])
  53
  54 AC_HEADER_SYS_WAIT
  55
  56 AC_HEADER_DIRENT
  57 AC_HEADER_MAJOR
  58 AC_HEADER_STAT
  59 AC_HEADER_STDC
  60
  61 AC_MSG_CHECKING([for st_fstype string in struct stat])
  62 AC_CACHE_VAL(diff_cv_st_fstype_string,
  63   [AC_TRY_COMPILE([#include <sys/types.h>
  64 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  65    diff_cv_st_fstype_string=yes,
  66    diff_cv_st_fstype_string=no)])
  67 AC_MSG_RESULT($diff_cv_st_fstype_string)
  68 if test $diff_cv_st_fstype_string = yes; then
  69   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  70     [Define if struct stat has a char st_fstype[] member.])
  71 fi
  72
  73 AC_TYPE_SIGNAL
  74 AC_TYPE_MODE_T
  75 AC_TYPE_PID_T
  76 AC_TYPE_OFF_T
  77 AC_TYPE_SIZE_T
  78 AC_TYPE_UID_T
  79 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  80                                    [Type of major device numbers.]))
  81 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  82                                    [Type of minor device numbers.]))
  83 AC_CHECK_TYPE(dev_t, unsigned)
  84 AC_CHECK_TYPE(ino_t, unsigned)
  85
  86 gt_TYPE_SSIZE_T
  87
  88 # gnulib modules
  89 gl_INIT
  90 # paxutils modules
  91 tar_PAXUTILS
  92
  93 TAR_HEADERS_ATTR_XATTR_H
  94
  95 AC_CHECK_FUNCS_ONCE([fchmod fchown fsync lstat mkfifo readlink symlink])
  96
  97 # we use gnulib's acl.h - because of very useful file_has_acl() function.  M4
  98 # file from gnulib/acl does a quite good job of course.  The problem is that
  99 # this function works on wide list of platforms and we need to restrict tar to
 100 # use POSIX.1e ACLs only.
 101 AC_ARG_WITH([posix-acls],
 102     AS_HELP_STRING([--without-posix-acls],
 103                    [do not use POSIX.1e access control lists]),
 104     [with_posix_acls=no])
 105 AC_CHECK_HEADERS(sys/acl.h,, [with_posix_acl=no])
 106 AC_SEARCH_LIBS([acl_get_file],  [acl pacl],, [with_posix_acl=no])
 107 AC_SEARCH_LIBS([acl_get_fd],    [acl pacl],, [with_posix_acl=no])
 108 AC_SEARCH_LIBS([acl_set_file],  [acl pacl],, [with_posix_acl=no])
 109 AC_SEARCH_LIBS([acl_set_fd],    [acl pacl],, [with_posix_acl=no])
 110 AC_SEARCH_LIBS([acl_to_text],   [acl pacl],, [with_posix_acl=no])
 111 AC_SEARCH_LIBS([acl_from_text], [acl pacl],, [with_posix_acl=no])
 112 if test "x$with_posix_acls" != xno; then
 113   AC_DEFINE(HAVE_POSIX_ACLS,,[Define when we have working POSIX acls])
 114 fi
 115
 116 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 117 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 118 AC_CHECK_DECLS([time],,, [#include <time.h>])
 119
 120 AC_REPLACE_FUNCS(waitpid)
 121
 122 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 123   [if test -n "$RSH"; then
 124     tar_cv_path_RSH=$RSH
 125   else
 126     tar_cv_path_RSH=no
 127     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 128         /usr/bin/nsh /usr/bin/rcmd
 129     do
 130       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 131       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 132       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 133       if test -f $ac_file; then
 134         if (test -h $ac_file) 2>/dev/null; then
 135           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 136         else
 137           tar_cv_path_RSH=$ac_file
 138           break
 139         fi
 140       fi
 141     done
 142   fi])
 143 if test $tar_cv_path_RSH = no; then
 144   AC_CHECK_HEADERS(netdb.h)
 145 else
 146   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 147     [Define to the full path of your rsh, if any.])
 148 fi
 149
 150 TAR_COMPR_PROGRAM(compress)
 151 TAR_COMPR_PROGRAM(gzip)
 152 TAR_COMPR_PROGRAM(bzip2)
 153 TAR_COMPR_PROGRAM(lzip)
 154 TAR_COMPR_PROGRAM(lzma)
 155 TAR_COMPR_PROGRAM(lzop)
 156 TAR_COMPR_PROGRAM(xz)
 157
 158 AC_MSG_CHECKING(for default archive format)
 159
 160 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 161            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 162
 163 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 164   DEFAULT_ARCHIVE_FORMAT="GNU"
 165 fi
 166 case $DEFAULT_ARCHIVE_FORMAT in
 167   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 168   *) AC_MSG_ERROR(Invalid format name);;
 169 esac
 170 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 171   [By default produce archives of this format])
 172 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 173
 174 AC_MSG_CHECKING(for default archive)
 175
 176 AC_ARG_VAR([DEFAULT_ARCHIVE],
 177            [Set the name of the default archive (default: -)])
 178 if test -z "$DEFAULT_ARCHIVE"; then
 179   DEFAULT_ARCHIVE=-
 180 else
 181   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 182     AC_MSG_WARN(DEFAULT_ARCHIVE '$DEFAULT_ARCHIVE' not found on this system)
 183   fi
 184   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 185   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 186   # FIXME: Rearrange, here.
 187   case $DEFAULT_ARCHIVE in
 188     *[[0-7][lmh]])
 189       AC_DEFINE(DENSITY_LETTER, 1,
 190         [Define to 1 if density may be indicated by [lmh] at end of device.])
 191       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 192       ;;
 193     *[[0-7]])
 194       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 195       ;;
 196     *)
 197       device_prefix=
 198       ;;
 199   esac
 200   case "$device_prefix" in
 201     ?*)
 202       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 203         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 204       ;;
 205   esac
 206 fi
 207 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 208   [Define to a string giving the full name of the default archive file.])
 209 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 210
 211 AC_ARG_VAR([DEFAULT_BLOCKING],
 212            [Define default blocking factor (default: 20)])
 213 AC_MSG_CHECKING(for default blocking)
 214 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 215 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 216   [Define to a number giving the default blocking size for archives.])
 217 AC_MSG_RESULT($DEFAULT_BLOCKING)
 218
 219 AC_MSG_CHECKING(for default quoting style)
 220
 221 m4_define([QUOTING_STYLES],dnl
 222           [literal|shell|shell-always|c|escape|locale|clocale])
 223 DEFAULT_QUOTING_STYLE="escape"
 224 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 225            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 226
 227 case $DEFAULT_QUOTING_STYLE in
 228 QUOTING_STYLES) ;;
 229 *)  AC_MSG_ERROR(Invalid quoting style);;
 230 esac
 231 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 232 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 233 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 234   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 235
 236 # Iconv
 237 AM_ICONV
 238 AC_CHECK_HEADERS(iconv.h)
 239 AC_CHECK_TYPE(iconv_t,:,
 240               AC_DEFINE(iconv_t, int,
 241                         [Conversion descriptor type]),
 242               [
 243 #ifdef HAVE_ICONV_H
 244 # include <iconv.h>
 245 #endif
 246 ])
 247
 248 # Gettext.
 249 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 250 AM_GNU_GETTEXT_VERSION([0.16])
 251
 252 # Initialize the test suite.
 253 AC_CONFIG_TESTDIR(tests)
 254 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 255 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 256
 257 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 258 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 259 AC_ARG_ENABLE(backup-scripts,
 260               AC_HELP_STRING([--enable-backup-scripts],
 261                              [Create and install backup and restore scripts]),
 262               [case $enableval in
 263                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 264                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 265                     ;;
 266                esac])
 267
 268 AC_SUBST(BACKUP_SED_COND)
 269 if date +%Y-%m-%d 2>/dev/null >&2; then
 270         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 271 else
 272         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 273 fi
 274
 275 AC_OUTPUT([Makefile\
 276            doc/Makefile\
 277            gnu/Makefile\
 278            lib/Makefile\
 279            po/Makefile.in\
 280            scripts/Makefile\
 281            rmt/Makefile\
 282            src/Makefile])