configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
   4 dnl long enough, that we might as well just require that.
   5 AC_PREREQ(2.59)
   6 AC_INIT([survex], [1.2.32], [https://trac.survex.com/])
   7 AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
   8 RELEASE=1
   9
  10 AC_SUBST(RELEASE)
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_SRCDIR([src/aven.cc])
  13
  14 COPYRIGHT_MSG="Copyright (C) 1990-2017 Olly Betts"
  15 AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
  16
  17 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
  18 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
  19                    [Copyright Message for Aven])
  20
  21 AC_SUBST(COPYRIGHT_MSG)
  22 AC_SUBST(AVEN_COPYRIGHT_MSG)
  23
  24 COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
  25 AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
  26
  27 AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
  28                    [Copyright Message in UTF-8])
  29 AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
  30                    [Copyright Message for Aven in UTF-8])
  31
  32 dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
  33 PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
  34 AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
  35                    [Name of package (capitalised)])
  36 AC_SUBST(PRETTYPACKAGE)
  37
  38 dnl set COMMAVERSION to VERSION with the dots replaced by commas -
  39 dnl e.g. "0,99" or "1,0,22"
  40 COMMAVERSION=`echo "$VERSION"|tr '.' ','`
  41 AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
  42                    [Version number of package (comma-separated)])
  43 AC_SUBST(COMMAVERSION)
  44
  45 PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
  46 AC_ARG_ENABLE(docdir,
  47 [  --enable-docdir=DIR Set directory for installing documentation to DIR],
  48 [case $enableval in
  49  yes|no)
  50   AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
  51 esac
  52 PKGDOCDIR="$enableval"
  53 ]
  54 )
  55 PKGDOCDIR_EXPANDED=`(
  56  test NONE = "$prefix" && prefix="$ac_default_prefix"
  57  test NONE = "$exec_prefix" && exec_prefix="$prefix"
  58  eval echo "$PKGDOCDIR"
  59 )`
  60 AC_SUBST(PKGDOCDIR)
  61 AC_SUBST(PKGDOCDIR_EXPANDED)
  62
  63 AC_CANONICAL_HOST
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_PROG_CXX
  70 AC_PROG_CXXCPP
  71
  72 dnl Probe for any options needed to enable C++11 support.
  73 AX_CXX_COMPILE_STDCXX_11
  74
  75 AM_PROG_CC_C_O
  76
  77 AC_LANG_C
  78
  79 AC_C_INLINE
  80
  81 AC_EXEEXT
  82 AC_OBJEXT
  83
  84 mswindows=no
  85 macosx=no
  86 case $host_os in
  87 darwin*) macosx=yes ;;
  88 *mingw*|*cygwin*|windows*) mswindows=yes ;;
  89 esac
  90
  91 AC_C_BIGENDIAN
  92
  93 AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
  94 AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
  95
  96 AC_CHECK_LIB(m, sqrt)
  97
  98 AC_PATH_XTRA
  99
 100 OSPROGS=
 101 dnl AC_MSG_CHECKING([for OS-specific programs to build])
 102 dnl if test yes = "$mswindows"; then
 103 dnl   OSPROGS=
 104 dnl elif test yes = "$macosx"; then
 105 dnl   OSPROGS=
 106 dnl fi
 107 dnl AC_MSG_RESULT([${OSPROGS:-none}])
 108 AC_SUBST([OSPROGS])
 109
 110 dnl The wxWidgets libraries we need:
 111 wx_libs="core,gl,html"
 112
 113 AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
 114 AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
 115 : ${WX_CONFIG="$WXCONFIG"}
 116
 117 AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
 118 AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
 119
 120 if test -n "$WX_CONFIG" ; then
 121   dnl WX_CONFIG specified - sanity check the value
 122   dnl don't check for --ldflags - older wx-config didn't do that
 123   if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
 124     :
 125   else
 126     AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
 127   fi
 128 else
 129   if test yes = "$macosx" ; then
 130     wxdef=__WXMAC__
 131   elif test yes = "$mswindows" ; then
 132     wxdef=__WXMSW__
 133   else
 134     wxdef=__WXGTK__
 135   fi
 136   dnl See if wx-config exists and is for the correct version.
 137   dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
 138   dnl preference.
 139   AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config])
 140   if test -n "$WX_CONFIG" ; then
 141     if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
 142       :
 143     else
 144       AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
 145     fi
 146   else
 147     AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
 148   fi
 149 fi
 150
 151 dnl Unless the user has explicitly specified a --unicode setting, prefer
 152 dnl --unicode=yes if we can get it.
 153 case $WX_CONFIG in
 154   *--unicode=*) ;;
 155   *)
 156     if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
 157       WX_CONFIG="$WX_CONFIG --unicode=yes"
 158     elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
 159       WX_CONFIG="$WX_CONFIG --unicode=no"
 160     fi ;;
 161 esac
 162
 163 WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
 164 dnl Needed for nvidia drivers on linux (for some setups anyway).
 165 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
 166 dnl We use functions from libGLU so always link -lGLU explicitly if it's
 167 dnl present.
 168 AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
 169 dnl We use functions from libGL so always link -lGL explicitly if it's
 170 dnl present.
 171 AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
 172 AC_SUBST(WX_LIBS)
 173 dnl Mac OS X has OpenGL/gl.h.
 174 AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
 175 dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
 176 AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
 177
 178 dnl Older wx-config didn't support --ldflags (2.6.3 doesn't), and neither do
 179 dnl newer ones (3.0.1 doesn't) but presumably some in between did - error goes
 180 dnl to stderr, with nothing to stdout, so just ignore stderr.
 181 WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
 182 AC_SUBST(WX_LDFLAGS)
 183 WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
 184 AC_SUBST(WX_CFLAGS)
 185 WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
 186 AC_SUBST(WX_CXXFLAGS)
 187
 188 AC_LANG_C
 189 save_CFLAGS=$CFLAGS
 190 CFLAGS="$CFLAGS $WX_CFLAGS"
 191 AC_CHECK_SIZEOF([wxChar], [], [
 192   #include <wx/defs.h>
 193   #if wxCHECK_VERSION(2,9,0)
 194   #include <wx/chartype.h>
 195   #else
 196   #include <wx/wxchar.h>
 197   #endif
 198 ])
 199 CFLAGS=$save_CFLAGS
 200
 201 dnl Check for libav (FIXME: does our code still work with ffmpeg?)
 202 PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
 203   AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
 204   save_CXXFLAGS=$CXXFLAGS
 205   save_LIBS=$LIBS
 206   CFLAGS="$CFLAGS $LIBAV_CFLAGS"
 207   LIBS="$LIBS $LIBAV_LIBS"
 208   AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
 209   AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
 210   AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
 211   AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
 212   AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
 213   CXXFLAGS=$save_CXXFLAGS
 214   LIBS=$save_LIBS
 215 ], [
 216   dnl Build without movie export feature.
 217 ])
 218 AC_SUBST([LIBAV_LIBS])
 219 AC_SUBST([LIBAV_CFLAGS])
 220
 221 dnl Check for PROJ4
 222 PKG_CHECK_MODULES([PROJ], [proj], [
 223 ], [
 224   dnl pkg-config support in proj seems quite new, so probe directly if not
 225   dnl found.
 226   AC_CHECK_LIB([proj], [pj_init_plus], [
 227       PROJ_LIBS=-lproj
 228       PROJ_CFLAGS=
 229     ], [
 230       AC_MSG_ERROR([PROJ4 required for coordinate transformations])
 231     ])
 232 ])
 233 AC_SUBST([PROJ_LIBS])
 234 AC_SUBST([PROJ_CFLAGS])
 235
 236 dnl Checks for header files.
 237 AC_HEADER_STDC
 238 dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
 239 AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
 240
 241 dnl Checks for typedefs, structures, and compiler characteristics.
 242 AC_TYPE_SIZE_T
 243 AC_STRUCT_TM
 244 AC_TYPE_SIGNAL
 245
 246 dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
 247 dnl if it isn't, assume it is 1000000, as it is on SunOS 4
 248 AC_TRY_COMPILE([#include <time.h>],[
 249 #ifndef CLOCKS_PER_SEC
 250 choke me
 251 #endif
 252 ], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
 253
 254 dnl Check for 16-bit and 32-bit integer types.
 255 AC_TYPE_INT16_T
 256 AC_TYPE_INT32_T
 257
 258 dnl Checks for library functions.
 259 AC_FUNC_STRFTIME
 260 if test yes != "$ac_cv_func_strftime"; then
 261   AC_LIBOBJ(strftime)
 262 fi
 263 AC_FUNC_VPRINTF
 264 dnl Check if there's a declaration of lround().  Below we also check for
 265 dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
 266 dnl against.  Some platforms are missing a prototype for lround(), so
 267 dnl both checks are useful.
 268 AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
 269 dnl check for strcasecmp here as well as below - this one is to get
 270 dnl HAVE_STRCASECMP defined if appropriate (for img.c)
 271 AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot lstat mmap])
 272
 273 dnl difftime seems to be an ANSI invention
 274 AC_CHECK_FUNCS(difftime)
 275
 276 dnl Much faster than using getc()/putc(), at least on Linux.
 277 AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
 278
 279 AC_CHECK_FUNCS([setenv unsetenv])
 280
 281 dnl try to find a case-insensitive compare
 282
 283 strcasecmp=no
 284 dnl The order of these tests is important.
 285 AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
 286 if test no = "$strcasecmp"; then
 287   AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
 288 fi
 289 if test no = "$strcasecmp"; then
 290   AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
 291 fi
 292
 293 AC_MSG_CHECKING([how to compare strings ignoring case])
 294 case $strcasecmp in
 295 no)
 296   AC_LIBOBJ(strcasecmp)
 297   AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
 298 strcasecmp)
 299   AC_MSG_RESULT([strcasecmp]) ;;
 300 *)
 301   AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
 302     [strcasecmp define for systems which call it something else])
 303   AC_MSG_RESULT([$strcasecmp]) ;;
 304 esac
 305
 306 AC_MSG_CHECKING(for sgmltools v2 or v3)
 307 if test : != "$SGMLTOOLS" ; then
 308   : ${SGMLTOOLS=sgmltools}
 309   case `(exec 2>&5 ; $SGMLTOOLS --version)` in
 310   *" version 3"*)
 311     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 312   *" version 2"*)
 313     AC_MSG_RESULT([$SGMLTOOLS]) ;;
 314   *)
 315     SGMLTOOLS="$MISSING sgmltools"
 316     AC_MSG_RESULT(not found) ;;
 317   esac
 318 else
 319   AC_MSG_RESULT([$SGMLTOOLS])
 320 fi
 321 AC_SUBST(SGMLTOOLS)
 322 AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
 323
 324 AC_MSG_CHECKING(for docbook2man)
 325 if test : != "$DOCBOOK2MAN" ; then
 326   : ${DOCBOOK2MAN=docbook2man}
 327   $DOCBOOK2MAN 2> /dev/null
 328   if test $? = 1 ; then
 329     AC_MSG_RESULT([$DOCBOOK2MAN])
 330   else
 331     DOCBOOK2MAN="$MISSING docbook2man"
 332     AC_MSG_RESULT([not found])
 333   fi
 334 else
 335   AC_MSG_RESULT([$DOCBOOK2MAN])
 336 fi
 337 AC_SUBST(DOCBOOK2MAN)
 338 AC_ARG_VAR(DOCBOOK2MAN, [docbook2man command])
 339
 340 dnl extra warning flags for building with GCC
 341 if test yes = "$GCC"; then
 342   if test yes = "$cross_compiling"; then
 343 dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
 344 dnl      -Wwrite-strings -Wcast-align"
 345 dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
 346 dnl to disable it for mingw builds.
 347     AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
 348       -Wwrite-strings -Wcast-align"
 349     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
 350       -Wwrite-strings -Wcast-align -Wno-sign-compare"
 351   else
 352     AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 353       -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
 354       -Wcast-align"
 355     AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
 356       -Wwrite-strings -Wcast-align"
 357   fi
 358   dnl too many complaints from headers, etc: -Wconversion
 359 fi
 360 AC_SUBST(AM_CFLAGS)
 361 AC_SUBST(AM_CXXFLAGS)
 362
 363 dnl See if large file support is available.  Survex is unlikely to need to
 364 dnl process files > 2GB in size, but LFS is also needed for stat() to work
 365 dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
 366 AC_SYS_LARGEFILE
 367
 368 AC_ARG_ENABLE(profiling,
 369 [  --enable-profiling Build binaries to generate profiling information],
 370 [case $enableval in
 371   yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
 372        AM_CFLAGS="$AM_CFLAGS -pg"
 373        AC_MSG_RESULT(building binaries to generate profiling information);;
 374   no) ;;
 375   *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
 376 esac])
 377
 378 HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
 379 AC_SUBST(HTMLFILES)
 380
 381 EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
 382 AC_SUBST(EXTRA_TEXT)
 383
 384 AC_SUBST_FILE(DESC)
 385 DESC=desc.txt
 386 AC_SUBST_FILE(AVENDESC)
 387 AVENDESC=desc-aven.txt
 388
 389 dnl Don't define DATADIR if building for MS Windows - it won't be used, and
 390 dnl can conflict with the DATADIR typedef in objidl.h
 391 if test no = "$mswindows"; then
 392   AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
 393 fi
 394
 395 AH_BOTTOM(
 396 [/* Use getc_unlocked() and putc_unlocked() where available, since they are
 397  * faster, and we don't multithread file accesses.
 398  */
 399
 400 #ifdef HAVE_GETC_UNLOCKED
 401 # define GETC(F) getc_unlocked(F)
 402 #else
 403 # define GETC(F) getc(F)
 404 #endif
 405 #ifdef HAVE_PUTC_UNLOCKED
 406 # define PUTC(C, F) putc_unlocked(C, F)
 407 #else
 408 # define PUTC(C, F) putc(C, F)
 409 #endif
 410 ])
 411
 412 AC_CONFIG_FILES([
 413  Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
 414  lib/images/Makefile
 415  tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
 416  survex.spec lib/Info.plist
 417  ])
 418 AC_OUTPUT
 419 dnl FIXME update msvc makefile for 1.2 branch
 420 dnl src/msvc/config.h